push sheeet

pkgs/by-name/ne/networkmanager-l2tp/fix-paths.patch

@@ -0,0 +1,22 @@
+diff --git a/shared/utils.c b/shared/utils.c
+index 453e277..28716a5 100644
+--- a/shared/utils.c
++++ b/shared/utils.c
+@@ -39,7 +39,7 @@ check_ipsec_daemon(const char *path)
+ const char *
+ nm_find_ipsec(void)
+ {
+-    static const char *ipsec_binary_paths[] = {"/usr/bin/ipsec",
++    static const char *ipsec_binary_paths[] = {"@strongswan@/bin/ipsec",
+                                                "/sbin/ipsec",
+                                                "/usr/sbin/ipsec",
+                                                "/usr/local/sbin/ipsec",
+@@ -70,7 +70,7 @@ nm_find_l2tpd(NML2tpL2tpDaemon *l2tp_daemon)
+                                                "/usr/local/sbin/kl2tpd",
+                                                NULL};
+ 
+-    static const char *xl2tp_binary_paths[] = {"/usr/bin/xl2tpd",
++    static const char *xl2tp_binary_paths[] = {"@xl2tpd@/bin/xl2tpd",
+                                                "/sbin/xl2tpd",
+                                                "/usr/sbin/xl2tpd",
+                                                "/usr/local/sbin/xl2tpd",

pkgs/by-name/ne/networkmanager-l2tp/package.nix

@@ -0,0 +1,87 @@
+{
+  stdenv,
+  lib,
+  replaceVars,
+  fetchFromGitHub,
+  autoreconfHook,
+  pkg-config,
+  gtk3,
+  gtk4,
+  networkmanager,
+  ppp,
+  xl2tpd,
+  strongswan,
+  libsecret,
+  withGnome ? true,
+  libnma,
+  libnma-gtk4,
+  glib,
+  openssl,
+  nss,
+}:
+
+stdenv.mkDerivation rec {
+  name = "${pname}${lib.optionalString withGnome "-gnome"}-${version}";
+  pname = "NetworkManager-l2tp";
+  version = "1.20.20";
+
+  src = fetchFromGitHub {
+    owner = "nm-l2tp";
+    repo = "network-manager-l2tp";
+    rev = version;
+    hash = "sha256-AmbDWBCUG9fvqA6iJopYtbitdRwv2faWvIeKN90p234=";
+  };
+
+  patches = [
+    (replaceVars ./fix-paths.patch {
+      inherit strongswan xl2tpd;
+    })
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    glib # for gdbus-codegen
+    pkg-config
+  ]
+  ++ lib.optionals withGnome [
+    gtk4 # for gtk4-builder-tool
+  ];
+
+  buildInputs = [
+    networkmanager
+    ppp
+    openssl
+    nss
+  ]
+  ++ lib.optionals withGnome [
+    gtk3
+    gtk4
+    libsecret
+    libnma
+    libnma-gtk4
+  ];
+
+  configureFlags = [
+    "--with-gnome=${if withGnome then "yes" else "no"}"
+    "--with-gtk4=${if withGnome then "yes" else "no"}"
+    "--localstatedir=/var"
+    "--enable-absolute-paths"
+  ];
+
+  enableParallelBuilding = true;
+  strictDeps = true;
+
+  passthru = {
+    networkManagerPlugin = "VPN/nm-l2tp-service.name";
+  };
+
+  meta = with lib; {
+    description = "L2TP plugin for NetworkManager";
+    inherit (networkmanager.meta) platforms;
+    homepage = "https://github.com/nm-l2tp/network-manager-l2tp";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [
+      obadz
+    ];
+  };
+}