push sheeet

pkgs/by-name/mm/MMA/package.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  makeWrapper,
+  python3,
+  alsa-utils,
+  timidity,
+}:
+
+stdenv.mkDerivation rec {
+  version = "25.05.0";
+  pname = "mma";
+
+  src = fetchurl {
+    url = "https://www.mellowood.ca/mma/mma-bin-${version}.tar.gz";
+    sha256 = "sha256-J72uTwAlWa/dRPf7/lO1epbmjTQar+3/U//+IJ9u4PM=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [
+    python3
+    alsa-utils
+    timidity
+  ];
+
+  patchPhase = ''
+    sed -i 's@/usr/bin/aplaymidi@/${alsa-utils}/bin/aplaymidi@g' mma-splitrec
+    sed -i 's@/usr/bin/aplaymidi@/${alsa-utils}/bin/aplaymidi@g' util/mma-splitrec.py
+    sed -i 's@/usr/bin/arecord@/${alsa-utils}/bin/arecord@g' mma-splitrec
+    sed -i 's@/usr/bin/arecord@/${alsa-utils}/bin/arecord@g' util/mma-splitrec.py
+    sed -i 's@/usr/bin/timidity@/${timidity}/bin/timidity@g' mma-splitrec
+    sed -i 's@/usr/bin/timidity@/${timidity}/bin/timidity@g' util/mma-splitrec.py
+    find . -type f | xargs sed -i 's@/usr/bin/env python@${python3.interpreter}@g'
+    find . -type f | xargs sed -i 's@/usr/bin/python3@${python3.interpreter}@g'
+  '';
+
+  installPhase = ''
+    mkdir -p $out/{bin,share/mma,share/man/man1,share/man/man8}
+    mkdir -p $out/etc
+
+    cp mma.py $out/bin/mma
+    cp mma-gb $out/bin/mma-gb
+    cp mma-libdoc $out/bin/mma-libdoc
+    cp mma-renum $out/bin/mma-renum
+    cp mma-splitrec $out/bin/mma-splitrec
+    cp util/mma-mnx.py $out/bin/mma-mnx
+    cp util/mma-rm2std.py $out/bin/mma-rm2std
+    cp util/mmatabs.py $out/bin/mmatabs
+    cp util/mup2mma.py $out/bin/mup2mma
+    cp util/pg2mma.py $out/bin/pg2mma
+    cp util/synthsplit.py $out/bin/mma-synthsplit
+    cp -r {docs,egs,includes,lib,MMA,text,plugins} $out/share/mma
+
+    cp util/README.* $out/share/mma/docs
+    mv $out/share/mma/docs/man/mma-libdoc.8 $out/share/man/man8
+    mv $out/share/mma/docs/man/mma-renum.1 $out/share/man/man1
+    mv $out/share/mma/docs/man/mma.1 $out/share/man/man1
+    mv $out/share/mma/docs/man/mma-gb.1 $out/share/man/man1
+    rm -rf $out/share/mma/docs/man
+    find $out -type f | xargs sed -i "s@/usr/share/mma@$out/share/mma@g"
+  '';
+
+  preFixup = ''
+    PYTHONPATH=$out/share/mma/:$PYTHONPATH
+    for f in $out/bin/*; do
+          wrapProgram $f \
+           --prefix PYTHONPATH : $PYTHONPATH
+    done
+    cd $out/share/mma/
+    $out/bin/mma -G
+  '';
+
+  meta = {
+    description = "Creates MIDI tracks for a soloist to perform over from a user supplied file containing chords";
+    homepage = "https://www.mellowood.ca/mma/index.html";
+    license = lib.licenses.gpl2;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/mm/mm-common/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  bash,
+  gnome,
+  meson,
+  python3,
+  ninja,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "mm-common";
+  version = "1.0.7";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
+    sha256 = "SUq/zngUGCWbHp2IiMc69N5LbzvjbMddm6qLqg8qejk=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    python3
+    ninja
+  ];
+
+  # for shebangs
+  buildInputs = [
+    python3
+    bash
+  ];
+
+  passthru = {
+    updateScript = gnome.updateScript {
+      packageName = pname;
+      versionPolicy = "none";
+    };
+  };
+
+  meta = with lib; {
+    description = "Common build files of GLib/GTK C++ bindings";
+    longDescription = ''
+      The mm-common module provides the build infrastructure and utilities
+      shared among the GNOME C++ binding libraries. It is only a required
+      dependency for building the C++ bindings from the gnome.org version
+      control repository. An installation of mm-common is not required for
+      building tarball releases, unless configured to use maintainer-mode.
+    '';
+    homepage = "https://www.gtkmm.org";
+    license = licenses.gpl2Plus;
+    teams = [ teams.gnome ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/mm/mm/package.nix

@@ -0,0 +1,26 @@
+{
+  lib,
+  buildGoModule,
+  fetchgit,
+}:
+
+buildGoModule {
+  pname = "mm";
+  version = "2020.11.17";
+
+  src = fetchgit {
+    url = "https://git.lost.host/meutraa/mm.git";
+    rev = "e5fa8eeb845aac8f28fc36013ee8a1dbe1e5710c";
+    hash = "sha256-SdD4EE/rc85H7xqKB/kU8XFsC63i1sVObPha/zrxFGk=";
+  };
+
+  vendorHash = "sha256-zJJ9PzQShv2iRNyCg1XVscbwjV9ZtMIojJDtXXm3rVM=";
+
+  meta = with lib; {
+    description = "File system based matrix client";
+    mainProgram = "mm";
+    homepage = "https://git.lost.host/meutraa/mm";
+    license = licenses.isc;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/mm/mmake/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "mmake";
+  version = "1.4.0";
+
+  src = fetchFromGitHub {
+    owner = "tj";
+    repo = "mmake";
+    rev = "v${version}";
+    sha256 = "sha256-JPsVfLIl06PJ8Nsfu7ogwrttB1G93HTKbZFqUTSV9O8=";
+  };
+
+  vendorHash = "sha256-0z+sujzzBl/rtzXbhL4Os+jYfLUuO9PlXshUDxAH9DU=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  # Almost all tests require non-local networking, trying to resolve githubusercontent.com.
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://github.com/tj/mmake";
+    description = "Small program  which wraps make to provide additional functionality";
+    longDescription = ''
+      Mmake is a small program  which wraps make to provide additional
+      functionality,  such   as  user-friendly  help   output,  remote
+      includes,  and   eventually  more.   It  otherwise  acts   as  a
+      pass-through to standard make.
+    '';
+    license = licenses.mit;
+    maintainers = [ maintainers.gabesoft ];
+    mainProgram = "mmake";
+  };
+}

pkgs/by-name/mm/mmark/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  testers,
+  mmark,
+}:
+
+buildGoModule {
+  pname = "mmark";
+  version = "2.2.32";
+
+  src = fetchFromGitHub {
+    owner = "mmarkdown";
+    repo = "mmark";
+    # The tag has an outdated version number and fails the version ntest
+    # The pinned revision includes one extra commit that fixes the issue
+    # rev = "v${version}";
+    rev = "158e9cca0280c58e205cb69b02bf33d7d826915e";
+    hash = "sha256-OzmqtmAAsG3ncrTl2o9rhK75i1WIpDnph0YrY38SlU0=";
+  };
+
+  vendorHash = "sha256-GjR9cOGLB6URHQi+qcyNbP7rm0+y4wypvgUxgJzIgGQ=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  passthru.tests.version = testers.testVersion {
+    package = mmark;
+  };
+
+  meta = {
+    description = "Powerful markdown processor in Go geared towards the IETF";
+    homepage = "https://github.com/mmarkdown/mmark";
+    license = with lib.licenses; bsd2;
+    maintainers = with lib.maintainers; [ yrashk ];
+    mainProgram = "mmark";
+  };
+}

pkgs/by-name/mm/mmc-utils/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  gitUpdater,
+  sparse,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mmc-utils";
+  version = "1.0";
+
+  src = fetchgit {
+    url = "https://git.kernel.org/pub/scm/utils/mmc/mmc-utils.git";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-iWLA1psNPUBCPOP393/xnYJ6BEuOcPCEYgymqE06F3Q=";
+  };
+
+  nativeBuildInputs = [ sparse ];
+
+  makeFlags = [
+    "CC=${stdenv.cc.targetPrefix}cc"
+    "prefix=$(out)"
+    "mandir=$(out)/share/man"
+  ];
+
+  enableParallelBuilding = true;
+
+  passthru.updateScript = gitUpdater {
+    rev-prefix = "v";
+  };
+
+  meta = with lib; {
+    description = "Configure MMC storage devices from userspace";
+    mainProgram = "mmc";
+    homepage = "https://git.kernel.org/pub/scm/utils/mmc/mmc-utils.git/";
+    license = licenses.gpl2Only;
+    maintainers = [ maintainers.dezgeg ];
+    platforms = platforms.linux;
+  };
+})

pkgs/by-name/mm/mmctl/package.nix

@@ -0,0 +1,13 @@
+{
+  mattermost,
+}:
+
+mattermost.withoutTests.server.overrideAttrs (o: {
+  pname = "mmctl";
+  subPackages = [ "cmd/mmctl" ];
+
+  meta = o.meta // {
+    description = "Remote CLI tool for Mattermost";
+    mainProgram = "mmctl";
+  };
+})

pkgs/by-name/mm/mmdbctl/package.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  stdenv,
+  runCommand,
+  mmdbctl,
+  dbip-country-lite,
+}:
+
+buildGoModule rec {
+  pname = "mmdbctl";
+  version = "1.4.8";
+
+  src = fetchFromGitHub {
+    owner = "ipinfo";
+    repo = "mmdbctl";
+    tag = "mmdbctl-${version}";
+    hash = "sha256-9s/dyORfv3lNf9W6oE1PHhaTgJFdeFa46pf54c/cwH0=";
+  };
+
+  vendorHash = "sha256-4T3HEzRerC4KrGQnMNSW3OVzChUIf4yJ7qS9v8mWIX4=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd mmdbctl \
+      --bash <($out/bin/mmdbctl completion bash) \
+      --fish <($out/bin/mmdbctl completion fish) \
+      --zsh <($out/bin/mmdbctl completion zsh)
+  '';
+
+  passthru.tests = {
+    simple = runCommand "${pname}-test" { } ''
+      ${lib.getExe mmdbctl} verify ${dbip-country-lite.mmdb} | grep valid
+      ${lib.getExe mmdbctl} metadata ${dbip-country-lite.mmdb} | grep DBIP-Country-Lite
+      touch $out
+    '';
+  };
+
+  meta = {
+    description = "MMDB file management CLI supporting various operations on MMDB database files";
+    homepage = "https://github.com/ipinfo/mmdbctl";
+    changelog = "https://github.com/ipinfo/mmdbctl/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ moraxyc ];
+    mainProgram = "mmdbctl";
+  };
+}

pkgs/by-name/mm/mmdbinspect/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "mmdbinspect";
+  version = "0.2.0";
+
+  src = fetchFromGitHub {
+    owner = "maxmind";
+    repo = "mmdbinspect";
+    tag = "v${version}";
+    hash = "sha256-PYn+NgJDZBP+9nIU0kxg9KYT0EV35omagspcsCpa9DM=";
+    fetchSubmodules = true;
+  };
+
+  vendorHash = "sha256-HNgofsfMsqXttnrNDIPgLHag+2hqQTREomcesWldpMo=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  meta = {
+    description = "Look up records for one or more IPs/networks in one or more .mmdb databases";
+    homepage = "https://github.com/maxmind/mmdbinspect";
+    changelog = "https://github.com/maxmind/mmdbinspect/blob/${src.rev}/CHANGELOG.md";
+    license = with lib.licenses; [
+      asl20
+      mit
+    ];
+    maintainers = with lib.maintainers; [ moraxyc ];
+    mainProgram = "mmdbinspect";
+  };
+}

pkgs/by-name/mm/mmdoc/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmark-gfm,
+  xxd,
+  fastJson,
+  libzip,
+  ninja,
+  meson,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "mmdoc";
+  version = "0.20.0";
+
+  src = fetchFromGitHub {
+    owner = "ryantm";
+    repo = "mmdoc";
+    rev = version;
+    hash = "sha256-NS8i5xvCwq0pSdfxnaxnpuwmDAkfH6Tkc4N2F6aGvWY=";
+  };
+
+  nativeBuildInputs = [
+    ninja
+    meson
+    pkg-config
+    xxd
+  ];
+
+  buildInputs = [
+    cmark-gfm
+    fastJson
+    libzip
+  ];
+
+  meta = with lib; {
+    description = "Minimal Markdown Documentation";
+    mainProgram = "mmdoc";
+    homepage = "https://github.com/ryantm/mmdoc";
+    license = licenses.cc0;
+    maintainers = with maintainers; [ ryantm ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/mm/mmex/package.nix

@@ -0,0 +1,89 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  appstream,
+  cmake,
+  gettext,
+  git,
+  makeWrapper,
+  lsb-release,
+  pkg-config,
+  wrapGAppsHook3,
+  curl,
+  sqlite,
+  wxGTK32,
+  gtk3,
+  lua,
+  wxsqlite3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "money-manager-ex";
+  version = "1.9.1";
+
+  src = fetchFromGitHub {
+    owner = "moneymanagerex";
+    repo = "moneymanagerex";
+    tag = "v${version}";
+    fetchSubmodules = true;
+    hash = "sha256-U8DvJPJwShbuKlKsWylH9kUEEw8/SY8KnYWNyInhE9k=";
+  };
+
+  postPatch = ''
+    substituteInPlace src/dbwrapper.cpp src/model/Model_Report.cpp \
+      --replace-fail "sqlite3mc_amalgamation.h" "sqlite3.h"
+  '';
+
+  nativeBuildInputs = [
+    appstream # for appstreamcli
+    cmake
+    gettext
+    git
+    makeWrapper
+    pkg-config
+    wrapGAppsHook3
+    wxGTK32
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    lsb-release
+  ];
+
+  buildInputs = [
+    curl
+    sqlite
+    wxGTK32
+    gtk3
+    lua
+    wxsqlite3
+  ];
+
+  strictDeps = true;
+
+  cmakeFlags = [
+    "-DWXSQLITE3_HAVE_CODEC=1"
+  ];
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optionals stdenv.cc.isClang [
+      "-Wno-deprecated-copy"
+      "-Wno-old-style-cast"
+      "-Wno-unused-parameter"
+    ]
+  );
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    mkdir -p $out/{Applications,bin}
+    mv $out/mmex.app $out/Applications
+    makeWrapper $out/{Applications/mmex.app/Contents/MacOS,bin}/mmex
+  '';
+
+  meta = {
+    description = "Easy-to-use personal finance software";
+    homepage = "https://www.moneymanagerex.org/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ ];
+    platforms = with lib.platforms; unix;
+    mainProgram = "mmex";
+  };
+}

pkgs/by-name/mm/mmg/package.nix

@@ -0,0 +1,43 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  unstableGitUpdater,
+  cmake,
+  perl,
+}:
+stdenv.mkDerivation {
+  pname = "mmg";
+  version = "5.7.3-unstable-2024-05-31";
+
+  src = fetchFromGitHub {
+    owner = "MmgTools";
+    repo = "mmg";
+    rev = "5a73683f84fe422031921bef4ced8905d8b9eb7e";
+    hash = "sha256-8m4iDsJdjlzuXatfIIZCY8RgrEp4BQihhmQfytu8aaU=";
+  };
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  nativeBuildInputs = [
+    cmake
+    perl
+  ];
+
+  preConfigure = ''
+    patchShebangs ./
+  '';
+
+  cmakeFlags = [
+    "-DBUILD_SHARED_LIBS:BOOL=TRUE"
+    "-DMMG_INSTALL_PRIVATE_HEADERS=ON"
+  ];
+
+  meta = with lib; {
+    description = "Open source software for bidimensional and tridimensional remeshing";
+    homepage = "http://www.mmgtools.org/";
+    platforms = platforms.unix;
+    license = licenses.lgpl3Plus;
+    maintainers = with maintainers; [ mkez ];
+  };
+}

pkgs/by-name/mm/mmh/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  ncurses,
+  autoreconfHook,
+  flex,
+}:
+let
+  rev = "7e93dee44df1a7e8f551a2e408a600b2e90a0974";
+in
+stdenv.mkDerivation {
+  pname = "mmh";
+  version = "unstable-2023-09-24";
+
+  src = fetchurl {
+    url = "http://git.marmaro.de/?p=mmh;a=snapshot;h=${rev};sf=tgz";
+    name = "mmh-${rev}.tgz";
+    hash = "sha256-t2Qnwtkli+/MDk6uaikS2SIP9LucK64os8kGcn2ytRU=";
+  };
+
+  postPatch = ''
+    substituteInPlace sbr/Makefile.in \
+      --replace-fail "ar " "${stdenv.cc.targetPrefix}ar "
+  '';
+
+  buildInputs = [ ncurses ];
+  nativeBuildInputs = [
+    autoreconfHook
+    flex
+  ];
+
+  # mhl.c:1031:58: error: pointer type mismatch in conditional expression []
+  #  1031 |                 putstr((c1->c_flags & RTRIM) ? rtrim(cp) : cp);
+  NIX_CFLAGS_COMPILE = [ " -Wno-error=incompatible-pointer-types" ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "Set of electronic mail handling programs";
+    homepage = "http://marmaro.de/prog/mmh";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.unix;
+    broken = stdenv.hostPlatform.isDarwin;
+    maintainers = with lib.maintainers; [ kaction ];
+  };
+}

pkgs/by-name/mm/mmixware/package.nix

@@ -0,0 +1,57 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  tetex,
+}:
+
+stdenv.mkDerivation {
+  pname = "mmixware";
+  version = "unstable-2021-06-18";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.lrz.de";
+    owner = "mmix";
+    repo = "mmixware";
+    rev = "7c790176d50d13ae2422fa7457ccc4c2d29eba9b";
+    sha256 = "sha256-eSwHiJ5SP/Nennalv4QFTgVnM6oan/DWDZRqtk0o6Z0=";
+  };
+
+  hardeningDisable = [ "format" ];
+
+  postPatch = ''
+    substituteInPlace Makefile --replace 'rm abstime.h' ""
+  '';
+
+  # Workaround build failure on -fno-common toolchains:
+  #   ld: mmix-config.o:(.bss+0x600): multiple definition of `buffer'; /build/ccDuGrwH.o:(.bss+0x20): first defined here
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  nativeBuildInputs = [ tetex ];
+  enableParallelBuilding = true;
+
+  makeFlags = [
+    "all"
+    "doc"
+    "CFLAGS=-O2"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/share/doc
+    cp *.ps $out/share/doc
+    install -Dm755 mmixal -t $out/bin
+    install -Dm755 mmix -t $out/bin
+    install -Dm755 mmotype -t $out/bin
+    install -Dm755 mmmix -t $out/bin
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "MMIX simulator and assembler";
+    homepage = "https://www-cs-faculty.stanford.edu/~knuth/mmix-news.html";
+    maintainers = with maintainers; [ siraben ];
+    platforms = platforms.unix;
+    license = licenses.publicDomain;
+  };
+}

pkgs/by-name/mm/mmj2/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  maven,
+  fetchFromGitHub,
+  jre,
+  makeWrapper,
+}:
+
+let
+  lastVersion = "2.5.2";
+
+in
+maven.buildMavenPackage {
+  pname = "mmj2";
+
+  # The latest stable version is from 2017 and doesn't include the mmj2jar/mmj2
+  # wrapper script, so use the unstable one for now
+  version = "${lastVersion}-unstable-2023-06-27";
+
+  src = fetchFromGitHub {
+    owner = "digama0";
+    repo = "mmj2";
+    fetchSubmodules = true;
+    rev = "1cd95c1fe4435899c8575644fccb412dd77d79e4";
+    hash = "sha256-WYBrLY04+bJGzjRMs8LgHnI6lMRhQKyz15DIoLeiE2s=";
+  };
+
+  mvnHash = "sha256-fu/q6CTvSllrfgnKNX6aIuPO65H/q0IPCHFuWmOFOvM=";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    local jar=$out/share/$pname/$pname.jar
+    local bin=$out/bin/$pname
+    install -Dm644 target/$pname-${lastVersion}-SNAPSHOT-jar-with-dependencies.jar $jar
+    install -Dm744 mmj2jar/$pname $bin
+    wrapProgram $bin \
+      --set MMJ2_JAR $jar \
+      --set JAVA ${jre}/bin/java
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "GUI Proof Assistant for the Metamath project";
+    longDescription = ''
+      mmj2 is a proof assistant for the Metamath language. Metamath is a
+      language that lets you express mathematical axioms and theorems. The proof
+      assistant includes a GUI for creating proofs, proof verification tools,
+      and grammatical/syntax analysis.
+    '';
+    homepage = "https://github.com/digama0/mmj2";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ io12 ];
+    platforms = platforms.linux;
+    mainProgram = "mmj2";
+  };
+}

pkgs/by-name/mm/mmsd-tng/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  c-ares,
+  dbus,
+  glib,
+  libphonenumber,
+  libsoup_3,
+  meson,
+  mobile-broadband-provider-info,
+  modemmanager,
+  ninja,
+  pkg-config,
+  protobuf,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mmsd-tng";
+  version = "2.6.4";
+
+  src = fetchFromGitLab {
+    owner = "kop316";
+    repo = "mmsd";
+    rev = finalAttrs.version;
+    hash = "sha256-/nHsLs7C2W7bCjTPBBlAN+O7zP4bgVW0dBmjHaoY2I8=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    c-ares
+    dbus
+    glib
+    libphonenumber
+    libsoup_3
+    mobile-broadband-provider-info
+    modemmanager
+    protobuf
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Multimedia Messaging Service Daemon - The Next Generation";
+    homepage = "https://gitlab.com/kop316/mmsd";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ julm ];
+    platforms = lib.platforms.linux;
+    mainProgram = "mmsdtng";
+  };
+})

pkgs/by-name/mm/mmseqs2/package.nix

@@ -0,0 +1,95 @@
+{
+  lib,
+  config,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  xxd,
+  perl,
+  installShellFiles,
+  enableAvx2 ? stdenv.hostPlatform.avx2Support,
+  enableSse4_1 ? stdenv.hostPlatform.sse4_1Support,
+  enableMpi ? false,
+  mpi,
+  cudaSupport ? config.cudaSupport,
+  cudaPackages,
+  llvmPackages,
+  zlib,
+  bzip2,
+  pkgsStatic,
+  runCommand,
+}:
+let
+  # require static library, libzstd.a
+  inherit (pkgsStatic) zstd;
+in
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mmseqs2";
+  version = "18-8cc5c";
+
+  src = fetchFromGitHub {
+    owner = "soedinglab";
+    repo = "mmseqs2";
+    tag = finalAttrs.version;
+    hash = "sha256-xOdtAE6qpEOH13ubs7KEFAEwsYbB3a5t+QXTC+QxgLs=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    xxd
+    perl
+    installShellFiles
+    zstd
+  ]
+  ++ lib.optionals cudaSupport [
+    cudaPackages.cuda_nvcc
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "HAVE_AVX2" enableAvx2)
+    (lib.cmakeBool "HAVE_SSE4_1" enableSse4_1)
+    (lib.cmakeBool "HAVE_MPI" enableMpi)
+    (lib.cmakeBool "USE_SYSTEM_ZSTD" true)
+    (lib.cmakeBool "HAVE_ARM8" stdenv.hostPlatform.isAarch64)
+  ]
+  ++ lib.optionals cudaSupport [
+    (lib.cmakeBool "ENABLE_CUDA" true)
+    (lib.cmakeFeature "CMAKE_CUDA_ARCHITECTURES" cudaPackages.flags.cmakeCudaArchitecturesString)
+  ];
+
+  buildInputs =
+    lib.optionals stdenv.cc.isClang [
+      llvmPackages.openmp
+      zlib
+      bzip2
+    ]
+    ++ lib.optional enableMpi mpi
+    ++ lib.optionals cudaSupport [
+      cudaPackages.cuda_cudart
+      cudaPackages.cuda_cccl
+    ];
+
+  postInstall = ''
+    installShellCompletion --bash --cmd mmseqs $out/util/bash-completion.sh
+    rm -r $out/util/
+  '';
+
+  passthru.tests = {
+    example = runCommand "mmseqs2-test" { } ''
+      ${lib.getExe finalAttrs.finalPackage} createdb ${finalAttrs.src}/examples/DB.fasta targetDB > $out
+      ${lib.getExe finalAttrs.finalPackage} createindex targetDB tmp >> $out
+      ${lib.getExe finalAttrs.finalPackage} easy-search ${finalAttrs.src}/examples/QUERY.fasta targetDB alnRes.m8 tmp >> $out
+    '';
+  };
+
+  meta = {
+    description = "Ultra fast and sensitive sequence search and clustering suite";
+    mainProgram = "mmseqs";
+    homepage = "https://mmseqs.com/";
+    changelog = "https://github.com/soedinglab/MMseqs2/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ natsukium ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/mm/mmtc/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "mmtc";
+  version = "0.3.2";
+
+  src = fetchFromGitHub {
+    owner = "figsoda";
+    repo = "mmtc";
+    rev = "v${version}";
+    sha256 = "sha256-gs6uytX4rm2JrJ4UbtHJDg+b+Z1ZjcsuUR0b13jQIy4=";
+  };
+
+  cargoHash = "sha256-TpAl7lMaQGSH9oMNqYIxnajsfh1HAdyU2suSFRfWYPs=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = ''
+    installManPage artifacts/mmtc.1
+    installShellCompletion artifacts/mmtc.{bash,fish} --zsh artifacts/_mmtc
+  '';
+
+  GEN_ARTIFACTS = "artifacts";
+
+  meta = {
+    description = "Minimal mpd terminal client that aims to be simple yet highly configurable";
+    homepage = "https://github.com/figsoda/mmtc";
+    changelog = "https://github.com/figsoda/mmtc/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mpl20;
+    maintainers = with lib.maintainers; [ figsoda ];
+    mainProgram = "mmtc";
+  };
+}

pkgs/by-name/mm/mmtf-cpp/package.nix

@@ -0,0 +1,41 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  msgpack-cxx,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mmtf-cpp";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "rcsb";
+    repo = "mmtf-cpp";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-8JrNobvekMggS8L/VORKA32DNUdXiDrYMObjd29wQmc=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  propagatedBuildInputs = [ msgpack-cxx ];
+
+  # Fix the build with msgpack-cxx ≥ 6.0.
+  #
+  # Upstream is unmaintained and does not plan to fix this; see
+  # <https://github.com/rcsb/mmtf-cpp/issues/44>.
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail 'find_package(msgpack)' 'find_package(msgpack-cxx)' \
+      --replace-fail msgpackc msgpack-cxx
+  '';
+
+  meta = with lib; {
+    description = "Library of exchange-correlation functionals with arbitrary-order derivatives";
+    homepage = "https://github.com/rcsb/mmtf-cpp";
+    license = licenses.mit;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.sheepforce ];
+  };
+})

pkgs/by-name/mm/mmtui/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "mmtui";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "SL-RU";
+    repo = "mmtui";
+    tag = "v${version}";
+    hash = "sha256-s+50kz6OODZ0xKz8oNF2YEzk+mLZ6gXXynl8g6Uwdo4=";
+  };
+
+  cargoHash = "sha256-9F1YMepkWksTQRrkziNhLxVJnhoDH17lSKef5kOjp3Y=";
+
+  nativeBuildInputs = [
+    rustPlatform.bindgenHook
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/SL-RU/mmtui/releases/tag/v${version}";
+    description = "TUI disk mount manager for TUI file managers";
+    homepage = "https://github.com/SL-RU/mmtui";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ grimmauld ];
+    mainProgram = "mmtui";
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/mm/mmv-go/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "mmv-go";
+  version = "0.1.6";
+
+  src = fetchFromGitHub {
+    owner = "itchyny";
+    repo = "mmv";
+    rev = "v${version}";
+    sha256 = "sha256-DNLiW0QX7WrBslwVCbvydLnE6JAcfcRALYqwsK/J5x0=";
+  };
+
+  vendorHash = "sha256-HHGiMSBu3nrIChSYaEu9i22nwhLKgVQkPvbTMHBWwAE=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.revision=${src.rev}"
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/itchyny/mmv";
+    description = "Rename multiple files using your $EDITOR";
+    license = licenses.mit;
+    maintainers = [ ];
+    mainProgram = "mmv";
+  };
+}

pkgs/by-name/mm/mmv/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  gengetopt,
+  m4,
+  gnupg,
+  git,
+  perl,
+  autoconf,
+  automake,
+  help2man,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "mmv";
+  version = "2.10";
+
+  src = fetchFromGitHub {
+    owner = "rrthomas";
+    repo = "mmv";
+    tag = "v${version}";
+    hash = "sha256-h+hdrIQz+7jKdMdJtWhBbZgvmNTIOr7Q38nhfAWC+G4=";
+    fetchSubmodules = true;
+  };
+
+  preConfigure = ''
+    ./bootstrap
+  '';
+
+  nativeBuildInputs = [
+    gengetopt
+    m4
+    git
+    gnupg
+    perl
+    autoconf
+    automake
+    help2man
+    pkg-config
+  ];
+
+  enableParallelBuilding = true;
+
+  env = lib.optionalAttrs stdenv.cc.isClang {
+    NIX_CFLAGS_COMPILE = toString [
+      "-Wno-error=implicit-function-declaration"
+      "-Wno-error=implicit-int"
+      "-Wno-error=int-conversion"
+    ];
+  };
+
+  meta = {
+    homepage = "https://github.com/rrthomas/mmv";
+    description = "Utility for wildcard renaming, copying, etc";
+    license = lib.licenses.gpl3Plus;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ siraben ];
+  };
+}