push sheeet

pkgs/by-name/nf/nf-test/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  fetchurl,
+  makeWrapper,
+  nextflow,
+  nf-test,
+  openjdk11,
+  stdenv,
+  testers,
+}:
+stdenv.mkDerivation rec {
+
+  pname = "nf-test";
+  version = "0.9.3";
+
+  src = fetchurl {
+    url = "https://github.com/askimed/nf-test/releases/download/v${version}/nf-test-${version}.tar.gz";
+    hash = "sha256-LLylgv34HiMXg+sjBbMdeLVPMV5+h+Z2xEWCiBqbNEY=";
+  };
+  sourceRoot = ".";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/nf-test
+    install -Dm644 nf-test.jar $out/share/nf-test
+
+    mkdir -p $out/bin
+    makeWrapper ${openjdk11}/bin/java $out/bin/nf-test \
+      --add-flags "-jar $out/share/nf-test/nf-test.jar" \
+      --prefix PATH : ${lib.makeBinPath [ nextflow ]} \
+
+    runHook postInstall
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = nf-test;
+    command = "nf-test version";
+  };
+
+  meta = with lib; {
+    description = "Simple test framework for Nextflow pipelines";
+    homepage = "https://www.nf-test.com/";
+    changelog = "https://github.com/askimed/nf-test/releases";
+    license = licenses.mit;
+    maintainers = with maintainers; [ rollf ];
+    mainProgram = "nf-test";
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/nf/nfd/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  stdenv,
+  boost186,
+  fetchFromGitHub,
+  libpcap,
+  ndn-cxx,
+  openssl,
+  pkg-config,
+  sphinx,
+  systemd,
+  wafHook,
+  websocketpp,
+  withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
+  withWebSocket ? true,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "nfd";
+  version = "24.07";
+
+  src = fetchFromGitHub {
+    owner = "named-data";
+    repo = "NFD";
+    rev = "NFD-${version}";
+    hash = "sha256-HbKPO3gwQWOZf4QZE+N7tAiqsNl1GrcwE4EUGjWmf5s=";
+  };
+
+  prePatch = lib.optional withWebSocket ''
+    ln -s ${websocketpp}/include/websocketpp websocketpp
+  '';
+
+  nativeBuildInputs = [
+    pkg-config
+    sphinx
+    wafHook
+  ];
+  buildInputs = [
+    libpcap
+    ndn-cxx
+    openssl
+  ]
+  ++ lib.optional withWebSocket websocketpp
+  ++ lib.optional withSystemd systemd;
+  wafConfigureFlags = [
+    "--boost-includes=${boost186.dev}/include"
+    "--boost-libs=${boost186.out}/lib"
+  ]
+  ++ lib.optional (!withWebSocket) "--without-websocket";
+
+  meta = with lib; {
+    homepage = "https://named-data.net/";
+    description = "Named Data Networking (NDN) Forwarding Daemon";
+    license = licenses.gpl3Plus;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ bertof ];
+  };
+}

