push sheeet

pkgs/by-name/ir/ir-lv2/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  fftw,
+  gtk2,
+  lv2,
+  libsamplerate,
+  libsndfile,
+  pkg-config,
+  zita-convolver,
+}:
+
+stdenv.mkDerivation {
+  pname = "ir.lv2";
+  version = "0-unstable-2018-06-21";
+
+  src = fetchgit {
+    url = "https://git.hq.sig7.se/ir.lv2.git";
+    rev = "38bf3ec7d370d8234dd55be99c14cf9533b43c60";
+    sha256 = "sha256-5toZYQX2oIAfQ5XPMMN+HGNE4FOE/t6mciih/OpU1dw=";
+  };
+
+  buildInputs = [
+    fftw
+    gtk2
+    lv2
+    libsamplerate
+    libsndfile
+    zita-convolver
+  ];
+
+  nativeBuildInputs = [ pkg-config ];
+
+  env.NIX_CFLAGS_COMPILE = "-fpermissive";
+
+  postBuild = "make convert4chan";
+
+  installPhase = ''
+    mkdir -p "$out/bin"
+    mkdir "$out/include"
+    mkdir -p "$out/share/doc"
+
+    make PREFIX="$out" INSTDIR="$out/lib/lv2" install
+    install -Dm755 convert4chan "$out/bin/convert4chan"
+  '';
+
+  meta = with lib; {
+    homepage = "http://factorial.hu/plugins/lv2/ir";
+    description = "Zero-latency, realtime, high performance signal convolver especially for creating reverb effects";
+    license = licenses.gpl2;
+    maintainers = [ maintainers.magnetophon ];
+    platforms = platforms.linux;
+    mainProgram = "convert4chan";
+  };
+}

pkgs/by-name/ir/ir-standard-fonts/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "ir-standard-fonts";
+  version = "20170121";
+
+  src = fetchFromGitHub {
+    owner = "molaeiali";
+    repo = "ir-standard-fonts";
+    rev = version;
+    hash = "sha256-o1d8SBX3nf7g6Gh4OP+JRS+LNrHTQOIiHhW3VNCkDV0=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    find . -name '*.ttf' -exec install -m444 -Dt $out/share/fonts/ir-standard-fonts {} \;
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/morealaz/ir-standard-fonts";
+    description = "Iran Supreme Council of Information and Communication Technology (SCICT) standard Persian fonts series";
+    # License information is unavailable.
+    license = licenses.unfree;
+    platforms = platforms.all;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/ir/irccat/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "irccat";
+  version = "0.4.12";
+
+  src = fetchFromGitHub {
+    owner = "irccloud";
+    repo = "irccat";
+    rev = "v${version}";
+    hash = "sha256-W6Qj+zg6jC304bEIQeFB8unSFgjV60zXV+I8hpw3AFA=";
+  };
+
+  vendorHash = "sha256-SUE868jVJywqE0A5yjMWohrMw58OUnxGGxvcR8UzPfE=";
+
+  meta = {
+    homepage = "https://github.com/irccloud/irccat";
+    changelog = "https://github.com/irccloud/irccat/releases/tag/v${version}0.4.11";
+    description = "Send events to IRC channels from scripts and other applications";
+    mainProgram = "irccat";
+    maintainers = with lib.maintainers; [ qyliss ];
+    license = lib.licenses.gpl3Only;
+  };
+}

pkgs/by-name/ir/irccloud/package.nix

@@ -0,0 +1,42 @@
+{
+  appimageTools,
+  fetchurl,
+  lib,
+}:
+
+let
+  pname = "irccloud";
+  version = "0.16.0";
+
+  src = fetchurl {
+    url = "https://github.com/irccloud/irccloud-desktop/releases/download/v${version}/IRCCloud-${version}-linux-x86_64.AppImage";
+    sha256 = "sha256-/hMPvYdnVB1XjKgU2v47HnVvW4+uC3rhRjbucqin4iI=";
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit pname version src;
+  };
+
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  extraPkgs = pkgs: [ pkgs.at-spi2-core ];
+
+  extraInstallCommands = ''
+    install -m 444 -D ${appimageContents}/irccloud.desktop $out/share/applications/irccloud.desktop
+    install -m 444 -D ${appimageContents}/usr/share/icons/hicolor/512x512/apps/irccloud.png \
+      $out/share/icons/hicolor/512x512/apps/irccloud.png
+    substituteInPlace $out/share/applications/irccloud.desktop \
+      --replace 'Exec=AppRun' 'Exec=${pname}'
+  '';
+
+  meta = with lib; {
+    description = "Desktop client for IRCCloud";
+    mainProgram = "irccloud";
+    homepage = "https://www.irccloud.com";
+    license = licenses.asl20;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ lightbulbjim ];
+  };
+}

pkgs/by-name/ir/ircdHybrid/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  openssl,
+  zlib,
+  libxcrypt,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ircd-hybrid";
+  version = "8.2.46";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/ircd-hybrid/ircd-hybrid-${version}.tgz";
+    sha256 = "sha256-pdXI8YiPqC+97XoxNFb1plm4cfLOB+b/getajXPzx0s=";
+  };
+
+  buildInputs = [
+    openssl
+    zlib
+    libxcrypt
+  ];
+
+  configureFlags = [
+    "--with-nicklen=100"
+    "--with-topiclen=360"
+    "--enable-openssl=${openssl.dev}"
+  ];
+
+  postInstall = "echo postinstall; mkdir -p \${out}/ ; rm -rf \${out}/logs ; ln -s /home/ircd \${out}/logs;";
+
+  meta = {
+    description = "IPv6-capable IRC server";
+    platforms = lib.platforms.unix;
+    homepage = "https://www.ircd-hybrid.org/";
+  };
+}

