push sheeet

pkgs/by-name/oh/oh-my-fish/001-writable-omf-path.diff

@@ -0,0 +1,12 @@
+diff -Naur source/bin/install source-new/bin/install
+--- source/bin/install	1969-12-31 21:00:01.000000000 -0300
++++ source-new/bin/install	2023-11-23 12:48:55.695330320 -0300
+@@ -245,6 +245,8 @@
+   command cp -r "$OFFLINE_PATH" "$OMF_PATH"
+     or abort "Failed to copy source!"
+
++  chmod -R u+w "$OMF_PATH"
++
+   # Set up Git remotes only if the offline install is a Git repository.
+   test -d "$OMF_PATH/.git"
+     and set_git_remotes

pkgs/by-name/oh/oh-my-fish/omf-install

@@ -0,0 +1,6 @@
+#!@runtimeShell@
+
+@fish@/bin/fish \
+    @omf@/share/oh-my-fish/bin/install \
+    --noninteractive \
+    --offline=@omf@/share/oh-my-fish

pkgs/by-name/oh/oh-my-fish/package.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fish,
+  runtimeShell,
+  replaceVars,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "oh-my-fish";
+  version = "unstable-2022-03-27";
+
+  src = fetchFromGitHub {
+    owner = "oh-my-fish";
+    repo = "oh-my-fish";
+    rev = "d428b723c8c18fef3b2a00b8b8b731177f483ad8";
+    hash = "sha256-msItKEPe7uSUpDAfCfdYZjt5NyfM3KtOrLUTO9NGqlg=";
+  };
+
+  patches = [
+    ./001-writable-omf-path.diff
+  ];
+
+  buildInputs = [
+    fish
+  ];
+
+  strictDeps = true;
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -pv $out/bin $out/share/oh-my-fish
+    cp -vr * $out/share/oh-my-fish
+
+    cp -v ${
+      replaceVars ./omf-install {
+        inherit fish runtimeShell;
+        # replaced below
+        omf = null;
+      }
+    } $out/bin/omf-install
+
+    substituteInPlace $out/bin/omf-install \
+      --replace-fail '@omf@' "$out"
+
+    chmod +x $out/bin/omf-install
+    cat $out/bin/omf-install
+
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://github.com/oh-my-fish/oh-my-fish";
+    description = "Fish Shell Framework";
+    longDescription = ''
+      Oh My Fish provides core infrastructure to allow you to install packages
+      which extend or modify the look of your shell. It's fast, extensible and
+      easy to use.
+    '';
+    license = lib.licenses.mit;
+    maintainers = [ ];
+    mainProgram = "omf-install";
+    inherit (fish.meta) platforms;
+  };
+})
+# TODO: customize the omf-install script

pkgs/by-name/oh/oh-my-git/package.nix

@@ -0,0 +1,136 @@
+{
+  lib,
+  autoPatchelfHook,
+  copyDesktopItems,
+  fetchFromGitHub,
+  makeDesktopItem,
+  stdenv,
+  alsa-lib,
+  gcc-unwrapped,
+  git,
+  godot3-export-templates,
+  godot3-headless,
+  libGLU,
+  libX11,
+  libXcursor,
+  libXext,
+  libXfixes,
+  libXi,
+  libXinerama,
+  libXrandr,
+  libXrender,
+  libglvnd,
+  libpulseaudio,
+  perl,
+  zlib,
+  udev, # for libudev
+}:
+
+stdenv.mkDerivation rec {
+  pname = "oh-my-git";
+  version = "0.6.5";
+
+  src = fetchFromGitHub {
+    owner = "git-learning-game";
+    repo = "oh-my-git";
+    rev = version;
+    sha256 = "sha256-XqxliMVU55D5JSt7Yo5btvZnnTlagSukyhXv6Akgklo=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    copyDesktopItems
+    godot3-headless
+  ];
+
+  buildInputs = [
+    alsa-lib
+    gcc-unwrapped.lib
+    git
+    libGLU
+    libX11
+    libXcursor
+    libXext
+    libXfixes
+    libXi
+    libXinerama
+    libXrandr
+    libXrender
+    libglvnd
+    libpulseaudio
+    perl
+    zlib
+    udev
+  ];
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "oh-my-git";
+      exec = "oh-my-git";
+      icon = "oh-my-git";
+      desktopName = "oh-my-git";
+      comment = "An interactive Git learning game!";
+      genericName = "An interactive Git learning game!";
+      categories = [ "Game" ];
+    })
+  ];
+
+  # patch shebangs so that e.g. the fake-editor script works:
+  # error: /usr/bin/env 'perl': No such file or directory
+  # error: There was a problem with the editor
+  postPatch = ''
+    patchShebangs scripts
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    # Cannot create file '/homeless-shelter/.config/godot/projects/...'
+    export HOME=$TMPDIR
+
+    # Link the export-templates to the expected location. The --export commands
+    # expects the template-file at .../templates/3.2.3.stable/linux_x11_64_release
+    # with 3.2.3 being the version of godot.
+    mkdir -p $HOME/.local/share/godot
+    ln -s ${godot3-export-templates}/share/godot/templates $HOME/.local/share/godot
+
+    mkdir -p $out/share/oh-my-git
+    godot3-headless --export "Linux" $out/share/oh-my-git/oh-my-git
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    ln -s $out/share/oh-my-git/oh-my-git $out/bin
+
+    # Patch binaries.
+    interpreter=$(cat $NIX_CC/nix-support/dynamic-linker)
+    patchelf \
+      --set-interpreter $interpreter \
+      --set-rpath ${lib.makeLibraryPath buildInputs} \
+      $out/share/oh-my-git/oh-my-git
+
+    mkdir -p $out/share/pixmaps
+    cp images/oh-my-git.png $out/share/pixmaps/oh-my-git.png
+
+    runHook postInstall
+  '';
+
+  runtimeDependencies = map lib.getLib [
+    alsa-lib
+    libpulseaudio
+    udev
+  ];
+
+  meta = with lib; {
+    homepage = "https://ohmygit.org/";
+    description = "Interactive Git learning game";
+    mainProgram = "oh-my-git";
+    license = with licenses; [ blueOak100 ];
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ jojosch ];
+  };
+}

