push sheeet

pkgs/by-name/nn/nn/package.nix

@@ -0,0 +1,29 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  unstableGitUpdater,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  name = "nn";
+  version = "2.0.8-unstable-2024-04-08";
+
+  src = fetchFromGitHub {
+    owner = "sakov";
+    repo = "nn-c";
+    rev = "f8e880b6ae39ff4bb4d617f61db5f92311bd04b6";
+    hash = "sha256-SzkLxR5ZkIlCoMlN18+uc1/xYWhHhXMdd2PpA1jvnFI=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/nn";
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = with lib; {
+    description = "C code for Natural Neighbours interpolation of 2D scattered data";
+    homepage = "https://github.com/sakov/nn-c/";
+    platforms = platforms.unix;
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ mkez ];
+  };
+})

pkgs/by-name/nn/nncp/package.nix

@@ -0,0 +1,84 @@
+{
+  cfgPath ? "/etc/nncp.hjson",
+  curl,
+  fetchurl,
+  lib,
+  genericUpdater,
+  go,
+  perl,
+  stdenv,
+  writeShellScript,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nncp";
+  version = "8.12.1";
+  outputs = [
+    "out"
+    "doc"
+    "info"
+  ];
+
+  src = fetchurl {
+    url = "http://www.nncpgo.org/download/nncp-${finalAttrs.version}.tar.xz";
+    hash = "sha256-yTwndQ43aBCned7iKPZm70zCC3zMapf2GXtornjiZos=";
+  };
+
+  nativeBuildInputs = [
+    go
+  ];
+
+  # Build parameters
+  CFGPATH = cfgPath;
+  SENDMAIL = "sendmail";
+
+  preConfigure = "export GOCACHE=$NIX_BUILD_TOP/gocache";
+
+  buildPhase = ''
+    runHook preBuild
+    ./build
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    PREFIX=$out ./install
+    runHook postInstall
+  '';
+
+  enableParallelBuilding = true;
+
+  passthru.updateScript = genericUpdater {
+    versionLister = writeShellScript "nncp-versionLister" ''
+      ${curl}/bin/curl -s ${finalAttrs.meta.downloadPage} | ${perl}/bin/perl -lne 'print $1 if /Release.*>([0-9.]+)</'
+    '';
+  };
+
+  meta = {
+    broken = stdenv.hostPlatform.isDarwin;
+    changelog = "http://www.nncpgo.org/News.html";
+    description = "Secure UUCP-like store-and-forward exchanging";
+    downloadPage = "http://www.nncpgo.org/Tarballs.html";
+    homepage = "http://www.nncpgo.org/";
+    license = lib.licenses.gpl3Only;
+    longDescription = ''
+      This utilities are intended to help build up small size (dozens of
+      nodes) ad-hoc friend-to-friend (F2F) statically routed darknet
+      delay-tolerant networks for fire-and-forget secure reliable files,
+      file requests, Internet mail and commands transmission. All
+      packets are integrity checked, end-to-end encrypted, explicitly
+      authenticated by known participants public keys. Onion encryption
+      is applied to relayed packets. Each node acts both as a client and
+      server, can use push and poll behaviour model.
+
+      Out-of-box offline sneakernet/floppynet, dead drops, sequential
+      and append-only CD-ROM/tape storages, air-gapped computers
+      support. But online TCP daemon with full-duplex resumable data
+      transmission exists.
+    '';
+    maintainers = with lib.maintainers; [
+      woffs
+    ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/nn/nnd/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  fetchFromGitHub,
+  pkgsCross,
+}:
+let
+  inherit (pkgsCross.musl64) rustPlatform;
+in
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "nnd";
+  version = "0.50";
+
+  src = fetchFromGitHub {
+    owner = "al13n321";
+    repo = "nnd";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-PxSiAjciRHhRd0UHlRh7ondvYk9ytTSruO7f7CIYA6w=";
+  };
+
+  cargoHash = "sha256-zTQlqtg1pdLGnAOvl5hN9mKf3bg7jnjrVJYmRgSzcNw=";
+
+  meta = {
+    description = "Debugger for Linux";
+    homepage = "https://github.com/al13n321/nnd/tree/main";
+    license = lib.licenses.asl20;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with lib.maintainers; [ sinjin2300 ];
+    mainProgram = "nnd";
+  };
+})

