push sheeet

pkgs/by-name/oa/oak/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "oak";
+  version = "0.3";
+
+  src = fetchFromGitHub {
+    owner = "thesephist";
+    repo = "oak";
+    rev = "v${version}";
+    sha256 = "sha256-DK5n8xK57CQiukyBt9+CFK1j8+nphP//T2jTXq64VH8=";
+  };
+
+  vendorHash = "sha256-iQtb3zNa57nB6x4InVPw7FCmW7XPw5yuz0OcfASXPD8=";
+
+  meta = with lib; {
+    description = "Expressive, simple, dynamic programming language";
+    mainProgram = "oak";
+    homepage = "https://oaklang.org/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ tejasag ];
+  };
+}

pkgs/by-name/oa/oakctl/package.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libgcc,
+  autoPatchelfHook,
+  testers,
+  oakctl,
+}:
+
+let
+  version = "0.13.2";
+
+  # Note: Extracted from install script
+  # https://oakctl-releases.luxonis.com/oakctl-installer.sh
+  sources = {
+    x86_64-linux = fetchurl {
+      url = "https://oakctl-releases.luxonis.com/data/${version}/linux_x86_64/oakctl";
+      hash = "sha256-uS7CUnj9+/kBwGaaZA9P6R2//vhZ1cJW+lhkQePZ0is=";
+    };
+    aarch64-linux = fetchurl {
+      url = "https://oakctl-releases.luxonis.com/data/${version}/linux_aarch64/oakctl";
+      hash = "sha256-+WFSV3TALeJtdcxkcduaN8tWGLCrOxvs3UV6cOr1xAI=";
+    };
+    aarch64-darwin = fetchurl {
+      url = "https://oakctl-releases.luxonis.com/data/${version}/darwin_arm64/oakctl";
+      hash = "sha256-OgVmfYcRNVcLGjEbxdVUtsV45vICj+jKPQJ578aRwZs=";
+    };
+    x86_64-darwin = fetchurl {
+      url = "https://oakctl-releases.luxonis.com/data/${version}/darwin_x86_64/oakctl";
+      hash = "sha256-KjJxwMRLs0XqiOTHjke+dSVKBftwBDYppjrqsbf0Qe8=";
+    };
+  };
+
+  src =
+    sources.${stdenv.hostPlatform.system}
+      or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "oakctl";
+  inherit version src;
+
+  dontUnpack = true;
+  dontConfigure = true;
+  dontBuild = true;
+
+  passthru.tests.version = testers.testVersion {
+    command = "HOME=$TMPDIR oakctl version";
+    package = oakctl;
+  };
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [ autoPatchelfHook ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
+    libgcc
+    stdenv.cc.cc.lib
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    install -D -m 0755 $src $out/bin/oakctl
+
+    runHook postInstall
+  '';
+
+  # Note: The command 'oakctl self-update' won't work as the binary is located in the nix/store
+  meta = {
+    description = "Tool to interact with Luxonis OAK4 cameras";
+    homepage = "https://docs.luxonis.com/software-v3/oak-apps/oakctl/";
+    license = lib.licenses.unfree;
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "x86_64-darwin"
+      "aarch64-darwin"
+    ];
+    mainProgram = "oakctl";
+    maintainers = with lib.maintainers; [ phodina ];
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+})

pkgs/by-name/oa/oam-tools/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "oam-tools";
+  version = "0.1.2";
+
+  src = fetchFromGitHub {
+    owner = "owasp-amass";
+    repo = "oam-tools";
+    tag = "v${version}";
+    hash = "sha256-vt4V8em8Iaz3BVKIqlcAv+VIpJtD58xb3QrkIr4tYuU=";
+  };
+
+  vendorHash = "sha256-yFKYZlA06yE48Wiz0cKgD57JEREwYyYkLM1NZPV8+Xc=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  meta = with lib; {
+    description = "Analysis and management tools for an Open Asset Model database";
+    homepage = "https://github.com/owasp-amass/oam-tools";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ fab ];
+  };
+}

pkgs/by-name/oa/oama/generated-package.nix

