push sheeet

pkgs/by-name/hp/hp2p/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  python3Packages,
+  autoconf,
+  automake,
+  mpi,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hp2p";
+  version = "4.2";
+
+  src = fetchFromGitHub {
+    owner = "cea-hpc";
+    repo = "hp2p";
+    tag = finalAttrs.version;
+    hash = "sha256-KuDf1VhLQRDDY3NZaNaHDVGipLmB8+1K36/W1fKnno0=";
+  };
+
+  enableParallelBuilding = true;
+  nativeBuildInputs = [
+    autoconf
+    automake
+    python3Packages.wrapPython
+  ];
+  buildInputs = [
+    mpi
+  ]
+  ++ (with python3Packages; [
+    python
+    plotly
+  ]);
+  pythonPath = (with python3Packages; [ plotly ]);
+
+  preConfigure = ''
+    patchShebangs autogen.sh
+    ./autogen.sh
+    export CC=mpicc
+    export CXX=mpic++
+  '';
+
+  postInstall = ''
+    wrapPythonPrograms
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "MPI based benchmark for network diagnostics";
+    homepage = "https://github.com/cea-hpc/hp2p";
+    changelog = "https://github.com/cea-hpc/hp2p/releases/tag/${finalAttrs.version}";
+    platforms = lib.platforms.unix;
+    license = lib.licenses.cecill-c;
+    maintainers = [ lib.maintainers.bzizou ];
+    mainProgram = "hp2p.exe";
+    badPlatforms = [
+      # hp2p_algo_cpp.cpp:38:10: error: no member named 'random_shuffle' in namespace 'std'
+      lib.systems.inspect.patterns.isDarwin
+    ];
+  };
+})

pkgs/by-name/hp/hpcg/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  mpi,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "hpcg";
+  version = "3.1";
+
+  src = fetchurl {
+    url = "http://www.hpcg-benchmark.org/downloads/hpcg-${version}.tar.gz";
+    sha256 = "197lw2nwmzsmfsbvgvi8z7kj69n374kgfzzp8pkmk7mp2vkk991k";
+  };
+
+  buildInputs = [ mpi ];
+
+  makeFlags = [ "arch=Linux_MPI" ];
+
+  enableParallelBuilding = true;
+
+  dontConfigure = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin $out/share/hpcg
+
+    cp bin/xhpcg $out/bin
+    cp bin/hpcg.dat $out/share/hpcg
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "HPC conjugate gradient benchmark";
+    homepage = "https://www.hpcg-benchmark.org";
+    platforms = platforms.linux;
+    license = licenses.bsd3;
+    maintainers = [ maintainers.markuskowa ];
+    mainProgram = "xhpcg";
+  };
+}

pkgs/by-name/hp/hpe-ltfs/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fuse,
+  icu66,
+  pkg-config,
+  libxml2,
+  libuuid,
+}:
+
+stdenv.mkDerivation rec {
+  version = "3.4.2_Z7550-02501";
+  pname = "hpe-ltfs";
+
+  src = fetchFromGitHub {
+    rev = version;
+    owner = "nix-community";
+    repo = "hpe-ltfs";
+    sha256 = "193593hsc8nf5dn1fkxhzs1z4fpjh64hdkc8q6n9fgplrpxdlr4s";
+  };
+
+  sourceRoot = "${src.name}/ltfs";
+
+  # include sys/sysctl.h is deprecated in glibc. The sysctl calls are only used
+  # for Apple to determine the kernel version. Because this build only targets
+  # Linux is it safe to remove.
+  patches = [ ./remove-sysctl.patch ];
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    fuse
+    icu66
+    libxml2
+    libuuid
+  ];
+
+  meta = with lib; {
+    description = "HPE's implementation of the open-source tape filesystem standard ltfs";
+    homepage = "https://support.hpe.com/hpesc/public/km/product/1009214665/Product";
+    license = licenses.lgpl21;
+    maintainers = [ maintainers.redvers ];
+    platforms = platforms.linux;
+    downloadPage = "https://github.com/nix-community/hpe-ltfs";
+  };
+}

