push sheeet

pkgs/by-name/ls/ls-lint/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "ls-lint";
+  version = "2.3.1";
+
+  src = fetchFromGitHub {
+    owner = "loeffel-io";
+    repo = "ls-lint";
+    rev = "v${version}";
+    sha256 = "sha256-kwZvpZaiS58UFE+qncQ370E8bnEuzQACK0FOAYlJwV0=";
+  };
+
+  vendorHash = "sha256-XbYfHgpZCGv6w/55dGiFcYTQ36f0n3w8XwnC7wIUFro=";
+
+  meta = with lib; {
+    description = "Extremely fast file and directory name linter";
+    mainProgram = "ls_lint";
+    homepage = "https://ls-lint.org/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ flokli ];
+  };
+}

pkgs/by-name/ls/lsb-release/lsb_release.sh

@@ -0,0 +1,190 @@
+#! @runtimeShell@
+
+set -o errexit
+set -o nounset
+
+show_help() {
+  @coreutils@/bin/cat << EOF
+Usage: lsb_release [options]
+
+Options:
+  -h, --help         show this help message and exit
+  -v, --version      show LSB modules this system supports
+  -i, --id           show distributor ID
+  -d, --description  show description of this distribution
+  -r, --release      show release number of this distribution
+  -c, --codename     show code name of this distribution
+  -a, --all          show all of the above information
+  -s, --short        show requested information in short format
+EOF
+  exit 0
+}
+
+# Potential command-line options.
+version=0
+id=0
+description=0
+release=0
+codename=0
+all=0
+short=0
+
+@getopt@/bin/getopt --test > /dev/null && rc=$? || rc=$?
+if [[ $rc -ne 4 ]]; then
+  # This shouldn't happen.
+  echo "Warning: Enhanced getopt not supported, please open an issue in nixpkgs." >&2
+else
+  # Define all short and long options.
+  SHORT=hvidrcas
+  LONG=help,version,id,description,release,codename,all,short
+
+  # Parse all options.
+  PARSED=`@getopt@/bin/getopt --options $SHORT --longoptions $LONG --name "$0" -- "$@"`
+
+  eval set -- "$PARSED"
+fi
+
+
+# Process each argument, and set the appropriate flag if we recognize it.
+while [[ $# -ge 1 ]]; do
+  case "$1" in
+    -v|--version)
+      version=1
+      ;;
+    -i|--id)
+      id=1
+      ;;
+    -d|--description)
+      description=1
+      ;;
+    -r|--release)
+      release=1
+      ;;
+    -c|--codename)
+      codename=1
+      ;;
+    -a|--all)
+      all=1
+      ;;
+    -s|--short)
+      short=1
+      ;;
+    -h|--help)
+      show_help
+      ;;
+    --)
+      shift
+      break
+      ;;
+    *)
+      echo "lsb_release: unrecognized option '$1'"
+      echo "Type 'lsb_release -h' for a list of available options."
+      exit 1
+      ;;
+  esac
+  shift
+done
+
+#  Read our variables.
+if [[ -e /etc/os-release ]]; then
+  . /etc/os-release
+  OS_RELEASE_FOUND=1
+else
+  # This is e.g. relevant for the Nix build sandbox and compatible with the
+  # original lsb_release binary:
+  OS_RELEASE_FOUND=0
+  NAME="n/a"
+  PRETTY_NAME="(none)"
+  VERSION_ID="n/a"
+  VERSION_CODENAME="n/a"
+fi
+
+# Default output
+if [[ "$version" = "0" ]] && [[ "$id" = "0" ]] && \
+   [[ "$description" = "0" ]] && [[ "$release" = "0" ]] && \
+   [[ "$codename" = "0" ]] && [[ "$all" = "0" ]]; then
+  if [[ "$OS_RELEASE_FOUND" = "1" ]]; then
+    echo "No LSB modules are available." >&2
+  else
+    if [[ "$short" = "0" ]]; then
+      printf "LSB Version:\tn/a\n"
+    else
+      printf "n/a\n"
+    fi
+  fi
+  exit 0
+fi
+
+# Now output the data - The order of these was chosen to match
+# what the original lsb_release used.
+
+SHORT_OUTPUT=""
+append_short_output() {
+  if [[ "$1" = "n/a" ]]; then
+    SHORT_OUTPUT+=" $1"
+  else
+    SHORT_OUTPUT+=" \"$1\""
+  fi
+}
+
+if [[ "$all" = "1" ]] || [[ "$version" = "1" ]]; then
+  if [[ "$OS_RELEASE_FOUND" = "1" ]]; then
+    if [[ "$short" = "0" ]]; then
+      echo "No LSB modules are available." >&2
+    else
+      append_short_output "n/a"
+    fi
+  else
+    if [[ "$short" = "0" ]]; then
+      printf "LSB Version:\tn/a\n"
+    else
+      append_short_output "n/a"
+    fi
+  fi
+fi
+
+if [[ "$all" = "1" ]] || [[ "$id" = "1" ]]; then
+  if [[ "$short" = "0" ]]; then
+    printf "Distributor ID:\t$NAME\n"
+  else
+    append_short_output "$NAME"
+  fi
+fi
+
+if [[ "$all" = "1" ]] || [[ "$description" = "1" ]]; then
+  if [[ "$short" = "0" ]]; then
+    printf "Description:\t$PRETTY_NAME\n"
+  else
+    append_short_output "$PRETTY_NAME"
+  fi
+fi
+
+if [[ "$all" = "1" ]] || [[ "$release" = "1" ]]; then
+  if [[ "$short" = "0" ]]; then
+    printf "Release:\t$VERSION_ID\n"
+  else
+    append_short_output "$VERSION_ID"
+  fi
+fi
+
+if [[ "$all" = "1" ]] || [[ "$codename" = "1" ]]; then
+  if [[ "$short" = "0" ]]; then
+    printf "Codename:\t$VERSION_CODENAME\n"
+  else
+    append_short_output "$VERSION_CODENAME"
+  fi
+fi
+
+if [[ "$short" = "1" ]]; then
+  # Output in one line without the first space:
+  echo "${SHORT_OUTPUT:1}"
+fi
+
+# For compatibility with the original lsb_release:
+if [[ "$OS_RELEASE_FOUND" = "0" ]]; then
+  if [[ "$all" = "1" ]] || [[ "$id" = "1" ]] || \
+     [[ "$description" = "1" ]] || [[ "$release" = "1" ]] || \
+     [[ "$codename" = "1" ]]; then
+    exit 3
+  fi
+fi