@@ -0,0 +1,106 @@
+# This file has been autogenerate with cabal2nix.
+# Update via ./update.sh
+{
+  mkDerivation,
+  aeson,
+  base,
+  base64-bytestring,
+  bytestring,
+  containers,
+  cryptohash-sha256,
+  directory,
+  fetchgit,
+  hsyslog,
+  http-conduit,
+  http-types,
+  lib,
+  mtl,
+  network,
+  network-uri,
+  optparse-applicative,
+  pretty-simple,
+  process,
+  random,
+  streaming-commons,
+  string-qq,
+  strings,
+  text,
+  time,
+  twain,
+  unix,
+  utf8-string,
+  warp,
+  yaml,
+}:
+mkDerivation {
+  pname = "oama";
+  version = "0.20.2";
+  src = fetchgit {
+    url = "https://github.com/pdobsan/oama.git";
+    sha256 = "1zr2a77b3azdqyk6hzchhg573gwwb5h0d7x382srggm25lp3isk9";
+    rev = "bbe5a6d9f87659c8a24b6515694acf1b522a396b";
+    fetchSubmodules = true;
+  };
+  isLibrary = true;
+  isExecutable = true;
+  libraryHaskellDepends = [
+    aeson
+    base
+    base64-bytestring
+    bytestring
+    containers
+    cryptohash-sha256
+    directory
+    hsyslog
+    http-conduit
+    http-types
+    mtl
+    network
+    network-uri
+    optparse-applicative
+    pretty-simple
+    process
+    random
+    streaming-commons
+    string-qq
+    strings
+    text
+    time
+    twain
+    unix
+    utf8-string
+    warp
+    yaml
+  ];
+  executableHaskellDepends = [
+    aeson
+    base
+    base64-bytestring
+    bytestring
+    containers
+    cryptohash-sha256
+    directory
+    hsyslog
+    http-conduit
+    http-types
+    mtl
+    network
+    network-uri
+    optparse-applicative
+    pretty-simple
+    process
+    random
+    streaming-commons
+    string-qq
+    strings
+    text
+    time
+    twain
+    unix
+    utf8-string
+    warp
+    yaml
+  ];
+  license = lib.licenses.bsd3;
+  mainProgram = "oama";
+}

pkgs/by-name/oa/oama/package.nix

@@ -0,0 +1,48 @@
+{
+  haskell,
+  lib,
+  stdenv,
+  coreutils,
+  libsecret,
+  gnupg,
+  makeBinaryWrapper,
+  withLibsecret ? true, # default oama config uses libsecret
+  withGpg ? false,
+}:
+let
+  inherit (haskell.lib.compose) overrideCabal justStaticExecutables;
+
+  overrides = {
+    description = "OAuth credential MAnager";
+    homepage = "https://github.com/pdobsan/oama";
+    maintainers = with lib.maintainers; [ aidalgol ];
+
+    passthru.updateScript = ./update.sh;
+
+    buildDepends = [
+      makeBinaryWrapper
+    ];
+
+    postInstall = ''
+      wrapProgram $out/bin/oama \
+        --prefix PATH : ${
+          lib.makeBinPath (
+            [ coreutils ] ++ lib.optional withLibsecret libsecret ++ lib.optional withGpg gnupg
+          )
+        }
+    '';
+  };
+
+  raw-pkg = haskell.packages.ghc912.callPackage ./generated-package.nix { };
+in
+lib.pipe raw-pkg [
+  (overrideCabal overrides)
+  # FIXME: eliminate all erroneous references on aarch64-darwin manually,
+  # see https://github.com/NixOS/nixpkgs/issues/318013
+  (
+    if stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64 then
+      lib.id
+    else
+      justStaticExecutables
+  )
+]

pkgs/by-name/oa/oama/update.sh

@@ -0,0 +1,22 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p haskell.packages.ghc910.cabal2nix nix-prefetch-git curl jq
+
+set -euo pipefail
+
+# This is the directory of this update.sh script.
+script_dir="$( cd "$( dirname "${BASH_SOURCE[0]}" )" >/dev/null 2>&1 && pwd )"
+derivation_file="${script_dir}/generated-package.nix"
+latest_version="$(curl --silent https://api.github.com/repos/pdobsan/oama/releases/latest | jq --raw-output '.tag_name')"
+
+echo "Updating oama to version ${latest_version}."
+echo "Running cabal2nix and outputting to ${derivation_file}..."
+
+cat > "${derivation_file}" << EOF
+# This file has been autogenerate with cabal2nix.
+# Update via ./update.sh
+EOF
+
+cabal2nix --revision "${latest_version}" https://github.com/pdobsan/oama.git >> "${derivation_file}"
+nixfmt "${derivation_file}"
+
+echo "Finished."