pkgs/by-name/ir/ircdog/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "ircdog";
+  version = "0.5.5";
+
+  src = fetchFromGitHub {
+    owner = "goshuirc";
+    repo = "ircdog";
+    tag = "v${version}";
+    hash = "sha256-maF53Z0FHAhGmnOnMsX0dDnmckPNBY4Bcm4OBM/x4hQ=";
+  };
+
+  vendorHash = null;
+
+  meta = {
+    description = "Simple wrapper over the raw IRC protocol that can respond to pings, and interprets formatting codes";
+    mainProgram = "ircdog";
+    homepage = "https://github.com/ergochat/ircdog";
+    changelog = "https://github.com/ergochat/ircdog/releases/tag/v${version}";
+    license = lib.licenses.isc;
+    maintainers = with lib.maintainers; [ hexa ];
+  };
+}

pkgs/by-name/ir/iredis/package.nix

@@ -0,0 +1,76 @@
+{
+  lib,
+  stdenv,
+  python3,
+  fetchFromGitHub,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "iredis";
+  version = "1.15.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "laixintao";
+    repo = "iredis";
+    tag = "v${version}";
+    hash = "sha256-g/gQb9QOyfa7kyHCUZf/kLZRO5IE8389BUCYz8Sqr8o=";
+  };
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace-fail 'packaging = "^23.0"' 'packaging = "*"' \
+      --replace-fail 'wcwidth = "0.1.9"' 'wcwidth = "*"' \
+      --replace-fail 'redis = "^5.0.0"' 'redis = "*"'
+  '';
+
+  nativeBuildInputs = with python3.pkgs; [
+    poetry-core
+  ];
+
+  propagatedBuildInputs = with python3.pkgs; [
+    click
+    configobj
+    mistune
+    packaging
+    prompt-toolkit
+    pygments
+    python-dateutil
+    redis
+    wcwidth
+  ];
+
+  nativeCheckInputs = with python3.pkgs; [
+    freezegun
+    pexpect
+    pytestCheckHook
+  ];
+
+  enabledTestPaths = [
+    # Only execute unittests, because cli tests require a running Redis
+    "tests/unittests/"
+  ];
+
+  disabledTestPaths = [
+    # Fails on sandbox
+    "tests/unittests/test_client.py"
+    "tests/unittests/test_render_functions.py::test_render_unixtime_config_raw"
+    "tests/unittests/test_render_functions.py::test_render_time"
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    # Flaky tests
+    "tests/unittests/test_entry.py::test_command_shell_options_higher_priority"
+    "tests/unittests/test_utils.py::test_timer"
+  ];
+
+  pythonImportsCheck = [ "iredis" ];
+
+  meta = {
+    description = "Terminal Client for Redis with AutoCompletion and Syntax Highlighting";
+    changelog = "https://github.com/laixintao/iredis/blob/${src.tag}/CHANGELOG.md";
+    homepage = "https://iredis.xbin.io/";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ phanirithvij ];
+    mainProgram = "iredis";
+  };
+}

pkgs/by-name/ir/irker/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  python3,
+  pkg-config,
+  xmlto,
+  docbook2x,
+  docbook_xsl,
+  docbook_xml_dtd_412,
+}:
+
+stdenv.mkDerivation {
+  pname = "irker";
+  version = "2017-02-12";
+
+  src = fetchFromGitLab {
+    owner = "esr";
+    repo = "irker";
+    rev = "dc0f65a7846a3922338e72d8c6140053fe914b54";
+    sha256 = "1hslwqa0gqsnl3l6hd5hxpn0wlachxd51infifhlwhyhd6iwgx8p";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    xmlto
+    docbook2x
+    docbook_xsl
+    docbook_xml_dtd_412
+  ];
+
+  buildInputs = [
+    python3
+    # Needed for proxy support I believe, which I haven't tested.
+    # Probably needs to be propagated and some wrapPython magic
+    # python.pkgs.pysocks
+  ];
+
+  strictDeps = true;
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace '-o 0 -g 0' ""
+  '';
+
+  installFlags = [
+    "prefix=/"
+    "DESTDIR=$$out"
+  ];
+
+  meta = with lib; {
+    description = "IRC client that runs as a daemon accepting notification requests";
+    homepage = "https://gitlab.com/esr/irker";
+    license = licenses.bsd2;
+    maintainers = [ ];
+    mainProgram = "irkerd";
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/ir/iro/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage {
+  pname = "iro";
+  version = "0-unstable-2024-10-24";
+
+  src = fetchFromGitHub {
+    owner = "kyoheiu";
+    repo = "iro";
+    rev = "ba4adc00e13da9086389357b0e92e608928a8b39";
+    hash = "sha256-hGGrEGG1LyzfUCEnV7ahhRO0GrLk28xDWZEFqUHk1rE=";
+  };
+
+  cargoHash = "sha256-7QAhgUI6Pu0iqE6JyfYI4x3O/XTDb8B1Sy3hw9EVMYo=";
+
+  meta = {
+    description = "CLI tool to convet Hex color code or RGB to color code, RGB, HSL and color name";
+    homepage = "https://github.com/kyoheiu/iro";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ airrnot ];
+    mainProgram = "iro";
+  };
+}

pkgs/by-name/ir/irods-icommands/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  llvmPackages,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+  help2man,
+  irods,
+}:
+
+llvmPackages.stdenv.mkDerivation (finalAttrs: {
+  pname = "irods-icommands";
+  inherit (irods) version;
+
+  src = fetchFromGitHub {
+    owner = "irods";
+    repo = "irods_client_icommands";
+    tag = finalAttrs.version;
+    hash = "sha256-lo1eCI/CSzl7BJWdPo7KKVHfznkPN6GwsiQThUGuQdw=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    help2man
+  ];
+
+  buildInputs = [ irods ];
+
+  cmakeFlags = irods.commonCmakeFlags ++ [
+    (lib.cmakeFeature "ICOMMANDS_INSTALL_DIRECTORY" "${placeholder "out"}/bin")
+    (lib.cmakeBool "ICOMMANDS_INSTALL_SYMLINKS" false)
+  ];
+
+  meta = {
+    inherit (irods.meta)
+      homepage
+      license
+      maintainers
+      platforms
+      ;
+    description = irods.meta.description + " CLI clients";
+    longDescription = irods.meta.longDescription + ''
+
+      This package provides the CLI clients, called 'icommands'.
+    '';
+  };
+})

