push sheeet

pkgs/by-name/me/memcachedTestHook/memcached-test-hook.sh

@@ -0,0 +1,27 @@
+preCheckHooks+=('memcachedStart')
+postCheckHooks+=('memcachedStop')
+
+
+memcachedStart() {
+  if [[ "${memcachedTestPort:-}" == "" ]]; then
+    memcachedTestPort=11211
+  fi
+
+  echo 'starting memcached'
+
+  # Note about Darwin: unless the output is redirected, the parent process becomes launchd instead of bash.
+  # This would leave the memcached process running in case of a test failure (the postCheckHook would not be executed),
+  # hanging the Nix build forever.
+  @memcached@ -p "$memcachedTestPort" >/dev/null 2>&1 &
+  MEMCACHED_PID=$!
+
+  echo 'waiting for memcached to be ready'
+  while ! (echo 'quit' | @nc@ localhost "$memcachedTestPort") ; do
+    sleep 1
+  done
+}
+
+memcachedStop() {
+  echo 'stopping memcached'
+  kill "$MEMCACHED_PID"
+}

pkgs/by-name/me/memcachedTestHook/package.nix

@@ -0,0 +1,18 @@
+{
+  callPackage,
+  makeSetupHook,
+  lib,
+  memcached,
+  netcat,
+}:
+
+makeSetupHook {
+  name = "memcached-test-hook";
+  substitutions = {
+    memcached = lib.getExe memcached;
+    nc = lib.getExe netcat;
+  };
+  passthru.tests = {
+    simple = callPackage ./test.nix { };
+  };
+} ./memcached-test-hook.sh

pkgs/by-name/me/memcachedTestHook/test.nix

@@ -0,0 +1,41 @@
+{
+  memcachedTestHook,
+  netcat,
+  stdenv,
+}:
+
+stdenv.mkDerivation {
+  name = "memcached-test-hook-test";
+
+  nativeCheckInputs = [
+    memcachedTestHook
+    netcat
+  ];
+
+  dontUnpack = true;
+  doCheck = true;
+
+  preCheck = ''
+    memcachedTestPort=11212
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+
+    echo "running test"
+    if echo -e "stats\nquit" | nc localhost $memcachedTestPort; then
+      echo "connected to memcached"
+      TEST_RAN=1
+    fi
+
+    runHook postCheck
+  '';
+
+  __darwinAllowLocalNetworking = true;
+
+  installPhase = ''
+    [[ $TEST_RAN == 1 ]]
+    echo "test passed"
+    touch $out
+  '';
+}