push sheeet

pkgs/by-name/na/nautilus-python/fix-paths.patch

@@ -0,0 +1,14 @@
+diff --git a/src/nautilus-python.c b/src/nautilus-python.c
+index 843e3c6..466a513 100644
+--- a/src/nautilus-python.c
++++ b/src/nautilus-python.c
+@@ -184,6 +184,9 @@ nautilus_python_init_python (void) {
+         return FALSE;
+     }
+ 
++    debug("Add PyGObject to path");
++    PyRun_SimpleString("import site;import functools; functools.reduce(lambda k, p: site.addsitedir(p, k), [@pythonPaths@], site._init_pathinfo())");
++
+     /* import gobject */
+     debug("init_pygobject");
+     if (!np_init_pygobject()) {

pkgs/by-name/na/nautilus-python/package.nix

@@ -0,0 +1,71 @@
+{
+  stdenv,
+  lib,
+  replaceVars,
+  fetchurl,
+  meson,
+  ninja,
+  pkg-config,
+  gtk-doc,
+  docbook-xsl-nons,
+  docbook_xml_dtd_412,
+  python3,
+  nautilus,
+  gnome,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nautilus-python";
+  version = "4.0.1";
+
+  outputs = [
+    "out"
+    "dev"
+    "doc"
+    "devdoc"
+  ];
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/nautilus-python/${lib.versions.majorMinor finalAttrs.version}/nautilus-python-${finalAttrs.version}.tar.xz";
+    hash = "sha256-/EnBBPsyoK0ZWmawE2eEzRnRDYs+jVnV7n9z6PlOko8=";
+  };
+
+  patches = [
+    # Make PyGObject’s gi library available.
+    (replaceVars ./fix-paths.patch {
+      pythonPaths = lib.concatMapStringsSep ", " (pkg: "'${pkg}/${python3.sitePackages}'") [
+        python3.pkgs.pygobject3
+      ];
+    })
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    meson
+    ninja
+    gtk-doc
+    docbook-xsl-nons
+    docbook_xml_dtd_412
+    python3.pythonOnBuildForHost
+  ];
+
+  buildInputs = [
+    python3
+    python3.pkgs.pygobject3
+    nautilus
+  ];
+
+  passthru = {
+    updateScript = gnome.updateScript {
+      packageName = "nautilus-python";
+    };
+  };
+
+  meta = with lib; {
+    description = "Python bindings for the Nautilus Extension API";
+    homepage = "https://gitlab.gnome.org/GNOME/nautilus-python";
+    license = licenses.gpl2Plus;
+    teams = [ teams.gnome ];
+    platforms = platforms.unix;
+  };
+})