pkgs/by-name/ir/irods/package.nix

@@ -0,0 +1,115 @@
+{
+  lib,
+  llvmPackages,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+  bison,
+  flex,
+  libarchive,
+  pam,
+  unixODBC,
+  jsoncons,
+  curl,
+  systemdLibs,
+  openssl,
+  boost183,
+  nlohmann_json,
+  nanodbc,
+  fmt_9,
+  spdlog,
+}:
+
+llvmPackages.stdenv.mkDerivation (finalAttrs: {
+  pname = "irods";
+  version = "5.0.1";
+
+  src = fetchFromGitHub {
+    owner = "irods";
+    repo = "irods";
+    tag = finalAttrs.version;
+    hash = "sha256-/mcuqukgDoMc89FL/TfOhHWglsfdLmQbAnQYT8vTFsY=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    bison
+    flex
+  ];
+
+  buildInputs = [
+    libarchive
+    pam
+    unixODBC
+    jsoncons
+    curl
+    systemdLibs
+  ];
+
+  propagatedBuildInputs = [
+    openssl
+    # Can potentially be unpinned after:
+    # <https://github.com/irods/irods/issues/7248>
+    boost183
+    nlohmann_json
+    nanodbc
+    # Tracking issue for `fmt_11`:
+    # <https://github.com/irods/irods/issues/8454>
+    fmt_9
+    (spdlog.override {
+      fmt = fmt_9;
+    })
+  ];
+
+  cmakeFlags = finalAttrs.passthru.commonCmakeFlags ++ [
+    # Tracking issues for moving these to `find_package`:
+    # * <https://github.com/irods/irods/issues/6249>
+    # * <https://github.com/irods/irods/issues/6253>
+    (lib.cmakeFeature "IRODS_EXTERNALS_FULLPATH_BOOST" "${boost183}")
+    (lib.cmakeFeature "IRODS_EXTERNALS_FULLPATH_NANODBC" "${nanodbc}")
+    (lib.cmakeFeature "IRODS_EXTERNALS_FULLPATH_JSONCONS" "${jsoncons}")
+  ];
+
+  postPatch = ''
+    patchShebangs ./test
+    substituteInPlace plugins/database/CMakeLists.txt --replace-fail \
+      'COMMAND cpp -E -P -D''${plugin} "''${CMAKE_CURRENT_BINARY_DIR}/src/icatSysTables.sql.pp" ' \
+      'COMMAND cpp -E -P -D''${plugin} "''${CMAKE_CURRENT_BINARY_DIR}/src/icatSysTables.sql.pp" -o '
+    substituteInPlace server/auth/CMakeLists.txt --replace-fail SETUID ""
+  '';
+
+  passthru = {
+    commonCmakeFlags = [
+      # We already use Clang in the `stdenv`.
+      (lib.cmakeBool "IRODS_BUILD_WITH_CLANG" false)
+      # Upstream builds with LLVM 16 and doesn’t handle newer warnings.
+      (lib.cmakeBool "IRODS_BUILD_WITH_WERROR" false)
+      (lib.cmakeFeature "IRODS_HOME_DIRECTORY" "${placeholder "out"}")
+      (lib.cmakeFeature "IRODS_LINUX_DISTRIBUTION_NAME" "NixOS")
+      (lib.cmakeFeature "IRODS_LINUX_DISTRIBUTION_VERSION" lib.trivial.release)
+      (lib.cmakeFeature "IRODS_LINUX_DISTRIBUTION_VERSION_MAJOR" lib.trivial.release)
+      (lib.cmakeFeature "CPACK_GENERATOR" "TGZ")
+    ];
+  };
+
+  meta = {
+    description = "Integrated Rule-Oriented Data System (iRODS)";
+    longDescription = ''
+      The Integrated Rule-Oriented Data System (iRODS) is open source data management
+      software used by research organizations and government agencies worldwide.
+      iRODS is released as a production-level distribution aimed at deployment in mission
+      critical environments.  It virtualizes data storage resources, so users can take
+      control of their data, regardless of where and on what device the data is stored.
+      As data volumes grow and data services become more complex, iRODS is increasingly
+      important in data management. The development infrastructure supports exhaustive
+      testing on supported platforms; plug-in support for microservices, storage resources,
+      drivers, and databases; and extensive documentation, training and support services.
+    '';
+    homepage = "https://irods.org";
+    license = lib.licenses.bsd3;
+    maintainers = [ lib.maintainers.bzizou ];
+    platforms = lib.platforms.linux;
+    mainProgram = "irodsServer";
+  };
+})