pkgs/by-name/ls/lsb-release/package.nix

@@ -0,0 +1,28 @@
+{
+  replaceVarsWith,
+  lib,
+  runtimeShell,
+  coreutils,
+  getopt,
+}:
+
+replaceVarsWith {
+  name = "lsb_release";
+
+  src = ./lsb_release.sh;
+
+  dir = "bin";
+  isExecutable = true;
+
+  replacements = {
+    inherit coreutils getopt runtimeShell;
+  };
+
+  meta = with lib; {
+    description = "Prints certain LSB (Linux Standard Base) and Distribution information";
+    mainProgram = "lsb_release";
+    license = [ licenses.mit ];
+    maintainers = [ ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ls/lscolors/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  rustPlatform,
+  fetchCrate,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "lscolors";
+  version = "0.20.0";
+
+  src = fetchCrate {
+    inherit version pname;
+    hash = "sha256-EUUPVSpHc9tN1Hi7917hJ2psTZq5nnGw6PBeApvlVtw=";
+  };
+
+  cargoHash = "sha256-WsbzlL+RbR8Hnrsbgr7gFpBlo3RBKcNYPbOsZWygyrI=";
+
+  buildFeatures = [ "nu-ansi-term" ];
+
+  # setid is not allowed in the sandbox
+  checkFlags = [ "--skip=tests::style_for_setid" ];
+
+  meta = {
+    description = "Rust library and tool to colorize paths using LS_COLORS";
+    homepage = "https://github.com/sharkdp/lscolors";
+    changelog = "https://github.com/sharkdp/lscolors/releases/tag/v${version}";
+    license = with lib.licenses; [
+      asl20 # or
+      mit
+    ];
+    maintainers = with lib.maintainers; [ SuperSandro2000 ];
+    mainProgram = "lscolors";
+  };
+}

pkgs/by-name/ls/lsd/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  installShellFiles,
+  pandoc,
+  testers,
+  lsd,
+  git,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "lsd";
+  version = "1.1.5";
+
+  src = fetchFromGitHub {
+    owner = "lsd-rs";
+    repo = "lsd";
+    rev = "v${version}";
+    hash = "sha256-LlMcBMb40yN+rlvGVsh7JaC3j9sF60YxitQQXe1q/oI=";
+  };
+
+  cargoHash = "sha256-yOJKXfPtzaYF012YCyW3m+9ffag4En4ZfTaiVh/85dM=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    pandoc
+  ];
+
+  postInstall = ''
+    pandoc --standalone --to man doc/lsd.md -o lsd.1
+    installManPage lsd.1
+
+    installShellCompletion --cmd lsd \
+      --bash $releaseDir/build/lsd-*/out/lsd.bash \
+      --fish $releaseDir/build/lsd-*/out/lsd.fish \
+      --zsh $releaseDir/build/lsd-*/out/_lsd
+  '';
+
+  nativeCheckInputs = [ git ];
+
+  passthru.tests.version = testers.testVersion { package = lsd; };
+
+  meta = {
+    homepage = "https://github.com/lsd-rs/lsd";
+    description = "Next gen ls command";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      zowoq
+      SuperSandro2000
+    ];
+    mainProgram = "lsd";
+  };
+}

pkgs/by-name/ls/lsd2dsl/package.nix

