push sheeet

pkgs/by-name/kb/kb/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "kb";
+  version = "0.1.8";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "gnebbia";
+    repo = "kb";
+    tag = "v${version}";
+    hash = "sha256-X2yFQYH4nqI5CqPtKFHq3+V/itqTpUho9en4WEIRjQM=";
+  };
+
+  postPatch = ''
+    # `attr` module is not available. And `attrs` defines another `attr` package
+    # that shadows it.
+    substituteInPlace setup.py \
+      --replace-fail \
+        "install_requires=[\"colored\",\"toml\",\"attr\",\"attrs\",\"gitpython\"]," \
+        "install_requires=[\"colored\",\"toml\",\"attrs\",\"gitpython\"],"
+  '';
+
+  build-system = with python3.pkgs; [
+    setuptools
+  ];
+
+  dependencies = with python3.pkgs; [
+    colored
+    toml
+    attrs
+    gitpython
+  ];
+
+  nativeCheckInputs = with python3.pkgs; [
+    pytest-cov-stub
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [ "kb" ];
+
+  meta = {
+    description = "Minimalist command line knowledge base manager";
+    longDescription = ''
+      kb is a text-oriented minimalist command line knowledge base manager. kb
+      can be considered a quick note collection and access tool oriented toward
+      software developers, penetration testers, hackers, students or whoever has
+      to collect and organize notes in a clean way. Although kb is mainly
+      targeted on text-based note collection, it supports non-text files as well
+      (e.g., images, pdf, videos and others).
+    '';
+    homepage = "https://github.com/gnebbia/kb";
+    changelog = "https://github.com/gnebbia/kb/blob/${src.tag}/CHANGELOG.md";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ wesleyjrz ];
+    mainProgram = "kb";
+  };
+}

pkgs/by-name/kb/kbd/package.nix

@@ -0,0 +1,149 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  nixosTests,
+  autoreconfHook,
+  pkg-config,
+  flex,
+  perl,
+  bison,
+  autoPatchelfHook,
+  check,
+  pam,
+  bash,
+  bashNonInteractive,
+  coreutils,
+  zlib,
+  bzip2,
+  xz,
+  zstd,
+  gitUpdater,
+  pkgsCross,
+  withVlock ? true,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kbd";
+  version = "2.9.0";
+
+  __structuredAttrs = true;
+
+  src = fetchgit {
+    url = "https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-uUECxFdm/UhoHKLHLFe6/ygCQ+4mrQOZExKl+ReaTNw=";
+  };
+
+  # vlock is moved into its own output, since it depends on pam. This
+  # reduces closure size for most use cases.
+  outputs = [
+    "out"
+    "dev"
+    "scripts"
+    "man"
+  ]
+  ++ lib.optionals withVlock [
+    "vlock"
+  ];
+
+  patches = [
+    ./search-paths.patch
+  ];
+
+  postPatch = ''
+    # Renaming keymaps with name clashes, because loadkeys just picks
+    # the first keymap it sees. The clashing names lead to e.g.
+    # "loadkeys no" defaulting to a norwegian dvorak map instead of
+    # the much more common qwerty one.
+    pushd data/keymaps/i386
+    mv qwertz/cz{,-qwertz}.map
+    mv olpc/es{,-olpc}.map
+    mv olpc/pt{,-olpc}.map
+    mv fgGIod/trf{,-fgGIod}.map
+    mv colemak/{en-latin9,colemak}.map
+    popd
+  '';
+
+  preConfigure = ''
+    # Perl and Bash only used during build time
+    patchShebangs --build contrib/
+  '';
+
+  configureFlags = [
+    "--enable-optional-progs"
+    "--enable-libkeymap"
+    "--disable-nls"
+    (lib.enableFeature withVlock "vlock")
+  ]
+  ++ lib.optionals (!lib.systems.equals stdenv.buildPlatform stdenv.hostPlatform) [
+    "ac_cv_func_malloc_0_nonnull=yes"
+    "ac_cv_func_realloc_0_nonnull=yes"
+  ];
+
+  strictDeps = true;
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    flex
+    perl
+    bison
+    autoPatchelfHook # for patching dlopen()
+  ];
+
+  nativeCheckInputs = [
+    check
+  ];
+
+  buildInputs = [
+    zlib
+    bzip2
+    xz
+    zstd
+    bash
+  ]
+  ++ lib.optionals withVlock [ pam ];
+
+  postInstall = ''
+    substituteInPlace $out/bin/unicode_{start,stop} \
+      --replace-fail /usr/bin/tty ${coreutils}/bin/tty
+
+    moveToOutput bin/unicode_start $scripts
+    moveToOutput bin/unicode_stop $scripts
+  ''
+  + lib.optionalString withVlock ''
+    moveToOutput bin/vlock $vlock
+    moveToOutput etc/pam.d/vlock $vlock
+  '';
+
+  outputChecks.out.disallowedRequisites = [
+    bash
+    bashNonInteractive
+  ];
+
+  passthru = {
+    updateScript = gitUpdater {
+      # No nicer place to find latest release.
+      url = "https://github.com/legionus/kbd.git";
+      rev-prefix = "v";
+    };
+    tests = {
+      cross =
+        let
+          systemString = if stdenv.buildPlatform.isAarch64 then "gnu64" else "aarch64-multiplatform";
+        in
+        pkgsCross.${systemString}.kbd;
+      inherit (nixosTests) keymap kbd-setfont-decompress kbd-update-search-paths-patch;
+    };
+  };
+
+  meta = {
+    homepage = "https://kbd-project.org/";
+    description = "Linux keyboard tools and keyboard maps";
+    platforms = lib.platforms.linux;
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ davidak ];
+  };
+})