pkgs/by-name/oh/oh-my-posh/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+buildGoModule rec {
+  pname = "oh-my-posh";
+  version = "26.23.6";
+
+  src = fetchFromGitHub {
+    owner = "jandedobbeleer";
+    repo = "oh-my-posh";
+    tag = "v${version}";
+    hash = "sha256-4Po4QKPetRmTfmgq7lTK300h1Nn7spxNxRB9q58yrzo=";
+  };
+
+  vendorHash = "sha256-R1MNLBATbivhP27VfWLGNnZ8uJWzKhx4XhNILc7FCmE=";
+
+  sourceRoot = "${src.name}/src";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/jandedobbeleer/oh-my-posh/src/build.Version=${version}"
+    "-X github.com/jandedobbeleer/oh-my-posh/src/build.Date=1970-01-01T00:00:00Z"
+  ];
+
+  tags = [
+    "netgo"
+    "osusergo"
+    "static_build"
+  ];
+
+  postPatch = ''
+    # these tests requires internet access
+    rm cli/image/image_test.go config/migrate_glyphs_test.go cli/upgrade/notice_test.go segments/upgrade_test.go
+  '';
+
+  postInstall = ''
+    mv $out/bin/{src,oh-my-posh}
+    mkdir -p $out/share/oh-my-posh
+    cp -r $src/themes $out/share/oh-my-posh/
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Prompt theme engine for any shell";
+    mainProgram = "oh-my-posh";
+    homepage = "https://ohmyposh.dev";
+    changelog = "https://github.com/JanDeDobbeleer/oh-my-posh/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      lucperkins
+      urandom
+    ];
+  };
+}

pkgs/by-name/oh/oh-my-zsh/package.nix

