push sheeet

pkgs/by-name/ma/mailspring/darwin.nix

@@ -0,0 +1,34 @@
+{
+  stdenv,
+  fetchurl,
+  pname,
+  version,
+  meta,
+  unzip,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  inherit pname version meta;
+
+  src = fetchurl {
+    url = "https://github.com/Foundry376/Mailspring/releases/download/${finalAttrs.version}/Mailspring-AppleSilicon.zip";
+    hash = "sha256-jbsU8pSvhPFKFjIr+2ZHETOihKKoqQiZmKQ6eGtAIKk=";
+  };
+  dontUnpack = true;
+
+  nativeBuildInputs = [
+    unzip
+    makeWrapper
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/Applications $out/bin
+    unzip $src -d $out/Applications
+    makeWrapper $out/Applications/Mailspring.app/Contents/MacOS/Mailspring $out/bin/mailspring
+
+    runHook postInstall
+  '';
+})

pkgs/by-name/ma/mailspring/linux.nix

@@ -0,0 +1,94 @@
+{
+  stdenv,
+  lib,
+  pname,
+  version,
+  meta,
+  fetchurl,
+  autoPatchelfHook,
+  alsa-lib,
+  coreutils,
+  db,
+  dpkg,
+  glib,
+  gtk3,
+  wrapGAppsHook3,
+  libkrb5,
+  libsecret,
+  nss,
+  openssl,
+  udev,
+  xorg,
+  libgbm,
+  libdrm,
+  libappindicator,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  inherit pname version meta;
+
+  src = fetchurl {
+    url = "https://github.com/Foundry376/Mailspring/releases/download/${finalAttrs.version}/mailspring-${finalAttrs.version}-amd64.deb";
+    hash = "sha256-iJ6VzwvNTIRqUq9OWNOWOSuLbqhx+Lqx584kuyIslyA=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    dpkg
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    alsa-lib
+    db
+    glib
+    gtk3
+    libkrb5
+    libsecret
+    nss
+    xorg.libxkbfile
+    xorg.libXdamage
+    xorg.libXScrnSaver
+    xorg.libXtst
+    xorg.libxshmfence
+    libgbm
+    libdrm
+  ];
+
+  runtimeDependencies = [
+    coreutils
+    openssl
+    (lib.getLib udev)
+    libappindicator
+    libsecret
+  ];
+
+  unpackPhase = ''
+    runHook preUnpack
+
+    dpkg -x $src .
+
+    runHook postUnpack
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{bin,lib}
+    cp -ar ./usr/share $out
+
+    substituteInPlace $out/share/mailspring/resources/app.asar.unpacked/mailsync \
+      --replace-fail dirname ${coreutils}/bin/dirname
+
+    ln -s $out/share/mailspring/mailspring $out/bin/mailspring
+    ln -s ${lib.getLib openssl}/lib/libcrypto.so $out/lib/libcrypto.so.1.0.0
+
+    runHook postInstall
+  '';
+
+  postFixup = # sh
+    ''
+      substituteInPlace $out/share/applications/Mailspring.desktop \
+        --replace-fail Exec=mailspring Exec=$out/bin/mailspring
+    '';
+})

pkgs/by-name/ma/mailspring/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  callPackage,
+}:
+let
+  pname = "mailspring";
+  version = "1.16.0";
+
+  meta = {
+    description = "Beautiful, fast and maintained fork of Nylas Mail by one of the original authors";
+    downloadPage = "https://github.com/Foundry376/Mailspring";
+    homepage = "https://getmailspring.com";
+    license = lib.licenses.gpl3Plus;
+    longDescription = ''
+      Mailspring is an open-source mail client forked from Nylas Mail and built with Electron.
+      Mailspring's sync engine runs locally, but its source is not open.
+    '';
+    mainProgram = "mailspring";
+    maintainers = with lib.maintainers; [ toschmidt ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-darwin"
+    ];
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+
+  linux = callPackage ./linux.nix { inherit pname version meta; };
+  darwin = callPackage ./darwin.nix { inherit pname version meta; };
+in
+if stdenv.hostPlatform.isDarwin then darwin else linux