pkgs/by-name/ir/iroh/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "iroh";
+  version = "0.92.0";
+
+  src = fetchFromGitHub {
+    owner = "n0-computer";
+    repo = "iroh";
+    rev = "v${version}";
+    hash = "sha256-Xdiw77zJd0WfrEqo4Y6BwyD9qAKFEIUS511CQvtU9xs=";
+  };
+
+  cargoHash = "sha256-Bq53DOZZ+MJlzJVHL6uPAH/YXkeSFFHhTlC2ZkvW7FM=";
+
+  # Some tests require network access which is not available in nix build sandbox.
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Efficient IPFS for the whole world right now";
+    homepage = "https://iroh.computer";
+    license = with licenses; [
+      asl20
+      mit
+    ];
+    maintainers = with maintainers; [ cameronfyfe ];
+    mainProgram = "iroh";
+  };
+}

pkgs/by-name/ir/ironbar/package.nix

@@ -0,0 +1,114 @@
+{
+  gtk3,
+  gdk-pixbuf,
+  librsvg,
+  webp-pixbuf-loader,
+  gobject-introspection,
+  glib-networking,
+  glib,
+  shared-mime-info,
+  gsettings-desktop-schemas,
+  wrapGAppsHook3,
+  gtk-layer-shell,
+  adwaita-icon-theme,
+  libxkbcommon,
+  libdbusmenu-gtk3,
+  openssl,
+  pkg-config,
+  hicolor-icon-theme,
+  rustPlatform,
+  lib,
+  fetchFromGitHub,
+  luajit,
+  luajitPackages,
+  libpulseaudio,
+  libinput,
+  libevdev,
+  features ? [ ],
+  systemd,
+}:
+
+let
+  hasFeature = f: features == [ ] || builtins.elem f features;
+in
+rustPlatform.buildRustPackage rec {
+  pname = "ironbar";
+  version = "0.17.1";
+
+  src = fetchFromGitHub {
+    owner = "JakeStanger";
+    repo = "ironbar";
+    rev = "v${version}";
+    hash = "sha256-aph9onWsaEYJqz1bcBNijEexnH0MPLtoblpU9KSbksA=";
+  };
+
+  cargoHash = "sha256-puBoRdCd1A8FmEu5PmczgYAdPdTA8FA1CWsh7qWjHzQ=";
+
+  buildInputs = [
+    gtk3
+    gdk-pixbuf
+    glib
+    gtk-layer-shell
+    glib-networking
+    shared-mime-info
+    adwaita-icon-theme
+    hicolor-icon-theme
+    gsettings-desktop-schemas
+    libxkbcommon
+    systemd
+  ]
+  ++ lib.optionals (hasFeature "http") [ openssl ]
+  ++ lib.optionals (hasFeature "volume") [ libpulseaudio ]
+  ++ lib.optionals (hasFeature "cairo") [ luajit ]
+  ++ lib.optionals (hasFeature "tray") [ libdbusmenu-gtk3 ]
+  ++ lib.optionals (hasFeature "keyboard") [
+    libinput
+    libevdev
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    wrapGAppsHook3
+    gobject-introspection
+  ];
+  propagatedBuildInputs = [ gtk3 ];
+
+  runtimeDeps = [ luajitPackages.lgi ];
+
+  buildNoDefaultFeatures = features != [ ];
+  buildFeatures = features;
+
+  gappsWrapperArgs = ''
+    # Thumbnailers
+    --prefix XDG_DATA_DIRS : "${gdk-pixbuf}/share"
+    --prefix XDG_DATA_DIRS : "${librsvg}/share"
+    --prefix XDG_DATA_DIRS : "${webp-pixbuf-loader}/share"
+    --prefix XDG_DATA_DIRS : "${shared-mime-info}/share"
+
+    # gtk-launch
+    --suffix PATH : "${lib.makeBinPath [ gtk3 ]}"
+  ''
+  + lib.optionalString (hasFeature "cairo") ''
+    --prefix LUA_PATH : "./?.lua;${luajitPackages.lgi}/share/lua/5.1/?.lua;${luajitPackages.lgi}/share/lua/5.1/?/init.lua;${luajit}/share/lua/5.1/\?.lua;${luajit}/share/lua/5.1/?/init.lua"
+    --prefix LUA_CPATH : "./?.so;${luajitPackages.lgi}/lib/lua/5.1/?.so;${luajit}/lib/lua/5.1/?.so;${luajit}/lib/lua/5.1/loadall.so"
+  '';
+
+  preFixup = ''
+    gappsWrapperArgs+=(
+      ${gappsWrapperArgs}
+    )
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/JakeStanger/ironbar";
+    description = "Customizable gtk-layer-shell wlroots/sway bar written in Rust";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [
+      yavko
+      donovanglover
+      jakestanger
+    ];
+    mainProgram = "ironbar";
+  };
+}

pkgs/by-name/ir/ironwail/package.nix