@@ -0,0 +1,88 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  makeDesktopItem,
+  copyDesktopItems,
+  cmake,
+  boost,
+  cups,
+  fmt,
+  libvorbis,
+  libsndfile,
+  minizip,
+  gtest,
+  qt6,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lsd2dsl";
+  version = "0.6.0";
+
+  src = fetchFromGitHub {
+    owner = "nongeneric";
+    repo = "lsd2dsl";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-0UsxDNpuWpBrfjh4q3JhZnOyXhHatSa3t/cApiG2JzM=";
+  };
+
+  patches = [
+    (fetchpatch {
+      url = "https://github.com/nongeneric/lsd2dsl/commit/bbda5be1b76a4a44804483d00c07d79783eceb6b.patch";
+      hash = "sha256-7is83D1cMBArXVLe5TP7D7lUcwnTMeXjkJ+cbaH5JQk=";
+    })
+  ];
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt --replace "-Werror" ""
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    qt6.wrapQtAppsHook
+  ]
+  ++ lib.optional stdenv.hostPlatform.isLinux copyDesktopItems;
+
+  buildInputs = [
+    boost
+    cups
+    fmt
+    libvorbis
+    libsndfile
+    minizip
+    gtest
+    qt6.qt5compat
+    qt6.qtwebengine
+  ];
+
+  env.NIX_CFLAGS_COMPILE = "-Wno-int-conversion";
+
+  desktopItems = lib.singleton (makeDesktopItem {
+    name = "lsd2dsl";
+    exec = "lsd2dsl-qtgui";
+    desktopName = "lsd2dsl";
+    genericName = "lsd2dsl";
+    comment = finalAttrs.meta.description;
+    categories = [
+      "Dictionary"
+      "FileTools"
+      "Qt"
+    ];
+  });
+
+  installPhase = ''
+    install -Dm755 console/lsd2dsl gui/lsd2dsl-qtgui -t $out/bin
+  '';
+
+  meta = {
+    homepage = "https://rcebits.com/lsd2dsl/";
+    description = "Lingvo dictionaries decompiler";
+    longDescription = ''
+      A decompiler for ABBYY Lingvo’s proprietary dictionaries.
+    '';
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ sikmir ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ls/lsdvd/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libdvdread,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lsdvd";
+  version = "0.17";
+  src = fetchurl {
+    url = "mirror://sourceforge/lsdvd/lsdvd-${version}.tar.gz";
+    sha256 = "1274d54jgca1prx106iyir7200aflr70bnb1kawndlmcckcmnb3x";
+  };
+
+  buildInputs = [ libdvdread ];
+  nativeBuildInputs = [ pkg-config ];
+
+  meta = with lib; {
+    homepage = "https://sourceforge.net/projects/lsdvd/";
+    description = "Display information about audio, video, and subtitle tracks on a DVD";
+    license = licenses.gpl2Only;
+    platforms = platforms.linux;
+    mainProgram = "lsdvd";
+  };
+}

pkgs/by-name/ls/lse/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  bash,
+  fetchFromGitHub,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lse";
+  version = "4.14nw";
+
+  src = fetchFromGitHub {
+    owner = "diego-treitos";
+    repo = "linux-smart-enumeration";
+    tag = version;
+    hash = "sha256-qGLmrbyeyhHG6ONs7TJLTm68xpvxB1iAnMUApfTSqEk=";
+  };
+
+  buildInputs = [ bash ];
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp lse.sh $out/bin/lse.sh
+    wrapProgram $out/bin/lse.sh \
+      --prefix PATH : ${lib.makeBinPath [ bash ]}
+  '';
+
+  meta = {
+    description = "Linux enumeration tool with verbosity levels";
+    homepage = "https://github.com/diego-treitos/linux-smart-enumeration";
+    changelog = "https://github.com/diego-treitos/linux-smart-enumeration/releases/tag/${version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ fab ];
+    mainProgram = "lse.sh";
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/ls/lsfg-vk-ui/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  glib,
+  pango,
+  gdk-pixbuf,
+  gtk4,
+  libadwaita,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "lsfg-vk-ui";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "PancakeTAS";
+    repo = "lsfg-vk";
+    tag = "v${version}";
+    hash = "sha256-nIyVOil/gHC+5a+sH3vMlcqVhixjJaGWqXbyoh2Nqyw=";
+  };
+
+  cargoHash = "sha256-hIQRS/egIDU5Vu/1KWHtpt4S26h+9GadVr+lBAG2LDg=";
+
+  sourceRoot = "source/ui";
+
+  nativeBuildInputs = [
+    pkg-config
+    glib
+  ];
+
+  buildInputs = [
+    pango
+    gdk-pixbuf
+    gtk4
+    libadwaita
+  ];
+
+  postInstall = ''
+    install -Dm444 $src/ui/rsc/gay.pancake.lsfg-vk-ui.desktop $out/share/applications/gay.pancake.lsfg-vk-ui.desktop
+    install -Dm444 $src/ui/rsc/icon.png $out/share/icons/hicolor/256x256/apps/gay.pancake.lsfg-vk-ui.png
+  '';
+
+  meta = {
+    description = "Graphical configuration interface for lsfg-vk";
+    homepage = "https://github.com/PancakeTAS/lsfg-vk/";
+    changelog = "https://github.com/PancakeTAS/lsfg-vk/releases/tag/${src.tag}";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ pabloaul ];
+    mainProgram = "lsfg-vk-ui";
+  };
+}