pkgs/by-name/nf/nfdump/package.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoconf,
+  automake,
+  libtool,
+  pkg-config,
+  bzip2,
+  libpcap,
+  flex,
+  bison,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "nfdump";
+  version = "1.7.6";
+
+  src = fetchFromGitHub {
+    owner = "phaag";
+    repo = "nfdump";
+    tag = "v${version}";
+    hash = "sha256-4iyoQAjOQW4KNJbRmdisdecuOz+DFvQGEKgq8cq7GDI=";
+  };
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    flex
+    libtool
+    pkg-config
+    bison
+  ];
+
+  buildInputs = [
+    bzip2
+    libpcap
+  ];
+
+  preConfigure = ''
+    # The script defaults to glibtoolize on darwin, so we pass the correct
+    # name explicitly.
+    LIBTOOLIZE=libtoolize ./autogen.sh
+  '';
+
+  configureFlags = [
+    "--enable-nsel"
+    "--enable-sflow"
+    "--enable-readpcap"
+    "--enable-nfpcapd"
+  ];
+
+  meta = {
+    description = "Tools for working with netflow data";
+    longDescription = ''
+      nfdump is a set of tools for working with netflow data.
+    '';
+    homepage = "https://github.com/phaag/nfdump";
+    changelog = "https://github.com/phaag/nfdump/releases/tag/v${version}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ takikawa ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/nf/nfft/package.nix

@@ -0,0 +1,59 @@
+{
+  autoconf,
+  automake,
+  cunit,
+  fetchFromGitHub,
+  fftw,
+  lib,
+  libtool,
+  llvmPackages,
+  stdenv,
+  bash,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nfft";
+  version = "3.5.3";
+
+  src = fetchFromGitHub {
+    owner = "NFFT";
+    repo = "nfft";
+    rev = finalAttrs.version;
+    hash = "sha256-HR8ME9PVC+RAv1GIgV2vK6eLU8Wk28+rSzbutThBv3w=";
+  };
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    cunit
+    libtool
+    bash
+  ];
+
+  preConfigure = ''
+    bash bootstrap.sh
+  '';
+
+  configureFlags = [
+    "--enable-all"
+    "--enable-openmp"
+    "--enable-portable-binary"
+  ];
+
+  env.NIX_CFLAGS_COMPILE = "-Wno-error=incompatible-pointer-types";
+
+  enableParalleBuilding = true;
+
+  buildInputs = lib.optionals stdenv.cc.isClang [ llvmPackages.openmp ];
+
+  propagatedBuildInputs = [ fftw ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Nonequispaced fast Fourier transform";
+    homepage = "https://www-user.tu-chemnitz.de/~potts/nfft/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ hmenke ];
+  };
+})

pkgs/by-name/nf/nflz/package.nix

@@ -0,0 +1,36 @@
+{
+  fetchCrate,
+  lib,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "nflz";
+  version = "1.0.2";
+
+  src = fetchCrate {
+    inherit pname version;
+    hash = "sha256-c9+79zrIU/M1Rh+DiaLJzbrNSa4IKrYk1gP0dsabUiw=";
+  };
+
+  cargoHash = "sha256-aw3p0Lr/gWC1yDpVCXVibj4eU7ZFCQDy8kHtE6d6Yjg=";
+
+  # Tests do not work in the package published on crates.io, since the folder
+  # with test resources is not packaged.
+  doCheck = false;
+
+  meta = {
+    description = "Numbered Files Leading Zeros helps you to manage ascending numbered file names";
+    longDescription = ''
+      CLI to add leading zeros to ascending numbered file names.
+      NFLZ stands for Numbered Files Leading Zeros.
+
+      This library helps you to manage files inside your file system that
+      belong to a set of ordered files. An example are photos from a camera.
+    '';
+    homepage = "https://github.com/phip1611/nflz";
+    license = with lib.licenses; [ mit ];
+    maintainers = with lib.maintainers; [ phip1611 ];
+    mainProgram = "nflz";
+  };
+}

pkgs/by-name/nf/nfpm/package.nix

@@ -0,0 +1,55 @@
+{
+  stdenv,
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  buildPackages,
+}:
+
+buildGoModule rec {
+  pname = "nfpm";
+  version = "2.43.2";
+
+  src = fetchFromGitHub {
+    owner = "goreleaser";
+    repo = "nfpm";
+    rev = "v${version}";
+    hash = "sha256-RHYGVSR/hMekaNoIxBP2zw3RZi/SSj4RlSMJNvgbigw=";
+  };
+
+  vendorHash = "sha256-7OhiaB0PpwvFj+yLyoN0+/qpF+p/c/Vw+7Tn2XVYYjg=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version}"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall =
+    let
+      emulator = stdenv.hostPlatform.emulator buildPackages;
+    in
+    ''
+      ${emulator} $out/bin/nfpm man > nfpm.1
+      installManPage ./nfpm.1
+      installShellCompletion --cmd nfpm \
+        --bash <(${emulator} $out/bin/nfpm completion bash) \
+        --fish <(${emulator} $out/bin/nfpm completion fish) \
+        --zsh  <(${emulator} $out/bin/nfpm completion zsh)
+    '';
+
+  meta = {
+    description = "Simple deb and rpm packager written in Go";
+    homepage = "https://github.com/goreleaser/nfpm";
+    changelog = "https://github.com/goreleaser/nfpm/releases/tag/v${version}";
+    maintainers = with lib.maintainers; [
+      techknowlogick
+      caarlos0
+    ];
+    license = with lib.licenses; [ mit ];
+    mainProgram = "nfpm";
+  };
+}

