push sheeet

pkgs/by-name/ne/netlify-cli/package.nix

@@ -0,0 +1,43 @@
+{
+  buildNpmPackage,
+  callPackage,
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  nodejs,
+  pkg-config,
+  vips,
+}:
+
+buildNpmPackage rec {
+  pname = "netlify-cli";
+  version = "19.0.2";
+
+  src = fetchFromGitHub {
+    owner = "netlify";
+    repo = "cli";
+    tag = "v${version}";
+    hash = "sha256-+P+hS/g/xRFNvzESZ5LyxyQSSRZ7BzCg9ZX/ndNLeDg=";
+  };
+
+  npmDepsHash = "sha256-3C+tTqLJCm48pAbQMiIq2SsHmb4bcCaf3IU/cTeR5BA=";
+
+  inherit nodejs;
+
+  buildInputs = [ vips ];
+  nativeBuildInputs = [ pkg-config ];
+
+  passthru = {
+    tests.test = callPackage ./test.nix { };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Netlify command line tool";
+    homepage = "https://github.com/netlify/cli";
+    changelog = "https://github.com/netlify/cli/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ roberth ];
+    mainProgram = "netlify";
+  };
+}

pkgs/by-name/ne/netlify-cli/test.nix

@@ -0,0 +1,45 @@
+{
+  curl,
+  darwin,
+  lib,
+  netlify-cli,
+  runCommand,
+  stdenv,
+}:
+
+runCommand "netlify-cli-test"
+  {
+    nativeBuildInputs = [
+      netlify-cli
+      curl
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      darwin.ps
+    ];
+    meta.timeout = 600;
+  }
+  ''
+    mkdir home
+    export HOME=$PWD/home
+
+    # Create a simple site
+    echo '<h1>hi</h1>' >index.html
+    echo '/with-redirect /' >_redirects
+
+    # Start a local server and wait for it to respond
+    netlify dev --offline --port 8888 2>&1 | tee log &
+    sleep 0.1 || true
+    for (( i=0; i<300; i++ )); do
+      if grep --ignore-case 'Server now ready' <log; then
+        break
+      else
+        sleep 1
+      fi
+    done
+
+    # Test the local server
+    curl -L http://localhost:8888/with-redirect | grep '<h1>hi</h1>'
+
+    # Success
+    touch $out
+  ''