push sheeet

pkgs/by-name/mo/mosh/bash_completion_datadir.patch

@@ -0,0 +1,19 @@
+diff --git a/configure.ac b/configure.ac
+index 3ad983d..ff8ff96 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -476,13 +476,7 @@ AS_IF([echo "$protobuf_LIBS" | grep -q -- -pthread],
+ 
+ # Bash completion needs to ask where it goes if >= 2.0 is installed.
+ AS_IF([test "$install_completion" != no],
+-  [PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
+-     [if test "$prefix" = "NONE"; then
+-        completions="`pkg-config --variable=completionsdir bash-completion`"
+-      else
+-        completions="`pkg-config --define-variable=prefix=$prefix --variable=completionsdir bash-completion`"
+-      fi],
+-     [completions="${sysconfdir}/bash_completion.d"])
++   [completions="`pkg-config --define-variable=datadir=$datadir --variable=completionsdir bash-completion`"]
+    AC_SUBST([completions])])
+ 
+ AC_CONFIG_FILES([

pkgs/by-name/mo/mosh/mosh-client_path.patch

@@ -0,0 +1,22 @@
+diff --git a/scripts/mosh.pl b/scripts/mosh.pl
+index 56e96d7..2a2177e 100755
+--- a/scripts/mosh.pl
++++ b/scripts/mosh.pl
+@@ -61,7 +61,7 @@ my $have_ipv6 = eval {
+ 
+ $|=1;
+ 
+-my $client = 'mosh-client';
++my $client = '@mosh-client@';
+ my $server = 'mosh-server';
+ 
+ my $predict = undef;
+@@ -91,7 +91,7 @@ my @cmdline = @ARGV;
+ my $usage =
+ qq{Usage: $0 [options] [--] [user@]host [command...]
+         --client=PATH        mosh client on local machine
+-                                (default: "mosh-client")
++                                (default: "@mosh-client@")
+         --server=COMMAND     mosh server on remote machine
+                                 (default: "mosh-server")
+ 

pkgs/by-name/mo/mosh/package.nix

@@ -0,0 +1,92 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  zlib,
+  protobuf,
+  ncurses,
+  pkg-config,
+  makeWrapper,
+  perl,
+  openssl,
+  autoreconfHook,
+  openssh,
+  bash-completion,
+  fetchpatch,
+  withUtempter ? stdenv.hostPlatform.isLinux && !stdenv.hostPlatform.isMusl,
+  libutempter,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "mosh";
+  version = "1.4.0";
+
+  src = fetchFromGitHub {
+    owner = "mobile-shell";
+    repo = "mosh";
+    rev = "mosh-${version}";
+    hash = "sha256-tlSsHu7JnXO+sorVuWWubNUNdb9X0/pCaiGG5Y0X/g8=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    makeWrapper
+    protobuf
+    perl
+  ];
+  buildInputs = [
+    protobuf
+    ncurses
+    zlib
+    openssl
+    bash-completion
+    perl
+  ]
+  ++ lib.optional withUtempter libutempter;
+
+  strictDeps = true;
+
+  enableParallelBuilding = true;
+
+  patches = [
+    ./ssh_path.patch
+    ./mosh-client_path.patch
+    # Fix build with bash-completion 2.10
+    ./bash_completion_datadir.patch
+
+    # Fixes build with protobuf3 23.x
+    (fetchpatch {
+      url = "https://github.com/mobile-shell/mosh/commit/eee1a8cf413051c2a9104e8158e699028ff56b26.patch";
+      hash = "sha256-CouLHWSsyfcgK3k7CvTK3FP/xjdb1pfsSXYYQj3NmCQ=";
+    })
+  ];
+
+  postPatch = ''
+    substituteInPlace scripts/mosh.pl \
+      --subst-var-by ssh "${openssh}/bin/ssh" \
+      --subst-var-by mosh-client "$out/bin/mosh-client"
+  '';
+
+  configureFlags = [ "--enable-completion" ] ++ lib.optional withUtempter "--with-utempter";
+
+  postInstall = ''
+    wrapProgram $out/bin/mosh --prefix PERL5LIB : $PERL5LIB
+  '';
+
+  meta = with lib; {
+    homepage = "https://mosh.org/";
+    description = "Mobile shell (ssh replacement)";
+    longDescription = ''
+      Remote terminal application that allows roaming, supports intermittent
+      connectivity, and provides intelligent local echo and line editing of
+      user keystrokes.
+
+      Mosh is a replacement for SSH. It's more robust and responsive,
+      especially over Wi-Fi, cellular, and long-distance links.
+    '';
+    license = licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ skeuchel ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/mo/mosh/ssh_path.patch

@@ -0,0 +1,13 @@
+diff --git i/scripts/mosh.pl w/scripts/mosh.pl
+index c511482..55bf5f3 100755
+--- i/scripts/mosh.pl
++++ w/scripts/mosh.pl
+@@ -66,7 +66,7 @@ my $use_remote_ip = 'proxy';
+ my $family = 'prefer-inet';
+ my $port_request = undef;
+ 
+-my @ssh = ('ssh');
++my @ssh = ('@ssh@');
+ 
+ my $term_init = 1;
+