@@ -0,0 +1,107 @@
+{
+  lib,
+  stdenv,
+  SDL2,
+  fetchurl,
+  gzip,
+  libvorbis,
+  libmad,
+  flac,
+  libopus,
+  opusfile,
+  libogg,
+  libGL,
+  curl,
+  libxmp,
+  mpg123,
+  vulkan-headers,
+  vulkan-loader,
+  copyDesktopItems,
+  makeDesktopItem,
+  pkg-config,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ironwail";
+  version = "0.8.0";
+
+  src = fetchurl {
+    url = "https://github.com/andrei-drexler/ironwail/archive/refs/tags/v${finalAttrs.version}.tar.gz";
+    hash = "sha256-IcODVQ0FgfTi74cvJnM6cPh/Der1bbltdTTo5hITUeI=";
+  };
+
+  sourceRoot = "${finalAttrs.pname}-${finalAttrs.version}/Quake";
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    pkg-config
+    vulkan-headers
+    gzip
+    libGL
+    libvorbis
+    libmad
+    flac
+    curl
+    libopus
+    opusfile
+    libogg
+    libxmp
+    mpg123
+    vulkan-loader
+    SDL2
+  ];
+
+  buildFlags = [
+    "DO_USERDIRS=1"
+    # Makefile defaults, set here to enforce consistency on Darwin build
+    "USE_CODEC_WAVE=1"
+    "USE_CODEC_MP3=1"
+    "USE_CODEC_VORBIS=1"
+    "USE_CODEC_FLAC=1"
+    "USE_CODEC_OPUS=1"
+    "USE_CODEC_MIKMOD=0"
+    "USE_CODEC_UMX=0"
+    "USE_CODEC_XMP=1"
+    "MP3LIB=mad"
+    "VORBISLIB=vorbis"
+    "SDL_CONFIG=sdl2-config"
+    "USE_SDL2=1"
+  ];
+
+  preInstall = ''
+    mkdir -p "$out/bin"
+    mkdir -p "$out/share/quake"
+    substituteInPlace Makefile --replace-fail "cp ironwail.pak /usr/local/games/quake" "cp ironwail.pak $out/share/quake/ironwail.pak"
+    substituteInPlace Makefile --replace-fail "/usr/local/games/quake" "$out/bin/ironwail"
+  '';
+
+  enableParallelBuilding = true;
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "ironwail";
+      exec = "ironwail";
+      desktopName = "Ironwail";
+      categories = [ "Game" ];
+    })
+  ];
+
+  meta = {
+    description = "Fork of the QuakeSpasm engine for iD software's Quake";
+    homepage = "https://github.com/andrei-drexler/ironwail";
+    longDescription = ''
+      Ironwail is a fork of QuakeSpasm with focus on high performance instead of
+      compatibility.
+      It features the ability to play the 2021 re-release content with no setup
+      required, a mods menu for quick access to installation of mods, and ease of
+      switching to installed mods.
+      It also include various visual features as well as improved limits for playing
+      larger levels with less performance impacts.
+    '';
+
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.necrophcodr ];
+    mainProgram = "ironwail";
+  };
+})

pkgs/by-name/ir/irpf/package.nix

@@ -0,0 +1,98 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+  copyDesktopItems,
+  jdk11,
+  makeDesktopItem,
+  makeWrapper,
+  unzip,
+  xdg-utils,
+  writeScript,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "irpf";
+  version = "2025-1.6";
+
+  # https://www.gov.br/receitafederal/pt-br/centrais-de-conteudo/download/pgd/dirpf
+  # Para outros sistemas operacionais -> Multi
+  src =
+    let
+      year = lib.head (lib.splitVersion finalAttrs.version);
+    in
+    fetchzip {
+      url = "https://downloadirpf.receita.fazenda.gov.br/irpf/${year}/irpf/arquivos/IRPF${finalAttrs.version}.zip";
+      hash = "sha256-U2HweRi6acrmMT+9B1263mhGIn/84Z6JeqKP6XvTeXE=";
+    };
+
+  passthru.updateScript = writeScript "update-irpf" ''
+    #!/usr/bin/env nix-shell
+    #!nix-shell -i bash -p curl pup common-updater-scripts
+
+    set -eu -o pipefail
+    #parses the html with the install links for the containers that contain the instalation files of type 'file archive, gets the version number of each version, and sorts to get the latest one on the website
+    version="$(curl -s https://www.gov.br/receitafederal/pt-br/centrais-de-conteudo/download/pgd/dirpf | pup '.rfb_container .rfb_ositem:parent-of(.fa-file-archive) attr{href}' | grep -oP "IRPF\K(\d+)-[\d.]+\d" | sort -r |  head -1)"
+    update-source-version irpf "$version"
+  '';
+
+  nativeBuildInputs = [
+    unzip
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "irpf";
+      exec = "irpf";
+      icon = "rfb64";
+      desktopName = "Imposto de Renda Pessoa Física";
+      comment = "Programa Oficial da Receita para elaboração do IRPF";
+      categories = [ "Office" ];
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    BASEDIR="$out/share/irpf"
+    mkdir -p "$BASEDIR"
+
+    cp --no-preserve=mode -r help lib lib-modulos "$BASEDIR"
+
+    install -Dm644 irpf.jar Leia-me.htm offline.png online.png pgd-updater.jar "$BASEDIR"
+
+    # make xdg-open overrideable at runtime
+    makeWrapper ${jdk11}/bin/java $out/bin/irpf \
+      --add-flags "-Dawt.useSystemAAFontSettings=gasp" \
+      --add-flags "-Dswing.aatext=true" \
+      --add-flags "-jar $BASEDIR/irpf.jar" \
+      --suffix PATH : ${lib.makeBinPath [ xdg-utils ]} \
+      --set _JAVA_AWT_WM_NONREPARENTING 1 \
+      --set AWT_TOOLKIT MToolkit
+
+    mkdir -p $out/share/pixmaps
+    unzip -j lib/ppgd-icones-4.0.jar icones/rfb64.png -d $out/share/pixmaps
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Brazillian government application for reporting income tax";
+    longDescription = ''
+      Brazillian government application for reporting income tax.
+
+      IRFP - Imposto de Renda Pessoa Física - Receita Federal do Brasil.
+    '';
+    homepage = "https://www.gov.br/receitafederal/pt-br";
+    license = licenses.unfree;
+    platforms = platforms.all;
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    maintainers = with maintainers; [
+      atila
+      bryanasdev000
+    ];
+    mainProgram = "irpf";
+  };
+})

