push sheeet

pkgs/by-name/lc/lc0/package.nix

@@ -0,0 +1,72 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  python3,
+  zlib,
+  gtest,
+  eigen,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lc0";
+  version = "0.31.2";
+
+  src = fetchFromGitHub {
+    owner = "LeelaChessZero";
+    repo = "lc0";
+    tag = "v${version}";
+    hash = "sha256-8watDDxSyZ5khYqpXPyjQso2MkOzfI6o2nt0vkuiEUI=";
+    fetchSubmodules = true;
+  };
+
+  patchPhase = ''
+    runHook prePatch
+
+    patchShebangs --build scripts/*
+
+    runHook postPatch
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    python3
+  ];
+
+  buildInputs = [
+    eigen
+    gtest
+    zlib
+  ];
+
+  mesonFlags = [
+    "-Dplain_cuda=false"
+    "-Daccelerate=false"
+    "-Dmetal=disabled"
+    "-Dembed=false"
+  ]
+  # in version 31 this option will be required
+  ++ lib.optionals (lib.versionAtLeast version "0.31") [ "-Dnative_cuda=false" ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    homepage = "https://lczero.org/";
+    description = "Open source neural network based chess engine";
+    longDescription = ''
+      Lc0 is a UCI-compliant chess engine designed to play chess via neural network, specifically those of the LeelaChessZero project.
+    '';
+    maintainers = with lib.maintainers; [ _9glenda ];
+    platforms = lib.platforms.unix;
+    license = lib.licenses.gpl3Plus;
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+
+}

pkgs/by-name/lc/lc3tools/0001-mangle-configure.patch

@@ -0,0 +1,29 @@
+diff --git a/configure b/configure
+index 46f9af4..dfc1b3e 100755
+--- a/configure
++++ b/configure
+@@ -17,10 +17,11 @@ esac
+ 
+ # Some binaries that we'll need, and the places that we might find them.
+ 
+-binlist="uname flex gcc wish rm cp mkdir chmod sed"
+-pathlist="/bin /usr/bin /usr/local/bin /sw/bin /usr/x116/bin /usr/X11R6/bin"
+-libpathlist="/lib /usr/lib /usr/local/lib"
+-incpathlist="/include /usr/include /usr/local/include"
++IFS=:
++binlist="uname:flex:gcc:wish:rm:cp:mkdir:chmod:sed"
++pathlist=$PATH
++libpathlist=$LIBS
++incpathlist=$INCLUDES
+ 
+ 
+ # Find the binaries (or die trying).
+@@ -55,7 +56,7 @@ case `$uname -s` in
+ 		echo "Configuring for Cygwin..."
+ 		;;
+ 	Linux*) echo "Configuring for Linux..."
+-		OS_SIM_LIBS="-lcurses"
++		# OS_SIM_LIBS="-lcurses"
+ 		;;
+ 	SunOS*)  echo "Configuring for Solaris..."
+ 		OS_SIM_LIBS="-lcurses -lsocket -lnsl"

pkgs/by-name/lc/lc3tools/0002-lc3os-path.patch

@@ -0,0 +1,21 @@
+diff --git a/lc3sim.c b/lc3sim.c
+index dac7f7a..736fd7c 100644
+--- a/lc3sim.c
++++ b/lc3sim.c
+@@ -665,14 +665,14 @@ init_machine ()
+     bzero (lc3_sym_hash, sizeof (lc3_sym_hash));
+     clear_all_breakpoints ();
+ 
+-    if (read_obj_file (INSTALL_DIR "/lc3os.obj", &os_start, &os_end) == -1) {
++    if (read_obj_file (INSTALL_DIR "/share/lc3tools/lc3os.obj", &os_start, &os_end) == -1) {
+ 	if (gui_mode)
+ 	    puts ("ERR {Failed to read LC-3 OS code.}");
+ 	else
+ 	    puts ("Failed to read LC-3 OS code.");
+ 	show_state_if_stop_visible ();
+     } else {
+-	if (read_sym_file (INSTALL_DIR "/lc3os.sym") == -1) {
++	if (read_sym_file (INSTALL_DIR "/share/lc3tools/lc3os.sym") == -1) {
+ 	    if (gui_mode)
+ 		puts ("ERR {Failed to read LC-3 OS symbols.}");
+ 	    else

pkgs/by-name/lc/lc3tools/0003-lc3sim-tk-path.patch

@@ -0,0 +1,13 @@
+diff --git a/Makefile.def b/Makefile.def
+index 34f7df3..05dc86c 100644
+--- a/Makefile.def
++++ b/Makefile.def
+@@ -155,7 +155,7 @@ dist_lc3sim-tk: lc3sim-tk
+ 
+ lc3sim-tk: lc3sim-tk.def
+ 	${SED} -e 's @@WISH@@ ${WISH} g' \
+-		-e 's*@@LC3_SIM@@*"${INSTALL_DIR}/lc3sim"*g' \
++		-e 's*@@LC3_SIM@@*"${INSTALL_DIR}/bin/lc3sim"*g' \
+ 		-e 's!@@CODE_FONT@@!${CODE_FONT}!g' \
+ 		-e 's!@@BUTTON_FONT@@!${BUTTON_FONT}!g' \
+ 		-e 's!@@CONSOLE_FONT@@!${CONSOLE_FONT}!g' \

pkgs/by-name/lc/lc3tools/0004-configure-use-cc.patch

@@ -0,0 +1,22 @@
+diff --git a/configure b/configure
+index dfc1b3e..55577af 100755
+--- a/configure
++++ b/configure
+@@ -18,7 +18,7 @@ esac
+ # Some binaries that we'll need, and the places that we might find them.
+ 
+ IFS=:
+-binlist="uname:flex:gcc:wish:rm:cp:mkdir:chmod:sed"
++binlist="uname:flex:cc:wish:rm:cp:mkdir:chmod:sed"
+ pathlist=$PATH
+ libpathlist=$LIBS
+ incpathlist=$INCLUDES
+@@ -109,7 +109,7 @@ fi
+ # Splice it all in to Makefile.def to create the Makefile.
+ 
+ rm -f Makefile
+-sed -e "s __GCC__ $gcc g" -e "s __FLEX__ $flex g" -e "s __EXE__ $EXE g"     \
++sed -e "s __GCC__ $cc g" -e "s __FLEX__ $flex g" -e "s __EXE__ $EXE g"     \
+     -e "s*__OS_SIM_LIBS__*$OS_SIM_LIBS*g" -e "s __RM__ $rm g"               \
+     -e "s __CP__ $cp g" -e "s __MKDIR__ $mkdir g" -e "s __CHMOD__ $chmod g" \
+     -e "s __USE_READLINE__ $USE_READLINE g" -e "s*__RLLPATH__*$RLLPATH*g"   \

pkgs/by-name/lc/lc3tools/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+  flex,
+  tk,
+  ncurses,
+  readline,
+}:
+
+stdenv.mkDerivation {
+  pname = "lc3tools";
+  version = "0.12";
+
+  src = fetchurl {
+    url = "https://highered.mheducation.com/sites/dl/free/0072467509/104652/lc3tools_v12.zip";
+    hash = "sha256-PTM0ole8pHiJmUaahjPwcBQY8/hVVgQhADZ4bSABt3I=";
+  };
+
+  patches = [
+    # the original configure looks for things in the FHS path
+    # I have modified it to take environment vars
+    ./0001-mangle-configure.patch
+
+    # lc3sim looks for the LC3 OS in $out/share/lc3tools instead of $out
+    ./0002-lc3os-path.patch
+
+    # lc3sim-tk looks for lc3sim in $out/bin instead of $out
+    ./0003-lc3sim-tk-path.patch
+
+    # use `cc` instead of `gcc`; on macOS the latter is not present
+    ./0004-configure-use-cc.patch
+  ];
+
+  nativeBuildInputs = [ unzip ];
+  buildInputs = [
+    flex
+    tk
+    ncurses
+    readline
+  ];
+
+  # lumetta published this a while ago but handrolled his configure
+  # jank in the original packaging makes this necessary:
+  LIBS = "${flex}/lib:${ncurses}/lib:${readline}/lib";
+  INCLUDES = "${flex}/include:${ncurses}/include:${readline}/include";
+
+  # it doesn't take `--prefix`
+  prefixKey = "--installdir ";
+
+  postInstall = ''
+    mkdir -p $out/{bin,share/lc3tools}
+
+    mv -t $out/share/lc3tools $out/{COPYING,NO_WARRANTY,README} $out/lc3os*
+    mv -t $out/bin $out/lc3*
+  '';
+
+  meta = with lib; {
+    longDescription = ''
+      The LC-3 tools package contains the lc3as assembler, the lc3sim simulator,
+      and lc3sim-tk, a Tcl/Tk-based GUI frontend to the simulator.
+    '';
+    description = "Toolchain and emulator for the LC-3 architecture";
+    homepage = "https://highered.mheducation.com/sites/0072467509/student_view0/lc-3_simulator.html";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ anna328p ];
+    mainProgram = "lc3sim-tk";
+    platforms = with lib.platforms; unix ++ windows;
+  };
+}

pkgs/by-name/lc/lcab/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lcab";
+  version = "1.0b12";
+
+  src = fetchurl {
+    # Original site is no longer available
+    url = "http://deb.debian.org/debian/pool/main/l/lcab/lcab_${finalAttrs.version}.orig.tar.gz";
+    hash = "sha256-Bl8sF5O2XyhHHA9xt88SCnBk8o0cRLB8q/SewOl/H8g=";
+  };
+
+  patches = [
+    # Fix version number
+    (fetchurl {
+      url = "https://salsa.debian.org/debian/lcab/-/raw/f72d6db6504123bd124b1a4be21ead8cc1535c9e/debian/patches/20-version.patch";
+      hash = "sha256-Yb6E8nQVdicmjcGnxR7HHdsd7D+ThXk02UHiaB+PLvE=";
+    })
+  ];
+
+  meta = with lib; {
+    description = "Create cabinet (.cab) archives";
+    homepage = "http://ohnopub.net/~ohnobinki/lcab";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ emilytrau ];
+    platforms = platforms.unix;
+    mainProgram = "lcab";
+  };
+})

pkgs/by-name/lc/lcalc/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  autoreconfHook,
+  gengetopt,
+  pkg-config,
+  fetchFromGitLab,
+  pari,
+}:
+
+stdenv.mkDerivation rec {
+  version = "2.1.1";
+  pname = "lcalc";
+
+  src = fetchFromGitLab {
+    owner = "sagemath";
+    repo = "lcalc";
+    tag = version;
+    hash = "sha256-0CYrRGn5YQ07BaGu0Q5otnjwyh3sNq21EXp3M/KlRdw=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    gengetopt
+    pkg-config
+  ];
+
+  buildInputs = [
+    pari
+  ];
+
+  configureFlags = [
+    "--with-pari"
+  ];
+
+  meta = with lib; {
+    homepage = "https://gitlab.com/sagemath/lcalc";
+    description = "Program for calculating with L-functions";
+    mainProgram = "lcalc";
+    license = with licenses; [ gpl2 ];
+    teams = [ teams.sage ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/lc/lcdf-typetools/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lcdf-typetools";
+  version = "2.110";
+
+  src = fetchFromGitHub {
+    owner = "kohler";
+    repo = "lcdf-typetools";
+    rev = "v${version}";
+    sha256 = "sha256-hoILYYCef2R1v6aN9V+FoYnXYaKsnGN2jlpb/QFAN/w=";
+  };
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  configureFlags = [ "--without-kpathsea" ];
+
+  meta = with lib; {
+    description = "Utilities for manipulating OpenType, PostScript Type 1, and Multiple Master fonts";
+    homepage = "https://www.lcdf.org/type";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ dtzWill ];
+  };
+}

pkgs/by-name/lc/lcdproc/hardcode_mtab.patch

@@ -0,0 +1,17 @@
+diff --git a/clients/lcdproc/machine_Linux.c b/clients/lcdproc/machine_Linux.c
+index 7bb7266..a629674 100644
+--- a/clients/lcdproc/machine_Linux.c
++++ b/clients/lcdproc/machine_Linux.c
+@@ -259,11 +259,7 @@ machine_get_fs(mounts_type fs[], int *cnt)
+	char line[256];
+	int x = 0, err;
+
+-#ifdef MTAB_FILE
+-	mtab_fd = fopen(MTAB_FILE, "r");
+-#else
+-#error "Can't find your mounted filesystem table file."
+-#endif
++	mtab_fd = fopen("/etc/mtab", "r");
+
+	/* Get rid of old, unmounted filesystems... */
+	memset(fs, 0, sizeof(mounts_type) * 256);