pkgs/by-name/ls/lsfg-vk/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  fetchFromGitHub,
+  cmake,
+  vulkan-headers,
+  llvmPackages,
+}:
+
+llvmPackages.stdenv.mkDerivation rec {
+  pname = "lsfg-vk";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "PancakeTAS";
+    repo = "lsfg-vk";
+    tag = "v${version}";
+    hash = "sha256-hWpuPH7mKbeMaLaRUwtlkNLy4lOnJEe+yd54L7y2kV0=";
+    fetchSubmodules = true;
+  };
+
+  postPatch = ''
+    substituteInPlace VkLayer_LS_frame_generation.json \
+      --replace-fail "liblsfg-vk.so" "$out/lib/liblsfg-vk.so"
+  '';
+
+  nativeBuildInputs = [
+    llvmPackages.clang-tools
+    llvmPackages.libllvm
+    cmake
+  ];
+
+  buildInputs = [
+    vulkan-headers
+  ];
+
+  meta = {
+    description = "Vulkan layer for frame generation (Requires owning Lossless Scaling)";
+    homepage = "https://github.com/PancakeTAS/lsfg-vk/";
+    changelog = "https://github.com/PancakeTAS/lsfg-vk/releases/tag/${src.tag}";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ pabloaul ];
+  };
+}

pkgs/by-name/ls/lsh/package.nix

@@ -0,0 +1,24 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+buildGoModule rec {
+  pname = "lsh";
+  version = "1.4.2";
+  src = fetchFromGitHub {
+    owner = "latitudesh";
+    repo = "lsh";
+    rev = "v${version}";
+    sha256 = "sha256-TV3ix1W/+rUXgeoVYneAfosa6ikf7e3giwsX4gyp2o0=";
+  };
+  vendorHash = "sha256-ogdyzfayleka4Y8x74ZtttD7MaeCl1qP/rQi9x0tMto=";
+  subPackages = [ "." ];
+  meta = {
+    changelog = "https://github.com/latitudesh/lsh/releases/tag/v${version}";
+    description = "Command-Line Interface for Latitude.sh";
+    homepage = "https://github.com/latitudesh/lsh";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.dzmitry-lahoda ];
+  };
+}

pkgs/by-name/ls/lshw/package.nix

@@ -0,0 +1,62 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  hwdata,
+  gtk3,
+  pkg-config,
+  gettext,
+  sqlite, # compile GUI
+  withGUI ? false,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lshw";
+  # Fix repology.org by not including the prefixed B, otherwise the `pname` attr
+  # gets filled as `lshw-B.XX.XX` in `nix-env --query --available --attr nixpkgs.lshw --meta`
+  # See https://github.com/NixOS/nix/pull/4463 for a definitive fix
+  version = "02.20";
+
+  src = fetchFromGitHub {
+    owner = "lyonel";
+    repo = "lshw";
+    rev = "B.${version}";
+    hash = "sha256-4etC7ymMgn1Q4f98DNASv8vn0AT55dYPdacZo6GRDw0=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    gettext
+  ];
+
+  buildInputs = [
+    hwdata
+  ]
+  ++ lib.optionals withGUI [
+    gtk3
+    sqlite
+  ];
+
+  makeFlags = [
+    "PREFIX=$(out)"
+    "VERSION=${src.rev}"
+  ];
+
+  buildFlags = [ "all" ] ++ lib.optional withGUI "gui";
+
+  hardeningDisable = lib.optionals stdenv.hostPlatform.isStatic [ "fortify" ];
+
+  installTargets = [ "install" ] ++ lib.optional withGUI "install-gui";
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    changelog = "https://github.com/lyonel/lshw/blob/master/docs/Changelog";
+    description = "Provide detailed information on the hardware configuration of the machine";
+    homepage = "https://ezix.org/project/wiki/HardwareLiSter";
+    license = licenses.gpl2;
+    mainProgram = "lshw";
+    maintainers = with maintainers; [ thiagokokada ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ls/lsirec/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  python3,
+}:
+
+stdenv.mkDerivation {
+  pname = "lsirec";
+  version = "0-unstable-2019-03-03";
+
+  src = fetchFromGitHub {
+    owner = "marcan";
+    repo = "lsirec";
+    rev = "2dfb6dc92649feb01a3ddcfd117d4a99098084f2";
+    sha256 = "sha256-8v+KKjAJlJNpUT0poedRTQfPiDiwahrosXD35Bmh3jM=";
+  };
+
+  buildInputs = [ python3 ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 'lsirec' "$out/bin/lsirec"
+    install -Dm755 'sbrtool.py' "$out/bin/sbrtool"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "LSI SAS2008/SAS2108 low-level recovery tool for Linux";
+    homepage = "https://github.com/marcan/lsirec";
+    platforms = platforms.linux;
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ Luflosi ];
+    # never built on aarch64-linux since first introduction in nixpkgs
+    broken = stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64;
+  };
+}

