push sheeet

pkgs/by-name/hm/hm/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  fetchpatch,
+  gitUpdater,
+  cmake,
+  llvmPackages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hm";
+  version = "18.0";
+
+  src = fetchFromGitLab {
+    domain = "vcgit.hhi.fraunhofer.de";
+    owner = "jvet";
+    repo = "HM";
+    tag = "HM-${finalAttrs.version}";
+    hash = "sha256-zWBwrnCNKi2sIopdu2XQj/7IoTsJQzlcIFNNKM0glDQ=";
+  };
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail "-msse4.1" ""
+  '';
+
+  cmakeFlags = [
+    (lib.cmakeBool "HIGH_BITDEPTH" true)
+  ];
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    llvmPackages.openmp
+  ];
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    [
+      "-Wno-error=array-bounds"
+    ]
+    ++ lib.optionals stdenv.cc.isClang [
+      "-Wno-error=bitwise-instead-of-logical"
+      "-Wno-error=missing-braces"
+      "-Wno-error=nontrivial-memcall"
+    ]
+  );
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm 755 -t $out/bin ../bin/umake/*/*/release/*
+
+    runHook postInstall
+  '';
+
+  strictDeps = true;
+
+  passthru = {
+    updateScript = gitUpdater { rev-prefix = "HM-"; };
+  };
+
+  meta = {
+    description = "Reference software for HEVC";
+    homepage = "https://vcgit.hhi.fraunhofer.de/jvet/HM";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ jopejoe1 ];
+  };
+})

pkgs/by-name/hm/hmat-oss/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  blas,
+  lapack,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hmat-oss";
+  version = "1.10.0";
+
+  src = fetchFromGitHub {
+    owner = "jeromerobert";
+    repo = "hmat-oss";
+    tag = finalAttrs.version;
+    hash = "sha256-GnFlvZCEzSCcBVLjFWLe+AKXVA6UMs/gycrOJ2TBqrE=";
+  };
+
+  cmakeFlags = [
+    "-DHMAT_GIT_VERSION=OFF"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    pkg-config # used to find the LAPACK
+  ];
+
+  buildInputs = [
+    blas
+    lapack
+  ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "Hierarchical matrix C/C++ library";
+    homepage = "https://github.com/jeromerobert/hmat-oss";
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ gdinh ];
+  };
+})

pkgs/by-name/hm/hmcl/package.nix

@@ -0,0 +1,137 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeDesktopItem,
+  wrapGAppsHook3,
+  copyDesktopItems,
+  imagemagick,
+  jdk,
+  jdk17,
+  jdk21,
+  hmclJdk ? jdk,
+  minecraftJdks ? [
+    jdk
+    jdk17
+    jdk21
+  ],
+  xorg,
+  glib,
+  libGL,
+  glfw,
+  openal,
+  libglvnd,
+  alsa-lib,
+  wayland,
+  vulkan-loader,
+  libpulseaudio,
+  gobject-introspection,
+  callPackage,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hmcl";
+  version = "3.6.18";
+
+  src = fetchurl {
+    # HMCL has built-in keys, such as the Microsoft OAuth secret and the CurseForge API key.
+    # See https://github.com/HMCL-dev/HMCL/blob/refs/tags/release-3.6.12/.github/workflows/gradle.yml#L26-L28
+    url = "https://github.com/HMCL-dev/HMCL/releases/download/release-${finalAttrs.version}/HMCL-${finalAttrs.version}.jar";
+    hash = "sha256-x8UcHdBYXdnTabJh2hxsknYipYNBJW2vKxJKHhryMLQ=";
+  };
+
+  icon = fetchurl {
+    url = "https://github.com/HMCL-dev/HMCL/raw/release-${finalAttrs.version}/HMCL/src/main/resources/assets/img/icon@8x.png";
+    hash = "sha256-1OVq4ujA2ZHboB7zEk7004kYgl9YcoM4qLq154MZMGo=";
+  };
+
+  dontUnpack = true;
+
+  dontWrapGApps = true;
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "HMCL";
+      exec = "hmcl";
+      icon = "hmcl";
+      comment = finalAttrs.meta.description;
+      desktopName = "HMCL";
+      categories = [ "Game" ];
+    })
+  ];
+
+  nativeBuildInputs = [
+    gobject-introspection
+    wrapGAppsHook3
+    copyDesktopItems
+    imagemagick
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{bin,lib/hmcl}
+    cp $src $out/lib/hmcl/hmcl.jar
+
+    for n in 16 32 48 64 96 128 256
+    do
+      size=$n"x"$n
+      mkdir -p $out/share/icons/hicolor/$size/apps
+      magick ${finalAttrs.icon} -resize $size $out/share/icons/hicolor/$size/apps/hmcl.png
+    done
+
+    runHook postInstall
+  '';
+
+  fixupPhase =
+    let
+      libpath = lib.makeLibraryPath (
+        [
+          libGL
+          glfw
+          glib
+          openal
+          libglvnd
+          vulkan-loader
+        ]
+        ++ lib.optionals stdenv.hostPlatform.isLinux [
+          xorg.libX11
+          xorg.libXxf86vm
+          xorg.libXext
+          xorg.libXcursor
+          xorg.libXrandr
+          xorg.libXtst
+          libpulseaudio
+          wayland
+          alsa-lib
+        ]
+      );
+    in
+    ''
+      runHook preFixup
+
+      makeBinaryWrapper ${hmclJdk}/bin/java $out/bin/hmcl \
+        --add-flags "-jar $out/lib/hmcl/hmcl.jar" \
+        --set LD_LIBRARY_PATH ${libpath} \
+        --prefix PATH : "${lib.makeBinPath minecraftJdks}"\
+        ''${gappsWrapperArgs[@]}
+
+      runHook postFixup
+    '';
+
+  passthru.updateScript = lib.getExe (callPackage ./update.nix { });
+
+  meta = {
+    homepage = "https://hmcl.huangyuhui.net";
+    description = "Minecraft Launcher which is multi-functional, cross-platform and popular";
+    changelog = "https://docs.hmcl.net/changelog/stable.html";
+    mainProgram = "hmcl";
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [
+      daru-san
+      moraxyc
+    ];
+    inherit (hmclJdk.meta) platforms;
+  };
+})

pkgs/by-name/hm/hmcl/update.nix

@@ -0,0 +1,40 @@
+{
+  writeShellApplication,
+  nix,
+  nix-update,
+  curl,
+  common-updater-scripts,
+  jq,
+}:
+
+writeShellApplication {
+  name = "update-hmcl";
+  runtimeInputs = [
+    curl
+    jq
+    nix
+    common-updater-scripts
+    nix-update
+  ];
+
+  text = ''
+    # get old info
+    oldVersion=$(nix-instantiate --eval --strict -A "hmcl.version" | jq -e -r)
+
+    get_latest_release() {
+        curl --fail ''${GITHUB_TOKEN:+ -H "Authorization: bearer $GITHUB_TOKEN"} \
+             -s "https://api.github.com/repos/HMCL-dev/HMCL/releases/latest" | jq -r ".tag_name"
+    }
+
+    version=$(get_latest_release)
+    version="''${version#release-}"
+
+    if [[ "$oldVersion" == "$version" ]]; then
+        echo "Already up to date!"
+        exit 0
+    fi
+
+    nix-update hmcl --version="$version"
+    update-source-version hmcl --source-key=icon --ignore-same-version
+  '';
+}

pkgs/by-name/hm/hmm/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  rustPlatform,
+  fetchCrate,
+  perl,
+  writableTmpDirAsHomeHook,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "hmm";
+  version = "0.6.0";
+
+  src = fetchCrate {
+    pname = "hmmcli";
+    inherit version;
+    hash = "sha256-WPePzqZ2iGeJ7kzTj8eg7q1JEjw91WY7gViJJ46SLRY=";
+  };
+
+  cargoHash = "sha256-wyuV+jWY7w4VDn314yRkqmeqgRijPb+XgmUiy73U3Zc=";
+
+  nativeCheckInputs = [
+    perl
+    writableTmpDirAsHomeHook
+  ];
+  # FIXME: remove patch when upstream version of rustc-serialize is updated
+  # https://github.com/NixOS/nixpkgs/pull/310673
+  cargoPatches = [ ./rustc-serialize-fix.patch ];
+
+  meta = {
+    description = "Small command-line note-taking app";
+    homepage = "https://github.com/samwho/hmm";
+    changelog = "https://github.com/samwho/hmm/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ figsoda ];
+  };
+}

pkgs/by-name/hm/hmm/rustc-serialize-fix.patch

@@ -0,0 +1,16 @@
+diff --git a/Cargo.lock b/Cargo.lock
+index b1cc23695b30..ffdeb1c90618 100644
+--- a/Cargo.lock
++++ b/Cargo.lock
+@@ -996,9 +996,9 @@ dependencies = [
+ 
+ [[package]]
+ name = "rustc-serialize"
+-version = "0.3.24"
++version = "0.3.25"
+ source = "registry+https://github.com/rust-lang/crates.io-index"
+-checksum = "dcf128d1287d2ea9d80910b5f1120d0b8eede3fbf1abe91c40d39ea7d51e6fda"
++checksum = "fe834bc780604f4674073badbad26d7219cadfb4a2275802db12cbae17498401"
+ 
+ [[package]]
+ name = "rustix"

pkgs/by-name/hm/hmmer/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  easel,
+  perl,
+  python3,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  version = "3.4";
+  pname = "hmmer";
+
+  src = fetchurl {
+    url = "http://eddylab.org/software/hmmer/hmmer-${finalAttrs.version}.tar.gz";
+    hash = "sha256-ynDZT9DPJxvXBjQjqrsRbULeUzEXNDqbJ6ZcF/8G+/M=";
+  };
+
+  enableParallelBuilding = true;
+
+  doCheck = true;
+
+  nativeCheckInputs = [
+    perl
+    python3
+  ];
+
+  preCheck = ''
+    install -Dm755 ${easel.src}/devkit/sqc easel/devkit/sqc
+    patchShebangs easel/devkit/sqc testsuite/* src/hmmpress.itest.pl
+  '';
+
+  doInstallCheck = true;
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  versionCheckProgram = "${placeholder "out"}/bin/hmmalign";
+
+  versionCheckProgramArg = "-h";
+
+  meta = {
+    description = "Biosequence analysis using profile hidden Markov models";
+    longDescription = ''
+      HMMER is used for searching sequence databases for sequence homologs, and for making sequence alignments. It implements methods using probabilistic models called profile hidden Markov models (profile HMMs).
+      HMMER is often used together with a profile database, such as Pfam or many of the databases that participate in Interpro. But HMMER can also work with query sequences, not just profiles, just like BLAST. For example, you can search a protein query sequence against a database with phmmer, or do an iterative search with jackhmmer.
+      HMMER is designed to detect remote homologs as sensitively as possible, relying on the strength of its underlying probability models. In the past, this strength came at significant computational expense, but as of the new HMMER3 project, HMMER is now essentially as fast as BLAST.
+      HMMER can be downloaded and installed as a command line tool on your own hardware, and now it is also more widely accessible to the scientific community via new search servers at the European Bioinformatics Institute.
+    '';
+    homepage = "http://hmmer.org/";
+    changelog = "https://github.com/EddyRivasLab/hmmer/blob/hmmer-${finalAttrs.version}/release-notes/RELEASE-${finalAttrs.version}.md";
+    license = lib.licenses.bsd3;
+    maintainers = [ lib.maintainers.iimog ];
+    platforms = lib.platforms.unix;
+  };
+})