pkgs/by-name/ir/irqbalance/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  pkg-config,
+  glib,
+  ncurses,
+  libcap_ng,
+  enableSystemd ? lib.meta.availableOn stdenv.hostPlatform systemdMinimal,
+  systemdMinimal,
+  nixosTests,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "irqbalance";
+  version = "1.9.4-unstable-2025-06-10";
+
+  src = fetchFromGitHub {
+    owner = "Irqbalance";
+    repo = "irqbalance";
+    rev = "8e8945e5092caf45605dfb1e66165e2eb9ec1f56";
+    sha256 = "sha256-DSXFJZ0MyI10ZVFcGY0Sx1kye1ALMeG41nmyqbfO8vQ=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+  buildInputs = [
+    glib
+    ncurses
+    libcap_ng
+  ]
+  ++ (lib.optionals enableSystemd [
+    systemdMinimal
+  ]);
+
+  configureFlags = lib.optionals enableSystemd [
+    "--with-systemd"
+    "systemdsystemunitdir=$$out/lib/systemd/system"
+  ];
+
+  postInstall = ''
+    # Systemd service
+    sed -i "/^EnvironmentFile=/d" "$out/lib/systemd/system/irqbalance.service"
+    substituteInPlace "$out/lib/systemd/system/irqbalance.service" \
+      --replace-fail /usr/sbin/irqbalance "$out/bin/irqbalance --journal" \
+      --replace-fail ' $IRQBALANCE_ARGS' ""
+  '';
+
+  passthru.tests.nixos = nixosTests.irqbalance;
+
+  meta = {
+    homepage = "https://github.com/Irqbalance/irqbalance";
+    changelog = lib.strings.optionalString (
+      !lib.strings.hasInfix "-unstable-" version
+    ) "https://github.com/Irqbalance/irqbalance/releases/tag/v${version}";
+    description = "Daemon to help balance the cpu load generated by interrupts across all of a systems cpus";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ moni ];
+    mainProgram = "irqbalance";
+  };
+}

pkgs/by-name/ir/irrd/package.nix

@@ -0,0 +1,162 @@
+{
+  lib,
+  python3,
+  fetchPypi,
+  fetchFromGitHub,
+  fetchpatch,
+  git,
+  postgresql,
+  postgresqlTestHook,
+  valkey,
+  redisTestHook,
+}:
+
+let
+  py = python3.override {
+    self = py;
+    packageOverrides = final: prev: {
+      # sqlalchemy 2.0 is not supported
+      sqlalchemy = prev.sqlalchemy_1_4;
+
+      # checkInputs do not work wiht sqlalchemy < 2.0
+      factory-boy = prev.factory-boy.overridePythonAttrs (
+        lib.const {
+          doCheck = false;
+        }
+      );
+
+      # https://github.com/irrdnet/irrd/blob/22fe77e46ef1b4e43e346257795e171e7ee70d44/pyproject.toml#L30
+      beautifultable = prev.beautifultable.overridePythonAttrs (oldAttrs: rec {
+        version = "0.8.0";
+        src = fetchPypi {
+          inherit (oldAttrs) pname;
+          inherit version;
+          hash = "sha256-1E2VUbvte/qIZ1Mk+E77mqhXOE1E6fsh61MPCgutuBU=";
+        };
+        doCheck = false;
+      });
+    };
+  };
+in
+
+py.pkgs.buildPythonPackage rec {
+  pname = "irrd";
+  version = "4.5.0b1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "irrdnet";
+    repo = "irrd";
+    rev = "v${version}";
+    hash = "sha256-Hr/PbC4N/yrYeQ7bTfqIchDFmaL3c4afxV1XS7FR1F8=";
+  };
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace-fail py-radix py-radix-sr
+  '';
+
+  pythonRelaxDeps = true;
+
+  build-system = with python3.pkgs; [ poetry-core ];
+
+  nativeCheckInputs = [
+    git
+    valkey
+    redisTestHook
+    postgresql
+    postgresqlTestHook
+  ]
+  ++ (with py.pkgs; [
+    pytest-asyncio_0
+    pytest-freezegun
+    pytestCheckHook
+    smtpdfix
+    httpx
+  ]);
+
+  dependencies =
+    with py.pkgs;
+    [
+      python-gnupg
+      passlib
+      bcrypt
+      ipy
+      ordered-set
+      beautifultable
+      pyyaml
+      datrie
+      setproctitle
+      python-daemon
+      pid
+      py.pkgs.redis
+      hiredis
+      coredis
+      requests
+      pytz
+      ariadne
+      uvicorn
+      starlette
+      psutil
+      asgiref
+      pydantic
+      typing-extensions
+      py-radix-sr
+      psycopg2-binary
+      sqlalchemy
+      alembic
+      ujson
+      wheel
+      websockets
+      limits
+      factory-boy
+      webauthn
+      wtforms
+      imia
+      starlette-wtf
+      zxcvbn
+      pyotp
+      asgi-logger
+      wtforms-bootstrap5
+      email-validator
+      jinja2
+      joserfc
+      time-machine
+    ]
+    ++ py.pkgs.uvicorn.optional-dependencies.standard;
+
+  preCheck = ''
+    export SMTPD_HOST=127.0.0.1
+    export IRRD_DATABASE_URL="postgresql:///$PGDATABASE"
+    export IRRD_REDIS_URL="redis://localhost/1"
+  '';
+
+  # required for test_object_writing_and_status_checking
+  postgresqlTestSetupPost = ''
+    echo "track_commit_timestamp=on" >> $PGDATA/postgresql.conf
+    pg_ctl restart
+  '';
+
+  postCheck = ''
+    kill $REDIS_PID
+  '';
+
+  disabledTests = [
+    # Skip tests that require internet access
+    "test_020_dash_o_noop"
+    "test_050_non_json_response"
+  ];
+
+  disabledTestPaths = [
+    # Doesn't work with later pytest releases
+    "irrd/server/whois/tests/test_query_response.py"
+  ];
+
+  meta = {
+    changelog = "https://irrd.readthedocs.io/en/v${version}/releases/";
+    description = "Internet Routing Registry database server, processing IRR objects in the RPSL format";
+    license = lib.licenses.mit;
+    homepage = "https://github.com/irrdnet/irrd";
+    teams = [ lib.teams.wdz ];
+  };
+}