pkgs/by-name/nf/nfs-ganesha/allow-bypassing-dbus-pkg-config-test.patch

@@ -0,0 +1,44 @@
+diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
+index 73276dff6..94027f5cb 100644
+--- a/src/CMakeLists.txt
++++ b/src/CMakeLists.txt
+@@ -974,21 +974,27 @@ endif(USE_EFENCE)
+
+ gopt_test(USE_DBUS)
+ if(USE_DBUS)
+-  find_package(PkgConfig)
+-  # pkg_check_modules doesn't fatal error on REQUIRED, so handle it ourselves
+-  pkg_check_modules(DBUS ${USE_DBUS_REQUIRED} dbus-1)
+-  if(NOT DBUS_FOUND)
+-    if(USE_DBUS_REQUIRED)
+-      message(FATAL_ERROR "Cannot find DBUS libs but requested on command line")
+-    else(USE_DBUS_REQUIRED)
+-      message(WARNING "Cannot find DBUS libs. Disabling DBUS support")
+-      set(USE_DBUS OFF)
+-    endif(USE_DBUS_REQUIRED)
+-  else(NOT DBUS_FOUND)
++  if(DBUS_NO_PKGCONFIG)
+     set(SYSTEM_LIBRARIES ${DBUS_LIBRARIES} ${SYSTEM_LIBRARIES})
+     LIST(APPEND CMAKE_LIBRARY_PATH ${DBUS_LIBRARY_DIRS})
+     link_directories (${DBUS_LIBRARY_DIRS})
+-  endif(NOT DBUS_FOUND)
++  else(DBUS_NO_PKGCONFIG)
++    find_package(PkgConfig)
++    # pkg_check_modules doesn't fatal error on REQUIRED, so handle it ourselves
++    pkg_check_modules(DBUS ${USE_DBUS_REQUIRED} dbus-1)
++    if(NOT DBUS_FOUND)
++      if(USE_DBUS_REQUIRED)
++        message(FATAL_ERROR "Cannot find DBUS libs but requested on command line")
++      else(USE_DBUS_REQUIRED)
++        message(WARNING "Cannot find DBUS libs. Disabling DBUS support")
++        set(USE_DBUS OFF)
++      endif(USE_DBUS_REQUIRED)
++    else(NOT DBUS_FOUND)
++      set(SYSTEM_LIBRARIES ${DBUS_LIBRARIES} ${SYSTEM_LIBRARIES})
++      LIST(APPEND CMAKE_LIBRARY_PATH ${DBUS_LIBRARY_DIRS})
++      link_directories (${DBUS_LIBRARY_DIRS})
++    endif(NOT DBUS_FOUND)
++  endif(DBUS_NO_PKGCONFIG)
+ endif(USE_DBUS)
+
+ if(USE_CB_SIMULATOR AND NOT USE_DBUS)

pkgs/by-name/nf/nfs-ganesha/package.nix