@@ -0,0 +1,135 @@
+# This script was inspired by the ArchLinux User Repository package:
+#
+#   https://aur.archlinux.org/cgit/aur.git/tree/PKGBUILD?h=oh-my-zsh-git
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nixosTests,
+  writeScript,
+  common-updater-scripts,
+  git,
+  nix,
+  jq,
+  coreutils,
+  gnused,
+  curl,
+  cacert,
+  bash,
+}:
+
+stdenv.mkDerivation rec {
+  version = "2025-09-27";
+  pname = "oh-my-zsh";
+
+  src = fetchFromGitHub {
+    owner = "ohmyzsh";
+    repo = "ohmyzsh";
+    rev = "242e2faa51675494cbfa78a81f3ff47d81039863";
+    sha256 = "sha256-xYwo5/ONf5nRgfVSnEadPUkPDaOsJhk7doqRs4zp39E=";
+  };
+
+  strictDeps = true;
+  buildInputs = [ bash ];
+
+  installPhase = ''
+    runHook preInstall
+
+    outdir=$out/share/oh-my-zsh
+    template=templates/zshrc.zsh-template
+
+    mkdir -p $outdir
+    cp -r * $outdir
+    cd $outdir
+
+    rm LICENSE.txt
+    rm -rf .git*
+
+    chmod -R +w templates
+
+    # Change the path to oh-my-zsh dir and disable auto-updating.
+    sed -i -e "s#ZSH=\"\$HOME/.oh-my-zsh\"#ZSH=\"$outdir\"#" \
+           -e 's/\# \(DISABLE_AUTO_UPDATE="true"\)/\1/' \
+     $template
+
+    chmod +w oh-my-zsh.sh
+
+    # Both functions expect oh-my-zsh to be in ~/.oh-my-zsh and try to
+    # modify the directory.
+    cat >> oh-my-zsh.sh <<- EOF
+
+    # Undefine functions that don't work on Nix.
+    unfunction uninstall_oh_my_zsh
+    unfunction upgrade_oh_my_zsh
+    EOF
+
+    # Look for .zsh_variables, .zsh_aliases, and .zsh_funcs, and source
+    # them, if found.
+    cat >> $template <<- EOF
+
+    # Load the variables.
+    if [ -f ~/.zsh_variables ]; then
+        . ~/.zsh_variables
+    fi
+
+    # Load the functions.
+    if [ -f ~/.zsh_funcs ]; then
+      . ~/.zsh_funcs
+    fi
+
+    # Load the aliases.
+    if [ -f ~/.zsh_aliases ]; then
+        . ~/.zsh_aliases
+    fi
+    EOF
+
+    runHook postInstall
+  '';
+
+  passthru = {
+    tests = { inherit (nixosTests) oh-my-zsh; };
+
+    updateScript = writeScript "update.sh" ''
+      #!${stdenv.shell}
+      set -o errexit
+      PATH=${
+        lib.makeBinPath [
+          common-updater-scripts
+          curl
+          cacert
+          git
+          nix
+          jq
+          coreutils
+          gnused
+        ]
+      }
+
+      oldVersion="$(nix-instantiate --eval -E "with import ./. {}; lib.getVersion oh-my-zsh" | tr -d '"')"
+      latestSha="$(curl -L -s https://api.github.com/repos/ohmyzsh/ohmyzsh/commits\?sha\=master\&since\=$oldVersion | jq -r '.[0].sha')"
+
+      if [ ! "null" = "$latestSha" ]; then
+        latestDate="$(curl -L -s https://api.github.com/repos/ohmyzsh/ohmyzsh/commits/$latestSha | jq '.commit.committer.date' | sed 's|"\(.*\)T.*|\1|g')"
+        update-source-version oh-my-zsh "$latestDate" --rev="$latestSha"
+      else
+        echo "${pname} is already up-to-date"
+      fi
+    '';
+  };
+
+  meta = with lib; {
+    description = "Framework for managing your zsh configuration";
+    longDescription = ''
+      Oh My Zsh is a framework for managing your zsh configuration.
+
+      To copy the Oh My Zsh configuration file to your home directory, run
+      the following command:
+
+        $ cp -v $(nix-env -q --out-path oh-my-zsh | cut -d' ' -f3)/share/oh-my-zsh/templates/zshrc.zsh-template ~/.zshrc
+    '';
+    homepage = "https://ohmyz.sh/";
+    license = licenses.mit;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ nequissimus ];
+  };
+}

pkgs/by-name/oh/oh/package.nix

@@ -0,0 +1,30 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "oh";
+  version = "0.8.3";
+
+  src = fetchFromGitHub {
+    owner = "michaelmacinnis";
+    repo = "oh";
+    rev = "v${version}";
+    sha256 = "sha256-ryIh6MRIOVZPm2USpJC69Z/upIXGUHgcd17eZBA9Edc=";
+  };
+
+  vendorHash = "sha256-Qma5Vk0JO/tTrZanvTCE40LmjeCfBup3U3N7gyhfp44=";
+
+  meta = with lib; {
+    homepage = "https://github.com/michaelmacinnis/oh";
+    description = "New Unix shell";
+    mainProgram = "oh";
+    license = licenses.mit;
+  };
+
+  passthru = {
+    shellPath = "/bin/oh";
+  };
+}

pkgs/by-name/oh/oha/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  stdenv,
+  pkg-config,
+  openssl,
+  rust-jemalloc-sys,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "oha";
+  version = "1.10.0";
+
+  src = fetchFromGitHub {
+    owner = "hatoo";
+    repo = "oha";
+    tag = "v${version}";
+    hash = "sha256-xzzlW0oYjlvOItSTmMM5wBlPd7JcmLvpJ+Bf0cCh4ao=";
+  };
+
+  cargoHash = "sha256-k3NlPGtWyj8mTvH+FIasiwrf7JjyY2yKJVTHFjPnIEI=";
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [
+    pkg-config
+  ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
+    openssl
+    rust-jemalloc-sys
+  ];
+
+  # tests don't work inside the sandbox
+  doCheck = false;
+
+  meta = {
+    description = "HTTP load generator inspired by rakyll/hey with tui animation";
+    homepage = "https://github.com/hatoo/oha";
+    changelog = "https://github.com/hatoo/oha/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ figsoda ];
+    mainProgram = "oha";
+  };
+}