pkgs/by-name/ls/lsiutil/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  kmod,
+  coreutils,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lsiutil";
+  version = "1.72";
+
+  src = fetchurl {
+    url = "https://github.com/exactassembly/meta-xa-stm/raw/f96cf6e13f3c9c980f5651510dd96279b9b2af4f/recipes-support/lsiutil/files/lsiutil-${version}.tar.gz";
+    sha256 = "sha256-aTi+EogY1aDWYq3anjRkjz1mzINVfUPQbOPHthxrvS4=";
+  };
+
+  postPatch = ''
+    substituteInPlace lsiutil.c \
+      --replace /sbin/modprobe "${kmod}/bin/modprobe" \
+      --replace /bin/mknod "${coreutils}/bin/mknod"
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    gcc -Wall -O lsiutil.c -o lsiutil
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/bin"
+    install -Dm755 lsiutil "$out/bin/lsiutil"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/exactassembly/meta-xa-stm/tree/master/recipes-support/lsiutil/files";
+    description = "Configuration utility for MPT adapters (FC, SCSI, and SAS/SATA)";
+    license = licenses.unfree;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ Luflosi ];
+  };
+}

pkgs/by-name/ls/lsix/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  makeWrapper,
+  imagemagick,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "lsix";
+  version = "1.9.1";
+
+  src = fetchFromGitHub {
+    owner = "hackerb9";
+    repo = "lsix";
+    rev = finalAttrs.version;
+    sha256 = "sha256-msTG7otjzksg/2XyPDy31LEb7uGXSgB8fzfHvad9nPA=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 lsix -t $out/bin
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/lsix \
+      --prefix PATH : ${lib.makeBinPath [ (imagemagick.override { ghostscriptSupport = true; }) ]}
+  '';
+
+  meta = with lib; {
+    description = "Shows thumbnails in terminal using sixel graphics";
+    homepage = "https://github.com/hackerb9/lsix";
+    license = licenses.gpl3Only;
+    platforms = platforms.all;
+    maintainers = with maintainers; [
+      justinlime
+      kidonng
+    ];
+    mainProgram = "lsix";
+  };
+})

pkgs/by-name/ls/lsof/package.nix

