push sheeet

pkgs/by-name/jb/jbake/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  makeWrapper,
+  jre,
+}:
+
+stdenv.mkDerivation rec {
+  version = "2.6.7";
+  pname = "jbake";
+
+  src = fetchzip {
+    url = "https://github.com/jbake-org/jbake/releases/download/v${version}/jbake-${version}-bin.zip";
+    sha256 = "sha256-kikGnFsParq8g0dzzYtMr2vIJD2ie8PeF6TG2G5K7KE=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ jre ];
+
+  postPatch = "patchShebangs .";
+
+  installPhase = ''
+    mkdir -p $out
+    cp -vr * $out
+    wrapProgram $out/bin/jbake --set JAVA_HOME "${jre}"
+  '';
+
+  checkPhase = ''
+    export JAVA_HOME=${jre}
+    bin/jbake | grep -q "${version}" || (echo "jbake did not return correct version"; exit 1)
+  '';
+  doCheck = true;
+
+  meta = with lib; {
+    description = "Java based, open source, static site/blog generator for developers & designers";
+    homepage = "https://jbake.org/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ moaxcp ];
+  };
+}

pkgs/by-name/jb/jbang/package.nix

@@ -0,0 +1,58 @@
+{
+  stdenv,
+  lib,
+  fetchzip,
+  jdk,
+  makeWrapper,
+  coreutils,
+  curl,
+}:
+
+stdenv.mkDerivation rec {
+  version = "0.131.0";
+  pname = "jbang";
+
+  src = fetchzip {
+    url = "https://github.com/jbangdev/jbang/releases/download/v${version}/${pname}-${version}.tar";
+    sha256 = "sha256-Vp7iCO77JWQzPHcF0i5st5TBv1bqjbwnhGHk3+sIr2A=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+    rm bin/jbang.{cmd,ps1}
+    cp -r . $out
+    wrapProgram $out/bin/jbang \
+      --set JAVA_HOME ${jdk} \
+      --set PATH ${
+        lib.makeBinPath [
+          (placeholder "out")
+          coreutils
+          jdk
+          curl
+        ]
+      }
+    runHook postInstall
+  '';
+
+  installCheckPhase = ''
+    $out/bin/jbang --version 2>&1 | grep -q "${version}"
+  '';
+
+  meta = with lib; {
+    description = "Run java as scripts anywhere";
+    mainProgram = "jbang";
+    longDescription = ''
+      jbang uses the java language to build scripts similar to groovy scripts. Dependencies are automatically
+      downloaded and the java code runs.
+    '';
+    homepage = "https://www.jbang.dev";
+    sourceProvenance = with lib.sourceTypes; [
+      binaryBytecode
+    ];
+    license = licenses.mit;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ moaxcp ];
+  };
+}

pkgs/by-name/jb/jbig2dec/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  python3,
+  autoconf,
+  automake,
+  libtool,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jbig2dec";
+  version = "0.20";
+
+  src = fetchurl {
+    url = "https://github.com/ArtifexSoftware/jbig2dec/archive/${version}/jbig2dec-${version}.tar.gz";
+    hash = "sha256-qXBTaaZjOrpTJpNFDsgCxWI5fhuCRmLegJ7ekvZ6/yE=";
+  };
+
+  postPatch = ''
+    patchShebangs test_jbig2dec.py
+  '';
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    libtool
+  ];
+
+  # `autogen.sh` runs `configure`, and expects that any flags needed
+  # by `configure` (like `--host`) are passed to `autogen.sh`.
+  configureScript = "./autogen.sh";
+
+  nativeCheckInputs = [ python3 ];
+  doCheck = true;
+
+  meta = {
+    homepage = "https://www.jbig2dec.com/";
+    description = "Decoder implementation of the JBIG2 image compression format";
+    mainProgram = "jbig2dec";
+    license = lib.licenses.agpl3Only;
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/jb/jbig2enc/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  leptonica,
+  zlib,
+  libwebp,
+  giflib,
+  libjpeg,
+  libpng,
+  libtiff,
+  python3,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jbig2enc";
+  version = "0.30";
+
+  src = fetchFromGitHub {
+    owner = "agl";
+    repo = "jbig2enc";
+    rev = version;
+    hash = "sha256-B19l2NdMq+wWKQ5f/y5aoPiBtQnn6sqpaIoyIq+ugTg=";
+  };
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  buildInputs = [
+    leptonica
+    zlib
+    libwebp
+    giflib
+    libjpeg
+    libpng
+    libtiff
+    python3
+  ];
+
+  # We don't want to install this Python 2 script
+  #postInstall = ''
+  #  rm "$out/bin/pdf.py"
+  #'';
+
+  # This is necessary, because the resulting library has
+  # /tmp/nix-build-jbig2enc/src/.libs before /nix/store/jbig2enc/lib
+  # in its rpath, which means that patchelf --shrink-rpath removes
+  # the /nix/store one.  By cleaning up before fixup, we ensure that
+  # the /tmp/nix-build-jbig2enc/src/.libs directory is gone.
+  preFixup = ''
+    make clean
+  '';
+
+  meta = {
+    description = "Encoder for the JBIG2 image compression format";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.all;
+    homepage = "https://github.com/agl/jbig2enc";
+    mainProgram = "jbig2";
+  };
+}

