push sheeet

pkgs/by-name/mi/mill/package.nix

@@ -0,0 +1,74 @@
+{
+  autoPatchelfHook,
+  fetchurl,
+  jre,
+  lib,
+  makeWrapper,
+  sourcesJSON ? ./sources.json,
+  stdenvNoCC,
+  zlib,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "mill";
+  version = "1.0.4";
+
+  src =
+    let
+      source = (lib.importJSON sourcesJSON)."${stdenvNoCC.hostPlatform.system}";
+    in
+    fetchurl {
+      url = "https://repo1.maven.org/maven2/com/lihaoyi/mill-dist-${source.artifact-suffix}/${finalAttrs.version}/mill-dist-${source.artifact-suffix}-${finalAttrs.version}.exe";
+      inherit (source) hash;
+    };
+
+  buildInputs = [ zlib ];
+  nativeBuildInputs = [
+    makeWrapper
+  ]
+  ++ lib.optional stdenvNoCC.hostPlatform.isLinux autoPatchelfHook;
+
+  dontUnpack = true;
+  dontConfigure = true;
+  dontBuild = true;
+
+  # this is mostly downloading a pre-built artifact
+  preferLocal = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm 555 $src $out/bin/.mill-wrapped
+    # can't use wrapProgram because it sets --argv0
+    makeWrapper $out/bin/.mill-wrapped $out/bin/mill \
+      --prefix PATH : "${jre}/bin" \
+      --set-default JAVA_HOME "${jre}"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://com-lihaoyi.github.io/mill/";
+    license = licenses.mit;
+    description = "Build tool for Scala, Java and more";
+    mainProgram = "mill";
+    longDescription = ''
+      Mill is a build tool borrowing ideas from modern tools like Bazel, to let you build
+      your projects in a way that's simple, fast, and predictable. Mill has built in
+      support for the Scala programming language, and can serve as a replacement for
+      SBT, but can also be extended to support any other language or platform via
+      modules (written in Java or Scala) or through an external subprocesses.
+    '';
+    maintainers = with maintainers; [
+      scalavision
+      zenithal
+    ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "aarch64-darwin"
+      "x86_64-darwin"
+    ];
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+  };
+})

pkgs/by-name/mi/mill/sources.json

@@ -0,0 +1,18 @@
+{
+  "aarch64-darwin": {
+    "artifact-suffix": "native-mac-aarch64",
+    "hash": "sha256-A9dShPyfkfTuRJ1/DkLwb/5NTRTxc7OY7Rd1h0Tzjos="
+  },
+  "x86_64-darwin": {
+    "artifact-suffix": "native-mac-amd64",
+    "hash": "sha256-zctTOVxFghF9z9PUQt3OO20Ul/qY8H/j6MPpFNpw+Ow="
+  },
+  "aarch64-linux": {
+    "artifact-suffix": "native-linux-aarch64",
+    "hash": "sha256-E+IMTkRP1a1TigpRyVHPu0assgHEbzbF8lv7Rsm2FOM="
+  },
+  "x86_64-linux": {
+    "artifact-suffix": "native-linux-amd64",
+    "hash": "sha256-rgAqlTCZc8nedUU2D+Klo3KY0z9sI0KJczdaugM3//8="
+  }
+}