@@ -0,0 +1,124 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  sphinx,
+  krb5,
+  xfsprogs,
+  jemalloc,
+  libcap,
+  ntirpc,
+  liburcu,
+  bison,
+  flex,
+  nfs-utils,
+  acl,
+  useCeph ? false,
+  ceph,
+  useDbus ? true,
+  dbus,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "nfs-ganesha";
+  version = "6.5";
+
+  outputs = [
+    "out"
+    "man"
+    "tools"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "nfs-ganesha";
+    repo = "nfs-ganesha";
+    rev = "V${version}";
+    hash = "sha256-OHGmEzHu8y/TPQ70E2sicaLtNgvlf/bRq8JRs6S1tpY=";
+  };
+
+  patches = lib.optional useDbus ./allow-bypassing-dbus-pkg-config-test.patch;
+
+  preConfigure = "cd src";
+
+  cmakeFlags = [
+    "-DUSE_SYSTEM_NTIRPC=ON"
+    "-DSYSSTATEDIR=/var"
+    "-DENABLE_VFS_POSIX_ACL=ON"
+    "-DUSE_ACL_MAPPING=ON"
+    "-DCMAKE_BUILD_WITH_INSTALL_RPATH=ON"
+    "-DUSE_MAN_PAGE=ON"
+  ]
+  ++ lib.optionals useCeph [
+    "-DUSE_RADOS_RECOV=ON"
+    "-DRADOS_URLS=ON"
+    "-DUSE_FSAL_CEPH=ON"
+    "-DUSE_FSAL_RGW=ON"
+  ]
+  ++ lib.optionals useDbus [
+    "-DUSE_DBUS=ON"
+    "-DDBUS_NO_PKGCONFIG=ON"
+    "-DDBUS_LIBRARY_DIRS=${lib.getLib dbus}/lib"
+    "-DDBUS_INCLUDE_DIRS=${lib.getDev dbus}/include/dbus-1.0\\;${lib.getLib dbus}/lib/dbus-1.0/include"
+    "-DDBUS_LIBRARIES=dbus-1"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    bison
+    flex
+    sphinx
+  ]
+  ++ lib.optional useDbus dbus;
+
+  buildInputs = [
+    acl
+    krb5
+    xfsprogs
+    jemalloc
+    dbus.lib
+    libcap
+    ntirpc
+    liburcu
+    nfs-utils
+  ]
+  ++ lib.optional useCeph ceph;
+
+  postPatch = ''
+    substituteInPlace src/tools/mount.9P --replace "/bin/mount" "/usr/bin/env mount"
+  '';
+
+  postFixup = ''
+    patchelf --add-rpath $out/lib $out/bin/ganesha.nfsd
+    patchelf --add-rpath $out/lib $out/lib/libganesha_nfsd.so
+  ''
+  + lib.optionalString useCeph ''
+    patchelf --add-rpath $out/lib $out/bin/ganesha-rados-grace
+    patchelf --add-rpath $out/lib $out/lib/libganesha_rados_recov.so
+    patchelf --add-rpath $out/lib $out/lib/libganesha_rados_urls.so
+  '';
+
+  postInstall = ''
+    install -Dm755 $src/src/tools/mount.9P $tools/bin/mount.9P
+  ''
+  + lib.optionalString useDbus ''
+    # Policy for D-Bus statistics interface
+    install -Dm644 $src/src/scripts/ganeshactl/org.ganesha.nfsd.conf $out/etc/dbus-1/system.d/org.ganesha.nfsd.conf
+  '';
+
+  meta = with lib; {
+    description = "NFS server that runs in user space";
+    homepage = "https://github.com/nfs-ganesha/nfs-ganesha/wiki";
+    maintainers = [ maintainers.markuskowa ];
+    platforms = platforms.linux;
+    license = licenses.lgpl3Plus;
+    mainProgram = "ganesha.nfsd";
+    outputsToInstall = [
+      "out"
+      "man"
+      "tools"
+    ];
+  };
+}

pkgs/by-name/nf/nfs-utils/package.nix