pkgs/by-name/nn/nng/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+  mbedtlsSupport ? true,
+  mbedtls,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "nng";
+  version = "1.11";
+
+  src = fetchFromGitHub {
+    owner = "nanomsg";
+    repo = "nng";
+    rev = "v${version}";
+    hash = "sha256-yH/iK/DuVff2qby/wk6jJ9Tsmxrl9eMrb9bOxCzvmdA=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+  ]
+  ++ lib.optionals mbedtlsSupport [ mbedtls ];
+
+  buildInputs = lib.optionals mbedtlsSupport [ mbedtls ];
+
+  cmakeFlags = [
+    "-G Ninja"
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
+  ]
+  ++ lib.optionals mbedtlsSupport [
+    "-DMBEDTLS_ROOT_DIR=${mbedtls}"
+    "-DNNG_ENABLE_TLS=ON"
+  ];
+
+  meta = with lib; {
+    homepage = "https://nng.nanomsg.org/";
+    description = "Nanomsg next generation";
+    license = licenses.mit;
+    mainProgram = "nngcat";
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ nviets ];
+  };
+}

pkgs/by-name/nn/nnn/darwin-fix-file-mime-opts.patch

@@ -0,0 +1,15 @@
+diff --git a/src/nnn.c b/src/nnn.c
+index b3c0f986..c74e1ec9 100644
+--- a/src/nnn.c
++++ b/src/nnn.c
+@@ -508,9 +508,7 @@ alignas(max_align_t) static char g_pipepath[TMP_LEN_MAX];
+ static runstate g_state;
+ 
+ /* Options to identify file MIME */
+-#if defined(__APPLE__)
+-#define FILE_MIME_OPTS "-bIL"
+-#elif !defined(__sun) /* no MIME option for 'file' */
++#if !defined(__sun) /* no MIME option for 'file' */
+ #define FILE_MIME_OPTS "-biL"
+ #endif
+ 

pkgs/by-name/nn/nnn/package.nix

@@ -0,0 +1,105 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  installShellFiles,
+  makeWrapper,
+  pkg-config,
+  file,
+  ncurses,
+  readline,
+  which,
+  musl-fts,
+  pcre,
+  gnused,
+  # options
+  conf ? null,
+  withIcons ? false,
+  withNerdIcons ? false,
+  withEmojis ? false,
+  withPcre ? false,
+  extraMakeFlags ? [ ],
+}:
+
+# Mutually exclusive options
+assert withIcons -> (!withNerdIcons && !withEmojis);
+assert withNerdIcons -> (!withIcons && !withEmojis);
+assert withEmojis -> (!withIcons && !withNerdIcons);
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nnn";
+  version = "5.1";
+
+  src = fetchFromGitHub {
+    owner = "jarun";
+    repo = "nnn";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-+2lFFBtaqRPBkEspCFtKl9fllbSR5MBB+4ks3Xh7vp4=";
+  };
+
+  patches = [
+    # Nix-specific: ensure nnn passes correct arguments to the Nix file command on Darwin.
+    # By default, nnn expects the macOS default file command, not the one provided by Nix.
+    # However, both commands use different arguments to obtain the MIME type.
+    ./darwin-fix-file-mime-opts.patch
+  ];
+
+  configFile = lib.optionalString (conf != null) (builtins.toFile "nnn.h" conf);
+  preBuild = lib.optionalString (conf != null) "cp ${finalAttrs.configFile} src/nnn.h";
+
+  nativeBuildInputs = [
+    installShellFiles
+    makeWrapper
+    pkg-config
+  ];
+  buildInputs = [
+    readline
+    ncurses
+  ]
+  ++ lib.optional stdenv.hostPlatform.isMusl musl-fts
+  ++ lib.optional withPcre pcre;
+
+  env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isMusl "-I${musl-fts}/include";
+  NIX_LDFLAGS = lib.optionalString stdenv.hostPlatform.isMusl "-lfts";
+
+  makeFlags = [
+    "PREFIX=$(out)"
+  ]
+  ++ lib.optionals withIcons [ "O_ICONS=1" ]
+  ++ lib.optionals withNerdIcons [ "O_NERD=1" ]
+  ++ lib.optionals withEmojis [ "O_EMOJI=1" ]
+  ++ lib.optionals withPcre [ "O_PCRE=1" ]
+  ++ extraMakeFlags;
+
+  binPath = lib.makeBinPath [
+    file
+    which
+    gnused
+  ];
+
+  installTargets = [
+    "install"
+    "install-desktop"
+  ];
+
+  postInstall = ''
+    installShellCompletion --bash --name nnn.bash misc/auto-completion/bash/nnn-completion.bash
+    installShellCompletion --fish misc/auto-completion/fish/nnn.fish
+    installShellCompletion --zsh misc/auto-completion/zsh/_nnn
+
+    cp -r plugins $out/share
+    cp -r misc/quitcd $out/share/quitcd
+
+    wrapProgram $out/bin/nnn --prefix PATH : "$binPath"
+  '';
+
+  meta = {
+    description = "Small ncurses-based file browser forked from noice";
+    homepage = "https://github.com/jarun/nnn";
+    changelog = "https://github.com/jarun/nnn/blob/v${finalAttrs.version}/CHANGELOG";
+    license = lib.licenses.bsd2;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ Br1ght0ne ];
+    mainProgram = "nnn";
+  };
+})

