push sheeet

pkgs/by-name/lo/losslesscut-bin/build-from-appimage.nix

@@ -0,0 +1,50 @@
+{
+  appimageTools,
+  fetchurl,
+  makeWrapper,
+  pname,
+  version,
+  hash,
+  metaCommon ? { },
+}:
+
+let
+  src = fetchurl {
+    url = "https://github.com/mifi/lossless-cut/releases/download/v${version}/LosslessCut-linux-x86_64.AppImage";
+    inherit hash;
+  };
+
+  extracted = appimageTools.extractType2 {
+    inherit pname version src;
+  };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  profile = ''
+    export LC_ALL=C.UTF-8
+  '';
+
+  extraInstallCommands = ''
+    (
+      mkdir -p $out/share
+      cd ${extracted}/usr
+      find share -mindepth 1 -type d -exec mkdir -p $out/{} \;
+      find share -mindepth 1 -type f,l -exec ln -s $PWD/{} $out/{} \;
+    )
+    ln -s ${extracted}/losslesscut.png $out/share/icons/losslesscut.png
+    mkdir $out/share/applications
+    cp ${extracted}/losslesscut.desktop $out/share/applications
+    substituteInPlace $out/share/applications/losslesscut.desktop \
+      --replace AppRun losslesscut
+    wrapProgram "$out/bin/losslesscut" \
+      --add-flags "--disable-seccomp-filter-sandbox"
+  '';
+
+  meta = metaCommon // {
+    platforms = [ "x86_64-linux" ];
+    mainProgram = "losslesscut";
+  };
+}

pkgs/by-name/lo/losslesscut-bin/build-from-dmg.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  _7zz,
+  pname,
+  version,
+  hash,
+  isAarch64,
+  metaCommon ? { },
+}:
+
+stdenvNoCC.mkDerivation {
+  inherit pname version;
+
+  src = fetchurl {
+    url = "https://github.com/mifi/lossless-cut/releases/download/v${version}/LosslessCut-mac-${
+      if isAarch64 then "arm64" else "x64"
+    }.dmg";
+    inherit hash;
+  };
+
+  nativeBuildInputs = [ _7zz ];
+
+  sourceRoot = "LosslessCut.app";
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p "$out/Applications"
+    cd ..
+    mv "$sourceRoot" "$out/Applications"
+    mkdir -p "$out/bin"
+    ln -s "$out/Applications/$(basename "$sourceRoot")/Contents/MacOS/LosslessCut" "$out/bin/losslesscut"
+    runHook postInstall
+  '';
+
+  meta =
+    metaCommon
+    // (with lib; {
+      platforms = if isAarch64 then [ "aarch64-darwin" ] else platforms.darwin;
+      mainProgram = "losslesscut";
+    });
+}

pkgs/by-name/lo/losslesscut-bin/build-from-windows.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  p7zip,
+  pname,
+  version,
+  hash,
+  metaCommon ? { },
+}:
+
+stdenvNoCC.mkDerivation {
+  inherit pname version;
+
+  src = fetchurl {
+    url = "https://github.com/mifi/lossless-cut/releases/download/v${version}/LosslessCut-win-x64.7z";
+    inherit hash;
+  };
+
+  nativeBuildInputs = [ p7zip ];
+
+  unpackPhase = ''
+    runHook preUnpack
+    7z x "$src" -o"$sourceRoot"
+    runHook postUnpack
+  '';
+
+  sourceRoot = "LosslessCut-win-x64";
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p "$out/bin" "$out/libexec"
+    cd ..
+    mv "$sourceRoot" "$out/libexec"
+    ln -s "$out/libexec/$(basename "$sourceRoot")/LosslessCut.exe" "$out/bin/LosslessCut.exe"
+    runHook postInstall
+  '';
+
+  meta =
+    metaCommon
+    // (with lib; {
+      platforms = platforms.windows;
+      mainProgram = "LosslessCut.exe";
+    });
+}

pkgs/by-name/lo/losslesscut-bin/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  callPackage,
+  buildPackages,
+}:
+
+let
+  pname = "losslesscut";
+  version = "3.64.0";
+  metaCommon = with lib; {
+    description = "Swiss army knife of lossless video/audio editing";
+    homepage = "https://mifi.no/losslesscut/";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ ShamrockLee ];
+    mainProgram = "losslesscut";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+  };
+  x86_64-appimage = callPackage ./build-from-appimage.nix {
+    inherit pname version metaCommon;
+    hash = "sha256-K90cJuJFcIkPuAQusJcOBkZ5PQ8T25q7IFIhtmK+jzc=";
+    inherit (buildPackages) makeWrapper;
+  };
+  x86_64-dmg = callPackage ./build-from-dmg.nix {
+    inherit pname version metaCommon;
+    hash = "sha256-BO2KoYAevbVL0Eix1knvaPVBkWucYI89VkueWYRTcXY=";
+    isAarch64 = false;
+  };
+  aarch64-dmg = callPackage ./build-from-dmg.nix {
+    inherit pname version metaCommon;
+    hash = "sha256-/M5yafZQDqCoDzHpjZBC80CcL9KMO5lwvyCcq19caRg=";
+    isAarch64 = true;
+  };
+  x86_64-windows = callPackage ./build-from-windows.nix {
+    inherit pname version metaCommon;
+    hash = "sha256-FYrnTiZ5ATT+Y08zceIIHbVM//5Bg2ozIEyC5UxmIno=";
+  };
+in
+(
+  if stdenv.hostPlatform.system == "aarch64-darwin" then
+    aarch64-dmg
+  else if stdenv.hostPlatform.isDarwin then
+    x86_64-dmg
+  else if stdenv.hostPlatform.isCygwin then
+    x86_64-windows
+  else
+    x86_64-appimage
+).overrideAttrs
+  (oldAttrs: {
+    passthru = (oldAttrs.passthru or { }) // {
+      inherit
+        x86_64-appimage
+        x86_64-dmg
+        aarch64-dmg
+        x86_64-windows
+        ;
+    };
+    meta = oldAttrs.meta // {
+      platforms = lib.unique (
+        x86_64-appimage.meta.platforms
+        ++ x86_64-dmg.meta.platforms
+        ++ aarch64-dmg.meta.platforms
+        ++ x86_64-windows.meta.platforms
+      );
+    };
+  })