pkgs/by-name/hp/hpe-ltfs/remove-sysctl.patch

@@ -0,0 +1,14 @@
+diff --git a/src/libltfs/arch/arch_info.c b/src/libltfs/arch/arch_info.c
+index 179428f..114acf0 100644
+--- a/src/libltfs/arch/arch_info.c
++++ b/src/libltfs/arch/arch_info.c
+@@ -47,9 +47,6 @@
+ */
+ 
+ #include "libltfs/ltfs.h"
+-#ifndef mingw_PLATFORM
+-#include <sys/sysctl.h>
+-#endif
+ #include <sys/types.h>
+ #include <sys/stat.h>
+ #include <unistd.h>

pkgs/by-name/hp/hping/package.nix

@@ -0,0 +1,69 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  libpcap,
+  withTcl ? true,
+  tcl,
+}:
+
+stdenv.mkDerivation {
+  pname = "hping";
+  version = "2014-12-26";
+
+  src = fetchFromGitHub {
+    owner = "antirez";
+    repo = "hping";
+    rev = "3547c7691742c6eaa31f8402e0ccbb81387c1b99"; # there are no tags/releases
+    sha256 = "0y0n1ybij3yg9lfgzcwfmjz1sjg913zcqrv391xx83dm0j80sdpb";
+  };
+  patches = [
+    # Pull patch pending upstream inclusion for -fno-common toolchain
+    # support: https://github.com/antirez/hping/pull/64
+    (fetchpatch {
+      name = "fno-common.patch";
+      url = "https://github.com/antirez/hping/pull/64/commits/d057b9309aec3a5a53aaee1ac3451a8a5b71b4e8.patch";
+      sha256 = "0bqr7kdlziijja588ipj8g5hv2109wq01c6x2qadbhjfnsps1b6l";
+    })
+  ];
+
+  buildInputs = [ libpcap ] ++ lib.optional withTcl tcl;
+
+  postPatch = ''
+    substituteInPlace Makefile.in --replace "gcc" "$CC"
+    substituteInPlace version.c --replace "RELEASE_DATE" "\"$version\""
+  ''
+  + lib.optionalString stdenv.hostPlatform.isLinux ''
+    sed -i -e 's|#include <net/bpf.h>|#include <pcap/bpf.h>|' \
+      libpcap_stuff.c script.c
+  ''
+  + lib.optionalString (stdenv.buildPlatform != stdenv.hostPlatform) ''
+    substituteInPlace configure --replace 'BYTEORDER=`./byteorder -m`' BYTEORDER=${
+      {
+        littleEndian = "__LITTLE_ENDIAN_BITFIELD";
+        bigEndian = "__BIG_ENDIAN_BITFIELD";
+      }
+      .${stdenv.hostPlatform.parsed.cpu.significantByte.name}
+    }
+    substituteInPlace Makefile.in --replace './hping3 -v' ""
+  '';
+
+  configureFlags = [ (if withTcl then "TCLSH=${tcl}/bin/tclsh" else "--no-tcl") ];
+
+  installPhase = ''
+    install -Dm755 hping3 -t $out/sbin
+    ln -s $out/sbin/hping3 $out/sbin/hping
+    ln -s $out/sbin/hping3 $out/sbin/hping2
+    install -Dm644 docs/hping3.8 -t $out/share/man/man8
+    ln -s hping3.8.gz $out/share/man/man8/hping.8.gz
+    ln -s hping3.8.gz $out/share/man/man8/hping2.8.gz
+  '';
+
+  meta = with lib; {
+    description = "Command-line oriented TCP/IP packet assembler/analyzer";
+    homepage = "https://github.com/antirez/hping";
+    license = licenses.gpl2Only;
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/hp/hpipm/package.nix

@@ -0,0 +1,41 @@
+{
+  blas,
+  blasfeo,
+  cmake,
+  fetchFromGitHub,
+  lib,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hpipm";
+  #version = "0.1.3";  not building, use master instead
+  version = "0.1.3-unstable-2025-07-25";
+
+  src = fetchFromGitHub {
+    owner = "giaf";
+    repo = "hpipm";
+    rev = "00c2a084e059e2e1b79877f668e282d0c4282110";
+    hash = "sha256-Lg7po7xTs9jc8FiYFMbNFJooTjOpzBFiyd5f+TPMWQA=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [
+    blas
+    blasfeo
+  ];
+
+  cmakeFlags = [
+    "-DHPIPM_FIND_BLASFEO=ON"
+    "-DBUILD_SHARED_LIBS=ON"
+  ]
+  ++ lib.optionals (!stdenv.hostPlatform.isx86_64) [ "-DTARGET=GENERIC" ];
+
+  meta = {
+    description = "High-performance interior-point-method QP and QCQP solvers";
+    homepage = "https://github.com/giaf/hpipm";
+    changelog = "https://github.com/giaf/hpipm/blob/${finalAttrs.src.rev}/Changelog.txt";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ nim65s ];
+  };
+})