@@ -0,0 +1,94 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  buildPackages,
+  perl,
+  which,
+  ncurses,
+  nukeReferences,
+  freebsd,
+  ed,
+}:
+
+let
+  dialect = lib.last (lib.splitString "-" stdenv.hostPlatform.system);
+in
+
+stdenv.mkDerivation rec {
+  pname = "lsof";
+  version = "4.99.5";
+
+  src = fetchFromGitHub {
+    owner = "lsof-org";
+    repo = "lsof";
+    rev = version;
+    hash = "sha256-zn09cwFFz5ZNJu8GwGGSSGNx5jvXbKLT6/+Lcmn1wK8=";
+  };
+
+  postPatch = ''
+    patchShebangs --build lib/dialects/*/Mksrc
+    # Do not re-build version.h in every 'make' to allow nuke-refs below.
+    # We remove phony 'FRC' target that forces rebuilds:
+    #   'version.h: FRC ...' is translated to 'version.h: ...'.
+    sed -i lib/dialects/*/Makefile -e 's/version.h:\s*FRC/version.h:/'
+  ''
+  # help Configure find libproc.h in $SDKROOT
+  + lib.optionalString stdenv.hostPlatform.isDarwin ''
+    sed -i -e 's|lcurses|lncurses|g' \
+           -e "s|/Library.*/MacOSX.sdk/|\"$SDKROOT\"/|" Configure
+  '';
+
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+  nativeBuildInputs = [
+    nukeReferences
+    perl
+    which
+    ed
+  ];
+  buildInputs = [ ncurses ];
+
+  # Stop build scripts from searching global include paths
+  LSOF_INCLUDE = "${lib.getDev stdenv.cc.libc}/include";
+  configurePhase =
+    let
+      genericFlags = "LSOF_CC=$CC LSOF_AR=\"$AR cr\" LSOF_RANLIB=$RANLIB";
+      linuxFlags = lib.optionalString stdenv.hostPlatform.isLinux "LINUX_CONF_CC=$CC_FOR_BUILD";
+      freebsdFlags = lib.optionalString stdenv.hostPlatform.isFreeBSD "FREEBSD_SYS=${freebsd.sys.src}/sys";
+    in
+    "${genericFlags} ${linuxFlags} ${freebsdFlags} ./Configure -n ${dialect}";
+
+  preBuild = ''
+    for filepath in $(find dialects/${dialect} -type f); do
+      sed -i "s,/usr/include,$LSOF_INCLUDE,g" $filepath
+    done
+
+    # Wipe out development-only flags from CFLAGS embedding
+    make version.h
+    nuke-refs version.h
+  '';
+
+  installPhase = ''
+    # Fix references from man page https://github.com/lsof-org/lsof/issues/66
+    substituteInPlace Lsof.8 \
+      --replace ".so ./00DIALECTS" "" \
+      --replace ".so ./version" ".ds VN ${version}"
+    mkdir -p $out/bin $out/man/man8
+    cp Lsof.8 $out/man/man8/lsof.8
+    cp lsof $out/bin
+  '';
+
+  meta = {
+    homepage = "https://github.com/lsof-org/lsof";
+    description = "Tool to list open files";
+    mainProgram = "lsof";
+    longDescription = ''
+      List open files. Can show what process has opened some file,
+      socket (IPv6/IPv4/UNIX local), or partition (by opening a file
+      from it).
+    '';
+    license = lib.licenses.lsof;
+    maintainers = with lib.maintainers; [ dezgeg ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/ls/lsp-ai/package.nix

@@ -0,0 +1,77 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  cmake,
+  openssl,
+  zlib,
+  perl,
+  gitUpdater,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "lsp-ai";
+  version = "0.7.1";
+  src = fetchFromGitHub {
+    owner = "SilasMarvin";
+    repo = "lsp-ai";
+    tag = "v${version}";
+    hash = "sha256-mBbaJn4u+Wlu/Y4G4a6YUBWnmN143INAGm0opiAjnIk=";
+  };
+
+  checkFlags = [
+    # These integ tests require an account and network usage to work
+    "--skip=transformer_backends::open_ai::test::open_ai_completion_do_generate"
+    "--skip=transformer_backends::mistral_fim::test::mistral_fim_do_generate"
+    "--skip=transformer_backends::anthropic::test::anthropic_chat_do_generate"
+    "--skip=transformer_backends::open_ai::test::open_ai_chat_do_generate"
+    "--skip=transformer_backends::gemini::test::gemini_chat_do_generate"
+    "--skip=transformer_backends::ollama::test::ollama_chat_do_generate"
+    "--skip=transformer_backends::ollama::test::ollama_completion_do_generate"
+    "--skip=embedding_models::ollama::test::ollama_embeding"
+    "--skip=transformer_worker::tests::test_do_completion"
+    "--skip=transformer_worker::tests::test_do_generate"
+    "--skip=memory_backends::vector_store::tests::can_open_document"
+    "--skip=memory_backends::vector_store::tests::can_rename_document"
+    "--skip=memory_backends::vector_store::tests::can_build_prompt"
+    "--skip=memory_backends::vector_store::tests::can_change_document"
+    # These integ test require a LLM server to be running over the network
+    "--skip=lsp_ai::transformer_worker"
+    "--skip=lsp_ai::memory_worker"
+    "--skip=test_chat_sequence"
+    "--skip=test_completion_action_sequence"
+    "--skip=test_chat_completion_sequence"
+    "--skip=test_completion_sequence"
+    "--skip=test_fim_completion_sequence"
+    "--skip=test_refactor_action_sequence"
+  ];
+
+  cargoHash = "sha256-KR6BmYj3q9w0yGHFq9+l1x989XjiG3mkaZiyDGCYWPA=";
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+    perl
+  ];
+
+  buildInputs = [
+    openssl
+    zlib
+  ];
+
+  cargoBuildFlags = [ "-p lsp-ai" ];
+
+  passthru.updateScript = gitUpdater {
+    rev-prefix = "v";
+  };
+
+  meta = {
+    description = "Open-source language server that serves as a backend for AI-powered functionality";
+    homepage = "https://github.com/SilasMarvin/lsp-ai";
+    mainProgram = "lsp-ai";
+    changelog = "https://github.com/SilasMarvin/lsp-ai/releases/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ projectinitiative ];
+  };
+}

pkgs/by-name/ls/lsp-plugins/package.nix

@@ -0,0 +1,151 @@
+{
+  lib,
+  stdenv,
+  cairo,
+  fetchurl,
+  gst_all_1,
+  jack2,
+  ladspaH,
+  libGL,
+  libGLU,
+  libXrandr,
+  libsndfile,
+  lv2,
+  php82,
+  pkg-config,
+}:
+
+let
+  php = php82;
+in
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lsp-plugins";
+  version = "1.2.23";
+
+  outputs = [
+    "out"
+    "dev"
+    "doc"
+  ];
+
+  src = fetchurl {
+    url = "https://github.com/lsp-plugins/lsp-plugins/releases/download/${finalAttrs.version}/lsp-plugins-src-${finalAttrs.version}.tar.gz";
+    hash = "sha256-GxjSnDsEPiXbaJ9khSvgQZeVONxWf4WJilurHpSf14w=";
+  };
+
+  # By default, GStreamer plugins are installed right alongside GStreamer itself
+  # We can't do that in Nixpkgs, so lets install it to $out/lib like other plugins
+  postPatch = ''
+    substituteInPlace modules/lsp-plugin-fw/src/Makefile \
+      --replace-fail '$(shell pkg-config --variable=pluginsdir gstreamer-1.0)' '$(LIBDIR)/gstreamer-1.0'
+  '';
+
+  nativeBuildInputs = [
+    php
+    pkg-config
+  ];
+
+  buildInputs = [
+    cairo
+    gst_all_1.gst-plugins-base
+    gst_all_1.gstreamer
+    jack2
+    ladspaH
+    libGL
+    libGLU
+    libXrandr
+    libsndfile
+    lv2
+  ];
+
+  makeFlags = [
+    "ETCDIR=${placeholder "out"}/etc"
+    "PREFIX=${placeholder "out"}"
+    "SHAREDDIR=${placeholder "out"}/share"
+  ];
+
+  env.NIX_CFLAGS_COMPILE = "-DLSP_NO_EXPERIMENTAL";
+
+  configurePhase = ''
+    runHook preConfigure
+
+    make $makeFlags config
+
+    runHook postConfigure
+  '';
+
+  doCheck = true;
+
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "Collection of open-source audio plugins";
+    longDescription = ''
+      Compatible with the following formats:
+
+      - CLAP - set of plugins for Clever Audio Plugins API
+      - LADSPA - set of plugins for Linux Audio Developer's Simple Plugin API
+      - LV2 - set of plugins and UIs for Linux Audio Developer's Simple Plugin API (LADSPA) version 2
+      - LinuxVST - set of plugins and UIs for Steinberg's VST 2.4 format ported on GNU/Linux Platform
+      - JACK - Standalone versions for JACK Audio connection Kit with UI
+
+      Contains the following plugins (https://lsp-plug.in/?page=plugins)
+
+      Equalizers:
+      - Fliter
+      - Graphic Equalizer
+      - Parametric Equalizer
+      Dynamic Processing:
+      - Compressor
+      - Dynamic Processor
+      - Expander
+      - Gate
+      - Limiter
+      Multiband Dynamic Processing:
+      - GOTT Compressor
+      - Multiband Compressor
+      - Multiband Dynamics Processor
+      - Multiband Expander
+      - Multiband Gate
+      - Multiband Limiter
+      Convolution / Reverb processing:
+      - Impulse Responses
+      - Impulse Reverb
+      - Room Builder
+      Delay Effects:
+      - Artistic Delay
+      - Compensation Delay
+      - Slap-back Delay
+      Analyzers:
+      - Oscilloscope
+      - Phase Detector
+      - Spectrum Analyzer
+      Multiband Processing:
+      - Crossover
+      Samplers:
+      - Multisampler
+      - Sampler
+      Generators / Oscillators:
+      - Noise Generator
+      - Oscillator
+      Utilitary Plugins:
+      - A/B Test Plugin
+      - Flanger
+      - Latency Meter
+      - Loudness Compensator
+      - Mixer
+      - Profiler
+      - Surge Filter
+      - Trigger
+    '';
+    homepage = "https://lsp-plug.in";
+    changelog = "https://github.com/lsp-plugins/lsp-plugins/releases/tag/${finalAttrs.version}";
+    maintainers = with lib.maintainers; [
+      magnetophon
+      PowerUser64
+    ];
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ls/lsr/deps.nix

@@ -0,0 +1,42 @@
+# generated by zon2nix (https://github.com/nix-community/zon2nix)
+
+{
+  linkFarm,
+  fetchzip,
+  fetchgit,
+}:
+
+linkFarm "zig-packages" [
+  {
+    name = "ourio-0.0.0-_s-z0dAWAgD3XNod2pTh0H8X-a3CjtpAwduh7jcgBz0G";
+    path = fetchgit {
+      url = "https://github.com/rockorager/ourio";
+      rev = "ed8a67650e5dbb0a6dca811c9d769187e306ad94";
+      hash = "sha256-GbfZyzbjkVAcOECjQFWkDRw6QZr+kPXzadaI7xBSkig=";
+    };
+  }
+  {
+    name = "tls-0.1.0-ER2e0pU3BQB-UD2_s90uvppceH_h4KZxtHCrCct8L054";
+    path = fetchgit {
+      url = "https://github.com/ianic/tls.zig";
+      rev = "8250aa9184fbad99983b32411bbe1a5d2fd6f4b7";
+      hash = "sha256-EDK4L/K58V7sepDphjdxkJSGw9yQktuk8wd76c473wY=";
+    };
+  }
+  {
+    name = "zeit-0.6.0-5I6bk1J1AgA13rteb6E0steXiOUKBYTzJZMMIuK9oEmb";
+    path = fetchgit {
+      url = "https://github.com/rockorager/zeit";
+      rev = "4496d1c40b2223c22a1341e175fc2ecd94cc0de9";
+      hash = "sha256-To+8CLfKhRBgYnnlBKM+TD041wJ+jBpRZGFrghHaxTk=";
+    };
+  }
+  {
+    name = "zzdoc-0.0.0-tzT1PuPZAACr1jIJxjTrdOsLbfXS6idWFGfTq0gwxJiv";
+    path = fetchgit {
+      url = "https://github.com/rockorager/zzdoc";
+      rev = "57e86eb4e621bc4a96fbe0dd89ad0986db6d0483";
+      hash = "sha256-PAGgJCA/B3eSarTNbXB6ENwHNPiHq+wX/n6Rh2s8Pvk=";
+    };
+  }
+]

pkgs/by-name/ls/lsr/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  installShellFiles,
+  fetchgit,
+  zig_0_14,
+  callPackage,
+  versionCheckHook,
+}:
+
+let
+  zig = zig_0_14;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lsr";
+  version = "1.0.0";
+
+  src = fetchgit {
+    url = "https://tangled.sh/@rockorager.dev/lsr";
+    rev = "v${finalAttrs.version}";
+    sparseCheckout = [
+      "src"
+      "docs"
+    ];
+    hash = "sha256-VeB0R/6h9FXSzBfx0IgpGlBz16zQScDSiU7ZvTD/Cds=";
+  };
+
+  postPatch = ''
+    ln -s ${callPackage ./deps.nix { }} $ZIG_GLOBAL_CACHE_DIR/p
+  '';
+
+  nativeBuildInputs = [
+    installShellFiles
+    zig.hook
+  ];
+
+  doInstallCheck = true;
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+
+  meta = {
+    homepage = "https://tangled.sh/@rockorager.dev/lsr";
+    description = "ls but with io_uring";
+    changelog = "https://tangled.sh/@rockorager.dev/lsr/tags";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ ddogfoodd ];
+    platforms = lib.platforms.linux;
+    mainProgram = "lsr";
+  };
+})

