push sheeet

pkgs/by-name/kd/kdash/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  perl,
+  python3,
+  openssl,
+  xorg,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "kdash";
+  version = "0.6.2";
+
+  src = fetchFromGitHub {
+    owner = "kdash-rs";
+    repo = "kdash";
+    rev = "v${version}";
+    sha256 = "sha256-fFpdWVoeWycnp/hRw2S+hYpnXYmCs+rLqcZdmSSMGwI=";
+  };
+
+  nativeBuildInputs = [
+    perl
+    python3
+    pkg-config
+  ];
+
+  buildInputs = [
+    openssl
+    xorg.xcbutil
+  ];
+
+  cargoHash = "sha256-72DuM64wj8WW6soagodOFIeHvVn1CPpb1T3Y7GQYsbs=";
+
+  meta = with lib; {
+    description = "Simple and fast dashboard for Kubernetes";
+    mainProgram = "kdash";
+    homepage = "https://github.com/kdash-rs/kdash";
+    license = with licenses; [ mit ];
+    maintainers = with maintainers; [ matthiasbeyer ];
+  };
+}

pkgs/by-name/kd/kdbg/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  cmake,
+  qt6,
+  kdePackages,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kdbg";
+  version = "3.2.0";
+  src = fetchurl {
+    url = "mirror://sourceforge/kdbg/${version}/kdbg-${version}.tar.gz";
+    hash = "sha256-GoWLKWD/nWXBTiTbDLxeNArDMyPI/gSzADqyOgxrNHE=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    kdePackages.extra-cmake-modules
+    qt6.wrapQtAppsHook
+  ];
+  buildInputs = [
+    qt6.qt5compat
+    qt6.qtbase
+    kdePackages.ki18n
+    kdePackages.kconfig
+    kdePackages.kiconthemes
+    kdePackages.kxmlgui
+    kdePackages.kwindowsystem
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeFeature "BUILD_FOR_KDE_VERSION" "6")
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/kdbg --prefix QT_PLUGIN_PATH : ${qt6.qtbase}/${qt6.qtbase.qtPluginPrefix}
+  '';
+
+  dontWrapQtApps = true;
+
+  meta = with lib; {
+    homepage = "https://www.kdbg.org/";
+    description = ''
+      A graphical user interface to gdb, the GNU debugger. It provides an
+      intuitive interface for setting breakpoints, inspecting variables, and
+      stepping through code.
+    '';
+    mainProgram = "kdbg";
+    license = licenses.gpl2;
+    maintainers = [ maintainers.catern ];
+  };
+}

pkgs/by-name/kd/kddockwidgets/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  qt6,
+  spdlog,
+  fmt,
+  nlohmann_json,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "KDDockWidgets";
+  version = "2.3.0";
+
+  src = fetchFromGitHub {
+    owner = "KDAB";
+    repo = "KDDockWidgets";
+    rev = "v${version}";
+    sha256 = "sha256-NNGIR2MTaNs2zFeN9vmHxoRuss2IR7FQ8F34b00L9z4=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [
+    spdlog
+    fmt
+    nlohmann_json
+  ];
+  propagatedBuildInputs = with qt6; [
+    qtbase
+    qtdeclarative
+  ];
+
+  cmakeFlags = [ (lib.strings.cmakeBool "KDDockWidgets_QT6" true) ];
+
+  dontWrapQtApps = true;
+
+  meta = with lib; {
+    description = "KDAB's Dock Widget Framework for Qt";
+    homepage = "https://www.kdab.com/development-resources/qt-tools/kddockwidgets";
+    license = with licenses; [
+      gpl2Only
+      gpl3Only
+    ];
+    maintainers = with maintainers; [
+      _1000teslas
+      tmarkus
+    ];
+  };
+}

pkgs/by-name/kd/kde-gruvbox/package.nix

