push sheeet

pkgs/by-name/kl/klavaro/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  curl,
+  espeak,
+  file,
+  gtk3,
+  gtkdatabox,
+  intltool,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "klavaro";
+  version = "3.14";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/klavaro/${pname}-${version}.tar.bz2";
+    hash = "sha256-hxh+SdMBxRDmlkCYzbYSEmvwMNKodf15nq3K0+rlbas=";
+  };
+
+  nativeBuildInputs = [
+    intltool
+    makeWrapper
+    pkg-config
+  ];
+  buildInputs = [
+    curl
+    gtk3
+    gtkdatabox
+  ];
+
+  postPatch = ''
+    substituteInPlace src/tutor.c --replace '"espeak ' '"${espeak}/bin/espeak '
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/klavaro \
+      --prefix LD_LIBRARY_PATH : $out/lib
+  '';
+
+  # Fixes /usr/bin/file: No such file or directory
+  preConfigure = ''
+    substituteInPlace configure \
+      --replace "/usr/bin/file" "${file}/bin/file"
+  '';
+
+  # remove forbidden references to $TMPDIR
+  preFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
+    for f in "$out"/bin/*; do
+      if isELF "$f"; then
+        patchelf --shrink-rpath --allowed-rpath-prefixes "$NIX_STORE" "$f"
+      fi
+    done
+  '';
+
+  meta = with lib; {
+    description = "Free touch typing tutor program";
+    mainProgram = "klavaro";
+    homepage = "http://klavaro.sourceforge.net/";
+    changelog = "https://sourceforge.net/p/klavaro/code/HEAD/tree/trunk/ChangeLog";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [
+      mimame
+      davidak
+    ];
+  };
+}

pkgs/by-name/kl/klick/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  scons,
+  rubberband,
+  boost,
+  libjack2,
+  liblo,
+  libsamplerate,
+  libsndfile,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "klick";
+  version = "0.14.2";
+
+  src = fetchFromGitHub {
+    owner = "Allfifthstuning";
+    repo = "klick";
+    rev = version;
+    hash = "sha256-jHyeVCmyy9ipbVaF7GSW19DOVpU9EQJoLcGq9uos+eY=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    scons
+  ];
+  buildInputs = [
+    rubberband
+    libsamplerate
+    libsndfile
+    liblo
+    libjack2
+    boost
+  ];
+
+  preBuild = ''
+    substituteInPlace SConstruct \
+      --replace-fail 'pkg-config' "${stdenv.cc.targetPrefix}pkg-config"
+  '';
+
+  prefixKey = "PREFIX=";
+
+  meta = {
+    homepage = "https://das.nasophon.de/klick/";
+    description = "Advanced command-line metronome for JACK";
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.linux;
+    mainProgram = "klick";
+  };
+}

pkgs/by-name/kl/klipper-estimator/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  rustPlatform,
+  pkg-config,
+  openssl,
+  libgit2,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "klipper-estimator";
+  version = "3.7.3";
+
+  src = fetchFromGitHub {
+    owner = "Annex-Engineering";
+    repo = "klipper_estimator";
+    rev = "v${version}";
+    hash = "sha256-EjfW2qeq0ehGhjE2Psz5g/suYMZPvtQi2gaYb+NCa2U=";
+  };
+
+  cargoHash = "sha256-wMgFkzgoHjvE+5t+cA5OW2COXbUj/5tWXz0Zp9cd5lw=";
+
+  env.TOOL_VERSION = "v${version}";
+
+  buildInputs = [
+    openssl
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    libgit2
+  ];
+
+  nativeBuildInputs = [ pkg-config ];
+
+  meta = {
+    description = "Tool for determining the time a print will take using the Klipper firmware";
+    homepage = "https://github.com/Annex-Engineering/klipper_estimator";
+    changelog = "https://github.com/Annex-Engineering/klipper_estimator/releases/tag/v${version}";
+    mainProgram = "klipper_estimator";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ tmarkus ];
+  };
+}

pkgs/by-name/kl/klipperscreen/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  wrapGAppsHook3,
+  gobject-introspection,
+  gitUpdater,
+}:
+python3.pkgs.buildPythonApplication rec {
+  pname = "KlipperScreen";
+  version = "0.4.5";
+  format = "other";
+
+  src = fetchFromGitHub {
+    owner = "KlipperScreen";
+    repo = "KlipperScreen";
+    rev = "v${version}";
+    hash = "sha256-lKGMz5N4lKSqA614wjJiUfP5fUY+WqFDPxeX/Iyp2TQ=";
+  };
+
+  nativeBuildInputs = [
+    gobject-introspection
+    wrapGAppsHook3
+  ];
+
+  pythonPath = with python3.pkgs; [
+    jinja2
+    netifaces
+    requests
+    websocket-client
+    pycairo
+    pygobject3
+    mpv
+    six
+    dbus-python
+    sdbus-networkmanager
+  ];
+
+  dontWrapGApps = true;
+
+  preFixup = ''
+    mkdir -p $out/bin
+    cp -r . $out/dist
+    gappsWrapperArgs+=(--set PYTHONPATH "$PYTHONPATH")
+    wrapGApp $out/dist/screen.py
+    ln -s $out/dist/screen.py $out/bin/KlipperScreen
+  '';
+
+  passthru.updateScript = gitUpdater { url = meta.homepage; };
+
+  meta = with lib; {
+    description = "Touchscreen GUI for the Klipper 3D printer firmware";
+    homepage = "https://github.com/jordanruthe/KlipperScreen";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [
+      cab404
+      saturn745
+    ];
+    mainProgram = "KlipperScreen";
+  };
+}

pkgs/by-name/kl/klog-rs/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  stdenv,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "klog-rs";
+  version = "0.5.1";
+
+  src = fetchFromGitHub {
+    owner = "tobifroe";
+    repo = "klog";
+    rev = version;
+    hash = "sha256-VyUUzhVwJ1tNLICXwy7f85queH+pn4vL5HTL8IHcQ7w=";
+  };
+
+  cargoHash = "sha256-KJxssCN9/WoRR1Cv67CK5muVy+cqEEfzSioQtptplQs=";
+  checkFlags = [
+    # this integration test depends on a running kubernetes cluster
+    "--skip=k8s::tests::test_get_pod_list"
+    "--skip=k8s::tests::test_get_pod_list_for_resource"
+  ];
+
+  meta = {
+    description = "Tool to tail logs of multiple Kubernetes pods simultaneously";
+    homepage = "https://github.com/tobifroe/klog";
+    changelog = "https://github.com/tobifroe/klog/releases/tag/${version}";
+    license = lib.licenses.mit;
+    mainProgram = "klog";
+    maintainers = with lib.maintainers; [ tobifroe ];
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+}

pkgs/by-name/kl/klog-time-tracker/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "klog-time-tracker";
+  version = "6.6";
+
+  src = fetchFromGitHub {
+    owner = "jotaen";
+    repo = "klog";
+    rev = "v${version}";
+    hash = "sha256-Tq780+Gsu2Ym9+DeMpaOhsP2XluyKBh01USnmwlYsTs=";
+  };
+
+  vendorHash = "sha256-ilV/+Xogy4+5c/Rs0cCSvVTgDhL4mm9V/pxJB3XGDkw=";
+
+  meta = with lib; {
+    description = "Command line tool for time tracking in a human-readable, plain-text file format";
+    homepage = "https://klog.jotaen.net";
+    license = licenses.mit;
+    maintainers = [ maintainers.blinry ];
+    mainProgram = "klog";
+  };
+}

pkgs/by-name/kl/klong/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  fetchFromSourcehut,
+  installShellFiles,
+  makeBinaryWrapper,
+  gv,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "klong";
+  version = "20221212";
+
+  src = fetchurl {
+    url = "https://t3x.org/klong/klong${version}.tgz";
+    hash = "sha256-XhpIdyKKPGQ6mdv9LXPmC8P6hW4mFawv54yANw5/lrQ=";
+  };
+
+  docs = fetchFromSourcehut {
+    owner = "~nut";
+    repo = "klong-docs";
+    rev = "350da558709e3728df60ddf45fafe09e3fb89139";
+    hash = "sha256-yfvXljjJwCETWPa70zXhaQJOHhZYR2k+BKAd0Dw/U70=";
+  };
+
+  nativeBuildInputs = [
+    makeBinaryWrapper
+    installShellFiles
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -m 555 -Dt $out/bin kg kplot
+    install -m 444 -Dt $out/lib/klong lib/*.kg
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/kg --prefix KLONGPATH : $out/lib/klong
+    wrapProgram $out/bin/kplot --prefix PATH : ${
+      lib.makeBinPath [
+        "$out"
+        gv
+      ]
+    }
+    installManPage $docs/*.1
+  '';
+
+  meta = {
+    description = "Simple Array programming language";
+    homepage = "https://t3x.org/klong";
+    mainProgram = "kg";
+    maintainers = [ lib.maintainers.casaca ];
+    platforms = lib.platforms.all;
+    license = with lib.licenses; [
+      publicDomain
+      cc0
+    ];
+  };
+}

pkgs/by-name/kl/kluctl/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  buildPackages,
+  fetchFromGitHub,
+  installShellFiles,
+  testers,
+  makeWrapper,
+  python310,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "kluctl";
+  version = "2.27.0";
+
+  src = fetchFromGitHub {
+    owner = "kluctl";
+    repo = "kluctl";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-m/bfZb+sp0gqxfMdBr/gAOxfYHdrPwKRcJAqprkAkQE=";
+  };
+
+  subPackages = [ "cmd" ];
+
+  vendorHash = "sha256-TKMMMZ+8bv5kKgrHIp3CXmt4tpi5VejPpXv/oiX4M3c=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=v${finalAttrs.version}"
+  ];
+
+  # Depends on docker
+  doCheck = false;
+
+  nativeBuildInputs = [
+    installShellFiles
+    makeWrapper
+  ];
+
+  passthru.tests.version = testers.testVersion {
+    package = finalAttrs.finalPackage;
+    version = "v${finalAttrs.version}";
+  };
+
+  postInstall =
+    let
+      emulator = stdenv.hostPlatform.emulator buildPackages;
+    in
+    ''
+      mv $out/bin/{cmd,kluctl}
+      wrapProgram $out/bin/kluctl \
+        --set KLUCTL_USE_SYSTEM_PYTHON 1 \
+        --prefix PATH : '${lib.makeBinPath [ python310 ]}'
+      installShellCompletion --cmd kluctl \
+        --bash <(${emulator} $out/bin/kluctl completion bash) \
+        --fish <(${emulator} $out/bin/kluctl completion fish) \
+        --zsh  <(${emulator} $out/bin/kluctl completion zsh)
+    '';
+
+  meta = {
+    description = "Missing glue to put together large Kubernetes deployments";
+    mainProgram = "kluctl";
+    homepage = "https://kluctl.io/";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      sikmir
+      netthier
+    ];
+  };
+})

pkgs/by-name/kl/klystrack/package.nix

@@ -0,0 +1,91 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  SDL2,
+  SDL2_image,
+  pkg-config,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "klystrack";
+  version = "1.7.6";
+
+  src = fetchFromGitHub {
+    owner = "kometbomb";
+    repo = "klystrack";
+    tag = finalAttrs.version;
+    fetchSubmodules = true;
+    hash = "sha256-30fUI4abo4TxoUdZfKBowL4lF/lDiwnhQASr1kTVKcE=";
+  };
+
+  # https://github.com/kometbomb/klystrack/commit/6dac9eb5e75801ce4dec1d8b339f78e3df2f54bc fixes build but doesn't apply as-is, just patch in the flag
+  # Make embedded date reproducible
+  # Use pkg-config instead of sdl2-config
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail '-DUSESDL_IMAGE' '-DUSESDL_IMAGE -DUSESDL_RWOPS'
+
+    substituteInPlace Makefile klystron/Makefile \
+      --replace-fail 'date' 'date --date @$(SOURCE_DATE_EPOCH)'
+
+    substituteInPlace klystron/common.mk klystron/tools/makebundle/Makefile \
+      --replace-fail 'sdl2-config' 'pkg-config sdl2 SDL2_image'
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    SDL2
+    SDL2_image
+  ];
+
+  patches = [
+    (fetchpatch {
+      url = "https://github.com/kometbomb/klystrack/commit/bb537595d02140176831c4a1b8e9121978b32d22.patch";
+      hash = "sha256-sb7ZYf27qfmWp8RiZFIIOpUJenp0hNXvTAM8LgFO9Bk=";
+    })
+  ];
+
+  # Workaround build failure on -fno-common toolchains:
+  #   ld: libengine_gui.a(gui_menu.o):(.bss+0x0): multiple definition of
+  #     `menu_t'; objs.release/action.o:(.bss+0x20): first defined here
+  # TODO: remove it for 1.7.7+ release as it was fixed upstream.
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  buildFlags = [
+    "PREFIX=${placeholder "out"}"
+    "CFG=release"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 bin.release/klystrack $out/bin/klystrack
+
+    mkdir -p $out/lib/klystrack
+    cp -R res $out/lib/klystrack
+    cp -R key $out/lib/klystrack
+
+    install -DT icon/256x256.png $out/share/icons/hicolor/256x256/apps/klystrack.png
+    mkdir -p $out/share/applications
+    substitute linux/klystrack.desktop $out/share/applications/klystrack.desktop \
+      --replace "klystrack %f" "$out/bin/klystrack %f"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Chiptune tracker";
+    homepage = "https://kometbomb.github.io/klystrack";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ suhr ];
+    platforms = lib.platforms.linux;
+    mainProgram = "klystrack";
+  };
+})