pkgs/by-name/hp/hpl/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  blas,
+  lapack,
+  mpi,
+}:
+
+assert (!blas.isILP64) && (!lapack.isILP64);
+
+stdenv.mkDerivation rec {
+  pname = "hpl";
+  version = "2.3";
+
+  src = fetchurl {
+    url = "http://www.netlib.org/benchmark/hpl/hpl-${version}.tar.gz";
+    sha256 = "0c18c7fzlqxifz1bf3izil0bczv3a7nsv0dn6winy3ik49yw3i9j";
+  };
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    # only contains the static lib
+    rm -r $out/lib
+
+    install -D testing/ptest/HPL.dat $out/share/hpl/HPL.dat
+  '';
+
+  buildInputs = [
+    blas
+    lapack
+    mpi
+  ];
+
+  meta = with lib; {
+    description = "Portable Implementation of the Linpack Benchmark for Distributed-Memory Computers";
+    homepage = "http://www.netlib.org/benchmark/hpl/";
+    platforms = platforms.unix;
+    license = licenses.bsdOriginal;
+    maintainers = [ maintainers.markuskowa ];
+    mainProgram = "xhpl";
+  };
+}

pkgs/by-name/hp/hplip/hplip-3.20.11-nixos-cups-ppd-search-path.patch

@@ -0,0 +1,24 @@
+From: Bryan Gardiner <bog@khumba.net>
+Date: Sat, 9 Jan 2021 16:51:20 -0800
+Subject: [PATCH] Add NixOS CUPS PPD search path.
+
+---
+ base/g.py | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/base/g.py b/base/g.py
+index f73e23f..758f339 100644
+--- a/base/g.py
++++ b/base/g.py
+@@ -283,7 +283,7 @@ prop.max_message_len = 8192
+ prop.max_message_read = 65536
+ prop.read_timeout = 90
+ 
+-prop.ppd_search_path = '/usr/share;/usr/local/share;/usr/lib;/usr/local/lib;/usr/libexec;/opt;/usr/lib64'
++prop.ppd_search_path = '/var/lib/cups/path/share;/usr/share;/usr/local/share;/usr/lib;/usr/local/lib;/usr/libexec;/opt;/usr/lib64'
+ prop.ppd_search_pattern = 'HP-*.ppd.*'
+ prop.ppd_download_url = 'http://www.linuxprinting.org/ppd-o-matic.cgi'
+ prop.ppd_file_suffix = '-hpijs.ppd'
+-- 
+2.29.2
+

pkgs/by-name/hp/hplip/hplip.state

@@ -0,0 +1,4 @@
+[plugin]
+installed=1
+eula=1
+version=@version@

pkgs/by-name/hp/hplip/package.nix

