push sheeet

pkgs/by-name/kc/kcat/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  zlib,
+  rdkafka,
+  yajl,
+  avro-c,
+  libserdes,
+  which,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kcat";
+
+  version = "1.7.1";
+
+  src = fetchFromGitHub {
+    owner = "edenhill";
+    repo = "kcat";
+    rev = version;
+    sha256 = "sha256-pCIYNx0GYPGDYzTLq9h/LbOrJjhKWLAV4gq07Ikl5O4=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    which
+  ];
+
+  buildInputs = [
+    zlib
+    rdkafka
+    yajl
+    avro-c
+    libserdes
+  ];
+
+  meta = with lib; {
+    description = "Generic non-JVM producer and consumer for Apache Kafka";
+    mainProgram = "kcat";
+    homepage = "https://github.com/edenhill/kcat";
+    license = licenses.bsd2;
+    platforms = platforms.linux ++ platforms.darwin;
+    maintainers = with maintainers; [ nyarly ];
+  };
+}

pkgs/by-name/kc/kcc/package.nix

@@ -0,0 +1,100 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  makeDesktopItem,
+  copyDesktopItems,
+
+  qt6,
+  archiveSupport ? true,
+  p7zip,
+
+  versionCheckHook,
+  nix-update-script,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "kcc";
+  version = "9.1.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "ciromattia";
+    repo = "kcc";
+    tag = "v${version}";
+    hash = "sha256-FGRd2JVcz45KVjQCTEKIjKlkLJS/AsSsopeW9tXHWwk=";
+  };
+
+  nativeBuildInputs = [
+    qt6.wrapQtAppsHook
+    copyDesktopItems
+  ];
+
+  buildInputs = [
+    qt6.qtbase
+    qt6.qtwayland
+  ];
+
+  build-system = with python3.pkgs; [ setuptools ];
+
+  dependencies = with python3.pkgs; [
+    packaging # undeclared dependency
+    pymupdf
+    pyside6
+    pillow
+    psutil
+    python-slugify
+    raven
+    requests
+    mozjpeg_lossless_optimization
+    natsort
+    distro
+    numpy
+  ];
+
+  # Note: python scripts wouldn't get wrapped anyway, but let's be explicit about it
+  dontWrapQtApps = true;
+
+  makeWrapperArgs = [
+    "\${qtWrapperArgs[@]}"
+  ]
+  ++ lib.optionals archiveSupport [
+    ''--prefix PATH : ${lib.makeBinPath [ p7zip ]}''
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = "${placeholder "out"}/bin/kcc-c2e";
+
+  postInstall = ''
+    install -Dm644 \
+      icons/comic2ebook.png \
+      "$out/share/icons/hicolor/256x256/apps/kcc.png"
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "kcc";
+      exec = "kcc";
+      icon = "kcc";
+      desktopName = "Kindle Comic Converter";
+      comment = "A comic and manga converter for ebook readers";
+      categories = [ "Graphics" ];
+    })
+  ];
+
+  meta = {
+    description = "Python app to convert comic/manga files or folders to EPUB, Panel View MOBI or E-Ink optimized CBZ";
+    homepage = "https://kcc.iosphe.re";
+    mainProgram = "kcc";
+    changelog = "https://github.com/ciromattia/kcc/releases/tag/v${version}";
+    license = lib.licenses.isc;
+    maintainers = with lib.maintainers; [
+      dawidsowa
+      adfaure
+    ];
+  };
+}