pkgs/by-name/kb/kbd/search-paths.patch

@@ -0,0 +1,81 @@
+Add /etc/kbd to the list of directories to search for the console
+fonts, screen mappings, Unicode maps, keytable files, etc.
+
+Without this patch, kbd will only look inside
+/nix/store/<hash>-kbd-x.x.x/share.
+
+--- a/src/libkeymap/analyze.l
++++ b/src/libkeymap/analyze.l
+@@ -109,6 +109,9 @@ static const char *const include_dirpath1[] = {
+ 	NULL
+ };
+ static const char *const include_dirpath3[] = {
++	"/etc/kbd/" KEYMAPDIR "/include/",
++	"/etc/kbd/" KEYMAPDIR "/i386/include/",
++	"/etc/kbd/" KEYMAPDIR "/mac/include/",
+ 	DATADIR "/" KEYMAPDIR "/include/",
+ 	DATADIR "/" KEYMAPDIR "/i386/include/",
+ 	DATADIR "/" KEYMAPDIR "/mac/include/",
+--- a/src/libkfont/context.c
++++ b/src/libkfont/context.c
+@@ -13,5 +13,6 @@
+ /* search for the map file in these directories (with trailing /) */
+ static const char *const mapdirpath[]  = {
++	"/etc/kbd/" TRANSDIR "/",
+ 	DATADIR "/" TRANSDIR "/",
+ 	NULL
+ };
+@@ -28,5 +29,6 @@ static const char *const mapsuffixes[] = {
+ /* search for the font in these directories (with trailing /) */
+ static const char *const fontdirpath[]  = {
++	"/etc/kbd/" FONTDIR "/",
+ 	DATADIR "/" FONTDIR "/",
+ 	NULL
+ };
+@@ -42,5 +44,6 @@ static char const *const fontsuffixes[] = {
+ 
+ static const char *const unidirpath[]  = {
++	"/etc/kbd/" UNIMAPDIR "/",
+ 	DATADIR "/" UNIMAPDIR "/",
+ 	NULL
+ };
+@@ -55,5 +58,6 @@ static const char *const unisuffixes[] = {
+ /* hide partial fonts a bit - loading a single one is a bad idea */
+ static const char *const partfontdirpath[]  = {
++	"/etc/kbd/" FONTDIR "/" PARTIALDIR "/",
+ 	DATADIR "/" FONTDIR "/" PARTIALDIR "/",
+ 	NULL
+ };
+--- a/src/loadkeys.c
++++ b/src/loadkeys.c
+@@ -27,5 +27,6 @@
+ 
+ static const char *const dirpath1[] = {
++	"/etc/kbd/" KEYMAPDIR "/**",
+ 	DATADIR "/" KEYMAPDIR "/**",
+ 	KERNDIR "/",
+ 	NULL
+--- a/src/resizecons.c
++++ b/src/resizecons.c
+@@ -104,6 +104,7 @@ static void vga_set_verticaldisplayend_lowbyte(int);
+ 
+ const char *const dirpath[]  = {
+ 	"",
++	"/etc/kbd/" VIDEOMODEDIR "/",
+ 	DATADIR "/" VIDEOMODEDIR "/",
+ 	NULL
+ };
+--- a/src/setfont.c
++++ b/src/setfont.c
+@@ -48,8 +48,8 @@ usage(void)
+ 		  "\n"
+-		  "Files are loaded from the %s/*/.\n"),
+-		DATADIR);
++		  "Files are loaded from the %s/*/ or %s/*/.\n"),
++		DATADIR, "/etc/kbd");
+ 
+ 	print_report_bugs();
+ 
+ 	exit(retcode);
+ }
+ 

