push sheeet

pkgs/by-name/oo/oo7-portal/package.nix

@@ -0,0 +1,42 @@
+{
+  cargo,
+  meson,
+  ninja,
+  oo7,
+  pkg-config,
+  rustPlatform,
+  rustc,
+  stdenv,
+  systemdLibs,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "oo7-portal";
+  inherit (oo7) version src cargoDeps;
+
+  sourceRoot = "${finalAttrs.src.name}/portal";
+  cargoRoot = "../";
+
+  nativeBuildInputs = [
+    pkg-config
+    meson
+    ninja
+    rustPlatform.cargoSetupHook
+    rustc
+    cargo
+  ];
+
+  buildInputs = [
+    systemdLibs
+  ];
+
+  meta = {
+    inherit (oo7.meta)
+      homepage
+      changelog
+      license
+      maintainers
+      platforms
+      ;
+    description = "${oo7.meta.description} (XDG Desktop Portal)";
+  };
+})

pkgs/by-name/oo/oo7-server/package.nix

@@ -0,0 +1,42 @@
+{
+  cargo,
+  meson,
+  ninja,
+  oo7,
+  pkg-config,
+  rustPlatform,
+  rustc,
+  stdenv,
+  systemdLibs,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "oo7-server";
+  inherit (oo7) version src cargoDeps;
+
+  sourceRoot = "${finalAttrs.src.name}/server";
+  cargoRoot = "../";
+
+  nativeBuildInputs = [
+    pkg-config
+    meson
+    ninja
+    rustPlatform.cargoSetupHook
+    rustc
+    cargo
+  ];
+
+  buildInputs = [
+    systemdLibs
+  ];
+
+  meta = {
+    inherit (oo7.meta)
+      homepage
+      changelog
+      license
+      maintainers
+      platforms
+      ;
+    description = "${oo7.meta.description} (Daemon)";
+  };
+})

pkgs/by-name/oo/oo7/package.nix

@@ -0,0 +1,48 @@
+{
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  oo7,
+  pkg-config,
+  rustPlatform,
+  testers,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "oo7";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "bilelmoussaoui";
+    repo = "oo7";
+    rev = version;
+    hash = "sha256-FIHXjbxAqEH3ekTNL0/TBFZoeDYZ84W2+UeJDxcauk8=";
+  };
+
+  # TODO: this won't cover tests from the client crate
+  # Additionally cargo-credential will also not be built here
+  buildAndTestSubdir = "cli";
+
+  cargoHash = "sha256-4ibhHCRBsEcwG5+6Gf/uuswA/k9zJLj+RcMdmBcmvD4=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  passthru = {
+    tests.testVersion = testers.testVersion { package = oo7; };
+
+    updateScript = nix-update-script { };
+  };
+
+  meta = with lib; {
+    description = "James Bond went on a new mission as a Secret Service provider";
+    homepage = "https://github.com/bilelmoussaoui/oo7";
+    changelog = "https://github.com/bilelmoussaoui/oo7/releases/tag/${src.rev}";
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      getchoo
+      Scrumplex
+    ];
+    platforms = platforms.linux;
+    mainProgram = "oo7-cli";
+  };
+}

pkgs/by-name/oo/ookla-speedtest/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+}:
+
+let
+  stdenv = stdenvNoCC;
+
+  pname = "ookla-speedtest";
+  version = "1.2.0";
+
+  srcs = rec {
+    x86_64-linux = fetchurl {
+      url = "https://install.speedtest.net/app/cli/${pname}-${version}-linux-x86_64.tgz";
+      sha256 = "sha256-VpBZbFT/m+1j+jcy+BigXbwtsZrTbtaPIcpfZNXP7rc=";
+    };
+    i686-linux = fetchurl {
+      url = "https://install.speedtest.net/app/cli/${pname}-${version}-linux-i386.tgz";
+      sha256 = "sha256-n/fhjbrn7g4DxmEIRFovts7qbIb2ZILhOS9ViBt3L+g=";
+    };
+    aarch64-linux = fetchurl {
+      url = "https://install.speedtest.net/app/cli/${pname}-${version}-linux-aarch64.tgz";
+      sha256 = "sha256-OVPSMdo3g+K/iQS23XJ2fFxuUz4WPTdC/QQ3r/pDG9M=";
+    };
+    armv7l-linux = fetchurl {
+      url = "https://install.speedtest.net/app/cli/${pname}-${version}-linux-armhf.tgz";
+      sha256 = "sha256-5F/N672KGFVTU1Uz3QMtaxC8jGTu5BObEUe5wJg10I0=";
+    };
+    x86_64-darwin = fetchurl {
+      url = "https://install.speedtest.net/app/cli/${pname}-${version}-macosx-universal.tgz";
+      sha256 = "sha256-yfgZIUnryI+GmZmM7Ksc4UQUQEWQfs5vU89Qh39N5m8=";
+    };
+    aarch64-darwin = x86_64-darwin;
+  };
+in
+
+stdenv.mkDerivation {
+  inherit pname version;
+
+  src =
+    srcs.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
+
+  sourceRoot = ".";
+
+  dontBuild = true;
+  dontConfigure = true;
+
+  installPhase = ''
+    install -D speedtest $out/bin/speedtest
+    install -D speedtest.5 $out/share/man/man5/speedtest.5
+  '';
+
+  meta = with lib; {
+    description = "Command line internet speedtest tool by Ookla";
+    homepage = "https://www.speedtest.net/apps/cli";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    license = licenses.unfree;
+    maintainers = with maintainers; [ kranzes ];
+    platforms = lib.attrNames srcs;
+    mainProgram = "speedtest";
+  };
+}