pkgs/by-name/ls/lsscsi/package.nix

@@ -0,0 +1,24 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lsscsi";
+  version = "0.32";
+
+  src = fetchurl {
+    url = "http://sg.danny.cz/scsi/lsscsi-${version}.tgz";
+    sha256 = "sha256-CoAOnpTcoqtwLWXXJ3eujK4Hjj100Ly+1kughJ6AKaE=";
+  };
+
+  preConfigure = ''
+    substituteInPlace Makefile.in --replace /usr "$out"
+  '';
+
+  meta = with lib; {
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/ls/lssecret/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  pkg-config,
+  libsecret,
+}:
+
+stdenv.mkDerivation {
+  pname = "lssecret";
+  version = "unstable-2022-12-02";
+
+  src = fetchFromGitLab {
+    owner = "GrantMoyer";
+    repo = "lssecret";
+    rev = "20fd771a678a241abbb57152e3c2d9a8eee353cb";
+    hash = "sha256-yU70WZj4EC/sFJxyq2SQ0YQ6RCQHYiW/aQiYWo7+ujk=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ libsecret ];
+
+  makeFlags = [ "DESTDIR=$(out)" ];
+
+  meta = {
+    description = "Tool to list passwords and other secrets stored using the org.freedesktop.secrets dbus api";
+    homepage = "https://gitlab.com/GrantMoyer/lssecret";
+    license = lib.licenses.unlicense;
+    maintainers = with lib.maintainers; [ genericnerdyusername ];
+    platforms = lib.platforms.unix;
+    mainProgram = "lssecret";
+  };
+}

pkgs/by-name/ls/lstr/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  gitMinimal,
+  openssl,
+  versionCheckHook,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "lstr";
+  version = "0.2.1";
+
+  src = fetchFromGitHub {
+    owner = "bgreenwell";
+    repo = "lstr";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-uaefVDSTphboWW1BP2HkcuMiW87FmnVYxCthlrAKF5Y=";
+  };
+
+  cargoHash = "sha256-UVaqkNV1cNpbCNphk6YMqOz077xY9dUBgCGt7SLIH0U=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [ (lib.getDev openssl) ];
+
+  nativeCheckInputs = [ gitMinimal ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  doInstallCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  meta = {
+    description = "Fast, minimalist directory tree viewer written in Rust";
+    homepage = "https://github.com/bgreenwell/lstr";
+    changelog = "https://github.com/bgreenwell/lstr/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      DieracDelta
+      philiptaron
+    ];
+    mainProgram = "lstr";
+  };
+})