@@ -0,0 +1,36 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation {
+  pname = "kde-gruvbox";
+  version = "0-unstable-2015-08-09";
+
+  src = fetchFromGitHub {
+    owner = "printesoi";
+    repo = "kde-gruvbox";
+    rev = "2dd95283076d7194345a460edb3630cfd020759c";
+    sha256 = "sha256-ppAeEfwoHZg7XEj3zGc+uq4Z6hUgJNM2EjuDsc8pFQo=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/{plasma/desktoptheme,yakuake/kns_skins}
+    cp -R color-schemes konsole $out/share
+    cp -R plasma5/gruvbox $out/share/plasma/desktoptheme
+    cp -R yakuake/breeze-gruvbox-dark $out/share/yakuake/kns_skins
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Suite of themes for KDE applications that match the retro gruvbox colorscheme";
+    homepage = "https://github.com/printesoi/kde-gruvbox";
+    license = licenses.mit;
+    maintainers = [ maintainers.ymarkus ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/kd/kdeltachat/package.nix

@@ -0,0 +1,79 @@
+{
+  lib,
+  fetchFromGitHub,
+  fetchFromSourcehut,
+  cmake,
+  extra-cmake-modules,
+  pkg-config,
+  libdeltachat,
+  libsForQt5,
+  rustPlatform,
+  stdenv,
+}:
+
+let
+  libdeltachat' = libdeltachat.overrideAttrs rec {
+    version = "1.155.6";
+    src = fetchFromGitHub {
+      owner = "chatmail";
+      repo = "core";
+      tag = "v${version}";
+      hash = "sha256-d7EmmyLSJjFIZM1j6LP8f4WnXiptNTAqOdJD/oPL02Y=";
+    };
+    cargoDeps = rustPlatform.fetchCargoVendor {
+      pname = "deltachat-core-rust";
+      inherit version src;
+      hash = "sha256-E01aEzNi06LQntrlA+342a8Nl5API6v7HbdmuKpfajs=";
+    };
+  };
+  inherit (libsForQt5)
+    kirigami2
+    qtbase
+    qtimageformats
+    qtmultimedia
+    qtwebengine
+    wrapQtAppsHook
+    ;
+in
+stdenv.mkDerivation {
+  pname = "kdeltachat";
+  version = "unstable-2024-01-14";
+
+  src = fetchFromSourcehut {
+    owner = "~link2xt";
+    repo = "kdeltachat";
+    rev = "d61a01c2d6d5bdcc9ca500b466ed42689b2bd5c6";
+    hash = "sha256-KmL3ODXPi1c8C5z2ySHg0vA5Vg/dZumDZTbpxkzf7A4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    pkg-config
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    kirigami2
+    libdeltachat'
+    qtimageformats
+    qtmultimedia
+    qtwebengine
+  ];
+
+  # needed for qmlplugindump to work
+  QT_PLUGIN_PATH = "${qtbase.bin}/${qtbase.qtPluginPrefix}";
+  QML2_IMPORT_PATH = lib.concatMapStringsSep ":" (lib: "${lib}/${qtbase.qtQmlPrefix}") [
+    kirigami2
+    qtmultimedia
+  ];
+
+  meta = with lib; {
+    description = "Delta Chat client using Kirigami framework";
+    mainProgram = "kdeltachat";
+    homepage = "https://git.sr.ht/~link2xt/kdeltachat";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ dotlambda ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/kd/kdesvn/package.nix

@@ -0,0 +1,74 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitLab,
+  cmake,
+  qt5,
+  apr,
+  aprutil,
+  subversion,
+  subversionClient,
+  libsForQt5,
+  extra-cmake-modules,
+}:
+
+stdenv.mkDerivation {
+  pname = "kdesvn";
+  version = "2.1";
+
+  src = fetchFromGitLab {
+    domain = "invent.kde.org";
+    owner = "sdk";
+    repo = "kdesvn";
+    rev = "2028bc2f3621510db05e437e33f5cc225a7cd16b";
+    hash = "sha256-IaERXT648v2nTW89V6gpf7Dt95GJd92QmC50de+Knq8=";
+  };
+
+  cmakeFlags = [
+    "-DSUBVERSION_INSTALL_PATH=${lib.getDev subversion}"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    qt5.wrapQtAppsHook
+    apr.dev
+    aprutil.dev
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    qt5.qtbase
+    subversion
+    subversionClient
+    libsForQt5.kbookmarks
+    libsForQt5.kcodecs
+    libsForQt5.kcompletion
+    libsForQt5.kconfig
+    libsForQt5.kconfigwidgets
+    libsForQt5.kcoreaddons
+    libsForQt5.kdbusaddons
+    libsForQt5.kdoctools
+    libsForQt5.ki18n
+    libsForQt5.kiconthemes
+    libsForQt5.kitemviews
+    libsForQt5.kjobwidgets
+    libsForQt5.kio
+    libsForQt5.knotifications
+    libsForQt5.kparts
+    libsForQt5.kservice
+    libsForQt5.ktextwidgets
+    libsForQt5.kwallet
+    libsForQt5.kwidgetsaddons
+    libsForQt5.kxmlgui
+  ];
+
+  meta = {
+    homepage = "https://invent.kde.org/sdk/kdesvn";
+    platforms = lib.platforms.unix;
+    badPlatforms = lib.platforms.darwin;
+    maintainers = with lib.maintainers; [ bot-wxt1221 ];
+    mainProgram = "kdesvn";
+    description = "Subversion client by KDE";
+    license = lib.licenses.agpl3Plus;
+  };
+}

pkgs/by-name/kd/kdiff3/package.nix

@@ -0,0 +1,50 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  extra-cmake-modules,
+  boost,
+  kdePackages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kdiff3";
+  version = "1.12.3";
+
+  src = fetchurl {
+    url = "mirror://kde/stable/kdiff3/kdiff3-${finalAttrs.version}.tar.xz";
+    hash = "sha256-4iZUxFeIF5mAgwVSnGtZbAydw4taLswULsdtRvaHP0w=";
+  };
+
+  nativeBuildInputs = [
+    extra-cmake-modules
+    kdePackages.kdoctools
+    kdePackages.wrapQtAppsHook
+  ];
+
+  buildInputs = with kdePackages; [
+    qtbase
+    boost
+    kconfig
+    kcrash
+    kparts
+    kiconthemes
+  ];
+
+  cmakeFlags = [ "-Wno-dev" ];
+
+  env.LANG = "C.UTF-8";
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    ln -s "$out/Applications/KDE/kdiff3.app/Contents/MacOS" "$out/bin"
+  '';
+
+  meta = with lib; {
+    description = "Compares and merges 2 or 3 files or directories";
+    mainProgram = "kdiff3";
+    homepage = "https://invent.kde.org/sdk/kdiff3";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ peterhoeg ];
+    inherit (kdePackages.qtbase.meta) platforms;
+  };
+})

