push sheeet

pkgs/by-name/jd/jd-diff-patch/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "jd-diff-patch";
+  version = "2.3.0";
+
+  src = fetchFromGitHub {
+    owner = "josephburnett";
+    repo = "jd";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-eaNP7cSJ0IxfHLmPaNAw5MQzD41AiOIjVbAjQkU8uec=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/v2";
+
+  # not including web ui
+  excludedPackages = [
+    "gae"
+    "pack"
+  ];
+
+  vendorHash = "sha256-RerzCZL2soPNtl1hHWjdeNQNQ4VMlGYz3HNn4rTJSmU=";
+
+  meta = {
+    description = "Commandline utility and Go library for diffing and patching JSON values";
+    homepage = "https://github.com/josephburnett/jd";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      bryanasdev000
+      juliusfreudenberger
+    ];
+    mainProgram = "jd";
+  };
+})

pkgs/by-name/jd/jdd/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+  versionCheckHook,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "jdd";
+  version = "0.4.5";
+
+  src = fetchFromGitHub {
+    owner = "mahyarmirrashed";
+    repo = "jdd";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-3keJrKbR3+J3z22W8Xoabz9YhvjRRBBMo59l/eJo7Hs=";
+  };
+
+  vendorHash = "sha256-KEg5X2wHx7KPHEL1zJd/DeDnR69FyB6pajpHIYdep2k=";
+
+  ldflags = [ "-X=main.version=${finalAttrs.version}" ];
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+
+  meta = {
+    description = "Johnny Decimal daemon for automatically organizing files into the correct drawer using their filename";
+    homepage = "https://github.com/mahyarmirrashed/jdd";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ mahyarmirrashed ];
+    mainProgram = "jdd";
+  };
+})

pkgs/by-name/jd/jdenticon-cli/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  nodejs,
+  makeWrapper,
+  versionCheckHook,
+  nix-update-script,
+}:
+buildNpmPackage (finalAttrs: {
+  pname = "jdenticon-cli";
+  version = "3.3.0";
+  src = fetchFromGitHub {
+    owner = "dmester";
+    repo = "jdenticon";
+    tag = finalAttrs.version;
+    hash = "sha256-uOPNsfEreC7F+Y0WWmudZSPnGxqarna0JPOwQyK6LiQ=";
+  };
+  npmDepsHash = "sha256-LXwvb088oHmA57EryfYtKi0L/9sB+yyUr/K/qGA1W9k=";
+
+  nativeBuildInputs = [
+    makeWrapper
+    nodejs
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -D bin/jdenticon.js "$out/lib/jdenticon/bin/jdenticon.js"
+    install -D dist/jdenticon-node.js "$out/lib/jdenticon/dist/jdenticon-node.js"
+    install -d "$out/lib/jdenticon/node_modules"
+    cp -r node_modules/canvas-renderer  "$out/lib/jdenticon/node_modules"
+    makeWrapper "${lib.getExe nodejs}" "$out/bin/jdenticon" \
+      --add-flags "$out/lib/jdenticon/bin/jdenticon.js"
+
+    runHook postInstall
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/dmester/jdenticon/releases/tag/${finalAttrs.version}";
+    description = "JavaScript library for generating highly recognizable identicons using HTML5 canvas or SVG.";
+    homepage = "https://jdenticon.com/";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.gipphe ];
+    mainProgram = "jdenticon";
+  };
+})

pkgs/by-name/jd/jdepend/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ant,
+  jdk8,
+  makeWrapper,
+  stripJavaArchivesHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jdepend";
+  version = "2.10";
+
+  src = fetchFromGitHub {
+    owner = "clarkware";
+    repo = "jdepend";
+    rev = finalAttrs.version;
+    hash = "sha256-0/xGgAaJ7TTUHxShJbbcPzTODk4lDn+FOn5St5McrtM=";
+  };
+
+  nativeBuildInputs = [
+    ant
+    jdk8
+    makeWrapper
+    stripJavaArchivesHook
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+    ant jar
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm644 dist/jdepend-*.jar -t $out/share/jdepend
+
+    makeWrapper ${jdk8.jre}/bin/java $out/bin/jdepend \
+        --add-flags "-classpath $out/share/jdepend/jdepend-*.jar"
+
+    for type in "swingui" "textui" "xmlui"; do
+      makeWrapper $out/bin/jdepend $out/bin/jdepend-$type \
+          --add-flags "jdepend.$type.JDepend"
+    done
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    changelog = "https://github.com/clarkware/jdepend/blob/${finalAttrs.src.rev}/CHANGELOG.md";
+    description = "Traverses Java class file directories and generates design quality metrics for each Java package";
+    homepage = "http://www.clarkware.com/software/JDepend.html";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ pSub ];
+    platforms = platforms.linux;
+  };
+})