pkgs/by-name/oo/ooklaserver/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+}:
+let
+  filenameMapping = {
+    "x86_64-linux" = "OoklaServer-linux-x86_64-static-musl.zip";
+    "aarch64-linux" = "OoklaServer-linux-aarch64-static-musl.zip";
+    # Mach-O universal binary with 2 architectures: [x86_64:Mach-O 64-bit executable x86_64] [arm64]
+    "x86_64-darwin" = "OoklaServer-macosx.zip";
+    "aarch64-darwin" = "OoklaServer-macosx.zip";
+    "x86_64-windows" = "OoklaServer-windows64.zip";
+    "i686-windows" = "OoklaServer-windows32.zip";
+    # OoklaServer-linux64-deb9.zip
+    # OoklaServer-freebsd12_64.zip
+    # OoklaServer-freebsd13_64.zip
+  };
+in
+stdenv.mkDerivation {
+  version = "2.11.1.2";
+  pname = "ooklaserver";
+
+  src = fetchurl {
+    url = "https://web.archive.org/web/20240703022648/https://install.speedtest.net/ooklaserver/stable/OoklaServer.tgz";
+    hash = "sha256-tctLtTGmrVHs+4pI1PRHrqY+a4ISs6TKvLRKlFdWw88=";
+  };
+  sourceRoot = ".";
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  nativeBuildInputs = [ unzip ];
+
+  installPhase = ''
+    runHook preInstall
+    unzip ${filenameMapping.${stdenv.system}}
+    install -Dm555 OoklaServer${stdenv.hostPlatform.extensions.executable} "$out/bin/OoklaServer"
+    install -Dm444 OoklaServer.properties.default "$out/etc/OoklaServer.properties.default"
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Ookla TCP based server daemon that provides standalone testing";
+    homepage = "https://www.speedtest.net";
+    changelog = "https://support.ookla.com/hc/en-us/articles/234578608-Speedtest-Server-Release-Notes";
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = lib.licenses.unfree;
+    maintainers = with lib.maintainers; [ neverbehave ];
+    platforms = builtins.attrNames filenameMapping;
+    mainProgram = "OoklaServer";
+  };
+}

pkgs/by-name/oo/oonf-olsrd2/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "oonf-olsrd2";
+  version = "0.15.1";
+
+  src = fetchFromGitHub {
+    owner = "OLSR";
+    repo = "OONF";
+    rev = "v${version}";
+    hash = "sha256-7EH2K7gaBGD95WFlG6RRhKEWJm91Xv2GOHYQjZWuzl0=";
+  };
+
+  # Workaround build failure on -fno-common toolchains like upstream
+  # gcc-10. Otherwise build fails as:
+  #   ld: CMakeFiles/oonf_dlep_proxy.dir/router/dlep_router_session.c.o:(.bss+0x0):
+  #     multiple definition of `LOG_DLEP_ROUTER'; CMakeFiles/oonf_dlep_proxy.dir/router/dlep_router.c.o:(.bss+0x0): first defined here
+  # Can be removed once release with https://github.com/OLSR/OONF/pull/40 is out.
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  cmakeFlags = [
+    "-DOONF_NO_WERROR=yes"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  meta = with lib; {
+    description = "Adhoc wireless mesh routing daemon";
+    license = licenses.bsd3;
+    homepage = "http://olsr.org/";
+    maintainers = with maintainers; [ mkg20001 ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/oo/ooniprobe-cli/package.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "ooniprobe-cli";
+  version = "3.27.0";
+
+  src = fetchFromGitHub {
+    owner = "ooni";
+    repo = "probe-cli";
+    tag = "v${version}";
+    hash = "sha256-dVYxq/ojE3nPxdkQEXocJJKNXeaaS+Sdq+CO8j5M5jM=";
+  };
+
+  vendorHash = "sha256-JnvP0PUOYNJLBpY9BWlC6cJ+Sor2gxDgSKJ8KnUctWc=";
+
+  subPackages = [ "cmd/ooniprobe" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  meta = with lib; {
+    changelog = "https://github.com/ooni/probe-cli/releases/tag/${src.tag}";
+    description = "Open Observatory of Network Interference command line network probe";
+    homepage = "https://ooni.org/install/cli";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ dotlambda ];
+    mainProgram = "ooniprobe";
+  };
+}