push sheeet

pkgs/by-name/jf/jf/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "jf";
+  version = "0.6.2";
+
+  src = fetchFromGitHub {
+    owner = "sayanarijit";
+    repo = "jf";
+    rev = "v${version}";
+    hash = "sha256-A29OvGdG6PyeKMf5RarEOrfnNSmXhXri0AlECHWep6M=";
+  };
+
+  cargoHash = "sha256-NU5D7VMQtlOFzr+LqODvDzVw56wFClcBxKo1h8zfgfY=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  # skip auto manpage update
+  buildNoDefaultFeatures = true;
+
+  postInstall = ''
+    installManPage assets/jf.1
+  '';
+
+  meta = with lib; {
+    description = "Small utility to safely format and print JSON objects in the commandline";
+    mainProgram = "jf";
+    homepage = "https://github.com/sayanarijit/jf";
+    license = licenses.mit;
+    maintainers = [ maintainers.sayanarijit ];
+  };
+}

pkgs/by-name/jf/jfbview/package.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  versionCheckHook,
+  nix-update-script,
+  freetype,
+  harfbuzz,
+  imlib2,
+  libjpeg,
+  ncurses,
+  openjpeg,
+  zlib,
+  xorg,
+  cmake,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jfbview";
+  version = "0.6.0";
+
+  src = fetchFromGitHub {
+    owner = "jichu4n";
+    repo = "jfbview";
+    tag = finalAttrs.version;
+    fetchSubmodules = true;
+    hash = "sha256-ASgKXk5iVqKsBc1uzakHs5ojUb6AptGm9LxNyFcDngc=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    freetype
+    harfbuzz
+    imlib2
+    libjpeg
+    ncurses
+    openjpeg
+    xorg.libX11
+    zlib
+  ];
+
+  env.LDFLAGS = "-lImlib2";
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_TESTING" false)
+    (lib.cmakeFeature "CMAKE_BUILD_TYPE" "Release")
+    (lib.cmakeFeature "CMAKE_INSTALL_PREFIX" "/") # relative to $out
+  ];
+
+  makeFlags = [ "DESTDIR=${placeholder "out"}" ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "PDF and image viewer for the Linux framebuffer";
+    homepage = "https://github.com/jichu4n/jfbview";
+    changelog = "https://github.com/jichu4n/jfbview/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ ulysseszhan ];
+    platforms = lib.platforms.linux;
+    mainProgram = "jfbview";
+  };
+})

pkgs/by-name/jf/jffi/package.nix