pkgs/by-name/lc/lcdproc/package.nix

@@ -0,0 +1,93 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  autoreconfHook,
+  makeWrapper,
+  pkg-config,
+  doxygen,
+  freetype,
+  libX11,
+  libftdi,
+  libusb-compat-0_1,
+  libusb1,
+  ncurses,
+  perl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lcdproc";
+  version = "0.5.9";
+
+  src = fetchFromGitHub {
+    owner = "lcdproc";
+    repo = "lcdproc";
+    rev = "v${version}";
+    sha256 = "1r885zv1gsh88j43x6fvzbdgfkh712a227d369h4fdcbnnfd0kpm";
+  };
+
+  patches = [
+    ./hardcode_mtab.patch
+
+    # Pull upstream fix for -fno-common toolchains:
+    #   https://github.com/lcdproc/lcdproc/pull/148
+    (fetchpatch {
+      name = "fno-common.patch";
+      url = "https://github.com/lcdproc/lcdproc/commit/fda5302878692da933dc03cd011f8ddffefa07a4.patch";
+      sha256 = "0ld6p1r4rjsnjr63afw3lp5lx25jxjs07lsp9yc3q96r91r835cy";
+    })
+  ];
+
+  # we don't need to see the GPL every time we launch lcdd in the foreground
+  postPatch = ''
+    substituteInPlace server/main.c \
+      --replace 'output_GPL_notice();' '// output_GPL_notice();'
+  '';
+
+  configureFlags = [
+    "--enable-lcdproc-menus"
+    "--enable-drivers=all"
+    "--with-pidfile-dir=/run"
+  ];
+
+  buildInputs = [
+    freetype
+    libX11
+    libftdi
+    libusb-compat-0_1
+    libusb1
+    ncurses
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    doxygen
+    makeWrapper
+    pkg-config
+  ];
+
+  # In 0.5.9: gcc: error: libbignum.a: No such file or directory
+  enableParallelBuilding = false;
+
+  postFixup = ''
+    for f in $out/bin/*.pl ; do
+      substituteInPlace $f \
+        --replace /usr/bin/perl ${lib.getBin perl}/bin/perl
+    done
+
+    # NixOS will not use this file anyway but at least we can now execute LCDd
+    substituteInPlace $out/etc/LCDd.conf \
+      --replace server/drivers/ $out/lib/lcdproc/
+  '';
+
+  meta = with lib; {
+    description = "Client/server suite for controlling a wide variety of LCD devices";
+    homepage = "https://lcdproc.org/";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ peterhoeg ];
+    platforms = platforms.unix;
+    # never built on aarch64-darwin since first introduction in nixpkgs
+    broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64;
+  };
+}

pkgs/by-name/lc/lcevcdec/package.nix

@@ -0,0 +1,82 @@
+{
+  cmake,
+  fetchFromGitHub,
+  git,
+  gitUpdater,
+  fetchpatch,
+  lib,
+  nlohmann_json,
+  pkg-config,
+  python3,
+  stdenv,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lcevcdec";
+  version = "4.0.1";
+
+  outputs = [
+    "out"
+    "lib"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "v-novaltd";
+    repo = "LCEVCdec";
+    tag = finalAttrs.version;
+    hash = "sha256-azY4xle2wwopT9qEHa4+nXPkGzscWz9tYof1qN7Nw8c=";
+  };
+
+  postPatch = ''
+    substituteInPlace cmake/tools/version_files.py \
+      --replace-fail "args.git_version" '"${finalAttrs.version}"' \
+      --replace-fail "args.git_hash" '"${finalAttrs.src.rev}"' \
+      --replace-fail "args.git_date" '"1970-01-01"'
+    substituteInPlace cmake/templates/lcevc_dec.pc.in \
+      --replace-fail "@GIT_SHORT_VERSION@" "${finalAttrs.version}"
+  '';
+
+  env = {
+    includedir = "${placeholder "dev"}/include";
+    libdir = "${placeholder "out"}/lib";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    git
+    pkg-config
+    python3
+  ];
+
+  buildInputs = [
+    nlohmann_json
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeFeature "VN_SDK_FFMPEG_LIBS_PACKAGE" "")
+    (lib.cmakeBool "VN_SDK_UNIT_TESTS" false)
+    (lib.cmakeBool "VN_SDK_SAMPLE_SOURCE" false)
+    (lib.cmakeBool "VN_SDK_JSON_CONFIG" true)
+    (lib.cmakeBool "VN_CORE_AVX2" stdenv.hostPlatform.avx2Support)
+    # Requires avx for checking on runtime
+    (lib.cmakeBool "VN_CORE_SSE" stdenv.hostPlatform.avxSupport)
+    (lib.cmakeBool "VN_SDK_SIMD" stdenv.hostPlatform.avxSupport)
+  ];
+
+  passthru = {
+    updateScript = gitUpdater { };
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    homepage = "https://github.com/v-novaltd/LCEVCdec";
+    description = "MPEG-5 LCEVC Decoder";
+    license = lib.licenses.bsd3Clear;
+    pkgConfigModules = [ "lcevc_dec" ];
+    maintainers = with lib.maintainers; [ jopejoe1 ];
+    # https://github.com/v-novaltd/LCEVCdec/blob/bf7e0d91c969502e90a925942510a1ca8088afec/cmake/modules/VNovaProject.cmake#L29
+    platforms = lib.platforms.aarch ++ lib.platforms.x86;
+  };
+})

pkgs/by-name/lc/lci/package.nix

@@ -0,0 +1,23 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  readline,
+}:
+stdenv.mkDerivation rec {
+  version = "0.6";
+  pname = "lci";
+  src = fetchurl {
+    url = "mirror://sourceforge/lci/${pname}-${version}.tar.gz";
+    sha256 = "204f1ca5e2f56247d71ab320246811c220ed511bf08c9cb7f305cf180a93948e";
+  };
+  buildInputs = [ readline ];
+  meta = {
+    description = "Lambda calculus interpreter";
+    homepage = "https://www.chatzi.org/lci/";
+    mainProgram = "lci";
+    maintainers = with lib.maintainers; [ raskin ];
+    platforms = with lib.platforms; linux;
+    license = lib.licenses.gpl3;
+  };
+}

pkgs/by-name/lc/lcm/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  glib,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lcm";
+  version = "1.5.1";
+
+  src = fetchFromGitHub {
+    owner = "lcm-proj";
+    repo = "lcm";
+    rev = "v${version}";
+    hash = "sha256-043AJzalfx+qcCoxQgPU4T/DcUH0pXOE4v1aJaW3aXs=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+    "man"
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+  ];
+
+  buildInputs = [
+    glib
+  ];
+
+  meta = with lib; {
+    description = "Lightweight Communications and Marshalling (LCM)";
+    homepage = "https://github.com/lcm-proj/lcm";
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ kjeremy ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/lc/lcms1/cve-2013-4276.patch

@@ -0,0 +1,62 @@
+diff -ur lcms-1.19.dfsg/samples/icctrans.c lcms-1.19.dfsg-patched/samples/icctrans.c
+--- lcms-1.19.dfsg/samples/icctrans.c	2009-10-30 15:57:45.000000000 +0000
++++ lcms-1.19.dfsg-patched/samples/icctrans.c	2013-08-06 11:53:14.385266647 +0100
+@@ -86,6 +86,8 @@
+ static LPcmsNAMEDCOLORLIST InputColorant = NULL;
+ static LPcmsNAMEDCOLORLIST OutputColorant = NULL;
+ 
++unsigned int Buffer_size = 4096;
++
+ 
+ // isatty replacement
+ 
+@@ -500,7 +502,7 @@
+ 
+     Prefix[0] = 0;
+     if (!lTerse)
+-        sprintf(Prefix, "%s=", C);
++        snprintf(Prefix, 20, "%s=", C);
+ 
+     if (InHexa)
+     {
+@@ -648,7 +650,9 @@
+ static
+ void GetLine(char* Buffer)
+ {    
+-    scanf("%s", Buffer);
++    char User_buffer[Buffer_size];
++    fgets(User_buffer, (Buffer_size - 1), stdin);
++    sscanf(User_buffer,"%s", Buffer);
+     
+     if (toupper(Buffer[0]) == 'Q') { // Quit?
+ 
+@@ -668,7 +672,7 @@
+ static
+ double GetAnswer(const char* Prompt, double Range)
+ {
+-    char Buffer[4096];
++    char Buffer[Buffer_size];
+     double val = 0.0;
+ 	       
+     if (Range == 0.0) {              // Range 0 means double value
+@@ -738,7 +742,7 @@
+ static
+ WORD GetIndex(void)
+ {
+-    char Buffer[4096], Name[40], Prefix[40], Suffix[40];
++    char Buffer[Buffer_size], Name[40], Prefix[40], Suffix[40];
+     int index, max;
+ 
+     max = cmsNamedColorCount(hTrans)-1;
+diff -ur lcms-1.19.dfsg/tifficc/tiffdiff.c lcms-1.19.dfsg-patched/tifficc/tiffdiff.c
+--- lcms-1.19.dfsg/tifficc/tiffdiff.c	2009-10-30 15:57:46.000000000 +0000
++++ lcms-1.19.dfsg-patched/tifficc/tiffdiff.c	2013-08-06 11:49:06.698951157 +0100
+@@ -633,7 +633,7 @@
+     cmsIT8SetSheetType(hIT8, "TIFFDIFF");
+     
+    
+-    sprintf(Buffer, "Differences between %s and %s", TiffName1, TiffName2);
++    snprintf(Buffer, 256, "Differences between %s and %s", TiffName1, TiffName2);
+   
+     cmsIT8SetComment(hIT8, Buffer);
+ 

pkgs/by-name/lc/lcms1/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lcms";
+  version = "1.19";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/lcms/${pname}-${version}.tar.gz";
+    sha256 = "1abkf8iphwyfs3z305z3qczm3z1i9idc1lz4gvfg92jnkz5k5bl0";
+  };
+
+  patches = [ ./cve-2013-4276.patch ];
+
+  env = lib.optionalAttrs stdenv.cc.isGNU {
+    NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
+  };
+
+  outputs = [
+    "bin"
+    "dev"
+    "out"
+    "man"
+  ];
+
+  doCheck = false; # fails with "Error in Linear interpolation (2p): Must be i=8000, But is n=8001"
+
+  meta = {
+    description = "Color management engine";
+    homepage = "http://www.littlecms.com/";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/lc/lcms2/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libtiff,
+  libjpeg,
+  zlib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lcms2";
+  version = "2.17";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/lcms/${pname}-${version}.tar.gz";
+    hash = "sha256-0Rr1aeQqG6oWUNIK1h0S5Br0/q1Kp5ZKAfk7CLU6sHQ=";
+  };
+
+  outputs = [
+    "bin"
+    "dev"
+    "out"
+  ];
+
+  buildInputs = [
+    libtiff
+    libjpeg
+    zlib
+  ];
+
+  # See https://trac.macports.org/ticket/60656
+  LDFLAGS = if stdenv.hostPlatform.isDarwin then "-Wl,-w" else null;
+
+  meta = with lib; {
+    description = "Color management engine";
+    homepage = "http://www.littlecms.com/";
+    license = licenses.mit;
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/lc/lcov/package.nix

@@ -0,0 +1,88 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  perl,
+  python3,
+  perlPackages,
+  makeWrapper,
+  versionCheckHook,
+}:
+
+let
+  perlDeps = [
+    perlPackages.CaptureTiny
+    perlPackages.DateTime
+    perlPackages.DateTimeFormatW3CDTF
+    perlPackages.DevelCover
+    perlPackages.GD
+    perlPackages.JSONXS
+    perlPackages.PathTools
+  ]
+  ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [ perlPackages.MemoryProcess ];
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lcov";
+  version = "2.3.2";
+
+  src = fetchFromGitHub {
+    owner = "linux-test-project";
+    repo = "lcov";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-msttwM5QlSkeruKoVwZYpymz5JOJRb6QoSeF19AkEGI=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    perl
+  ];
+
+  buildInputs = [
+    perl
+    python3
+  ];
+
+  strictDeps = true;
+
+  makeFlags = [
+    "PREFIX=$(out)"
+    "VERSION=${finalAttrs.version}"
+    "RELEASE=1"
+  ];
+
+  preBuild = ''
+    patchShebangs --build bin/{fix.pl,get_version.sh} tests/*/*
+  '';
+
+  postInstall = ''
+    for f in "$out"/bin/{gen*,lcov,llvm2lcov,perl2lcov}; do
+      wrapProgram "$f" --set PERL5LIB ${perlPackages.makeFullPerlPath perlDeps}
+    done
+  '';
+
+  doInstallCheck = true;
+
+  versionCheckProgramArg = "--version";
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  meta = {
+    description = "Code coverage tool that enhances GNU gcov";
+
+    longDescription = ''
+      LCOV is an extension of GCOV, a GNU tool which provides information
+      about what parts of a program are actually executed (i.e.,
+      "covered") while running a particular test case.  The extension
+      consists of a set of PERL scripts which build on the textual GCOV
+      output to implement the following enhanced functionality such as
+      HTML output.
+    '';
+
+    homepage = "https://github.com/linux-test-project/lcov";
+    changelog = "https://github.com/linux-test-project/lcov/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.gpl2Plus;
+
+    maintainers = with lib.maintainers; [ dezgeg ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/lc/lcrq/package.nix

@@ -0,0 +1,37 @@
+{
+  stdenv,
+  fetchFromGitea,
+  lib,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lcrq";
+  version = "0.2.4";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "librecast";
+    repo = "lcrq";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-Vij0aV4BIVrpRSzVneyP7MjlsdJSz1mbMCShEOOYVbQ=";
+  };
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  meta = {
+    changelog = "https://codeberg.org/librecast/lcrq/src/tag/v${finalAttrs.version}/CHANGELOG.md";
+    description = "Librecast RaptorQ library";
+    homepage = "https://librecast.net/lcrq.html";
+    license = [
+      lib.licenses.gpl2
+      lib.licenses.gpl3
+    ];
+    maintainers = with lib.maintainers; [
+      albertchae
+      aynish
+      DMills27
+      jasonodoom
+      jleightcap
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/lc/lcsync/package.nix

@@ -0,0 +1,47 @@
+{
+  fetchFromGitea,
+  lcrq,
+  lib,
+  librecast,
+  libsodium,
+  stdenv,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lcsync";
+  version = "0.3.2";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "librecast";
+    repo = "lcsync";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-KirMifJ5Mc3WXuIZjFv6ZIzpz/bjGHMU2jnRGGQ2w/I=";
+  };
+  buildInputs = [
+    lcrq
+    librecast
+    libsodium
+  ];
+  configureFlags = [ "SETCAP_PROGRAM=true" ];
+  installFlags = [ "PREFIX=$(out)" ];
+  doCheck = true;
+
+  meta = {
+    changelog = "https://codeberg.org/librecast/lcsync/src/tag/v${finalAttrs.version}/CHANGELOG.md";
+    description = "Librecast File and Syncing Tool";
+    mainProgram = "lcsync";
+    homepage = "https://librecast.net/lcsync.html";
+    license = [
+      lib.licenses.gpl2
+      lib.licenses.gpl3
+    ];
+    maintainers = with lib.maintainers; [
+      albertchae
+      aynish
+      DMills27
+      jasonodoom
+      jleightcap
+    ];
+    platforms = lib.platforms.gnu;
+  };
+})