pkgs/by-name/kc/kcgi/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  pkg-config,
+  fetchFromGitHub,
+  libbsd,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kcgi";
+  version = "0.10.8";
+  underscoreVersion = lib.replaceStrings [ "." ] [ "_" ] version;
+
+  src = fetchFromGitHub {
+    owner = "kristapsdz";
+    repo = "kcgi";
+    rev = "VERSION_${underscoreVersion}";
+    sha256 = "0ha6r7bcgf6pcn5gbd2sl7835givhda1jql49c232f1iair1yqyp";
+  };
+  patchPhase = ''
+    substituteInPlace configure \
+      --replace /usr/local /
+  '';
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ ] ++ lib.optionals stdenv.hostPlatform.isLinux [ libbsd ];
+
+  dontAddPrefix = true;
+
+  installFlags = [ "DESTDIR=$(out)" ];
+
+  meta = with lib; {
+    broken = (stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64);
+    homepage = "https://kristaps.bsd.lv/kcgi";
+    description = "Minimal CGI and FastCGI library for C/C++";
+    license = licenses.isc;
+    platforms = platforms.all;
+    maintainers = [ maintainers.leenaars ];
+    mainProgram = "kfcgi";
+  };
+}

pkgs/by-name/kc/kchat/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  fetchurl,
+  appimageTools,
+}:
+
+appimageTools.wrapType2 rec {
+  pname = "kchat";
+  version = "3.3.3";
+
+  src = fetchurl {
+    url = "https://download.storage5.infomaniak.com/kchat/kchat-desktop-${version}-linux-x86_64.AppImage";
+    name = "kchat-${version}.AppImage";
+    hash = "sha256-5Nk2IMGk7BDDL7fuoOBO3wEcbtJDDDnQvUiqa8Pt8yU=";
+  };
+
+  extraInstallCommands =
+    let
+      contents = appimageTools.extractType2 { inherit pname version src; };
+    in
+    ''
+      mkdir -p "$out/share/applications"
+      mkdir -p "$out/share/lib/kchat"
+      cp -r ${contents}/{locales,resources} "$out/share/lib/kchat"
+      cp -r ${contents}/usr/* "$out"
+      cp "${contents}/kchat-desktop.desktop" "$out/share/applications/"
+      mv "$out/bin/kchat" "$out/bin/${meta.mainProgram}" || true
+      install -m 444 -D ${contents}/kchat-desktop.desktop $out/share/applications/kchat-desktop.desktop
+      substituteInPlace $out/share/applications/kchat-desktop.desktop --replace-fail 'Exec=AppRun' 'Exec=${meta.mainProgram}'
+    '';
+
+  meta = with lib; {
+    description = "Instant messaging service part of Infomaniak KSuite";
+    homepage = "https://www.infomaniak.com/en/apps/download-kchat";
+    license = licenses.unfree;
+    maintainers = [ maintainers.vinetos ];
+    mainProgram = "kchat";
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+    longDescription = ''
+      kChat is an instant messaging service which enables you to discuss, share and coordinate your teams in complete
+      security via your Internet browser, mobile phone, tablet or computer.
+    '';
+  };
+}

pkgs/by-name/kc/kchmviewer/package.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  qt5,
+  chmlib,
+  libzip,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kchmviewer";
+  version = "8.0";
+
+  src = fetchFromGitHub {
+    owner = "gyunaev";
+    repo = "kchmviewer";
+    tag = "RELEASE_${lib.replaceStrings [ "." ] [ "_" ] finalAttrs.version}";
+    hash = "sha256-YNpiBf6AFBCRbAZRPODvqGbQQedJJJrZFQIQyzIeBlw=";
+  };
+
+  patches = [
+    # remove unused webkit
+    (fetchpatch {
+      url = "https://github.com/gyunaev/kchmviewer/commit/a4a3984465cb635822953350c571950ae726b539.patch";
+      hash = "sha256-nHW18a4SrTG4fETJmKS4ojHXwnX1d1uN1m4H0GIuI28=";
+    })
+    # QtWebengine fixes
+    (fetchpatch {
+      url = "https://github.com/gyunaev/kchmviewer/commit/9ac73e7ad15de08aab6b1198115be2eb44da7afe.patch";
+      hash = "sha256-qg2ytqA2On7jg19WZmHIOU7vLQI2hoyqItySLEA64SY=";
+    })
+    (fetchpatch {
+      url = "https://github.com/gyunaev/kchmviewer/commit/99a6d94bdfce9c4578cce82707e71863a71d1453.patch";
+      hash = "sha256-o8JkaMmcJObmMt+o/6ooCAPCi+yRAWDAgxV+tR5eHfY=";
+    })
+    # Fix build on macOS
+    (fetchpatch {
+      url = "https://github.com/gyunaev/kchmviewer/pull/35/commits/b68ed6fe72eaf9ee4e7e42925f5071fbd02dc6b3.patch";
+      hash = "sha256-sJA0RE0Z83tYv0S42yQYWKKeLhW+YDsrxLkY5aMKKT4=";
+    })
+    (fetchpatch {
+      url = "https://github.com/gyunaev/kchmviewer/pull/35/commits/d307e4e829c5a6f57ab0040f786c3da7fd2f0a99.patch";
+      hash = "sha256-FWYfqG8heL6AnhevueCWHQc+c6Yj4+DuIdjIwXVZ+O4=";
+    })
+  ];
+
+  buildInputs = [
+    chmlib
+    libzip
+    qt5.qtwebengine
+  ];
+
+  nativeBuildInputs = [
+    qt5.qmake
+    qt5.wrapQtAppsHook
+  ];
+
+  postInstall =
+    if stdenv.hostPlatform.isDarwin then
+      ''
+        mkdir -p $out/{Applications,bin}
+        mv bin/kchmviewer.app $out/Applications
+        ln -s $out/Applications/kchmviewer.app/Contents/MacOS/kchmviewer $out/bin/kchmviewer
+      ''
+    else
+      ''
+        install -Dm755 bin/kchmviewer -t $out/bin
+        install -Dm644 packages/kchmviewer.png -t $out/share/pixmaps
+        install -Dm644 packages/kchmviewer.desktop -t $out/share/applications
+      '';
+
+  meta = {
+    description = "CHM (Winhelp) files viewer";
+    mainProgram = "kchmviewer";
+    homepage = "http://www.ulduzsoft.com/linux/kchmviewer/";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ sikmir ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/kc/kcl-language-server/package.nix

@@ -0,0 +1,53 @@
+{
+  fetchFromGitHub,
+  kcl,
+  lib,
+  pkg-config,
+  protobuf,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "kcl-language-server";
+  version = "0.11.2";
+
+  src = fetchFromGitHub {
+    owner = "kcl-lang";
+    repo = "kcl";
+    rev = "v${version}";
+    hash = "sha256-6XDLxTpgENhP7F51kicAJB7BNMtX4cONKJApAhqgdno=";
+  };
+
+  sourceRoot = "${src.name}/kclvm";
+
+  cargoHash = "sha256-eJ3Gh2l6T2DxJRQRHamPOr/ILtzsqFB497DdXVJ90RE=";
+
+  PROTOC = "${protobuf}/bin/protoc";
+  PROTOC_INCLUDE = "${protobuf}/include";
+
+  buildAndTestSubdir = "tools/src/LSP";
+
+  buildPhaseCargoFlags = [
+    "--profile"
+    "release"
+    "--offline"
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    protobuf
+  ];
+
+  doCheck = false;
+
+  meta = {
+    changelog = "https://github.com/kcl-lang/kcl/releases/tag/v${version}";
+    description = "High-performance implementation of KCL written in Rust that uses LLVM as the compiler backend";
+    downloadPage = "https://github.com/kcl-lang/kcl/tree/v${version}/kclvm/tools/src/LSP";
+    homepage = "https://www.kcl-lang.io/";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.linux;
+    maintainers = kcl.meta.maintainers;
+    mainProgram = "kcl-language-server";
+  };
+}

pkgs/by-name/kc/kcl/package.nix

@@ -0,0 +1,78 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  kclvm_cli,
+  kclvm,
+  lib,
+  nix-update-script,
+  stdenv,
+}:
+
+buildGoModule rec {
+  pname = "kcl";
+  version = "0.11.3";
+
+  src = fetchFromGitHub {
+    owner = "kcl-lang";
+    repo = "cli";
+    rev = "v${version}";
+    hash = "sha256-LJ+Mclw/dMyOeUHg6TAckSbvDGFYCf6mMGzDmiIQVZc=";
+  };
+
+  vendorHash = "sha256-jNQ0g7BGXUoYKV5RkU/f9GrSC3ygeZv83SekAmyKLxc=";
+
+  subPackages = [ "cmd/kcl" ];
+
+  ldflags = [
+    "-w -s"
+    "-X=kcl-lang.io/cli/pkg/version.version=v${version}"
+  ];
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  buildInputs = [
+    kclvm
+    kclvm_cli
+  ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    export HOME=$(mktemp -d)
+    for shell in bash fish zsh; do
+      installShellCompletion --cmd kcl \
+        --$shell <($out/bin/kcl completion $shell)
+    done
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    runHook preInstallCheck
+    set -o pipefail
+    $out/bin/kcl --version | grep $version
+    $out/bin/kcl <(echo 'hello = "KCL"') | grep "hello: KCL"
+    runHook postInstallCheck
+  '';
+
+  # By default, libs and bins are stripped. KCL will crash on darwin if they are.
+  dontStrip = stdenv.hostPlatform.isDarwin;
+
+  doCheck = true;
+
+  updateScript = nix-update-script { };
+
+  meta = {
+    description = "Command line interface for KCL programming language";
+    changelog = "https://github.com/kcl-lang/cli/releases/tag/v${version}";
+    homepage = "https://github.com/kcl-lang/cli";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+    maintainers = with lib.maintainers; [
+      peefy
+      selfuryon
+    ];
+    mainProgram = "kcl";
+    broken = stdenv.buildPlatform != stdenv.hostPlatform;
+  };
+}

pkgs/by-name/kc/kclvm/package.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  protobuf,
+  pkg-config,
+  rustc,
+}:
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "kclvm";
+  version = "0.11.2";
+
+  src = fetchFromGitHub {
+    owner = "kcl-lang";
+    repo = "kcl";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-6XDLxTpgENhP7F51kicAJB7BNMtX4cONKJApAhqgdno=";
+  };
+
+  env = {
+    PROTOC = "${protobuf}/bin/protoc";
+    PROTOC_INCLUDE = "${protobuf}/include";
+  };
+
+  cargoRoot = "kclvm";
+  cargoHash = "sha256-kX+3wyeElKXUOIyD24X9jfvSzdtg3HFilkqlWulq4cc=";
+  cargoPatches = [ ./fix-build.patch ];
+
+  preBuild = ''
+    cd kclvm
+  '';
+
+  buildInputs = [ rustc ];
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    install_name_tool -id $out/lib/libkclvm_cli_cdylib.dylib $out/lib/libkclvm_cli_cdylib.dylib
+  '';
+
+  nativeBuildInputs = [
+    pkg-config
+    protobuf
+  ];
+
+  meta = {
+    description = "High-performance implementation of KCL written in Rust that uses LLVM as the compiler backend";
+    homepage = "https://github.com/kcl-lang/kcl";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [
+      selfuryon
+      peefy
+    ];
+  };
+})

pkgs/by-name/kc/kclvm_cli/cargo_lock.patch

@@ -0,0 +1,10 @@
+--- /dev/null	2024-03-29 17:01:59.989114590 +0100
++++ cli/Cargo.lock	2024-04-17 13:27:32.243365234 +0200
+@@ -0,0 +1,7 @@
++# This file is automatically @generated by Cargo.
++# It is not intended for manual editing.
++version = 3
++
++[[package]]
++name = "kclvm_cli"
++version = "0.10.0"

pkgs/by-name/kc/kclvm_cli/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  kclvm,
+  rustc,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "kclvm_cli";
+  version = "0.11.0";
+
+  src = fetchFromGitHub {
+    owner = "kcl-lang";
+    repo = "kcl";
+    rev = "v${version}";
+    hash = "sha256-wRmLXR1r/FtZVfc6jifEj0jS0U0HIgJzBtuuzLQchjo=";
+  };
+
+  sourceRoot = "${src.name}/cli";
+
+  cargoHash = "sha256-ZhrjxHqwWwcVkCVkJJnVm2CZLfRlrI2383ejgI+B2KQ=";
+  cargoPatches = [ ./cargo_lock.patch ];
+
+  buildInputs = [
+    kclvm
+    rustc
+  ];
+
+  meta = with lib; {
+    description = "High-performance implementation of KCL written in Rust that uses LLVM as the compiler backend";
+    homepage = "https://github.com/kcl-lang/kcl";
+    license = licenses.asl20;
+    platforms = platforms.linux ++ platforms.darwin;
+    maintainers = with maintainers; [
+      selfuryon
+      peefy
+    ];
+    mainProgram = "kclvm_cli";
+  };
+}

pkgs/by-name/kc/kcollectd/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  fetchFromGitLab,
+  stdenv,
+  cmake,
+  boost,
+  shared-mime-info,
+  rrdtool,
+  kdePackages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kcollectd";
+  version = "0.12.2";
+  src = fetchFromGitLab {
+    owner = "aerusso";
+    repo = "kcollectd";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-35zb5Kx0tRP5l0hILdomCu2YSQfng02mbyyAClm4uZs=";
+  };
+
+  postPatch = lib.optional (!lib.versionOlder rrdtool.version "1.9.0") ''
+    substituteInPlace kcollectd/rrd_interface.cc --replace-fail 'char *arg[] =' 'const char *arg[] ='
+  '';
+
+  nativeBuildInputs = [
+    shared-mime-info
+    cmake
+  ]
+  ++ (with kdePackages; [
+    wrapQtAppsHook
+    extra-cmake-modules
+  ]);
+
+  buildInputs = [
+    boost
+    rrdtool
+  ]
+  ++ (with kdePackages; [
+    qtbase
+    kconfig
+    kio
+    kxmlgui
+    kiconthemes
+    ki18n
+    kguiaddons
+    breeze-icons
+  ]);
+
+  meta = {
+    description = "Graphical frontend to collectd";
+    homepage = "https://www.antonioerusso.com/projects/kcollectd/";
+    maintainers = with lib.maintainers; [ symphorien ];
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.linux;
+    mainProgram = "kcollectd";
+  };
+})

pkgs/by-name/kc/kconf/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  stdenv,
+}:
+buildGoModule rec {
+  pname = "kconf";
+  version = "2.0.0";
+
+  src = fetchFromGitHub {
+    owner = "particledecay";
+    repo = "kconf";
+    rev = "v${version}";
+    sha256 = "sha256-bLyLXkXOZRFaplv5sY0TgFffvbA3RUwz6b+7h3MN7kA=";
+  };
+
+  vendorHash = "sha256-REguLiYlcC2Q6ao2oMl92/cznW+E8MO2UGhQKRXZ1vQ=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/particledecay/kconf/build.Version=${version}"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd kconf \
+      --bash <($out/bin/kconf completion bash) \
+      --fish <($out/bin/kconf completion fish) \
+      --zsh <($out/bin/kconf completion zsh)
+  '';
+
+  meta = with lib; {
+    description = "Opinionated command line tool for managing multiple kubeconfigs";
+    mainProgram = "kconf";
+    homepage = "https://github.com/particledecay/kconf";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      thmzlt
+      sailord
+      vinetos
+    ];
+  };
+}

pkgs/by-name/kc/kconfig-frontends/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  bash,
+  bison,
+  flex,
+  gperf,
+  ncurses,
+  pkg-config,
+  python3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kconfig-frontends";
+  version = "4.11.0.1";
+
+  src = fetchurl {
+    url = "https://bitbucket.org/nuttx/tools/downloads/kconfig-frontends-${finalAttrs.version}.tar.bz2";
+    hash = "sha256-yxg4z+Lwl7oJyt4n1HUncg1bKeK3FcCpbDPQtqELqxM=";
+  };
+
+  patches = [
+    # This patch is a fixed file, there is no need to normalize it
+    (fetchurl {
+      url = "https://bitbucket.org/nuttx/tools/downloads/gperf3.1_kconfig_id_lookup.patch";
+      hash = "sha256-cqAWjRnMA/fJ8wnEfUxoPEW0hIJY/mprE6/TQMY6NPI=";
+    })
+  ];
+
+  outputs = [
+    "out"
+    "lib"
+    "dev"
+    "doc"
+  ];
+
+  nativeBuildInputs = [
+    bison
+    flex
+    gperf
+    pkg-config
+  ];
+
+  buildInputs = [
+    bash
+    ncurses
+    python3
+  ];
+
+  strictDeps = true;
+
+  configureFlags = [
+    "--enable-frontends=conf,mconf,nconf"
+  ];
+
+  env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-error=format-security";
+
+  meta = {
+    description = "Out of Linux tree packaging of the kconfig infrastructure";
+    longDescription = ''
+      Configuration language and system for the Linux kernel and other
+      projects. Features simple syntax and grammar, limited yet adequate option
+      types, simple organization of options, and direct and reverse
+      dependencies.
+    '';
+    homepage = "https://bitbucket.org/nuttx/tools/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/kc/kcov/package.nix

@@ -0,0 +1,96 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  zlib,
+  curl,
+  elfutils,
+  python3,
+  libiberty,
+  libopcodes,
+  runCommandCC,
+  rustc,
+}:
+
+let
+  self = stdenv.mkDerivation rec {
+    pname = "kcov";
+    version = "43";
+
+    src = fetchFromGitHub {
+      owner = "SimonKagstrom";
+      repo = "kcov";
+      rev = "v${version}";
+      sha256 = "sha256-hRJYuHNSXyRoUDBF/yIPXPcBBxZoTO5cgoB2tBhKPwY=";
+    };
+
+    preConfigure = "patchShebangs src/bin-to-c-source.py";
+    nativeBuildInputs = [
+      cmake
+      pkg-config
+      python3
+    ];
+
+    buildInputs = [
+      curl
+      zlib
+      elfutils
+      libiberty
+      libopcodes
+    ];
+
+    strictDeps = true;
+
+    passthru.tests = {
+      works-on-c = runCommandCC "works-on-c" { } ''
+        set -ex
+        cat - > a.c <<EOF
+        int main() {}
+        EOF
+        $CC a.c -o a.out
+        ${self}/bin/kcov /tmp/kcov ./a.out
+        test -e /tmp/kcov/index.html
+        touch $out
+        set +x
+      '';
+
+      works-on-rust = runCommandCC "works-on-rust" { nativeBuildInputs = [ rustc ]; } ''
+        set -ex
+        cat - > a.rs <<EOF
+        fn main() {}
+        EOF
+        # Put gcc in the path so that `cc` is found
+        rustc a.rs -o a.out
+        ${self}/bin/kcov /tmp/kcov ./a.out
+        test -e /tmp/kcov/index.html
+        touch $out
+        set +x
+      '';
+    };
+
+    meta = with lib; {
+      description = "Code coverage tester for compiled programs, Python scripts and shell scripts";
+
+      longDescription = ''
+        Kcov is a code coverage tester for compiled programs, Python
+        scripts and shell scripts. It allows collecting code coverage
+        information from executables without special command-line
+        arguments, and continuosly produces output from long-running
+        applications.
+      '';
+
+      homepage = "http://simonkagstrom.github.io/kcov/index.html";
+      license = licenses.gpl2;
+      changelog = "https://github.com/SimonKagstrom/kcov/blob/master/ChangeLog";
+
+      maintainers = with maintainers; [
+        gal_bolle
+        ekleog
+      ];
+      platforms = platforms.linux;
+    };
+  };
+in
+self

pkgs/by-name/kc/kcp/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kcp";
+  version = "1.7";
+
+  src = fetchFromGitHub {
+    owner = "skywind3000";
+    repo = "kcp";
+    rev = version;
+    hash = "sha256-yW40x4T++4rB7hoabGN8qiSN7octyoUYEfE9oDlLxjU=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = with lib; {
+    description = "Fast and Reliable ARQ Protocol";
+    homepage = "https://github.com/skywind3000/kcp";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.all;
+  };
+}