pkgs/by-name/oa/oapi-codegen/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "oapi-codegen";
+  version = "2.5.0";
+
+  src = fetchFromGitHub {
+    owner = "deepmap";
+    repo = "oapi-codegen";
+    tag = "v${version}";
+    hash = "sha256-Z10rJMancQLefyW0wXWaODIKfSY+4b3T+TAro//xsAQ=";
+  };
+
+  vendorHash = "sha256-obpY7ZATebI/7bkPMidC83xnN60P0lZsJhSuKr2A5T4=";
+
+  # Tests use network
+  doCheck = false;
+
+  subPackages = [ "cmd/oapi-codegen" ];
+
+  ldflags = [ "-X main.noVCSVersionOverride=${version}" ];
+
+  meta = {
+    description = "Go client and server OpenAPI 3 generator";
+    homepage = "https://github.com/deepmap/oapi-codegen";
+    changelog = "https://github.com/deepmap/oapi-codegen/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ j4m3s ];
+    mainProgram = "oapi-codegen";
+  };
+}

pkgs/by-name/oa/oath-toolkit/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  nix-update-script,
+  pam,
+  xmlsec,
+}:
+
+let
+  # TODO: Switch to OpenPAM once https://gitlab.com/oath-toolkit/oath-toolkit/-/issues/26 is addressed upstream
+  securityDependency = if stdenv.hostPlatform.isDarwin then xmlsec else pam;
+
+in
+stdenv.mkDerivation rec {
+  pname = "oath-toolkit";
+  version = "2.6.13";
+
+  src = fetchurl {
+    url = "mirror://savannah/${pname}/${pname}-${version}.tar.gz";
+    hash = "sha256-W12C6aRFUgbST8vX7li/THk5ii5nmX2AvUWuknWGsYs=";
+  };
+
+  buildInputs = [ securityDependency ];
+
+  configureFlags = lib.optionals stdenv.hostPlatform.isDarwin [ "--disable-pam" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Components for building one-time password authentication systems";
+    homepage = "https://www.nongnu.org/oath-toolkit/";
+    maintainers = with maintainers; [ schnusch ];
+    platforms = with platforms; linux ++ darwin;
+    mainProgram = "oathtool";
+  };
+}

pkgs/by-name/oa/oathkeeper/package.nix

@@ -0,0 +1,46 @@
+{
+  fetchFromGitHub,
+  buildGoModule,
+  lib,
+}:
+let
+  pname = "oathkeeper";
+  version = "0.40.9";
+  commit = "c75695837f170334b526359f28967aa33d61bce6";
+in
+buildGoModule {
+  inherit pname version commit;
+
+  src = fetchFromGitHub {
+    owner = "ory";
+    repo = "oathkeeper";
+    rev = "v${version}";
+    hash = "sha256-R7xKhKF7mhS/vmSpOj+QDL0OBBWnh42X2Kr3TDQxVIo=";
+  };
+
+  vendorHash = "sha256-qETVUpxckZGa41Ll+SZTGcDlImsCvbvGQBcIwuIzSY8=";
+
+  tags = [
+    "sqlite"
+    "json1"
+    "hsm"
+  ];
+
+  subPackages = [ "." ];
+
+  # Pass versioning information via ldflags
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/ory/oathkeeper/internal/driver/config.Version=${version}"
+    "-X github.com/ory/oathkeeper/internal/driver/config.Commit=${commit}"
+  ];
+
+  meta = {
+    description = "Open-source identity and access proxy that authorizes HTTP requests based on sets of rules";
+    homepage = "https://www.ory.sh/oathkeeper/";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ camcalaquian ];
+    mainProgram = "oathkeeper";
+  };
+}