pkgs/by-name/ls/lswt/package.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  stdenv,
+  fetchFromSourcehut,
+  fetchpatch,
+  wayland-scanner,
+  wayland,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lswt";
+  version = "2.0.0";
+
+  src = fetchFromSourcehut {
+    owner = "~leon_plickat";
+    repo = "lswt";
+    rev = "v${version}";
+    hash = "sha256-8jP6I2zsDt57STtuq4F9mcsckrjvaCE5lavqKTjhNT0=";
+  };
+
+  patches = [
+    # Subject: [PATCH] fix JSON formatting of identifier string
+    (fetchpatch {
+      url = "https://git.sr.ht/~leon_plickat/lswt/commit/d35786da4383388c19f5437128fd393a6f16f74f.patch";
+      hash = "sha256-3RTq8BXRR7MgKV0BueoOjPORMrYVAKNbKR74hZ75W/Y=";
+    })
+  ];
+
+  nativeBuildInputs = [ wayland-scanner ];
+  buildInputs = [ wayland ];
+
+  makeFlags = [
+    "DESTDIR=${placeholder "out"}"
+    "PREFIX="
+  ];
+
+  meta = with lib; {
+    description = "Command that lists Wayland toplevels";
+    homepage = "https://sr.ht/~leon_plickat/lswt";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ edrex ];
+    platforms = platforms.linux;
+    mainProgram = "lswt";
+  };
+}