pkgs/by-name/kd/kdigger/package.nix

@@ -0,0 +1,80 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+}:
+
+buildGoModule rec {
+  pname = "kdigger";
+  version = "1.5.1";
+
+  src = fetchFromGitHub {
+    owner = "quarkslab";
+    repo = "kdigger";
+    tag = "v${version}";
+    hash = "sha256-hpLhtTENtOBQjm+CZRAcx1BG9831JUFIsLL57wZIrso=";
+    # populate values that require us to use git. By doing this in postFetch we
+    # can delete .git afterwards and maintain better reproducibility of the src.
+    leaveDotGit = true;
+    postFetch = ''
+      cd "$out"
+      git rev-parse HEAD > $out/COMMIT
+      find "$out" -name .git -print0 | xargs -0 rm -rf
+    '';
+  };
+  vendorHash = "sha256-kMoTkrDuAJmgWAj7+V3a8VEYpPbTv3UdLscTdkpzud0=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  # static to be easily copied into containers since it's an in-pod pen-testing tool
+  env.CGO_ENABLED = 0;
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/quarkslab/kdigger/commands.VERSION=v${version}"
+    "-X github.com/quarkslab/kdigger/commands.BUILDERARCH=${stdenv.hostPlatform.linuxArch}"
+  ];
+
+  preBuild = ''
+    ldflags+=" -X github.com/quarkslab/kdigger/commands.GITCOMMIT=$(cat COMMIT)"
+  '';
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd kdigger \
+      --bash <($out/bin/kdigger completion bash) \
+      --fish <($out/bin/kdigger completion fish) \
+      --zsh <($out/bin/kdigger completion zsh)
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    runHook preInstallCheck
+
+    $out/bin/kdigger --help
+
+    runHook postInstallCheck
+  '';
+
+  meta = {
+    homepage = "https://github.com/quarkslab/kdigger";
+    changelog = "https://github.com/quarkslab/kdigger/releases/tag/v${version}";
+    description = "In-pod context discovery tool for Kubernetes penetration testing";
+    mainProgram = "kdigger";
+    longDescription = ''
+      kdigger, short for "Kubernetes digger", is a context discovery tool for
+      Kubernetes penetration testing. This tool is a compilation of various
+      plugins called buckets to facilitate pentesting Kubernetes from inside a
+      pod.
+    '';
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ jk ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "x86_64-darwin"
+    ];
+  };
+}