pkgs/by-name/nn/nnpdf/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  apfel,
+  gsl,
+  lhapdf,
+  libarchive,
+  yaml-cpp,
+  python3,
+  sqlite,
+  swig,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "nnpdf";
+  version = "4.0.9";
+
+  src = fetchFromGitHub {
+    owner = "NNPDF";
+    repo = "nnpdf";
+    rev = version;
+    hash = "sha256-PyhkHlOlzKfDxUX91NkeZWjdEzFR4PW0Yh5Yz6ZA27g=";
+  };
+
+  postPatch = ''
+    for file in CMakeLists.txt buildmaster/CMakeLists.txt; do
+      substituteInPlace $file \
+        --replace "-march=nocona -mtune=haswell" ""
+    done
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    apfel
+    gsl
+    lhapdf
+    libarchive
+    yaml-cpp
+    python3
+    python3.pkgs.numpy
+    sqlite
+    swig
+  ];
+
+  cmakeFlags = [
+    "-DCOMPILE_filter=ON"
+    "-DCOMPILE_evolvefit=ON"
+  ];
+
+  meta = with lib; {
+    description = "Open-source machine learning framework for global analyses of parton distributions";
+    mainProgram = "evolven3fit";
+    homepage = "https://docs.nnpdf.science/";
+    license = licenses.gpl3Only;
+    maintainers = [ maintainers.veprbl ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/nn/nntp-proxy/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libconfig,
+  pkg-config,
+  libevent,
+  openssl,
+  libxcrypt,
+}:
+
+stdenv.mkDerivation {
+  pname = "nntp-proxy";
+  version = "2014-01-06";
+
+  src = fetchFromGitHub {
+    owner = "nieluj";
+    repo = "nntp-proxy";
+    rev = "0358e7ad6c4676f90ac5074320b16e1461b0011a";
+    sha256 = "0jwxh71am83fbnq9mn06jl06rq8qybm506js79xmmc3xbk5pqvy4";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    libconfig
+    libevent
+    openssl
+    libxcrypt
+  ];
+
+  installFlags = [ "INSTALL_DIR=$(out)/bin/" ];
+
+  prePatch = ''
+    mkdir -p $out/bin
+    substituteInPlace Makefile \
+      --replace /usr/bin/install $(type -P install) \
+      --replace gcc cc
+  '';
+
+  meta = {
+    description = "Simple NNTP proxy with SSL support";
+    homepage = "https://github.com/nieluj/nntp-proxy";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ lib.maintainers.fadenb ];
+    platforms = lib.platforms.all;
+    mainProgram = "nntp-proxy";
+  };
+}