push sheeet

pkgs/by-name/ib/ibm-plex/hashes.nix

@@ -0,0 +1,16 @@
+{
+  "serif" = "sha256-8ygaAeMKygYS4GCub4YUQmkh87pYHfi3s0PQ6AbaeGw=";
+  "sans" = "sha256-mK+8GGl2ugF2+fS6yd3p5NWPHHcKEJWiShDS3lihOlI=";
+  "sans-condensed" = "sha256-/aJTXmrHuoPSrtCKNodBY7I0CriayNTx5LCXw+/MFvE=";
+  "sans-arabic" = "sha256-qi4k7kMLftIuq87idyxq46FOD6QYycdG6j3zJmu8mhI=";
+  "sans-devanagari" = "sha256-K57OVqcH5r9tZx8NFEoz1P3xpUooqpF7xxJzNmnObwE=";
+  "sans-thai" = "sha256-JZVbvZdj+IfBthiqivOXHrvAUe392M9ECGsiJkm0saE=";
+  "sans-thai-looped" = "sha256-cry/Ctwt1bsrdbvWkJIYWLjsvV6a1lLFsT85znqERnw=";
+  "sans-sc" = "sha256-Q3cEVlR/UkNZaGIhNMIdojId6fHmAsZdLwMsKq1zLRY=";
+  "sans-tc" = "sha256-kZvzSK6fEjfVMR4kxC4lxtD7GskqvJZx8BBJVT4T9MU=";
+  "sans-kr" = "sha256-FsHxMvLlI4yylgG96DOZIdW2DYpk7I+c5QgkVIkNZIE=";
+  "sans-jp" = "sha256-hUl/SSkN6q3pDTtrY2mJepw3ljhhLJskGbxfsTl9TuI=";
+  "sans-hebrew" = "sha256-rTuBQYLI+6gEFTumCdaWpeoLzRoyFSmqWbXziq+UG6I=";
+  "mono" = "sha256-OwUmrPfEehLDz0fl2ChYLK8FQM2p0G1+EMrGsYEq+6g=";
+  "math" = "sha256-dJA6uqxa/yb3eLY4l39NeP0yIl2NfrbaRpf6h0/F7Xc=";
+}

pkgs/by-name/ib/ibm-plex/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+  families ? [ ],
+}:
+let
+  version = import ./version.nix;
+  availableFamilies = import ./hashes.nix;
+
+  availableFamilyNames = builtins.attrNames availableFamilies;
+  selectedFamilies = if (families == [ ]) then availableFamilyNames else families;
+
+  unknownFamilies = lib.subtractLists availableFamilyNames families;
+in
+assert lib.assertMsg (unknownFamilies == [ ]) "Unknown font(s): ${toString unknownFamilies}";
+stdenvNoCC.mkDerivation {
+  pname = "ibm-plex";
+  inherit version;
+
+  srcs = map (
+    family:
+    fetchzip {
+      url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-${family}%40${version}/ibm-plex-${family}.zip";
+      hash = availableFamilies.${family};
+    }
+  ) selectedFamilies;
+
+  dontUnpack = true;
+  sourceRoot = ".";
+
+  installPhase = ''
+    runHook preInstall
+    find $srcs -type f -name '*.otf' -exec install -Dm644 {} -t $out/share/fonts/opentype \;
+    runHook postInstall
+  '';
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    description = "IBM Plex Typeface";
+    homepage = "https://www.ibm.com/plex/";
+    changelog = "https://github.com/IBM/plex/raw/v${version}/CHANGELOG.md";
+    license = lib.licenses.ofl;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [
+      romildo
+      ryanccn
+    ];
+  };
+}

pkgs/by-name/ib/ibm-plex/update.sh

@@ -0,0 +1,43 @@
+#! /usr/bin/env nix-shell
+#! nix-shell -i bash -p nix nix-prefetch jq
+#  shellcheck shell=bash
+set -eo pipefail
+
+families=(
+    "serif"
+    "sans"
+    "sans-condensed"
+    "sans-arabic"
+    "sans-devanagari"
+    "sans-thai"
+    "sans-thai-looped"
+    "sans-sc"
+    "sans-tc"
+    "sans-kr"
+    "sans-jp"
+    "sans-hebrew"
+    "mono"
+    "math"
+)
+
+version=$(curl --silent 'https://api.github.com/repos/IBM/plex/releases/latest' | jq -r '.tag_name | sub("^@ibm/[\\w-]+@"; "")')
+
+dirname="$(dirname "$0")"
+echo \""${version}"\" >"$dirname/version-new.nix"
+if diff -q "$dirname/version-new.nix" "$dirname/version.nix"; then
+    echo No new version available, current: "$version"
+    rm "$dirname/version-new.nix"
+    exit 0
+else
+    echo Updated to version "$version"
+    mv "$dirname/version-new.nix" "$dirname/version.nix"
+fi
+
+printf '{\n' > "$dirname/hashes.nix"
+
+for family in "${families[@]}"; do
+    url="https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-${family}%40${version}/ibm-plex-${family}.zip"
+    printf '  "%s" = "%s";\n' "$family" "$(nix-prefetch-url --unpack "$url" | xargs nix --extra-experimental-features nix-command hash convert --hash-algo sha256)" >>"$dirname/hashes.nix"
+done
+
+printf '}\n' >> "$dirname/hashes.nix"

pkgs/by-name/ib/ibm-plex/version.nix

@@ -0,0 +1 @@
+"1.1.0"

pkgs/by-name/ib/ibus-theme-tools/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  gettext,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "ibus-theme-tools";
+  version = "4.2.0";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "openSUSE";
+    repo = "IBus-Theme-Tools";
+    rev = "v${version}";
+    sha256 = "0i8vwnikwd1bfpv4xlgzc51gn6s18q58nqhvcdiyjzcmy3z344c2";
+  };
+
+  buildInputs = [ gettext ];
+
+  build-system = with python3Packages; [
+    setuptools
+  ];
+
+  dependencies = with python3Packages; [
+    tinycss2
+    pygobject3
+  ];
+
+  # No test.
+  doCheck = false;
+
+  pythonImportsCheck = [ "ibus_theme_tools" ];
+
+  meta = with lib; {
+    description = "Generate the IBus GTK or GNOME Shell theme from existing themes";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ hollowman6 ];
+    homepage = "https://github.com/openSUSE/IBus-Theme-Tools";
+    mainProgram = "ibus-theme-tools";
+  };
+}

pkgs/by-name/ib/ibusMinimal/package.nix

@@ -0,0 +1 @@
+{ ibus }: ibus.override { libOnly = true; }