pkgs/by-name/kd/kdiskmark/package.nix

@@ -0,0 +1,58 @@
+{
+  stdenv,
+  lib,
+  fio,
+  cmake,
+  fetchFromGitHub,
+  kdePackages,
+}:
+stdenv.mkDerivation rec {
+  pname = "kdiskmark";
+  version = "3.2.0";
+
+  src = fetchFromGitHub {
+    owner = "jonmagon";
+    repo = "kdiskmark";
+    rev = version;
+    hash = "sha256-b42PNUrG10RyGct6dPtdT89oO222tEovkSPoRcROfaQ=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = with kdePackages; [
+    cmake
+    extra-cmake-modules
+    wrapQtAppsHook
+  ];
+
+  buildInputs = with kdePackages; [
+    qtbase
+    qttools
+    polkit-qt-1
+  ];
+
+  preConfigure = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail \$\{POLKITQT-1_POLICY_FILES_INSTALL_DIR\} $out/share/polkit-1/actions
+  '';
+
+  qtWrapperArgs = [
+    "--prefix"
+    "PATH"
+    ":"
+    (lib.makeBinPath [ fio ])
+  ];
+
+  meta = with lib; {
+    description = "HDD and SSD benchmark tool with a friendly graphical user interface";
+    longDescription = ''
+      If kdiskmark is not run as root it can rely on polkit to get the necessary
+      privileges. In this case you must install it with `environment.systemPackages`
+      on NixOS, nix-env will not work.
+    '';
+    homepage = "https://github.com/JonMagon/KDiskMark";
+    maintainers = [ maintainers.symphorien ];
+    license = licenses.gpl3Only;
+    platforms = platforms.linux;
+    mainProgram = "kdiskmark";
+  };
+}

pkgs/by-name/kd/kdlfmt/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  stdenv,
+  installShellFiles,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "kdlfmt";
+  version = "0.1.4";
+
+  src = fetchFromGitHub {
+    owner = "hougesen";
+    repo = "kdlfmt";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-VHcpF9CTRDl9dtX/rZeDKVoCerI1sNjwURBpiE9bH80=";
+  };
+
+  cargoHash = "sha256-A8pp4IWL8hR4G1WDNFo6e3BVRxuVjfazIKOwCEGN7Rc=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd kdlfmt \
+      --bash <($out/bin/kdlfmt completions bash) \
+      --fish <($out/bin/kdlfmt completions fish) \
+      --zsh <($out/bin/kdlfmt completions zsh)
+  '';
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Formatter for kdl documents";
+    homepage = "https://github.com/hougesen/kdlfmt";
+    changelog = "https://github.com/hougesen/kdlfmt/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      airrnot
+      defelo
+    ];
+    mainProgram = "kdlfmt";
+  };
+})