pkgs/by-name/kb/kbdd/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  dbus-glib,
+  autoreconfHook,
+  xorg,
+}:
+
+stdenv.mkDerivation {
+  pname = "kbdd";
+  version = "unstable-2021-04-26";
+
+  src = fetchFromGitHub {
+    owner = "qnikst";
+    repo = "kbdd";
+    rev = "3145099e1fbbe65b27678be72465aaa5b5872874";
+    sha256 = "1gzcjnflgdqnjgphiqpzwbcx60hm0h2cprncm7i8xca3ln5q6ba1";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+  buildInputs = [
+    xorg.libX11
+    dbus-glib
+  ];
+
+  meta = {
+    description = "Simple daemon and library to make per window layout using XKB";
+    homepage = "https://github.com/qnikst/kbdd";
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.linux;
+    maintainers = [ ];
+    mainProgram = "kbdd";
+  };
+}

pkgs/by-name/kb/kbdlight/package.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kbdlight";
+  version = "1.3";
+
+  src = fetchFromGitHub {
+    owner = "hobarrera";
+    repo = "kbdlight";
+    rev = "v${version}";
+    sha256 = "1f08aid1xrbl4sb5447gkip9lnvkia1c4ap0v8zih5s9w8v72bny";
+  };
+
+  preConfigure = ''
+    substituteInPlace Makefile \
+      --replace /usr/local $out \
+      --replace 4755 0755
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/hobarrera/kbdlight";
+    description = "Very simple application that changes MacBooks' keyboard backlight level";
+    mainProgram = "kbdlight";
+    license = licenses.isc;
+    maintainers = [ maintainers.womfoo ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/kb/kbld/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "kbld";
+  version = "0.46.0";
+
+  src = fetchFromGitHub {
+    owner = "carvel-dev";
+    repo = "kbld";
+    rev = "v${version}";
+    hash = "sha256-3QLvUvm1OBLGS8ucFEDDLVupwof8ToG0RBJpUPtqThE=";
+  };
+
+  vendorHash = null;
+
+  subPackages = [ "cmd/kbld" ];
+
+  env.CGO_ENABLED = 0;
+
+  ldflags = [
+    "-X=carvel.dev/kbld/pkg/kbld/version.Version=${version}"
+  ];
+
+  meta = {
+    description = "Seamlessly incorporates image building and image pushing into your development and deployment workflows";
+    homepage = "https://carvel.dev/kbld/";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ benchand ];
+    mainProgram = "kbld";
+  };
+}