pkgs/by-name/jd/jdiskreport/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+  jre,
+  makeDesktopItem,
+  copyDesktopItems,
+}:
+
+let
+  desktopItem = makeDesktopItem {
+    desktopName = "JDiskReport";
+    genericName = "A graphical utility to visualize disk usage";
+    categories = [ "Utility" ];
+    exec = "jdiskreport";
+    name = "jdiskreport";
+  };
+in
+stdenv.mkDerivation rec {
+  pname = "jdiskreport";
+  version = "1.4.1";
+
+  src = fetchurl {
+    url = "https://www.jgoodies.com/download/jdiskreport/jdiskreport-${
+      lib.replaceStrings [ "." ] [ "_" ] version
+    }.zip";
+    sha256 = "0d5mzkwsbh9s9b1vyvpaawqc09b0q41l2a7pmwf7386b1fsx6d58";
+  };
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    unzip
+  ];
+  inherit jre;
+
+  installPhase = ''
+    runHook preInstall
+
+    unzip $src
+
+    jar=$(ls */*.jar)
+
+    mkdir -p $out/share/java
+    mv $jar $out/share/java
+
+    mkdir -p $out/bin
+    cat > $out/bin/jdiskreport <<EOF
+    #! $SHELL -e
+    exec $jre/bin/java -jar $out/share/java/$(basename $jar)
+    EOF
+    chmod +x $out/bin/jdiskreport
+
+    runHook postInstall
+  '';
+
+  desktopItems = [ desktopItem ];
+
+  meta = with lib; {
+    homepage = "http://www.jgoodies.com/freeware/jdiskreport/";
+    description = "Graphical utility to visualize disk usage";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.unfreeRedistributable; # TODO freedist, libs under BSD-3
+    platforms = [
+      "x86_64-linux"
+      "x86_64-darwin"
+    ];
+    maintainers = with maintainers; [ kylesferrazza ];
+    mainProgram = "jdiskreport";
+  };
+}

pkgs/by-name/jd/jdom/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jdom";
+  version = "2.0.6.1";
+
+  src = fetchzip {
+    url = "http://www.jdom.org/dist/binary/jdom-${version}.zip";
+    stripRoot = false;
+    hash = "sha256-Y++mlO+7N5EU2NhRzLl5x5WXNqu/2tDO/NpNhfRegcg=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/java
+    cp -a . $out/share/java
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Java-based solution for accessing, manipulating, and outputting XML data from Java code";
+    homepage = "http://www.jdom.org";
+    platforms = platforms.unix;
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = licenses.bsdOriginal;
+  };
+}

pkgs/by-name/jd/jdt-language-server/package.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  python3,
+  jdk,
+}:
+
+let
+  timestamp = "202507311558";
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jdt-language-server";
+  version = "1.49.0";
+
+  src = fetchurl {
+    url = "https://download.eclipse.org/jdtls/milestones/${finalAttrs.version}/jdt-language-server-${finalAttrs.version}-${timestamp}.tar.gz";
+    hash = "sha256-o/n7WSH1Jz0Pj+Q2WzY/utG9wuhpkdsxSbLXbxJlvNc=";
+  };
+
+  sourceRoot = ".";
+
+  buildInputs = [
+    # Used for the included wrapper
+    python3
+  ];
+
+  postPatch = ''
+    # We store the plugins, config, and features folder in different locations
+    # than in the original package. In addition, hard-code the path to the jdk
+    # in the wrapper, instead of searching for it in PATH at runtime.
+    substituteInPlace bin/jdtls.py \
+      --replace-fail "jdtls_base_path = Path(__file__).parent.parent" "jdtls_base_path = Path(\"$out/share/java/jdtls/\")" \
+      --replace-fail "java_executable = get_java_executable(known_args)" "java_executable = '${lib.getExe jdk}'"
+  '';
+
+  installPhase =
+    let
+      # The application ships with different config directories for each platform.
+      # Note the application come with ARM variants as well, although the
+      # current included wrapper doesn't use them.
+      configDir = if stdenv.hostPlatform.isDarwin then "config_mac" else "config_linux";
+    in
+    ''
+      runHook preInstall
+
+      install -Dm444 -t $out/share/java/jdtls/plugins/ plugins/*
+      install -Dm444 -t $out/share/java/jdtls/features/ features/*
+      install -Dm444 -t $out/share/java/jdtls/${configDir} ${configDir}/*
+      install -Dm555 -t $out/bin bin/jdtls
+      install -Dm444 -t $out/bin bin/jdtls.py
+
+      runHook postInstall
+    '';
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    homepage = "https://github.com/eclipse/eclipse.jdt.ls";
+    description = "Java language server";
+    sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
+    license = lib.licenses.epl20;
+    maintainers = with lib.maintainers; [ matt-snider ];
+    platforms = lib.platforms.all;
+    mainProgram = "jdtls";
+  };
+})

pkgs/by-name/jd/jdt-language-server/update.sh

@@ -0,0 +1,21 @@
+#! /usr/bin/env nix-shell
+#! nix-shell -i bash --pure -p curl cacert libxml2 yq nix jq
+
+set -euo pipefail
+
+cd "$(dirname "${BASH_SOURCE[0]}")"
+DRV_DIR="$PWD"
+
+# scrape the downloads page for release info
+newver=$(curl -s 'https://download.eclipse.org/jdtls/milestones/' | xmllint --html - --xmlout 2>/dev/null | xq --raw-output '.html.body.main.div.div.div[0].div.table.tr | max_by(.td[3]).td[1].a.["#text"]')
+
+prefix="https://download.eclipse.org/jdtls/milestones/$newver"
+
+filename=$(curl -s "$prefix/latest.txt")
+newtimestamp=$(echo $filename | sed "s|^.*-$newver-||;s|\.tar\.gz$||")
+newhash="$(nix-hash --to-sri --type sha256 $(nix-prefetch-url "$prefix/$filename"))";
+
+sed -i package.nix \
+    -e "/^  version =/ s|\".*\"|\"$newver\"|" \
+    -e "/^  timestamp =/ s|\".*\"|\"$newtimestamp\"|" \
+    -e "/^    hash =/ s|\".*\"|\"$newhash\"|" \

pkgs/by-name/jd/jdupes/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  libjodycode,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jdupes";
+  version = "1.29.0";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "jbruchon";
+    repo = "jdupes";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-ddl1GCA96j5H6C9KTtJudQ4wSUeOGA6p4P8JPbsVr9o=";
+    # Unicode file names lead to different checksums on HFS+ vs. other
+    # filesystems because of unicode normalisation. The testdir
+    # directories have such files and will be removed.
+    postFetch = "rm -r $out/testdir";
+  };
+
+  buildInputs = [ libjodycode ];
+
+  dontConfigure = true;
+
+  makeFlags = [
+    "PREFIX=${placeholder "out"}"
+    # don't link with ../libjodycode
+    "IGNORE_NEARBY_JC=1"
+    # link with system libjodycode (this case is erroneously missing in v1.29.0)
+    "LDFLAGS_EXTRA=-ljodycode"
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    "ENABLE_DEDUPE=1"
+    "STATIC_DEDUPE_H=1"
+  ]
+  ++ lib.optionals stdenv.cc.isGNU [ "HARDEN=1" ];
+
+  enableParallelBuilding = true;
+
+  doCheck = false; # broken Makefile, the above also removes tests
+
+  postInstall = ''
+    install -Dm444 -t $out/share/doc/jdupes CHANGES.txt LICENSE.txt README.md
+  '';
+
+  meta = {
+    description = "Powerful duplicate file finder and an enhanced fork of 'fdupes'";
+    longDescription = ''
+      jdupes is a program for identifying and taking actions upon
+      duplicate files. This fork known as 'jdupes' is heavily modified
+      from and improved over the original.
+    '';
+    homepage = "https://codeberg.org/jbruchon/jdupes";
+    license = lib.licenses.mit;
+    maintainers = [ ];
+    mainProgram = "jdupes";
+  };
+})