@@ -0,0 +1,75 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ant,
+  jdk,
+  libffi,
+  pkg-config,
+  texinfo,
+  stripJavaArchivesHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jffi";
+  version = "1.3.13";
+
+  src = fetchFromGitHub {
+    owner = "jnr";
+    repo = "jffi";
+    rev = "jffi-${finalAttrs.version}";
+    hash = "sha256-aBQkkZyXZkaJc4sr/jHnIRaJYP116u4Jqsr9XXzfOBA=";
+  };
+
+  nativeBuildInputs = [
+    ant
+    jdk
+    pkg-config
+    texinfo
+    stripJavaArchivesHook
+  ];
+
+  buildInputs = [ libffi ];
+
+  # The pkg-config script in the build.xml doesn't work propery
+  # set the lib path manually to work around this.
+  env.LIBFFI_LIBS = "${libffi}/lib/libffi${stdenv.hostPlatform.extensions.sharedLibrary}";
+  env.ANT_ARGS = "-Duse.system.libffi=1";
+
+  buildPhase = ''
+    runHook preBuild
+    ant jar
+    ant archive-platform-jar
+    runHook postBuild
+  '';
+
+  doCheck = true;
+
+  checkPhase = ''
+    runHook preCheck
+    ant test
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm644 dist/*.jar -t $out/share/java
+    runHook postInstall
+  '';
+
+  # nix can't detect libffi as a dependency inside the jar file, so we create
+  # a dummy file with the path to libffi, to make sure that nix knows about it
+  postFixup = ''
+    mkdir -p $out/nix-support
+    echo ${libffi} > $out/nix-support/depends
+  '';
+
+  meta = with lib; {
+    broken = stdenv.hostPlatform.isDarwin;
+    description = "Java Foreign Function Interface";
+    homepage = "https://github.com/jnr/jffi";
+    platforms = platforms.unix;
+    license = licenses.asl20;
+    maintainers = with maintainers; [ bachp ];
+  };
+})

pkgs/by-name/jf/jflap/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  jre8,
+  makeWrapper,
+  makeDesktopItem,
+  copyDesktopItems,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "jflap";
+  version = "7.1";
+
+  src = fetchurl {
+    url = "https://www.jflap.org/jflaptmp/july27-18/JFLAP${version}.jar";
+    sha256 = "oiwJXdxWsYFj6Ovu7xZbOgTLVw8160a5YQUWbgbJlAY=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  buildInputs = [
+    jre8
+  ];
+
+  dontUnpack = true;
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "jflap";
+      desktopName = "jflap";
+      genericName = "Formal language application";
+      exec = "jflap";
+      icon = fetchurl {
+        url = "https://www.jflap.org/jflapLogo2.jpg";
+        sha256 = "sha256-IiworHI+GT6Fm6B0E+FXnKe+hN8nZYPrxHGZFAcsWDw=";
+      };
+      comment = meta.description;
+      categories = [
+        "Development"
+        "Education"
+        "ComputerScience"
+        "DataVisualization"
+        "Engineering"
+        "Java"
+      ];
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/share/java
+    cp -s $src $out/share/java/jflap.jar
+    makeWrapper ${jre8}/bin/java $out/bin/jflap \
+      --prefix _JAVA_OPTIONS " " "-Dawt.useSystemAAFontSettings=gasp" \
+      --add-flags "-jar $out/share/java/jflap.jar"
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "GUI tool for experimenting with formal languages topics";
+    homepage = "https://www.jflap.org/";
+    license = licenses.unfree;
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    maintainers = with maintainers; [
+      grnnja
+    ];
+    platforms = jre8.meta.platforms;
+  };
+}

pkgs/by-name/jf/jflex/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  jre,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jflex";
+  version = "1.9.1";
+
+  src = fetchurl {
+    url = "http://jflex.de/release/jflex-${version}.tar.gz";
+    sha256 = "sha256-4MHp7vkf9t8E1z+l6v8T86ArZ5/uFHTlzK4AciTfbfY=";
+  };
+
+  sourceRoot = "${pname}-${version}";
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out
+    cp -a * $out
+    rm -f $out/bin/jflex.bat
+
+    patchShebangs $out
+    sed -i -e '/^JAVA=java/ s#java#${jre}/bin/java#' $out/bin/jflex
+    runHook postInstall
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    runHook preInstallCheck
+    $out/bin/jflex --version
+    runHook postInstallCheck
+  '';
+
+  meta = {
+    homepage = "https://www.jflex.de/";
+    description = "Lexical analyzer generator for Java, written in Java";
+    mainProgram = "jflex";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/jf/jfmt/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "jfmt";
+  version = "1.2.1";
+
+  src = fetchFromGitHub {
+    owner = "scruffystuffs";
+    repo = "${pname}.rs";
+    rev = "v${version}";
+    hash = "sha256-X3wk669G07BTPAT5xGbAfIu2Qk90aaJIi1CLmOnSG80=";
+  };
+
+  cargoHash = "sha256-skLK+jYeR0FPxD1fVswiOWyKpzu5/qL5mk69bLEmxic=";
+
+  meta = {
+    description = "CLI utility to format json files";
+    mainProgram = "jfmt";
+    homepage = "https://github.com/scruffystuffs/jfmt.rs";
+    changelog = "https://github.com/scruffystuffs/jfmt.rs/blob/${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.psibi ];
+  };
+}

pkgs/by-name/jf/jfrog-cli/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nodejs,
+  nix-update-script,
+}:
+
+buildGoModule rec {
+  pname = "jfrog-cli";
+  version = "2.78.10";
+
+  src = fetchFromGitHub {
+    owner = "jfrog";
+    repo = "jfrog-cli";
+    tag = "v${version}";
+    hash = "sha256-o3H+onnvGFGxUtFRYFHmrEQ5EqQCGP8n/NdqdEHNj84=";
+  };
+
+  proxyVendor = true;
+  vendorHash = "sha256-jzjYFnctUwQUVC59JIsrHTIWCqYiZTurNFLn9zuM+18=";
+
+  checkFlags = "-skip=^TestReleaseBundle";
+
+  postInstall = ''
+    # Name the output the same way as the original build script does
+    mv $out/bin/jfrog-cli $out/bin/jf
+  '';
+
+  # Some of the tests require a writable $HOME
+  preCheck = "export HOME=$TMPDIR";
+
+  nativeCheckInputs = [ nodejs ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/jfrog/jfrog-cli";
+    description = "Client for accessing to JFrog's Artifactory and Mission Control through their respective REST APIs";
+    changelog = "https://github.com/jfrog/jfrog-cli/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    mainProgram = "jf";
+    maintainers = with lib.maintainers; [
+      detegr
+      aidalgol
+    ];
+  };
+}

pkgs/by-name/jf/jfsutils/ar-fix.patch

@@ -0,0 +1,10 @@
+--- jfsutils-1.1.15/configure.in.orig	2018-11-27 20:46:55.830242385 +0300
++++ jfsutils-1.1.15/configure.in	2018-11-27 20:47:00.596307630 +0300
+@@ -15,6 +15,7 @@
+ AC_PATH_PROG(LN, ln, ln)
+ AC_PROG_LN_S
+ AC_PROG_RANLIB
++AM_PROG_AR
+ 
+ dnl Checks for header files.
+ AC_HEADER_STDC

pkgs/by-name/jf/jfsutils/hardening-format.patch

@@ -0,0 +1,37 @@
+--- a/fscklog/fscklog.c	2016-01-29 04:59:54.102223291 +0000
++++ b/fscklog/fscklog.c	2016-01-29 05:00:10.707552565 +0000
+@@ -252,8 +252,8 @@
+ 
+ 	sprintf(debug_detail, " [%s:%d]\n", basename(file_name), line_number);
+ 
+-	printf(msg_string);
+-	printf(debug_detail);
++	printf("%s", msg_string);
++	printf("%s", debug_detail);
+ 
+ 	return 0;
+ }
+--- a/fscklog/display.c	2016-01-29 05:05:42.582133444 +0000
++++ b/fscklog/display.c	2016-01-29 05:05:47.541231780 +0000
+@@ -182,7 +182,7 @@
+ 				} else {
+ 					/* the record looks ok */
+ 					msg_txt = &log_entry[log_entry_pos];
+-					printf(msg_txt);
++					printf("%s", msg_txt);
+ 					/*
+ 					 * set up for the next record
+ 					 */
+--- a/logdump/helpers.c	2016-01-29 05:06:26.081996021 +0000
++++ b/logdump/helpers.c	2016-01-29 05:06:43.097333425 +0000
+@@ -95,8 +95,8 @@
+ 
+ 	sprintf(debug_detail, " [%s:%d]\n", file_name, line_number);
+ 
+-	printf(msg_string);
+-	printf(debug_detail);
++	printf("%s", msg_string);
++	printf("%s", debug_detail);
+ 
+ 	return 0;
+ }