pkgs/by-name/oa/oatpp/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "oatpp";
+  version = "1.3.1";
+
+  src = fetchFromGitHub {
+    owner = "oatpp";
+    repo = "oatpp";
+    rev = version;
+    sha256 = "sha256-pTQ0DD4naE9m+6FfCVGg/i3WpNbtaR+38yyqjqN0uH0=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  # Tests fail on darwin. See https://github.com/NixOS/nixpkgs/pull/105419#issuecomment-735826894
+  doCheck = !stdenv.hostPlatform.isDarwin;
+
+  meta = with lib; {
+    homepage = "https://oatpp.io/";
+    description = "Light and powerful C++ web framework for highly scalable and resource-efficient web applications";
+    license = licenses.asl20;
+    maintainers = [ ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/oa/oauth2-proxy/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  versionCheckHook,
+}:
+
+buildGoModule rec {
+  pname = "oauth2-proxy";
+  version = "7.12.0";
+
+  src = fetchFromGitHub {
+    repo = "oauth2-proxy";
+    owner = "oauth2-proxy";
+    sha256 = "sha256-rUjdyGv7mua/bfcxbbQQXrXiJndK3HiyNyjLVnRbuG4=";
+    rev = "v${version}";
+  };
+
+  vendorHash = "sha256-6Asydomg4Xz0JciRnODJSqVBtFAmpfMjDnr1JKr222o=";
+
+  # Taken from https://github.com/oauth2-proxy/oauth2-proxy/blob/master/Makefile
+  ldflags = [ "-X github.com/oauth2-proxy/oauth2-proxy/v7/pkg/version.VERSION=v${version}" ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  meta = with lib; {
+    description = "Reverse proxy that provides authentication with Google, Github, or other providers";
+    homepage = "https://github.com/oauth2-proxy/oauth2-proxy/";
+    license = licenses.mit;
+    teams = [ teams.serokell ];
+    mainProgram = "oauth2-proxy";
+  };
+}

pkgs/by-name/oa/oauth2c/package.nix

@@ -0,0 +1,36 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "oauth2c";
+  version = "1.17.2";
+
+  src = fetchFromGitHub {
+    owner = "cloudentity";
+    repo = "oauth2c";
+    rev = "v${version}";
+    hash = "sha256-axCzPCYPn6T8AGqE92Yf/aVJ78Wl004Ts4YebSWYa6U=";
+  };
+
+  vendorHash = "sha256-ZQFIETfiNKyeZuskwNfoTXBy3MSWmG0tDztz0Mm7xJY=";
+
+  doCheck = false; # tests want to talk to oauth2c.us.authz.cloudentity.io
+
+  meta = with lib; {
+    homepage = "https://github.com/cloudentity/oauth2c";
+    description = "User-friendly OAuth2 CLI";
+    mainProgram = "oauth2c";
+    longDescription = ''
+      oauth2c is a command-line tool for interacting with OAuth 2.0
+      authorization servers. Its goal is to make it easy to fetch access tokens
+      using any grant type or client authentication method. It is compliant with
+      almost all basic and advanced OAuth 2.0, OIDC, OIDF FAPI and JWT profiles.
+    '';
+    license = licenses.asl20;
+    maintainers = [ maintainers.flokli ];
+    platforms = platforms.darwin ++ platforms.linux;
+  };
+}

pkgs/by-name/oa/oauth2l/package.nix

@@ -0,0 +1,39 @@
+{
+  stdenv,
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "oauth2l";
+  version = "1.3.3";
+
+  src = fetchFromGitHub {
+    owner = "google";
+    repo = "oauth2l";
+    rev = "v${version}";
+    hash = "sha256-jD8VFyAq6qcQhgvMmJj3D1xWGUvq3tMISbztLf1a72I=";
+  };
+
+  vendorHash = null;
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  # Fix tests by preventing them from writing to /homeless-shelter.
+  preCheck = "export HOME=$(mktemp -d)";
+
+  # tests fail on linux for some reason
+  doCheck = stdenv.hostPlatform.isDarwin;
+
+  meta = with lib; {
+    description = "Simple CLI for interacting with Google API authentication";
+    homepage = "https://github.com/google/oauth2l";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ happysalada ];
+    mainProgram = "oauth2l";
+  };
+}

pkgs/by-name/oa/oauth2ms/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  python3,
+}:
+
+stdenv.mkDerivation {
+  pname = "oauth2ms";
+  version = "2021-07-09";
+
+  src = fetchFromGitHub {
+    owner = "harishkrupo";
+    repo = "oauth2ms";
+    rev = "a1ef0cabfdea57e9309095954b90134604e21c08"; # No tags or releases in the repo
+    sha256 = "sha256-xPSWlHJAXhhj5I6UMjUtH1EZqCZWHJMFWTu3a4k1ETc";
+  };
+
+  buildInputs = [
+    (python3.withPackages (
+      ps: with ps; [
+        pyxdg
+        msal
+        python-gnupg
+      ]
+    ))
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    install -m755 -D oauth2ms $out/bin/oauth2ms
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/harishkrupo/oauth2ms";
+    description = "XOAUTH2 compatible Office365 token fetcher";
+    mainProgram = "oauth2ms";
+    platforms = platforms.all;
+    license = licenses.asl20;
+    maintainers = with maintainers; [ wentasah ];
+  };
+}