push sheeet

pkgs/by-name/mv/mvapich/package.nix

@@ -0,0 +1,123 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  bison,
+  numactl,
+  libxml2,
+  perl,
+  gfortran,
+  slurm,
+  openssh,
+  hwloc,
+  zlib,
+  makeWrapper,
+  # InfiniBand dependencies
+  opensm,
+  rdma-core,
+  # OmniPath dependencies
+  libpsm2,
+  libfabric,
+  # Compile with slurm as a process manager
+  useSlurm ? false,
+  # Network type for MVAPICH2
+  network ? "ethernet",
+}:
+
+assert builtins.elem network [
+  "ethernet"
+  "infiniband"
+  "omnipath"
+];
+
+stdenv.mkDerivation rec {
+  pname = "mvapich";
+  version = "2.3.7";
+
+  src = fetchurl {
+    url = "http://mvapich.cse.ohio-state.edu/download/mvapich/mv2/mvapich2-${version}.tar.gz";
+    sha256 = "sha256-w5pEkvS+UN9hAHhXSLoolOI85FCpQSgYHVFtpXV3Ua4=";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+    "man"
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    bison
+    makeWrapper
+    gfortran
+  ];
+  propagatedBuildInputs = [
+    numactl
+    rdma-core
+    zlib
+    opensm
+  ];
+  buildInputs = [
+    numactl
+    libxml2
+    perl
+    openssh
+    hwloc
+  ]
+  ++ lib.optionals (network == "infiniband") [
+    rdma-core
+    opensm
+  ]
+  ++ lib.optionals (network == "omnipath") [
+    libpsm2
+    libfabric
+  ]
+  ++ lib.optional useSlurm slurm;
+
+  configureFlags = [
+    "--with-pm=hydra"
+    "--enable-fortran=all"
+    "--enable-cxx"
+    "--enable-threads=multiple"
+    "--enable-hybrid"
+    "--enable-shared"
+    "FFLAGS=-fallow-argument-mismatch" # fix build with gfortran 10
+  ]
+  ++ lib.optional useSlurm "--with-pm=slurm"
+  ++ lib.optional (network == "ethernet") "--with-device=ch3:sock"
+  ++ lib.optionals (network == "infiniband") [
+    "--with-device=ch3:mrail"
+    "--with-rdma=gen2"
+    "--disable-ibv-dlopen"
+  ]
+  ++ lib.optionals (network == "omnipath") [
+    "--with-device=ch3:psm"
+    "--with-psm2=${libpsm2}"
+  ];
+
+  doCheck = true;
+
+  preFixup = ''
+    # /tmp/nix-build... ends up in the RPATH, fix it manually
+    for entry in $out/bin/mpichversion $out/bin/mpivars; do
+      echo "fix rpath: $entry"
+      patchelf --allowed-rpath-prefixes ${builtins.storeDir} --shrink-rpath $entry
+    done
+
+    # Ensure the default compilers are the ones mvapich was built with
+    substituteInPlace $out/bin/mpicc --replace 'CC="gcc"' 'CC=${stdenv.cc}/bin/cc'
+    substituteInPlace $out/bin/mpicxx --replace 'CXX="g++"' 'CXX=${stdenv.cc}/bin/c++'
+    substituteInPlace $out/bin/mpifort --replace 'FC="gfortran"' 'FC=${gfortran}/bin/gfortran'
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "MPI-3.1 implementation optimized for Infiband transport";
+    homepage = "https://mvapich.cse.ohio-state.edu";
+    license = licenses.bsd3;
+    maintainers = [ maintainers.markuskowa ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/mv/mvebu64boot/package.nix

@@ -0,0 +1,36 @@
+{
+  fetchFromGitHub,
+  stdenv,
+  lib,
+  ncurses,
+}:
+
+stdenv.mkDerivation {
+  pname = "mvebu64boot";
+  version = "0-unstable-2022-10-20";
+
+  src = fetchFromGitHub {
+    owner = "pali";
+    repo = "mvebu64boot";
+    rev = "e7ca70eff2dc278607cc07f6654bbddacb2e4ff6";
+    hash = "sha256-Y2yVr/BuOah5yMvF5EvM7frEUY8r+Hf4bNIKVkHgvQs=";
+  };
+
+  buildInputs = [
+    ncurses
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -D mvebu64boot $out/bin/mvebu64boot
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Boot 64-bit Marvell EBU SoC over UART";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ lukegb ];
+    platforms = platforms.all;
+    mainProgram = "mvebu64boot";
+  };
+}

pkgs/by-name/mv/mvfst/glog-0.7.patch

@@ -0,0 +1,26 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index a878c7c473..c76c989f91 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -52,7 +52,7 @@
+ find_package(fmt REQUIRED)
+ find_package(folly REQUIRED)
+ find_package(Fizz REQUIRED)
+-find_package(Glog REQUIRED)
++find_package(Glog CONFIG REQUIRED)
+ find_package(Threads)
+ 
+ SET(GFLAG_DEPENDENCIES "")
+diff --git a/cmake/QuicTest.cmake b/cmake/QuicTest.cmake
+index e7d9f0c0c3..5f4525189c 100644
+--- a/cmake/QuicTest.cmake
++++ b/cmake/QuicTest.cmake
+@@ -50,7 +50,7 @@
+   target_link_libraries(${QUIC_TEST_TARGET} PUBLIC
+     "${QUIC_TEST_DEPENDS}"
+     ${LIBGMOCK_LIBRARIES}
+-    ${GLOG_LIBRARY}
++    glog::glog
+   )
+ 
+   # Per https://github.com/facebook/mvfst/pull/9, disable some warnings

pkgs/by-name/mv/mvfst/package.nix

@@ -0,0 +1,131 @@
+{
+  lib,
+  stdenv,
+
+  fetchFromGitHub,
+
+  cmake,
+  ninja,
+
+  folly,
+  gflags,
+  glog,
+
+  fizz,
+
+  ctestCheckHook,
+
+  gtest,
+
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mvfst";
+  version = "2025.09.15.00";
+
+  outputs = [
+    "bin"
+    "out"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "facebook";
+    repo = "mvfst";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-ZgzqkR72xtO5VVd2cyMM3vSsUWdW6HEvu9T1sM+cPi8=";
+  };
+
+  patches = [
+    ./glog-0.7.patch
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+  ];
+
+  buildInputs = [
+    folly
+    gflags
+    glog
+  ];
+
+  propagatedBuildInputs = [
+    fizz
+  ];
+
+  nativeCheckInputs = [
+    ctestCheckHook
+  ];
+
+  checkInputs = [
+    gtest
+  ];
+
+  hardeningDisable = [
+    # causes test failures on aarch64
+    "pacret"
+    # causes empty cmake files to be generated
+    "trivialautovarinit"
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
+
+    (lib.cmakeBool "CMAKE_INSTALL_RPATH_USE_LINK_PATH" true)
+
+    (lib.cmakeBool "BUILD_TESTS" finalAttrs.finalPackage.doCheck)
+
+    (lib.cmakeFeature "CMAKE_INSTALL_PREFIX" (placeholder "dev"))
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    # Homebrew sets this, and the shared library build fails without
+    # it. I don‘t know, either. It scares me.
+    (lib.cmakeFeature "CMAKE_SHARED_LINKER_FLAGS" "-Wl,-undefined,dynamic_lookup")
+  ];
+
+  __darwinAllowLocalNetworking = true;
+
+  doCheck = true;
+
+  dontUseNinjaCheck = true;
+
+  postPatch = ''
+    # Make sure the libraries the `tperf` binary uses are installed.
+    printf 'install(TARGETS mvfst_test_utils)\n' >> quic/common/test/CMakeLists.txt
+    printf 'install(TARGETS mvfst_dsr_backend)\n' >> quic/dsr/CMakeLists.txt
+  '';
+
+  disabledTests = [
+    "*/QuicClientTransportIntegrationTest.NetworkTest/*"
+    "*/QuicClientTransportIntegrationTest.FlowControlLimitedTest/*"
+    "*/QuicClientTransportIntegrationTest.NetworkTestConnected/*"
+    "*/QuicClientTransportIntegrationTest.SetTransportSettingsAfterStart/*"
+    "*/QuicClientTransportIntegrationTest.TestZeroRttSuccess/*"
+    "*/QuicClientTransportIntegrationTest.ZeroRttRetryPacketTest/*"
+    "*/QuicClientTransportIntegrationTest.NewTokenReceived/*"
+    "*/QuicClientTransportIntegrationTest.UseNewTokenThenReceiveRetryToken/*"
+    "*/QuicClientTransportIntegrationTest.TestZeroRttRejection/*"
+    "*/QuicClientTransportIntegrationTest.TestZeroRttNotAttempted/*"
+    "*/QuicClientTransportIntegrationTest.TestZeroRttInvalidAppParams/*"
+    "*/QuicClientTransportIntegrationTest.ChangeEventBase/*"
+    "*/QuicClientTransportIntegrationTest.ResetClient/*"
+    "*/QuicClientTransportIntegrationTest.TestStatelessResetToken/*"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Implementation of the QUIC transport protocol";
+    homepage = "https://github.com/facebook/mvfst";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [
+      ris
+      emily
+      techknowlogick
+    ];
+  };
+})

pkgs/by-name/mv/mvnd/package.nix

@@ -0,0 +1,111 @@
+{
+  lib,
+  fetchFromGitHub,
+  graalvmPackages,
+  installShellFiles,
+  makeWrapper,
+  maven,
+  mvnd,
+  nix-update-script,
+  runCommand,
+  stdenv,
+  testers,
+}:
+
+let
+  platformMap = {
+    aarch64-darwin = "darwin-aarch64";
+    aarch64-linux = "linux-aarch64";
+    x86_64-darwin = "darwin-amd64";
+    x86_64-linux = "linux-amd64";
+  };
+  inherit (platformMap.${stdenv.system}) os arch;
+in
+
+maven.buildMavenPackage rec {
+  pname = "mvnd";
+  version = "1.0.3";
+  src = fetchFromGitHub {
+    owner = "apache";
+    repo = "maven-mvnd";
+    rev = version;
+    sha256 = "sha256-vlJG2uDY93iri1X7SYPRufAIN4fhAjCd8gCeCdz/QDE=";
+  };
+
+  # need graalvm at build-time for the `native-image` tool
+  mvnJdk = graalvmPackages.graalvm-ce;
+  mvnHash = "sha256-n6ZKEXDzyzMfUZt3WHkwCDB68gm30UGrFecffFy7ytA=";
+
+  nativeBuildInputs = [
+    graalvmPackages.graalvm-ce
+    installShellFiles
+    makeWrapper
+  ];
+
+  mvnDepsParameters = mvnParameters;
+  mvnParameters = lib.concatStringsSep " " (
+    [
+      "-Dmaven.buildNumber.skip=true" # skip build number generation; requires a git repository
+      "-Drat.skip=true" # skip license checks; they require manaul approval and should have already been run upstream
+      "-Dspotless.skip=true" # skip formatting checks
+
+      # skip tests that fail in the sandbox
+      "-pl"
+      "!integration-tests"
+      "-Dtest=!org.mvndaemon.mvnd.client.OsUtilsTest,!org.mvndaemon.mvnd.cache.impl.CacheFactoryTest,!org.mvndaemon.mvnd.client.NoDaemonTest"
+      "-Dsurefire.failIfNoSpecifiedTests=false"
+
+      "-Pnative"
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      # see `buildGraalvmNativeImage`
+      "-DbuildArgs=-H:-CheckToolchain"
+    ]
+  );
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    mkdir -p $out/mvnd-home
+
+    cp -r dist/target/maven-mvnd-${version}-${platformMap.${stdenv.system}}/* $out/mvnd-home
+    makeWrapper $out/mvnd-home/bin/mvnd $out/bin/mvnd \
+      --set-default MVND_HOME $out/mvnd-home
+
+    installShellCompletion --cmd mvnd \
+      --bash $out/mvnd-home/bin/mvnd-bash-completion.bash
+
+    runHook postInstall
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+  }
+  // (lib.optionalAttrs (!stdenv.hostPlatform.isDarwin) {
+    tests.version = testers.testVersion {
+      # `java` or `JAVA_HOME` is required to run mvnd
+      # presumably the user already has a JDK installed if they're using maven; don't pull in an unnecessary runtime dependency
+      package =
+        runCommand "mvnd"
+          {
+            inherit version;
+            nativeBuildInputs = [ makeWrapper ];
+          }
+          ''
+            mkdir -p $out/bin
+            makeWrapper ${mvnd}/bin/mvnd $out/bin/mvnd \
+              --suffix PATH : ${lib.makeBinPath [ mvnJdk ]}
+          '';
+    };
+  });
+
+  meta = {
+    description = "Apache Maven Daemon";
+    homepage = "https://maven.apache.org/";
+    license = lib.licenses.asl20;
+    platforms = builtins.attrNames platformMap;
+    maintainers = with lib.maintainers; [ nathanregner ];
+    mainProgram = "mvnd";
+  };
+}

pkgs/by-name/mv/mvt/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "mvt";
+  pyproject = true;
+  version = "2.5.4";
+
+  src = fetchFromGitHub {
+    owner = "mvt-project";
+    repo = "mvt";
+    tag = "v${version}";
+    hash = "sha256-xDUjyvOsiweRqibTe7V8I/ABeaahCoR/d5w23qixp9A";
+  };
+
+  build-system = with python3.pkgs; [ setuptools ];
+
+  dependencies = with python3.pkgs; [
+    adb-shell
+    appdirs
+    click
+    cryptography
+    libusb1
+    iosbackup
+    packaging
+    pyahocorasick
+    pyyaml
+    requests
+    rich
+    simplejson
+    tld
+  ];
+
+  nativeCheckInputs = with python3.pkgs; [
+    pytestCheckHook
+    pytest-mock
+    stix2
+  ];
+
+  meta = {
+    description = "Tool to facilitate the consensual forensic analysis of Android and iOS devices";
+    homepage = "https://docs.mvt.re/en/latest/";
+    # https://github.com/mvt-project/mvt/blob/main/LICENSE
+    license = lib.licenses.unfree;
+    changelog = "https://github.com/mvt-project/mvt/releases/tag/v${version}";
+    maintainers = with lib.maintainers; [ PapayaJackal ];
+  };
+}