pkgs/by-name/kb/kbs2/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  python3,
+  libxcb,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "kbs2";
+  version = "0.7.3";
+
+  src = fetchFromGitHub {
+    owner = "woodruffw";
+    repo = "kbs2";
+    rev = "v${version}";
+    hash = "sha256-X+NhUQzxfok9amqAiim/vjkee45hjdPedsZc3zwcOXA=";
+  };
+
+  cargoHash = "sha256-Auk/6ltjfXE1VzlxmKikcV6MHDczpuRqKJrg6UGgJZE=";
+
+  nativeBuildInputs = [ installShellFiles ] ++ lib.optionals stdenv.hostPlatform.isLinux [ python3 ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ libxcb ];
+
+  preCheck = ''
+    export HOME=$TMPDIR
+  '';
+
+  checkFlags = [
+    "--skip=kbs2::config::tests::test_find_config_dir"
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [ "--skip=test_ragelib_rewrap_keyfile" ];
+
+  postInstall = ''
+    mkdir -p $out/share/kbs2
+    cp -r contrib/ $out/share/kbs2
+  ''
+  + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd kbs2 \
+      --bash <($out/bin/kbs2 --completions bash) \
+      --fish <($out/bin/kbs2 --completions fish) \
+      --zsh <($out/bin/kbs2 --completions zsh)
+  '';
+
+  meta = {
+    description = "Secret manager backed by age";
+    mainProgram = "kbs2";
+    homepage = "https://github.com/woodruffw/kbs2";
+    changelog = "https://github.com/woodruffw/kbs2/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/kb/kbst/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "kbst";
+  version = "0.2.1";
+
+  src = fetchFromGitHub {
+    owner = "kbst";
+    repo = "kbst";
+    rev = "v${version}";
+    hash = "sha256-tbSYNJp/gzEz+wEAe3bvIiZL5axZvW+bxqTOBkYSpMY=";
+  };
+
+  vendorHash = "sha256-+FY6KGX606CfTVKM1HeHxCm9PkaqfnT5XeOEXUX3Q5I=";
+
+  ldflags =
+    let
+      package_url = "github.com/kbst/kbst";
+    in
+    [
+      "-s"
+      "-w"
+      "-X ${package_url}.version=${version}"
+      "-X ${package_url}.buildDate=unknown"
+      "-X ${package_url}.gitCommit=${src.rev}"
+      "-X ${package_url}.gitTag=v${version}"
+      "-X ${package_url}.gitTreeState=clean"
+    ];
+
+  doCheck = false;
+
+  doPostInstallCheck = true;
+  PostInstallCheckPhase = ''
+    $out/bin/kbst help | grep v${version} > /dev/null
+  '';
+
+  meta = with lib; {
+    description = "Kubestack framework CLI";
+    mainProgram = "kbst";
+    homepage = "https://www.kubestack.com/";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ mtrsk ];
+  };
+}

pkgs/by-name/kb/kbt/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  stdenv,
+  pkg-config,
+  xorg,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "kbt";
+  version = "2.1.0";
+
+  src = fetchFromGitHub {
+    owner = "bloznelis";
+    repo = "kbt";
+    rev = version;
+    hash = "sha256-ROCZDa5eyGF9yE+zdZ4snzdz8+jk+H6ZnqsnCe8JtJw=";
+  };
+
+  cargoHash = "sha256-wG1uB/oOUUAQVpGXe7sTqt9tLmFoLrOAmeat/d1xOM8=";
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [
+    pkg-config
+  ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
+    xorg.libX11
+  ];
+
+  meta = with lib; {
+    description = "Keyboard tester in terminal";
+    homepage = "https://github.com/bloznelis/kbt";
+    license = licenses.mit;
+    maintainers = with maintainers; [ figsoda ];
+    mainProgram = "kbt";
+  };
+}