push sheeet

pkgs/by-name/ij/ijhttp/package.nix

@@ -0,0 +1,44 @@
+{
+  fetchurl,
+  jdk17_headless,
+  lib,
+  makeWrapper,
+  stdenvNoCC,
+  unzip,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "ijhttp";
+  version = "252.23892.409";
+
+  src = fetchurl {
+    url = "https://download.jetbrains.com/resources/intellij/http-client/${finalAttrs.version}/intellij-http-client.zip";
+    hash = "sha256-yEEDG9NRYYj8K7+32FB3bJ+qPrVUL0/MMfPoBlol418=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    unzip
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/lib
+    mv lib $out/lib
+    install -Dm755 ijhttp $out/lib/ijhttp
+    makeWrapper $out/lib/ijhttp $out/bin/ijhttp \
+      --set JAVA_HOME ${jdk17_headless.home}
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Run HTTP requests from a terminal, e.g. for HTTP request testing";
+    homepage = "https://www.jetbrains.com/help/idea/http-client-cli.html";
+    license = lib.licenses.unfree;
+    mainProgram = "ijhttp";
+    platforms = lib.platforms.all;
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+  };
+})

pkgs/by-name/ij/ijq/package.nix

@@ -0,0 +1,61 @@
+{
+  buildGoModule,
+  fetchFromGitea,
+  lib,
+  jq,
+  installShellFiles,
+  makeBinaryWrapper,
+  scdoc,
+  nix-update-script,
+}:
+
+buildGoModule rec {
+  pname = "ijq";
+  version = "1.2.0";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "gpanders";
+    repo = "ijq";
+    rev = "v${version}";
+    hash = "sha256-PT7WnCZL4Cfo/+VW3ImOloDOI9d0GX4UTcC8Bf3OVAU=";
+  };
+
+  vendorHash = "sha256-1R3rv3FraT53dqGECRr+ulhplmmByqRW+VJ+y6nFR+Y=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    makeBinaryWrapper
+    scdoc
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.Version=${version}"
+  ];
+
+  postBuild = ''
+    scdoc < ijq.1.scd > ijq.1
+    installManPage ijq.1
+  '';
+
+  postInstall = ''
+    wrapProgram "$out/bin/ijq" \
+      --prefix PATH : "${lib.makeBinPath [ jq ]}"
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Interactive wrapper for jq";
+    mainProgram = "ijq";
+    homepage = "https://codeberg.org/gpanders/ijq";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [
+      justinas
+      mattpolzin
+      SuperSandro2000
+    ];
+  };
+}

pkgs/by-name/ij/ijs/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  stdenv,
+  autoreconfHook,
+  ghostscript,
+}:
+
+stdenv.mkDerivation {
+  pname = "ijs";
+  inherit (ghostscript) version src;
+
+  postPatch = "cd ijs";
+
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  configureFlags = [ "--enable-shared" ];
+
+  meta = with lib; {
+    homepage = "https://www.openprinting.org/download/ijs/";
+    description = "Raster printer driver architecture";
+
+    license = licenses.gpl3Plus;
+
+    platforms = platforms.all;
+    maintainers = [ ];
+  };
+}