push sheeet

pkgs/by-name/mo/mov-cli/mov-cli-test.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools-scm,
+  pytubefix,
+  requests,
+  devgoldyutils,
+}:
+
+buildPythonPackage rec {
+  pname = "mov-cli-test";
+  version = "1.1.7";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "mov-cli";
+    repo = "mov-cli-test";
+    rev = "refs/tags/${version}";
+    hash = "sha256-INdPAJxPxfo5bKg4Xn1r7bildxznXrTJxmDI21wylnI=";
+  };
+
+  doCheck = false;
+
+  propagatedBuildInputs = [
+    pytubefix
+    requests
+    devgoldyutils
+  ];
+
+  nativeBuildInputs = [ setuptools-scm ];
+
+  meta = {
+    description = "Mov-cli plugin that let's you test mov-cli's capabilities by watching free films and animations in the creative commons";
+    homepage = "https://github.com/mov-cli/mov-cli-test";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ youhaveme9 ];
+  };
+}

pkgs/by-name/mo/mov-cli/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  fetchFromGitHub,
+  ffmpeg,
+  fzf,
+  mpv,
+  python3,
+}:
+
+let
+  pname = "mov-cli";
+  version = "4.4.19";
+in
+python3.pkgs.buildPythonPackage {
+  inherit pname version;
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "mov-cli";
+    repo = "mov-cli";
+    tag = version;
+    hash = "sha256-sNeScHmQYR4Avr5OEFpE90Qn7udBgi1Ox5elFSyKXrY=";
+  };
+
+  propagatedBuildInputs = with python3.pkgs; [
+    beautifulsoup4
+    click
+    colorama
+    deprecation
+    httpx
+    inquirer
+    krfzf-py
+    lxml
+    poetry-core
+    pycrypto
+    python-decouple
+    setuptools
+    six
+    thefuzz
+    tldextract
+    toml
+    typer
+    unidecode
+    (callPackage ./mov-cli-test.nix { })
+  ];
+
+  pythonRelaxDeps = [
+    "httpx"
+    "tldextract"
+  ];
+
+  makeWrapperArgs =
+    let
+      binPath = lib.makeBinPath [
+        ffmpeg
+        fzf
+        mpv
+      ];
+    in
+    [
+      "--prefix PATH : ${binPath}"
+    ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mov-cli/mov-cli";
+    description = "Cli tool to browse and watch movies";
+    license = with lib.licenses; [ gpl3Only ];
+    mainProgram = "mov-cli";
+    maintainers = with lib.maintainers; [ baitinq ];
+  };
+}