@@ -0,0 +1,361 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  replaceVars,
+  pkg-config,
+  autoreconfHook,
+  gobject-introspection,
+  wrapGAppsHook3,
+  cups,
+  zlib,
+  libjpeg,
+  libusb1,
+  python3Packages,
+  sane-backends,
+  dbus,
+  file,
+  ghostscript,
+  usbutils,
+  net-snmp,
+  openssl,
+  perl,
+  net-tools,
+  avahi,
+  bash,
+  util-linux,
+  # To remove references to gcc-unwrapped
+  removeReferencesTo,
+  qt5,
+  withQt5 ? true,
+  withPlugin ? false,
+  withStaticPPDInstall ? false,
+}:
+
+let
+
+  pname = "hplip";
+  version = "3.25.2";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/hplip/${pname}-${version}.tar.gz";
+    hash = "sha256-6HL/KOslF3Balfbhg576HlCnejOq6JBSeN8r2CCRllM=";
+  };
+
+  plugin = fetchurl {
+    url = "https://www.openprinting.org/download/printdriver/auxfiles/HP/plugins/${pname}-${version}-plugin.run";
+    hash = "sha256-miz41WYehGVI27tZUjGlRIpctjcpzJPfjR9lLf0WelQ=";
+  };
+
+  hplipState = replaceVars ./hplip.state {
+    inherit version;
+  };
+
+  hplipPlatforms = {
+    i686-linux = "x86_32";
+    x86_64-linux = "x86_64";
+    armv6l-linux = "arm32";
+    armv7l-linux = "arm32";
+    aarch64-linux = "arm64";
+  };
+
+  hplipArch =
+    hplipPlatforms.${stdenv.hostPlatform.system}
+      or (throw "HPLIP not supported on ${stdenv.hostPlatform.system}");
+
+  pluginArches = [
+    "x86_32"
+    "x86_64"
+    "arm32"
+    "arm64"
+  ];
+
+in
+
+python3Packages.buildPythonApplication {
+  inherit pname version;
+  format = "other";
+
+  srcs = [ src ] ++ lib.optional withPlugin plugin;
+
+  unpackCmd = lib.optionalString withPlugin ''
+    if ! [[ "$curSrc" =~ -plugin\.run$ ]]; then return 1; fi # fallback to regular unpackCmdHooks
+
+    # Unpack plugin shar
+    sh "$curSrc" --noexec --keep
+  '';
+
+  sourceRoot = "${pname}-${version}";
+
+  buildInputs = [
+    libjpeg
+    cups
+    libusb1
+    sane-backends
+    dbus
+    file
+    ghostscript
+    net-snmp
+    openssl
+    perl
+    zlib
+    avahi
+  ]
+  ++ lib.optionals withQt5 [
+    qt5.qtwayland
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    removeReferencesTo
+    autoreconfHook
+    gobject-introspection
+    wrapGAppsHook3
+  ]
+  ++ lib.optional withQt5 qt5.wrapQtAppsHook;
+
+  pythonPath =
+    with python3Packages;
+    [
+      dbus
+      pillow
+      pygobject3
+      reportlab
+      usbutils
+      dbus-python
+      distro
+      distutils
+    ]
+    ++ lib.optionals withQt5 [
+      pyqt5
+      pyqt5-sip
+    ];
+
+  makeWrapperArgs = [
+    "--prefix"
+    "PATH"
+    ":"
+    "${net-tools}/bin"
+  ];
+
+  patches = [
+    # HPLIP's getSystemPPDs() function relies on searching for PPDs below common FHS
+    # paths, and hp-setup crashes if none of these paths actually exist (which they
+    # don't on NixOS).  Add the equivalent NixOS path, /var/lib/cups/path/share.
+    # See: https://github.com/NixOS/nixpkgs/issues/21796
+    ./hplip-3.20.11-nixos-cups-ppd-search-path.patch
+
+    # Remove all ImageProcessor functionality since that is closed source
+    (fetchurl {
+      url = "https://web.archive.org/web/20230226174550/https://sources.debian.org/data/main/h/hplip/3.22.10+dfsg0-1/debian/patches/0028-Remove-ImageProcessor-binary-installs.patch";
+      hash = "sha256-tNYccuwrcx5WCe7ULk8r8J6MVcUytGspiW64zAvO0qI=";
+    })
+  ];
+
+  postPatch = ''
+    # https://github.com/NixOS/nixpkgs/issues/44230
+    substituteInPlace createPPD.sh \
+      --replace-fail ppdc "${cups}/bin/ppdc" \
+      --replace-fail "gzip -c" "gzip -cn"
+
+    # HPLIP hardcodes absolute paths everywhere. Nuke from orbit.
+    find . -type f -exec sed -i \
+      -e s,/etc/hp,$out/etc/hp,g \
+      -e s,/etc/sane.d,$out/etc/sane.d,g \
+      -e s,/usr/include/libusb-1.0,${libusb1.dev}/include/libusb-1.0,g \
+      -e s,/usr/share/hal/fdi/preprobe/10osvendor,$out/share/hal/fdi/preprobe/10osvendor,g \
+      -e s,/usr/lib/systemd/system,$out/lib/systemd/system,g \
+      -e s,/var/lib/hp,$out/var/lib/hp,g \
+      -e s,/usr/bin/perl,${perl}/bin/perl,g \
+      -e s,/usr/bin/file,${file}/bin/file,g \
+      -e s,/usr/bin/gs,${ghostscript}/bin/gs,g \
+      -e s,/usr/share/cups/fonts,${ghostscript.fonts}/share/fonts,g \
+      -e "s,ExecStart=/usr/bin/python /usr/bin/hp-config_usb_printer,ExecStart=$out/bin/hp-config_usb_printer,g" \
+      -e s,Exec=/usr/bin/hp-uiscan,Exec=hp-uiscan,g \
+      -e s,Icon=/usr/share/icons/Humanity/devices/48/printer.svg,Icon=printer,g \
+      -e s,Icon=@abs_datadir@/hplip/data/images/128x128/hp_logo.png,Icon=hp_logo,g \
+      {} +
+
+    echo 'AUTOMAKE_OPTIONS = foreign' >> Makefile.am
+  '';
+
+  configureFlags =
+    let
+      out = placeholder "out";
+    in
+    [
+      "--with-hpppddir=${out}/share/cups/model/HP"
+      "--with-cupsfilterdir=${out}/lib/cups/filter"
+      "--with-cupsbackenddir=${out}/lib/cups/backend"
+      "--with-icondir=${out}/share/applications"
+      "--with-systraydir=${out}/xdg/autostart"
+      "--with-mimedir=${out}/etc/cups"
+      "--enable-policykit"
+      "--disable-qt4"
+
+      # remove ImageProcessor usage, it causes segfaults, see
+      # https://bugs.launchpad.net/hplip/+bug/1788706
+      # https://bugs.launchpad.net/hplip/+bug/1787289
+      "--disable-imageProcessor-build"
+    ]
+    ++ lib.optional withStaticPPDInstall "--enable-cups-ppd-install"
+    ++ lib.optional withQt5 "--enable-qt5";
+
+  # Prevent 'ppdc: Unable to find include file "<font.defs>"' which prevent
+  # generation of '*.ppd' files.
+  # This seems to be a 'ppdc' issue when the tool is run in a hermetic sandbox.
+  # Could not find how to fix the problem in 'ppdc' so this is a workaround.
+  CUPS_DATADIR = "${cups}/share/cups";
+
+  makeFlags =
+    let
+      out = placeholder "out";
+    in
+    [
+      "halpredir=${out}/share/hal/fdi/preprobe/10osvendor"
+      "rulesdir=${out}/etc/udev/rules.d"
+      "policykit_dir=${out}/share/polkit-1/actions"
+      "policykit_dbus_etcdir=${out}/etc/dbus-1/system.d"
+      "policykit_dbus_sharedir=${out}/share/dbus-1/system-services"
+      "PYTHONEXECDIR=${out}/lib/python${lib.versions.majorMinor python3Packages.python.version}/site-packages"
+      "hplip_confdir=${out}/etc/hp"
+      "hplip_statedir=${out}/var/lib/hp"
+    ];
+
+  postConfigure = ''
+    # don't save timestamp, in order to improve reproducibility
+    substituteInPlace Makefile \
+      --replace "GZIP_ENV = --best" "GZIP_ENV = --best -n"
+  '';
+
+  enableParallelBuilding = true;
+  enableParallelInstalling = false;
+
+  env = {
+    NIX_CFLAGS_COMPILE = toString [
+      "-Wno-error=implicit-int"
+      "-Wno-error=implicit-function-declaration"
+      "-Wno-error=return-mismatch"
+      "-Wno-error=int-conversion"
+      "-Wno-error=incompatible-pointer-types"
+    ];
+  };
+
+  #
+  # Running `hp-diagnose_plugin -g` can be used to diagnose
+  # issues with plugins.
+  #
+  postInstall = ''
+    for resolution in 16x16 32x32 64x64 128x128 256x256; do
+      mkdir -p $out/share/icons/hicolor/$resolution/apps
+      ln -s $out/share/hplip/data/images/$resolution/hp_logo.png \
+        $out/share/icons/hicolor/$resolution/apps/hp_logo.png
+    done
+  ''
+  + lib.optionalString withPlugin ''
+    pushd $NIX_BUILD_TOP/plugin_tmp
+
+    cp plugin.spec $out/share/hplip/
+
+    mkdir -p $out/share/hplip/data/firmware
+    cp *.fw.gz $out/share/hplip/data/firmware
+
+    mkdir -p $out/share/hplip/data/plugins
+    cp license.txt $out/share/hplip/data/plugins
+
+    mkdir -p $out/share/hplip/prnt/plugins
+    for plugin in lj hbpl1; do
+      cp $plugin-${hplipArch}.so $out/share/hplip/prnt/plugins
+      chmod 0755 $out/share/hplip/prnt/plugins/$plugin-${hplipArch}.so
+      ln -s $out/share/hplip/prnt/plugins/$plugin-${hplipArch}.so \
+        $out/share/hplip/prnt/plugins/$plugin.so
+    done
+
+    mkdir -p $out/share/hplip/scan/plugins
+    for plugin in bb_soap bb_marvell bb_soapht bb_escl; do
+      cp $plugin-${hplipArch}.so $out/share/hplip/scan/plugins
+      chmod 0755 $out/share/hplip/scan/plugins/$plugin-${hplipArch}.so
+      ln -s $out/share/hplip/scan/plugins/$plugin-${hplipArch}.so \
+        $out/share/hplip/scan/plugins/$plugin.so
+    done
+
+    mkdir -p $out/share/hplip/fax/plugins
+    for plugin in fax_marvell; do
+      cp $plugin-${hplipArch}.so $out/share/hplip/fax/plugins
+      chmod 0755 $out/share/hplip/fax/plugins/$plugin-${hplipArch}.so
+      ln -s $out/share/hplip/fax/plugins/$plugin-${hplipArch}.so \
+        $out/share/hplip/fax/plugins/$plugin.so
+    done
+
+    mkdir -p $out/var/lib/hp
+    cp ${hplipState} $out/var/lib/hp/hplip.state
+
+    popd
+  '';
+
+  # The installed executables are just symlinks into $out/share/hplip,
+  # but wrapPythonPrograms ignores symlinks. We cannot replace the Python
+  # modules in $out/share/hplip with wrapper scripts because they import
+  # each other as libraries. Instead, we emulate wrapPythonPrograms by
+  # 1. Calling patchPythonProgram on the original script in $out/share/hplip
+  # 2. Making our own wrapper pointing directly to the original script.
+  dontWrapPythonPrograms = true;
+  # We also avoid double (or triple in case qt5 support is added) wrapping
+  dontWrapGApps = true;
+  dontWrapQtApps = true;
+  preFixup = ''
+    buildPythonPath "$out $pythonPath"
+
+    for bin in $out/bin/*; do
+      py=$(readlink -m $bin)
+      rm $bin
+      echo "patching \`$py'..."
+      patchPythonScript "$py"
+      echo "wrapping \`$bin'..."
+      ${if withQt5 then "makeQtWrapper" else "makeWrapper"} "$py" "$bin" \
+          --prefix PATH ':' "$program_PATH" \
+          --set PYTHONNOUSERSITE "true" \
+          $makeWrapperArgs "''${gappsWrapperArgs[@]}"
+    done
+  '';
+
+  postFixup = ''
+    substituteInPlace $out/etc/hp/hplip.conf --replace /usr $out
+    # Patch udev rules:
+    # with plugin, they upload firmware to printers,
+    # without plugin, they complain about the missing plugin.
+    substituteInPlace $out/etc/udev/rules.d/56-hpmud.rules \
+      --replace {,${bash}}/bin/sh \
+      --replace /usr/bin/nohup "" \
+      --replace {,${util-linux}/bin/}logger \
+      --replace {/usr,$out}/bin
+    remove-references-to -t ${stdenv.cc.cc} $(readlink -f $out/lib/*.so)
+  '';
+
+  # There are some binaries there, which reference gcc-unwrapped otherwise.
+  stripDebugList = [
+    "share/hplip"
+    "lib/cups/backend"
+    "lib/cups/filter"
+    python3Packages.python.sitePackages
+    "lib/sane"
+  ];
+
+  meta = {
+    description = "Print, scan and fax HP drivers for Linux";
+    homepage = "https://developers.hp.com/hp-linux-imaging-and-printing";
+    downloadPage = "https://sourceforge.net/projects/hplip/files/hplip/";
+    license =
+      if withPlugin then
+        lib.licenses.unfree
+      else
+        with lib.licenses;
+        [
+          mit
+          bsd2
+          gpl2Plus
+        ];
+    platforms = lib.attrNames hplipPlatforms;
+    maintainers = with lib.maintainers; [ ttuegel ];
+  };
+}

pkgs/by-name/hp/hpp2plantuml/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  python3Packages,
+  fetchPypi,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "hpp2plantuml";
+  version = "0.8.6";
+  format = "wheel";
+
+  src = fetchPypi {
+    inherit pname version format;
+    hash = "sha256-9FggDDOxWr4z1DBbvYLyvgs3CCguFjq3I4E9ULwL0+Q=";
+  };
+
+  propagatedBuildInputs = with python3Packages; [
+    jinja2
+    cppheaderparser
+  ];
+
+  pythonImportsCheck = [ "hpp2plantuml" ];
+
+  nativeCheckInputs = with python3Packages; [ pytest ];
+
+  meta = {
+    description = "Convert C++ header files to PlantUML";
+    homepage = "https://github.com/thibaultmarin/hpp2plantuml";
+    license = lib.licenses.mit;
+    mainProgram = "hpp2plantuml";
+    maintainers = with lib.maintainers; [ eymeric ];
+  };
+}

pkgs/by-name/hp/hpx/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  asio,
+  boost,
+  cmake,
+  hwloc,
+  gperftools,
+  pkg-config,
+  python3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "hpx";
+  version = "1.11.0";
+
+  src = fetchFromGitHub {
+    owner = "STEllAR-GROUP";
+    repo = "hpx";
+    rev = "v${version}";
+    hash = "sha256-AhByaw1KnEDuRfKiN+/vQMbkG0BJ6Z3+h+QT8scFzAY=";
+  };
+
+  propagatedBuildInputs = [ hwloc ];
+  buildInputs = [
+    asio
+    boost
+    gperftools
+  ];
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    python3
+  ];
+
+  strictDeps = true;
+
+  meta = {
+    description = "C++ standard library for concurrency and parallelism";
+    homepage = "https://github.com/STEllAR-GROUP/hpx";
+    license = lib.licenses.boost;
+    platforms = [ "x86_64-linux" ]; # lib.platforms.linux;
+    maintainers = with lib.maintainers; [ bobakker ];
+  };
+}