pkgs/by-name/jb/jbigkit/package.nix

@@ -0,0 +1,99 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jbigkit";
+  version = "2.1";
+
+  src = fetchurl {
+    url = "https://www.cl.cam.ac.uk/~mgk25/jbigkit/download/jbigkit-${finalAttrs.version}.tar.gz";
+    hash = "sha256-3nEGtr+vSV1oZcfdesbKE4G9EuDYFAXqgefyFnJj2TI=";
+  };
+
+  patches = [
+    # Archlinux patch: this helps users to reduce denial-of-service risks, as in CVE-2017-9937
+    (fetchpatch {
+      url = "https://gitlab.archlinux.org/archlinux/packaging/packages/jbigkit/-/raw/main/0013-new-jbig.c-limit-s-maxmem-maximum-decoded-image-size.patch";
+      hash = "sha256-Yq5qCTF7KZTrm4oeWbpctb+QLt3shJUGEReZvd0ey9k=";
+    })
+    # Archlinux patch: fix heap overflow
+    (fetchpatch {
+      url = "https://gitlab.archlinux.org/archlinux/packaging/packages/jbigkit/-/raw/main/0015-jbg_newlen-check-for-end-of-file-within-MARKER_NEWLE.patch";
+      hash = "sha256-F3qA/btR9D9NfzrNY76X4Z6vG6NrisI36SjCDjS+F5s=";
+    })
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    # Archlinux patch: build shared object
+    (fetchpatch {
+      url = "https://gitlab.archlinux.org/archlinux/packaging/packages/jbigkit/-/raw/main/jbigkit-2.1-shared_lib.patch";
+      hash = "sha256-+efeeKg3FJ/TjSOj58kD+DwnaCm3zhGzKLfUes/d5rg=";
+    })
+    (fetchpatch {
+      url = "https://gitlab.archlinux.org/archlinux/packaging/packages/jbigkit/-/raw/main/jbigkit-2.1-ldflags.patch";
+      hash = "sha256-ik3NifyuhDHnIMTrNLAKInPgu2F5u6Gvk9daqrn8ZhY=";
+    })
+    # Archlinux patch: update coverity
+    (fetchpatch {
+      url = "https://gitlab.archlinux.org/archlinux/packaging/packages/jbigkit/-/raw/main/jbigkit-2.1-coverity.patch";
+      hash = "sha256-APm9A2f4sMufuY3cnL9HOcSCa9ov3pyzgQTTKLd49/E=";
+    })
+    # Archlinux patch: fix build warnings
+    (fetchpatch {
+      url = "https://gitlab.archlinux.org/archlinux/packaging/packages/jbigkit/-/raw/main/jbigkit-2.1-build_warnings.patch";
+      hash = "sha256-lDEJ1bvZ+zR7K4CiTq+aXJ8PGjILE3W13kznLLlGOOg=";
+    })
+  ];
+
+  makeFlags = [
+    "AR=${lib.getBin stdenv.cc.bintools.bintools}/bin/${stdenv.cc.targetPrefix}ar"
+    "CC=${stdenv.cc}/bin/${stdenv.cc.targetPrefix}cc"
+    "DESTDIR=${placeholder "out"}"
+    "RANLIB=${lib.getBin stdenv.cc.bintools.bintools}/bin/${stdenv.cc.targetPrefix}ranlib"
+  ];
+
+  postPatch = ''
+    sed -i 's/^\(CFLAGS.*\)$/\1 -fPIC/' Makefile
+
+    for f in Makefile libjbig/Makefile pbmtools/Makefile; do
+        sed -i -E 's/\bar /$(AR) /g;s/\branlib /$(RANLIB) /g' "$f"
+    done
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -vDm 644 libjbig/*.h -t "$out/include/"
+    install -vDm 755 pbmtools/{jbgtopbm{,85},pbmtojbg{,85}} -t "$out/bin/"
+    install -vDm 644 pbmtools/*.1* -t "$out/share/man/man1/"
+  ''
+  + lib.optionalString stdenv.hostPlatform.isDarwin ''
+    install -vDm 644 libjbig/libjbig*.a -t "$out/lib/"
+  ''
+  + lib.optionalString stdenv.hostPlatform.isLinux ''
+    install -vDm 755 libjbig/*.so.* -t "$out/lib/"
+
+    for lib in libjbig.so libjbig85.so; do
+      ln -sv "$lib.${finalAttrs.version}" "$out/lib/$lib"
+      ln -sv "$out/lib/$lib.${finalAttrs.version}" "$out/lib/$lib.0"
+    done
+  ''
+  + ''
+    runHook postInstall
+  '';
+
+  doCheck = true;
+
+  # Testing deletes all files on each test, causes test failures.
+  enableParallelChecking = false;
+
+  meta = {
+    description = "Software implementation of the JBIG1 data compression standard";
+    homepage = "http://www.cl.cam.ac.uk/~mgk25/jbigkit/";
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/jb/jbofihe/fix-gcc14-errors.patch

@@ -0,0 +1,37 @@
+diff --git a/add_trace_to_tabc.pl b/add_trace_to_tabc.pl
+index 04be787..3186075 100644
+--- a/add_trace_to_tabc.pl
++++ b/add_trace_to_tabc.pl
+@@ -15,11 +15,11 @@
+ # COPYRIGHT
+ 
+ print <<EOF;
+-extern elide_trace_reduce(int, int);
+-extern elide_trace_shift(int,int);
+-extern report_trace_shift(int);
+-extern report_trace_reduce(int, int);
+-extern report_trace_error(short *yyss, short *yyssp);
++extern void elide_trace_reduce(int, int);
++extern void elide_trace_shift(int,int);
++extern void report_trace_shift(int);
++extern void report_trace_reduce(int, int);
++extern void report_trace_error(short *yyss, short *yyssp);
+ EOF
+ 
+ while (<>) {
+diff --git a/dfasyn/n2d.h b/dfasyn/n2d.h
+index b2159ba..6c56abb 100644
+--- a/dfasyn/n2d.h
++++ b/dfasyn/n2d.h
+@@ -181,6 +181,10 @@ Expr * new_xor_expr(Expr *c1, Expr *c2);
+ Expr * new_cond_expr(Expr *c1, Expr *c2, Expr *c3);
+ Expr * new_sym_expr(char *sym_name);
+ 
++int yyparse(void);
++void yyerror(char *);
++int yylex(void);
++
+ void define_symbol(Evaluator *x, char *name, Expr *e);
+ void define_result(Evaluator *x, char *string, Expr *e, int early);
+ void define_symresult(Evaluator *x, char *string, Expr *e, int early);
+

pkgs/by-name/jb/jbofihe/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  bison,
+  flex,
+  perl,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jbofihe";
+  version = "0.43";
+
+  src = fetchFromGitHub {
+    owner = "lojban";
+    repo = "jbofihe";
+    rev = "v${finalAttrs.version}";
+    sha256 = "1xx7x1256sjncyzx656jl6jl546vn8zz0siymqalz6v9yf341p98";
+  };
+
+  patches = [
+    # fix build with gcc14:
+    # https://github.com/lojban/jbofihe/pull/19
+    ./fix-gcc14-errors.patch
+  ];
+
+  nativeBuildInputs = [
+    bison
+    flex
+    perl
+  ];
+
+  doCheck = true;
+  checkPhase = ''
+    runHook preCheck
+    (cd tests && ./run *.in)
+    runHook postCheck
+  '';
+
+  meta = {
+    description = "Parser & analyser for Lojban";
+    homepage = "https://github.com/lojban/jbofihe";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ chkno ];
+  };
+})

pkgs/by-name/jb/jboss/package.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  jdk,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jboss-as";
+  version = "7.1.1.Final";
+  src = fetchurl {
+    url = "https://download.jboss.org/jbossas/${lib.versions.majorMinor version}/jboss-as-${version}/jboss-as-${version}.tar.gz";
+    sha256 = "1bdjw0ib9qr498vpfbg8klqw6rl11vbz7vwn6gp1r5gpqkd3zzc8";
+  };
+
+  installPhase = ''
+    mv $PWD $out
+    find $out/bin -name \*.sh -print0 | xargs -0 sed -i -e '/#!\/bin\/sh/aJAVA_HOME=${jdk}'
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.jboss.org/";
+    description = "Open Source J2EE application server";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.lgpl21;
+    maintainers = [ maintainers.sander ];
+    platforms = platforms.unix;
+    knownVulnerabilities = [
+      "CVE-2015-7501: remote code execution in apache-commons-collections: InvokerTransformer during deserialisation"
+    ];
+  };
+}

pkgs/by-name/jb/jboss_mysql_jdbc/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  mysql_jdbc,
+}:
+
+stdenv.mkDerivation {
+  pname = "jboss-mysql-jdbc";
+  inherit (mysql_jdbc) version;
+
+  dontUnpack = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/server/default/lib
+    ln -s $mysql_jdbc/share/java/mysql-connector-java.jar $out/server/default/lib/mysql-connector-java.jar
+
+    runHook postInstall
+  '';
+
+  meta = {
+    inherit (mysql_jdbc.meta)
+      description
+      license
+      platforms
+      homepage
+      ;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/jb/jbrowse/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  fetchurl,
+  appimageTools,
+}:
+
+let
+  pname = "jbrowse";
+  version = "3.6.5";
+
+  src = fetchurl {
+    url = "https://github.com/GMOD/jbrowse-components/releases/download/v${version}/jbrowse-desktop-v${version}-linux.AppImage";
+    sha256 = "sha256-aCmNpZX8TBZm7nbS13GBUG4a/X4kvwWRHvwWWykoLwU=";
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit pname version src;
+  };
+
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+  unshareIpc = false;
+
+  extraInstallCommands = ''
+    mv $out/bin/jbrowse $out/bin/jbrowse-desktop
+    install -m 444 -D ${appimageContents}/jbrowse-desktop.desktop $out/share/applications/jbrowse-desktop.desktop
+    install -m 444 -D ${appimageContents}/jbrowse-desktop.png \
+       $out/share/icons/hicolor/512x512/apps/jbrowse-desktop.png
+    substituteInPlace $out/share/applications/jbrowse-desktop.desktop \
+      --replace 'Exec=AppRun --no-sandbox' 'Exec=jbrowse-desktop'
+  '';
+
+  meta = with lib; {
+    description = "Next-generation genome browser";
+    mainProgram = "jbrowse-desktop";
+    homepage = "https://jbrowse.org/jb2/";
+    license = licenses.asl20;
+    maintainers = [ ];
+    platforms = [ "x86_64-linux" ];
+  };
+}