pkgs/by-name/jf/jfsutils/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  libuuid,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jfsutils";
+  version = "1.1.15";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/jfs/jfsutils-${version}.tar.gz";
+    sha256 = "0kbsy2sk1jv4m82rxyl25gwrlkzvl3hzdga9gshkxkhm83v1aji4";
+  };
+
+  patches = [
+    ./types.patch
+    ./hardening-format.patch
+    # required for cross-compilation
+    ./ar-fix.patch
+    # fix for glibc>=2.28
+    (fetchpatch {
+      name = "add_sysmacros.patch";
+      url = "https://sources.debian.org/data/main/j/jfsutils/1.1.15-4/debian/patches/add_sysmacros.patch";
+      sha256 = "1qcwvxs4d0d24w5x98z59arqfx2n7f0d9xaqhjcg6w8n34vkhnyc";
+    })
+    # fix for musl
+    (fetchpatch {
+      name = "musl-fix-includes.patch";
+      url = "https://git.alpinelinux.org/aports/plain/main/jfsutils/musl-fix-includes.patch?id=567823dca7dc1f8ce919efbe99762d2d5c020124";
+      sha256 = "sha256-FjdUOI+y+MdSWxTR+csH41uR0P+PWWTfIMPwQjBfQtQ=";
+    })
+  ];
+
+  nativeBuildInputs = [ autoreconfHook ];
+  buildInputs = [ libuuid ];
+
+  # Workaround build failure on -fno-common toolchains like upstream
+  # gcc-10. Otherwise build fails as:
+  #     ld: extract.o:/build/jfsutils-1.1.15/fscklog/extract.c:67: multiple definition of
+  #       `xchklog_buffer'; display.o:/build/jfsutils-1.1.15/fscklog/display.c:57: first defined here
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  # this required for wipefreespace
+  postInstall = ''
+    mkdir -p $out/include
+    cp include/*.h $out/include
+    mkdir -p $out/lib
+    cp ./libfs/libfs.a $out/lib
+  '';
+
+  meta = with lib; {
+    description = "IBM JFS utilities";
+    homepage = "https://jfs.sourceforge.net";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/jf/jfsutils/types.patch

@@ -0,0 +1,12 @@
+diff -ru -x '*~' jfsutils-1.1.15-orig/libfs/devices.h jfsutils-1.1.15/libfs/devices.h
+--- jfsutils-1.1.15-orig/libfs/devices.h	2005-11-22 21:43:55.000000000 +0100
++++ jfsutils-1.1.15/libfs/devices.h	2013-01-28 13:58:56.888630278 +0100
+@@ -18,6 +18,8 @@
+ #ifndef H_DEVICES
+ #define H_DEVICES
+ 
++#include <inttypes.h>
++
+ #define GET	0
+ #define PUT	1
+ #define VRFY	2

pkgs/by-name/jf/jfsw/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  which,
+  SDL2,
+  perl,
+  pkg-config,
+  wrapGAppsHook3,
+  gtk3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jfsw";
+  version = "20240303";
+
+  src = fetchFromGitHub {
+    owner = "jonof";
+    repo = "jfsw";
+    tag = finalAttrs.version;
+    fetchSubmodules = true;
+    hash = "sha256-bOUgRa9zWufTFEj5huXAKeRerV8PqfqQVDoVUvRrj2I=";
+  };
+
+  nativeBuildInputs = [
+    which
+    SDL2
+    perl
+    pkg-config
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    SDL2
+    gtk3
+  ];
+
+  strictDeps = true;
+  enableParallelBuilding = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 sw -t $out/bin
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Modern port the original Shadow Warrior";
+    homepage = "http://www.jonof.id.au/jfsw/";
+    license = lib.licenses.gpl2Plus;
+    mainProgram = "sw";
+    maintainers = with lib.maintainers; [ moody ];
+    broken = stdenv.hostPlatform.isDarwin;
+    inherit (SDL2.meta) platforms;
+  };
+})

pkgs/by-name/jf/jftui/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  curl,
+  mpv,
+  yajl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jftui";
+  version = "0.7.5";
+
+  src = fetchFromGitHub {
+    owner = "Aanok";
+    repo = "jftui";
+    rev = "v${version}";
+    sha256 = "sha256-0gTJ2uXDcK9zCx6yKS3VxFyxSQZ2l4ydKUI2gYbsiao=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    curl
+    mpv
+    yajl
+  ];
+
+  installPhase = ''
+    install -Dm555 build/jftui $out/bin/jftui
+  '';
+
+  meta = with lib; {
+    description = "Jellyfin Terminal User Interface";
+    homepage = "https://github.com/Aanok/jftui";
+    license = licenses.unlicense;
+    maintainers = [ maintainers.nyanloutre ];
+    platforms = platforms.linux;
+    mainProgram = "jftui";
+  };
+}