push sheeet

pkgs/by-name/km/kmeet/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  fetchurl,
+  appimageTools,
+}:
+
+appimageTools.wrapType2 rec {
+  pname = "kmeet";
+  version = "2.0.1";
+
+  src = fetchurl {
+    url = "https://download.storage5.infomaniak.com/meet/kmeet-desktop-${version}-linux-x86_64.AppImage";
+    name = "kmeet-${version}.AppImage";
+    hash = "sha256-0lygBbIwaEydvFEfvADiL2k5GWzVpM1jX4orweriBYw=";
+  };
+
+  extraInstallCommands =
+    let
+      contents = appimageTools.extractType2 { inherit pname version src; };
+    in
+    ''
+      mkdir -p "$out/share/applications"
+      mkdir -p "$out/share/lib/kmeet"
+      cp -r ${contents}/{locales,resources} "$out/share/lib/kmeet"
+      cp -r ${contents}/usr/* "$out"
+      cp "${contents}/kMeet.desktop" "$out/share/applications/"
+      mv "$out/bin/kmeet" "$out/bin/${meta.mainProgram}" || true
+      substituteInPlace $out/share/applications/kMeet.desktop --replace 'Exec=AppRun' 'Exec=${meta.mainProgram}'
+    '';
+
+  meta = with lib; {
+    description = "Organise secure online meetings via your web browser, your mobile, your tablet or your computer";
+    homepage = "https://www.infomaniak.com/en/apps/download-kmeet";
+    license = licenses.unfree;
+    maintainers = [ maintainers.vinetos ];
+    mainProgram = "kmeet";
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+    longDescription = ''
+      kMeet allows you to organise secure online meetings via your web browser, your mobile, your tablet or your
+      computer.
+    '';
+  };
+}

pkgs/by-name/km/kmetronome/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  cmake,
+  pandoc,
+  pkg-config,
+  alsa-lib,
+  qt6Packages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kmetronome";
+  version = "1.4.1";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/kmetronome/${finalAttrs.version}/kmetronome-${finalAttrs.version}.tar.bz2";
+    hash = "sha256-FJVmSMu0KDoq8DHRxxGyHQQflPCvH1h+WdsV9wcPAPA=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pandoc
+    pkg-config
+    qt6Packages.qttools
+  ];
+
+  buildInputs = [
+    alsa-lib
+    qt6Packages.drumstick
+    qt6Packages.qtbase
+    qt6Packages.qtsvg
+  ];
+
+  dontWrapQtApps = true;
+
+  meta = {
+    homepage = "https://kmetronome.sourceforge.io/";
+    description = "ALSA MIDI metronome with Qt interface";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ orivej ];
+    platforms = lib.platforms.linux;
+    mainProgram = "kmetronome";
+  };
+})

pkgs/by-name/km/kmidimon/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  nix-update-script,
+  qt6,
+  qt6Packages,
+  cmake,
+  alsa-lib,
+  pandoc,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kmidimon";
+  version = "1.4.1";
+  src = fetchFromGitHub {
+    owner = "pedrolcl";
+    repo = "kmidimon";
+    tag = "RELEASE_${lib.replaceStrings [ "." ] [ "_" ] finalAttrs.version}";
+    hash = "sha256-cITRv/k7NJvTPJYNjDXb21ctr69ThIJppmBwrmj7O74=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    qt6.wrapQtAppsHook
+    pandoc
+  ];
+
+  buildInputs = [
+    qt6.qtbase
+    qt6.qttools
+    qt6.qt5compat
+    qt6Packages.drumstick
+    alsa-lib
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Drumstick MIDI Monitor";
+    longDescription = ''
+      Drumstick MIDI Monitor logs MIDI events coming from MIDI external ports or
+      applications via the ALSA sequencer, and from SMF (Standard MIDI files) or
+      WRK (Cakewalk/Sonar) files. It is especially useful for debugging MIDI
+      software or your MIDI setup.
+    '';
+    homepage = "https://github.com/pedrolcl/kmidimon";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ qweered ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/km/kminion/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+  nixosTests,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "kafka-minion";
+  version = "2.2.13";
+
+  src = fetchFromGitHub {
+    owner = "redpanda-data";
+    repo = "kminion";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-s7kHMMU/srqww/N5szTvX6hOFDV9k9hm+0EZUxIj9So=";
+  };
+
+  vendorHash = "sha256-vdbSKEWlFH4UkuBxu0LFs8+Rwa4aWTjE8gD4zKuvcs4=";
+
+  doCheck = false;
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${finalAttrs.version}"
+    "-X main.builtAt=unknown"
+  ];
+
+  passthru = {
+    tests = {
+      inherit (nixosTests.prometheus-exporters) kafka;
+    };
+    updateScript = ./update.sh;
+  };
+
+  meta = with lib; {
+    description = "Feature-rich Prometheus exporter for Apache Kafka written in Go";
+    license = licenses.mit;
+    maintainers = with maintainers; [ cafkafk ];
+    mainProgram = "kminion";
+  };
+})

pkgs/by-name/km/kminion/update.sh

@@ -0,0 +1,4 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p nix-update
+
+nix-update kminion

pkgs/by-name/km/kmod-blacklist-ubuntu/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+let
+  version = "31+20240202-2ubuntu8"; # Oriole 2024-10-03
+
+in
+stdenv.mkDerivation {
+  pname = "kmod-blacklist";
+  inherit version;
+
+  src = fetchurl {
+    url = "https://launchpad.net/ubuntu/+archive/primary/+files/kmod_${version}.debian.tar.xz";
+    hash = "sha256-i4XdCRedZIzMBbZL305enz8OAso3X14pdzNIITqK5hE=";
+  };
+
+  installPhase = ''
+    mkdir "$out"
+    for f in modprobe.d/*.conf; do
+      echo "''\n''\n## file: "`basename "$f"`"''\n''\n" >> "$out"/modprobe.conf
+      cat "$f" >> "$out"/modprobe.conf
+      # https://bugs.launchpad.net/ubuntu/+source/kmod/+bug/1475945
+      sed -i '/^blacklist i2c_i801/d' $out/modprobe.conf
+    done
+
+    substituteInPlace "$out"/modprobe.conf \
+      --replace /sbin/lsmod /run/booted-system/sw/bin/lsmod \
+      --replace /sbin/rmmod /run/booted-system/sw/bin/rmmod \
+      --replace /sbin/modprobe /run/booted-system/sw/bin/modprobe \
+      --replace " grep " " /run/booted-system/sw/bin/grep " \
+      --replace " xargs " " /run/booted-system/sw/bin/xargs "
+  '';
+
+  meta = with lib; {
+    homepage = "https://launchpad.net/ubuntu/+source/kmod";
+    description = "Linux kernel module blacklists from Ubuntu";
+    platforms = platforms.linux;
+    license = with licenses; [
+      gpl2Plus
+      lgpl21Plus
+    ];
+  };
+}

pkgs/by-name/km/kmod-debian-aliases/package.nix

@@ -0,0 +1,30 @@
+{
+  stdenv,
+  fetchurl,
+  lib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kmod-debian-aliases.conf";
+  version = "30+20230601-2";
+
+  src = fetchurl {
+    url = "https://snapshot.debian.org/archive/debian/20231117T085632Z/pool/main/k/kmod/kmod_${version}.debian.tar.xz";
+    hash = "sha256-xJMGKht8hu0aQjN9TER87Rv5EYkVMeDfX/jJ8+UjAqM=";
+  };
+
+  installPhase = ''
+    cp extra/aliases.conf $out
+  '';
+
+  meta = with lib; {
+    homepage = "https://packages.debian.org/source/sid/kmod";
+    description = "Linux configuration file for modprobe";
+    maintainers = with maintainers; [ mathnerd314 ];
+    platforms = with platforms; linux;
+    license = with licenses; [
+      gpl2Plus
+      lgpl21Plus
+    ];
+  };
+}

pkgs/by-name/km/kmon/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  libxcb,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "kmon";
+  version = "1.7.1";
+
+  src = fetchFromGitHub {
+    owner = "orhun";
+    repo = "kmon";
+    rev = "v${version}";
+    sha256 = "sha256-DzbbeVZifuxgmIu3yNv6EI7Jyh8MA0/oSaR5IEPNUN8=";
+  };
+
+  cargoHash = "sha256-B1sxbifMTnr6tLZCAuxVlQPL5oKCUL0wtw3/wOyfyyw=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  buildInputs = [ libxcb ];
+
+  postInstall = ''
+    installManPage $releaseDir/../man/kmon.8
+    installShellCompletion $releaseDir/../completions/kmon.{bash,fish} \
+      --zsh $releaseDir/../completions/_kmon
+  '';
+
+  meta = {
+    description = "Linux Kernel Manager and Activity Monitor";
+    homepage = "https://github.com/orhun/kmon";
+    changelog = "https://github.com/orhun/kmon/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      figsoda
+      matthiasbeyer
+    ];
+    mainProgram = "kmon";
+  };
+}

pkgs/by-name/km/kmscon/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  libtsm,
+  systemdLibs,
+  libxkbcommon,
+  libdrm,
+  libGLU,
+  libGL,
+  pango,
+  pixman,
+  pkg-config,
+  docbook_xsl,
+  libxslt,
+  libgbm,
+  ninja,
+  check,
+  buildPackages,
+}:
+stdenv.mkDerivation {
+  pname = "kmscon";
+  version = "9.0.0-unstable-2025-01-09";
+
+  src = fetchFromGitHub {
+    owner = "Aetf";
+    repo = "kmscon";
+    rev = "a81941f4464e6f9cee75bfb8a1db88c253ede33d";
+    sha256 = "sha256-l7Prt7CsYi4VCnp9xktvqqNT+4djSdO2GvP1JdxhNSI=";
+  };
+
+  strictDeps = true;
+
+  depsBuildBuild = [
+    buildPackages.stdenv.cc
+  ];
+
+  buildInputs = [
+    libGLU
+    libGL
+    libdrm
+    libtsm
+    libxkbcommon
+    pango
+    pixman
+    systemdLibs
+    libgbm
+    check
+  ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    docbook_xsl
+    pkg-config
+    libxslt # xsltproc
+  ];
+
+  env.NIX_CFLAGS_COMPILE =
+    lib.optionalString stdenv.cc.isGNU "-O "
+    + "-Wno-error=maybe-uninitialized -Wno-error=unused-result -Wno-error=implicit-function-declaration";
+
+  enableParallelBuilding = true;
+
+  patches = [
+    ./sandbox.patch # Generate system units where they should be (nix store) instead of /etc/systemd/system
+  ];
+
+  meta = with lib; {
+    description = "KMS/DRM based System Console";
+    mainProgram = "kmscon";
+    homepage = "https://www.freedesktop.org/wiki/Software/kmscon/";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/km/kmscon/sandbox.patch

@@ -0,0 +1,25 @@
+From d51e35a7ab936983b2a544992adae66093c6028f Mon Sep 17 00:00:00 2001
+From: hustlerone <nine-ball@tutanota.com>
+Date: Thu, 20 Feb 2025 11:05:56 +0100
+Subject: [PATCH] Patch for nixpkgs
+
+---
+ meson.build | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/meson.build b/meson.build
+index 964b44b..4415084 100644
+--- a/meson.build
++++ b/meson.build
+@@ -39,7 +39,7 @@ mandir = get_option('mandir')
+ moduledir = get_option('libdir') / meson.project_name()
+ 
+ systemd_deps = dependency('systemd', required: false)
+-systemdsystemunitdir = systemd_deps.get_variable('systemdsystemunitdir', default_value: get_option('libdir') / 'systemd/system')
++systemdsystemunitdir = get_option('libdir') / 'systemd'
+ 
+ #
+ # Required dependencies
+-- 
+2.47.2
+

pkgs/by-name/km/kmscube/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  meson,
+  ninja,
+  libdrm,
+  libX11,
+  libGL,
+  libgbm,
+  pkg-config,
+  gst_all_1,
+}:
+
+stdenv.mkDerivation {
+  pname = "kmscube";
+  version = "unstable-2023-09-25";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.freedesktop.org";
+    owner = "mesa";
+    repo = "kmscube";
+    rev = "96d63eb59e34c647cda1cbb489265f8c536ae055";
+    hash = "sha256-kpnn4JBNvwatrcCF/RGk/fQ7qiKD26iLBr9ovDmAKBo=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja
+  ];
+  buildInputs = [
+    libdrm
+    libX11
+    libGL
+    libgbm
+  ]
+  ++ (with gst_all_1; [
+    gstreamer
+    gst-plugins-base
+  ]);
+
+  meta = with lib; {
+    description = "Example OpenGL app using KMS/GBM";
+    homepage = "https://gitlab.freedesktop.org/mesa/kmscube";
+    license = licenses.mit;
+    maintainers = with maintainers; [ dezgeg ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/km/kmsvnc/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  libdrm,
+  libvncserver,
+  libxkbcommon,
+  libva,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kmsvnc";
+  version = "0.0.6";
+
+  src = fetchFromGitHub {
+    owner = "isjerryxiao";
+    repo = "kmsvnc";
+    rev = "v${version}";
+    hash = "sha256-fOryY9pkeRXjfOq4ZcUKBrBDMWEljLChwXSAbeMNXhw=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    libdrm
+    libvncserver
+    libxkbcommon
+    libva
+  ];
+
+  meta = with lib; {
+    description = "VNC server for DRM/KMS capable GNU/Linux devices";
+    homepage = "https://github.com/isjerryxiao/kmsvnc";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ nickcao ];
+    mainProgram = "kmsvnc";
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/km/kmsxx/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  cmake,
+  pkg-config,
+  libdrm,
+  fmt,
+  libevdev,
+  withPython ? false,
+  python3Packages,
+}:
+
+stdenv.mkDerivation {
+  pname = "kmsxx";
+  version = "2021-07-26";
+
+  src = fetchFromGitHub {
+    owner = "tomba";
+    repo = "kmsxx";
+    fetchSubmodules = true;
+    rev = "54f591ec0de61dd192baf781c9b2ec87d5b461f7";
+    hash = "sha256-j+20WY4a2iTKZnYjXhxbNnZZ53K3dHpDMTp+ZulS+7c=";
+  };
+
+  # Didn't detect pybind11 without cmake
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ]
+  ++ lib.optionals withPython [ cmake ];
+  buildInputs = [
+    libdrm
+    fmt
+    libevdev
+  ]
+  ++ lib.optionals withPython (
+    with python3Packages;
+    [
+      python
+      pybind11
+    ]
+  );
+
+  dontUseCmakeConfigure = true;
+
+  mesonFlags = lib.optional (!withPython) "-Dpykms=disabled";
+
+  meta = with lib; {
+    description = "C++11 library, utilities and python bindings for Linux kernel mode setting";
+    homepage = "https://github.com/tomba/kmsxx";
+    license = licenses.mpl20;
+    maintainers = [ ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/km/kmymoney/package.nix

@@ -0,0 +1,109 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  cmake,
+  doxygen,
+  graphviz,
+  pkg-config,
+  autoPatchelfHook,
+  kdePackages,
+  alkimia,
+  aqbanking,
+  gmp,
+  gwenhywfar,
+  libical,
+  libofx,
+  sqlcipher,
+
+  # Needed for running tests:
+  xvfb-run,
+
+  python3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kmymoney";
+  version = "5.2.1";
+
+  src = fetchurl {
+    url = "mirror://kde/stable/kmymoney/${finalAttrs.version}/kmymoney-${finalAttrs.version}.tar.xz";
+    hash = "sha256-/q30C21MkNd+MnFqhY3SN2kIGGMQTYzqYpELHsPkM2s=";
+  };
+
+  cmakeFlags = [
+    "-DBUILD_WITH_QT6=1"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    doxygen
+    graphviz
+    pkg-config
+    python3.pkgs.wrapPython
+  ]
+  ++ (with kdePackages; [
+    extra-cmake-modules
+    wrapQtAppsHook
+    kdoctools
+    autoPatchelfHook
+  ]);
+
+  buildInputs = [
+    alkimia
+    aqbanking
+    gmp
+    gwenhywfar
+    libical
+    libofx
+    sqlcipher
+  ]
+  ++ (with kdePackages; [
+    akonadi
+    karchive
+    kcmutils
+    kcontacts
+    qtwebengine
+    kdiagram
+    kholidays
+    kidentitymanagement
+    kitemmodels
+    plasma-activities
+    qgpgme
+  ])
+  ++ [
+    # Put it into buildInputs so that CMake can find it, even though we patch
+    # it into the interface later.
+    python3.pkgs.woob
+  ];
+
+  postPatch = ''
+    buildPythonPath "${python3.pkgs.woob}"
+    patchPythonScript "kmymoney/plugins/woob/interface/kmymoneywoob.py"
+
+    # Within the embedded Python interpreter, sys.argv is unavailable, so let's
+    # assign it to a dummy value so that the assignment of sys.argv[0] injected
+    # by patchPythonScript doesn't fail:
+    sed -i -e '1i import sys; sys.argv = [""]' \
+      "kmymoney/plugins/woob/interface/kmymoneywoob.py"
+  '';
+
+  # libpython is required by the python interpreter embedded in kmymoney, so we
+  # need to explicitly tell autoPatchelf about it.
+  postFixup = ''
+    patchelf --debug --add-needed libpython${python3.pythonVersion}.so \
+      "$out/bin/.kmymoney-wrapped"
+  '';
+
+  meta = {
+    description = "Personal finance manager for KDE";
+    mainProgram = "kmymoney";
+    homepage = "https://kmymoney.org/";
+    platforms = lib.platforms.linux;
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      aidalgol
+      das-g
+    ];
+  };
+})