pkgs/by-name/kd/kdocker/package.nix

@@ -0,0 +1,44 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  libX11,
+  libxcb,
+  perl, # For pod2man
+  qt6,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kdocker";
+  version = "6.2";
+
+  src = fetchFromGitHub {
+    owner = "user-none";
+    repo = "KDocker";
+    rev = "${finalAttrs.version}";
+    hash = "sha256-ckTi/w2Yynsl3aJzV9Uxfc7WxJtcCt44glJyqEEZrig=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    perl
+    qt6.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    libX11
+    libxcb
+    qt6.qtbase
+  ];
+
+  meta = with lib; {
+    description = "Dock any application into the system tray";
+    homepage = "https://github.com/user-none/KDocker";
+    changelog = "https://github.com/user-none/KDocker/blob/${finalAttrs.version}/ChangeLog";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ hexclover ];
+    platforms = platforms.linux;
+    mainProgram = "kdocker";
+  };
+})

pkgs/by-name/kd/kdoctor/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kdoctor";
+  version = "1.1.0";
+
+  src = fetchurl {
+    url = "https://github.com/Kotlin/kdoctor/releases/download/v${finalAttrs.version}/kdoctor_${finalAttrs.version}+97.zip";
+    hash = "sha256-H4lpdMf1AIU8BC+6DlvcwM1wLuEl+Hd9xBli/TGFMV4=";
+  };
+
+  nativeBuildInputs = [ unzip ];
+
+  unpackPhase = ''
+    runHook preUnpack
+    unzip $src -x META-INF/*
+    runHook postUnpack
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 kdoctor -t $out/bin/
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Environment analysis tool for Kotlin Multiplatform Mobile";
+    longDescription = ''
+      KDoctor is a command-line tool that helps to set up the environment for
+      Kotlin Multiplatform Mobile app development.
+    '';
+    homepage = "https://github.com/Kotlin/kdoctor";
+    license = licenses.asl20;
+    mainProgram = "kdoctor";
+    maintainers = with maintainers; [ sironheart ];
+    platforms = platforms.darwin;
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+  };
+})

pkgs/by-name/kd/kdotool/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  dbus,
+}:
+
+rustPlatform.buildRustPackage rec {
+  version = "0.2.2-pre";
+  pname = "kdotool";
+
+  src = fetchFromGitHub {
+    owner = "jinliu";
+    repo = "kdotool";
+    rev = "v${version}";
+    hash = "sha256-qx4bWAFQcoLM/r4aNzmoZdjclw8ccAW8lKLda6ON1aQ=";
+  };
+
+  cargoHash = "sha256-ASR2zMwVCKeEZPYQNoO54J00eZyTn1i6FE0NBCJWSCs=";
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ dbus ];
+
+  meta = with lib; {
+    description = "xdotool clone for KDE Wayland";
+    homepage = "https://github.com/jinliu/kdotool";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ kotatsuyaki ];
+  };
+}

pkgs/by-name/kd/kdsingleapplication/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  qt6,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "KDSingleApplication";
+  version = "1.2.0";
+
+  src = fetchFromGitHub {
+    owner = "KDAB";
+    repo = "KDSingleApplication";
+    tag = "v${version}";
+    hash = "sha256-rglt89Gw6OHXXVOEwf0TxezDzyHEvWepeGeup7fBlLs=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ qt6.qtbase ];
+
+  cmakeFlags = [ "-DKDSingleApplication_QT6=true" ];
+  dontWrapQtApps = true;
+
+  meta = {
+    description = "KDAB's helper class for single-instance policy applications";
+    homepage = "https://www.kdab.com/";
+    maintainers = with lib.maintainers; [ hellwolf ];
+    platforms = lib.platforms.unix;
+    license = lib.licenses.mit;
+    changelog = "https://github.com/KDAB/KDSingleApplication/releases/tag/v${version}";
+  };
+}