@@ -0,0 +1,200 @@
+{
+  stdenv,
+  fetchurl,
+  fetchpatch,
+  lib,
+  pkg-config,
+  util-linux,
+  libcap,
+  libtirpc,
+  libevent,
+  sqlite,
+  libkrb5,
+  kmod,
+  libuuid,
+  keyutils,
+  lvm2,
+  systemd,
+  coreutils,
+  tcp_wrappers,
+  python3,
+  buildPackages,
+  nixosTests,
+  rpcsvc-proto,
+  openldap,
+  cyrus_sasl,
+  libxml2,
+  udevCheckHook,
+  enablePython ? true,
+  enableLdap ? true,
+}:
+
+let
+  statdPath = lib.makeBinPath [
+    systemd
+    util-linux
+    coreutils
+  ];
+in
+
+stdenv.mkDerivation rec {
+  pname = "nfs-utils";
+  version = "2.7.1";
+
+  src = fetchurl {
+    url = "mirror://kernel/linux/utils/nfs-utils/${version}/${pname}-${version}.tar.xz";
+    hash = "sha256-iFyUioSli8pBSPRZWI+ac2nbtA3MRm8E5FXGsQ/Qqkg=";
+  };
+
+  # libnfsidmap is built together with nfs-utils from the same source,
+  # put it in the "lib" output, and the headers in "dev"
+  outputs = [
+    "out"
+    "dev"
+    "lib"
+    "man"
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    buildPackages.stdenv.cc
+    rpcsvc-proto
+    udevCheckHook
+  ];
+
+  buildInputs = [
+    libtirpc
+    libcap
+    libevent
+    sqlite
+    lvm2
+    libuuid
+    keyutils
+    libkrb5
+    tcp_wrappers
+    libxml2
+  ]
+  ++ lib.optional enablePython python3
+  ++ lib.optionals enableLdap [
+    openldap
+    cyrus_sasl
+  ];
+
+  enableParallelBuilding = true;
+
+  preConfigure = ''
+    substituteInPlace configure \
+      --replace '$dir/include/gssapi' ${lib.getDev libkrb5}/include/gssapi \
+      --replace '$dir/bin/krb5-config' ${lib.getDev libkrb5}/bin/krb5-config
+  '';
+
+  configureFlags = [
+    "--with-start-statd=${placeholder "out"}/bin/start-statd"
+    "--enable-gss"
+    "--enable-svcgss"
+    "--with-statedir=/var/lib/nfs"
+    "--with-krb5=${lib.getLib libkrb5}"
+    "--with-systemd=${placeholder "out"}/etc/systemd/system"
+    "--enable-libmount-mount"
+    "--with-pluginpath=${placeholder "lib"}/lib/libnfsidmap" # this installs libnfsidmap
+    "--with-rpcgen=${buildPackages.rpcsvc-proto}/bin/rpcgen"
+    "--with-modprobedir=${placeholder "out"}/etc/modprobe.d"
+  ]
+  ++ lib.optional enableLdap "--enable-ldap";
+
+  patches = lib.optionals stdenv.hostPlatform.isMusl [
+    # http://openwall.com/lists/musl/2015/08/18/10
+    (fetchpatch {
+      url = "https://raw.githubusercontent.com/alpinelinux/aports/cb880042d48d77af412d4688f24b8310ae44f55f/main/nfs-utils/musl-getservbyport.patch";
+      sha256 = "1fqws9dz8n1d9a418c54r11y3w330qgy2652dpwcy96cm44sqyhf";
+    })
+    (fetchpatch {
+      url = "https://raw.githubusercontent.com/void-linux/void-packages/bb636cdb1b274f44d92b1cb2fdf0dff6079f97aa/srcpkgs/nfs-utils/patches/nfs-utils-2.7.1-define_macros_for_musl.patch";
+      hash = "sha256-wsyioRjzs1PObMHwYgf5h/Ngv+s5MPsroAuUNGs9lR0=";
+    })
+    (fetchpatch {
+      url = "https://raw.githubusercontent.com/void-linux/void-packages/bb636cdb1b274f44d92b1cb2fdf0dff6079f97aa/srcpkgs/nfs-utils/patches/musl-svcgssd-sysconf.patch";
+      hash = "sha256-3TXgqswxlhFqXRPcjwo4MdqlTYl+dWVaa0E5r9Mnw18=";
+    })
+    (fetchpatch {
+      url = "https://raw.githubusercontent.com/void-linux/void-packages/bb636cdb1b274f44d92b1cb2fdf0dff6079f97aa/srcpkgs/nfs-utils/patches/musl-fix_long_unsigned_int.patch";
+      hash = "sha256-rS6sqqoGLIaPVq04+QiqP4qa88i1z4ZZCssM5k/XQ68=";
+    })
+  ];
+
+  postPatch = ''
+    patchShebangs tests
+    sed -i "s,/usr/sbin,$out/bin,g" utils/statd/statd.c
+    sed -i "s,^PATH=.*,PATH=$out/bin:${statdPath}," utils/statd/start-statd
+
+    substituteInPlace systemd/nfs-utils.service \
+      --replace "/bin/true" "${coreutils}/bin/true"
+
+    substituteInPlace tools/nfsrahead/Makefile.in systemd/Makefile.in \
+      --replace "/usr/lib/udev/rules.d/" "$out/lib/udev/rules.d/"
+
+    substituteInPlace utils/mount/Makefile.in \
+      --replace "chmod 4511" "chmod 0511"
+
+    sed '1i#include <stdint.h>' -i support/nsm/rpc.c
+  '';
+
+  makeFlags = [
+    "sbindir=$(out)/bin"
+    "generator_dir=$(out)/etc/systemd/system-generators"
+  ];
+
+  doInstallCheck = true;
+
+  installFlags = [
+    "statedir=$(TMPDIR)"
+    "statdpath=$(TMPDIR)"
+  ];
+
+  stripDebugList = [
+    "lib"
+    "libexec"
+    "bin"
+    "etc/systemd/system-generators"
+  ];
+
+  postInstall = ''
+    # Not used on NixOS
+    sed -i \
+      -e "s,/sbin/modprobe,${kmod}/bin/modprobe,g" \
+      -e "s,/usr/sbin,$out/bin,g" \
+      $out/etc/systemd/system/*
+  ''
+  + lib.optionalString (!enablePython) ''
+    # Remove all scripts that require python (currently mountstats and nfsiostat)
+    grep -l /usr/bin/python $out/bin/* | xargs -I {} rm -v {}
+  '';
+
+  # One test fails on mips.
+  # doCheck = !stdenv.hostPlatform.isMips;
+  # https://bugzilla.kernel.org/show_bug.cgi?id=203793
+  doCheck = false;
+
+  disallowedReferences = [ (lib.getDev libkrb5) ];
+
+  passthru.tests = {
+    nfs3-simple = nixosTests.nfs3.simple;
+    nfs4-simple = nixosTests.nfs4.simple;
+    nfs4-kerberos = nixosTests.nfs4.kerberos;
+  };
+
+  meta = with lib; {
+    description = "Linux user-space NFS utilities";
+
+    longDescription = ''
+      This package contains various Linux user-space Network File
+      System (NFS) utilities, including RPC `mount' and `nfs'
+      daemons.
+    '';
+
+    homepage = "https://linux-nfs.org/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/nf/nftrace/package.nix

@@ -0,0 +1,39 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  versionCheckHook,
+}:
+
+buildGoModule rec {
+  pname = "nftrace";
+  version = "0.1.0";
+
+  src = fetchFromGitHub {
+    owner = "aojea";
+    repo = "nftrace";
+    tag = "v${version}";
+    hash = "sha256-MTLl3XLDIjcK5GymW7D3B8+/A6W+kQ4cz5bbrfo6fQc=";
+  };
+
+  vendorHash = "sha256-UrsvUMdLWGX2QRFLxBLvMW1B5vZdcWI/lpyKiNAtA2o=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Commodity tool to use nftables trace functionality";
+    homepage = "https://github.com/aojea/nftrace";
+    changelog = "https://github.com/aojea/nftrace/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.jmbaur ];
+    mainProgram = "nftrace";
+  };
+}