pkgs/by-name/ir/irssi/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  glib,
+  libgcrypt,
+  libintl,
+  libotr,
+  meson,
+  ncurses,
+  ninja,
+  openssl,
+  perl,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "irssi";
+  version = "1.4.5";
+
+  src = fetchFromGitHub {
+    owner = "irssi";
+    repo = "irssi";
+    rev = version;
+    hash = "sha256-D+KMjkweStMqVhoQoiJPFt/G0vdf7x2FjYCvqGS8UqY=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    perl
+    pkg-config
+  ];
+
+  buildInputs = [
+    glib
+    libgcrypt
+    libintl
+    libotr
+    ncurses
+    openssl
+  ];
+
+  configureFlags = [
+    "-Dwith-proxy=yes"
+    "-Dwith-bot=yes"
+    "-Dwith-perl=yes"
+  ];
+
+  meta = with lib; {
+    description = "Terminal based IRC client";
+    mainProgram = "irssi";
+    homepage = "https://irssi.org";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [
+      fab
+      lovek323
+    ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/ir/iruby/Gemfile

@@ -0,0 +1,2 @@
+source 'https://rubygems.org'
+gem 'iruby', "0.8.2"

pkgs/by-name/ir/iruby/Gemfile.lock

@@ -0,0 +1,35 @@
+GEM
+  remote: https://rubygems.org/
+  specs:
+    data_uri (0.1.0)
+    ffi (1.15.5)
+    ffi-rzmq (2.0.7)
+      ffi-rzmq-core (>= 1.0.7)
+    ffi-rzmq-core (1.0.7)
+      ffi
+    io-console (0.6.0)
+    irb (1.7.4)
+      reline (>= 0.3.6)
+    iruby (0.8.2)
+      data_uri (~> 0.1)
+      ffi-rzmq
+      irb
+      logger
+      mime-types (>= 3.3.1)
+      multi_json (~> 1.11)
+    logger (1.7.0)
+    mime-types (3.5.1)
+      mime-types-data (~> 3.2015)
+    mime-types-data (3.2023.0808)
+    multi_json (1.15.0)
+    reline (0.3.8)
+      io-console (~> 0.5)
+
+PLATFORMS
+  ruby
+
+DEPENDENCIES
+  iruby (= 0.8.2)
+
+BUNDLED WITH
+   2.6.9

pkgs/by-name/ir/iruby/gemset.nix

@@ -0,0 +1,135 @@
+{
+  data_uri = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0fzkxgdxrlbfl4537y3n9mjxbm28kir639gcw3x47ffchwsgdcky";
+      type = "gem";
+    };
+    version = "0.1.0";
+  };
+  ffi = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "1862ydmclzy1a0cjbvm8dz7847d9rch495ib0zb64y84d3xd4bkg";
+      type = "gem";
+    };
+    version = "1.15.5";
+  };
+  ffi-rzmq = {
+    dependencies = [ "ffi-rzmq-core" ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "14a5kxfnf8l3ngyk8hgmk30z07aj1324ll8i48z67ps6pz2kpsrg";
+      type = "gem";
+    };
+    version = "2.0.7";
+  };
+  ffi-rzmq-core = {
+    dependencies = [ "ffi" ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0amkbvljpjfnv0jpdmz71p1i3mqbhyrnhamjn566w0c01xd64hb5";
+      type = "gem";
+    };
+    version = "1.0.7";
+  };
+  io-console = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0dikardh14c72gd9ypwh8dim41wvqmzfzf35mincaj5yals9m7ff";
+      type = "gem";
+    };
+    version = "0.6.0";
+  };
+  irb = {
+    dependencies = [ "reline" ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "158ca10kj3qqnql5g8f1g2arsnhgdl79mg74manpf8ldkwjjn3n8";
+      type = "gem";
+    };
+    version = "1.7.4";
+  };
+  iruby = {
+    dependencies = [
+      "data_uri"
+      "ffi-rzmq"
+      "irb"
+      "logger"
+      "mime-types"
+      "multi_json"
+    ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "11lb7flkqpaff303g6lj9vzdw9zc0s2qmz36a6i4x4qj559bz30n";
+      type = "gem";
+    };
+    version = "0.8.2";
+  };
+  logger = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "00q2zznygpbls8asz5knjvvj2brr3ghmqxgr83xnrdj4rk3xwvhr";
+      type = "gem";
+    };
+    version = "1.7.0";
+  };
+  mime-types = {
+    dependencies = [ "mime-types-data" ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0q8d881k1b3rbsfcdi3fx0b5vpdr5wcrhn88r2d9j7zjdkxp5mw5";
+      type = "gem";
+    };
+    version = "3.5.1";
+  };
+  mime-types-data = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "17zdim7kzrh5j8c97vjqp4xp78wbyz7smdp4hi5iyzk0s9imdn5a";
+      type = "gem";
+    };
+    version = "3.2023.0808";
+  };
+  multi_json = {
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0pb1g1y3dsiahavspyzkdy39j4q377009f6ix0bh1ag4nqw43l0z";
+      type = "gem";
+    };
+    version = "1.15.0";
+  };
+  reline = {
+    dependencies = [ "io-console" ];
+    groups = [ "default" ];
+    platforms = [ ];
+    source = {
+      remotes = [ "https://rubygems.org" ];
+      sha256 = "0lv1nv7z63n4qmsm3h5h273m7daxngkcq8ynkk9j8lmn7jji98lb";
+      type = "gem";
+    };
+    version = "0.3.8";
+  };
+}

