push sheeet

pkgs/by-name/li/libspatialite/package.nix

@@ -0,0 +1,102 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  validatePkgConfig,
+  freexl,
+  geos,
+  librttopo,
+  libxml2,
+  minizip,
+  proj,
+  sqlite,
+  libiconv,
+  zlib,
+  testers,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libspatialite";
+  version = "5.1.0";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchurl {
+    url = "https://www.gaia-gis.it/gaia-sins/libspatialite-sources/libspatialite-${finalAttrs.version}.tar.gz";
+    hash = "sha256-Q74t00na/+AW3RQAxdEShYKMIv6jXKUQnyHz7VBgUIA=";
+  };
+
+  patches = [
+    # Drop use of deprecated libxml2 HTTP API.
+    # From: https://www.gaia-gis.it/fossil/libspatialite/info/7c452740fe
+    # see also: https://github.com/NixOS/nixpkgs/issues/347085
+    ./xmlNanoHTTPCleanup.patch
+  ];
+
+  postPatch = lib.optionalString (!stdenv.hostPlatform.isStatic) ''
+    substituteInPlace spatialite.pc.in \
+      --replace-fail "@LIBS@ @LIBXML2_LIBS@ @SQLITE3_LIBS@ -lm" ""
+  '';
+
+  nativeBuildInputs = [
+    pkg-config
+    validatePkgConfig
+  ];
+
+  buildInputs = [
+    freexl
+    geos
+    librttopo
+    libxml2
+    minizip
+    proj
+    sqlite
+    zlib
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    libiconv
+  ];
+
+  configureFlags = [
+    "--with-geosconfig=${lib.getExe' (lib.getDev geos) "geos-config"}"
+  ];
+
+  enableParallelBuilding = true;
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    ln -s $out/lib/mod_spatialite.{so,dylib}
+  '';
+
+  # Failed tests (linux & darwin):
+  # - check_virtualtable6
+  # - check_drop_rename
+  doCheck = false;
+
+  preCheck = ''
+    export LD_LIBRARY_PATH=$(pwd)/src/.libs
+    export DYLD_LIBRARY_PATH=$(pwd)/src/.libs
+  '';
+
+  passthru.tests = {
+    pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "Extensible spatial index library in C++";
+    homepage = "https://www.gaia-gis.it/fossil/libspatialite";
+    # They allow any of these
+    license = with lib.licenses; [
+      gpl2Plus
+      lgpl21Plus
+      mpl11
+    ];
+    pkgConfigModules = [ "spatialite" ];
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ dotlambda ];
+    teams = [ lib.teams.geospatial ];
+  };
+})

pkgs/by-name/li/libspatialite/xmlNanoHTTPCleanup.patch

@@ -0,0 +1,26 @@
+diff --git a/src/wfs/wfs_in.c b/src/wfs/wfs_in.c
+index fe07a0d..7f2557d 100644
+--- a/src/wfs/wfs_in.c
++++ b/src/wfs/wfs_in.c
+@@ -76,7 +76,10 @@ Regione Toscana - Settore Sistema Informativo Territoriale ed Ambientale
+ #ifdef ENABLE_LIBXML2		/* LIBXML2 enabled: supporting XML documents */
+ 
+ #include <libxml/parser.h>
+-#include <libxml/nanohttp.h>
++
++#ifdef LIBXML_HTTP_ENABLED
++  #include <libxml/nanohttp.h>
++#endif
+ 
+ #define MAX_GTYPES	28
+ 
+@@ -4637,7 +4640,9 @@ SPATIALITE_DECLARE void
+ reset_wfs_http_connection (void)
+ {
+ /* Resets the libxml2 "nano HTTP": useful when changing the HTTP_PROXY settings */
++#ifdef LIBXML_HTTP_ENABLED
+     xmlNanoHTTPCleanup ();
++#endif
+ }
+ 
+ #else /* LIBXML2 isn't enabled */