push sheeet

pkgs/by-name/lf/lf/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+}:
+
+buildGoModule rec {
+  pname = "lf";
+  version = "38";
+
+  src = fetchFromGitHub {
+    owner = "gokcehan";
+    repo = "lf";
+    tag = "r${version}";
+    hash = "sha256-a3Ql0E3ZVbveGXGO+n2G2WBVjBk5HuJx9NiaZ7ZAVMc=";
+  };
+
+  vendorHash = "sha256-kZFmCkYd6ijJC/vedUoWZW1TUW1oGD9qA0GCQzfiTUE=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.gVersion=r${version}"
+  ];
+
+  # Force the use of the pure-go implementation of the os/user library.
+  # Relevant issue: https://github.com/gokcehan/lf/issues/191
+  tags = lib.optionals (!stdenv.hostPlatform.isDarwin) [ "osusergo" ];
+
+  postInstall = ''
+    install -D --mode=444 lf.desktop $out/share/applications/lf.desktop
+    installManPage lf.1
+    installShellCompletion etc/lf.{bash,zsh,fish}
+  '';
+
+  meta = {
+    description = "Terminal file manager written in Go and heavily inspired by ranger";
+    longDescription = ''
+      lf (as in "list files") is a terminal file manager written in Go. It is
+      heavily inspired by ranger with some missing and extra features. Some of
+      the missing features are deliberately omitted since it is better if they
+      are handled by external tools.
+    '';
+    homepage = "https://godoc.org/github.com/gokcehan/lf";
+    changelog = "https://github.com/gokcehan/lf/releases/tag/r${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ dotlambda ];
+    mainProgram = "lf";
+  };
+}

pkgs/by-name/lf/lftp/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  openssl,
+  pkg-config,
+  readline,
+  zlib,
+  libidn2,
+  gmp,
+  libiconv,
+  libunistring,
+  gettext,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lftp";
+  version = "4.9.3";
+
+  src = fetchurl {
+    urls = [
+      "https://lftp.yar.ru/ftp/${pname}-${version}.tar.xz"
+      "https://ftp.st.ryukoku.ac.jp/pub/network/ftp/lftp/${pname}-${version}.tar.xz"
+    ];
+    sha256 = "sha256-lucZnXk1vjPPaxFh6VWyqrQKt37N8qGc6k/BGT9Fftw=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    openssl
+    readline
+    zlib
+    libidn2
+    gmp
+    libiconv
+    libunistring
+    gettext
+  ];
+
+  hardeningDisable = lib.optional stdenv.hostPlatform.isDarwin "format";
+
+  env = lib.optionalAttrs stdenv.hostPlatform.isDarwin {
+    # Required to build with clang 16 or `configure` will fail to detect several standard functions.
+    NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
+  };
+
+  configureFlags = [
+    "--with-openssl"
+    "--with-readline=${readline.dev}"
+    "--with-zlib=${zlib.dev}"
+    "--without-expat"
+  ];
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "File transfer program supporting a number of network protocols";
+    homepage = "https://lftp.yar.ru/";
+    license = licenses.gpl3Plus;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.bjornfor ];
+  };
+}