pkgs/by-name/ir/iruby/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  bundlerApp,
+}:
+
+# Jupyter console:
+# nix run --impure --expr 'with import <nixpkgs> {}; jupyter-console.withSingleKernel iruby.definition'
+
+# Jupyter notebook:
+# nix run --impure --expr 'with import <nixpkgs> {}; jupyter.override { definitions.iruby = iruby.definition; }'
+
+let
+  self = bundlerApp {
+    pname = "iruby";
+    gemdir = ./.;
+    exes = [ "iruby" ];
+
+    passthru = {
+      definition = {
+        displayName = "IRuby";
+        argv = [
+          "${self}/bin/iruby"
+          "kernel"
+          "{connection_file}"
+        ];
+        language = "ruby";
+        logo32 = null;
+        logo64 = null;
+      };
+    };
+
+    passthru.updateScript = ./update.sh;
+
+    meta = {
+      description = "Ruby kernel for Jupyter";
+      homepage = "https://github.com/SciRuby/iruby";
+      license = lib.licenses.mit;
+      maintainers = with lib.maintainers; [
+        costrouc
+        thomasjm
+      ];
+      platforms = lib.platforms.unix;
+    };
+  };
+
+in
+
+self

pkgs/by-name/ir/iruby/update.sh

@@ -0,0 +1,18 @@
+#! /usr/bin/env nix-shell
+#! nix-shell -i bash -p curl jq bundler bundix ruby
+
+set -eu -o pipefail
+
+cd "$(dirname "$0")"
+
+# Update Gemfile with the latest iruby version
+echo "source 'https://rubygems.org'" > Gemfile
+echo -n "gem 'iruby', " >> Gemfile
+curl https://rubygems.org/api/v1/gems/iruby.json | jq .version >> Gemfile
+
+# Regenerate Gemfile.lock
+export BUNDLE_FORCE_RUBY_PLATFORM=1
+bundle lock
+
+# Regenerate gemset.nix
+bundix -l

pkgs/by-name/ir/irust/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  makeWrapper,
+  cargo,
+  rustfmt,
+  cargo-show-asm,
+  cargo-expand,
+  clang,
+  # Workaround to allow easily overriding runtime inputs
+  runtimeInputs ? [
+    cargo
+    rustfmt
+    cargo-show-asm
+    cargo-expand
+    clang
+  ],
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "irust";
+  version = "1.76.2";
+
+  src = fetchFromGitHub {
+    owner = "sigmaSd";
+    repo = "IRust";
+    rev = "irust@${version}";
+    hash = "sha256-bZKFoN6hr/TLTvGAWUXS+S3RnYhdirUeGz30LYbgA7g=";
+  };
+
+  cargoHash = "sha256-lcnKiJCFN/bN/4R6VIhut2Xz3ueYPgXkr4dsYH57d9g=";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  postFixup = ''
+    wrapProgram $out/bin/irust \
+      --suffix PATH : ${lib.makeBinPath runtimeInputs}
+  '';
+
+  checkFlags = [
+    "--skip=repl"
+    "--skip=printer::tests"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Cross Platform Rust Repl";
+    homepage = "https://github.com/sigmaSd/IRust";
+    license = licenses.mit;
+    maintainers = with maintainers; [ lelgenio ];
+    mainProgram = "irust";
+  };
+}