push sheeet

pkgs/by-name/op/openapi-generator-cli/example.nix

@@ -0,0 +1,37 @@
+{
+  openapi-generator-cli,
+  fetchurl,
+  runCommand,
+}:
+
+runCommand "openapi-generator-cli-test"
+  {
+    nativeBuildInputs = [ openapi-generator-cli ];
+    petstore = fetchurl {
+      url = "https://raw.githubusercontent.com/OAI/OpenAPI-Specification/14c0908becbccd78252be49bd92be8c53cd2b9e3/examples/v3.0/petstore.yaml";
+      hash = "sha256-q2D1naR41KwxLNn6vMbL0G+Pl1q4oaDCApsqQfZf7dU=";
+    };
+    config = builtins.toJSON {
+      elmVersion = "0.19";
+      elmPrefixCustomTypeVariants = false;
+    };
+    passAsFile = [ "config" ];
+  }
+  ''
+    openapi-generator-cli generate \
+      --input-spec $petstore \
+      --enable-post-process-file \
+      --generator-name elm \
+      --config "$config" \
+      --additional-properties elmEnableCustomBasePaths=true \
+      --output "$out" \
+      ;
+    find $out
+    echo >&2 'Looking for some keywords'
+    set -x
+    grep 'module Api.Request.Pets' $out/src/Api/Request/Pets.elm
+    grep 'createPets' $out/src/Api/Request/Pets.elm
+    grep '"limit"' $out/src/Api/Request/Pets.elm
+    set +x
+    echo "Looks OK!"
+  ''

pkgs/by-name/op/openapi-generator-cli/package.nix

@@ -0,0 +1,55 @@
+{
+  callPackage,
+  lib,
+  stdenv,
+  fetchurl,
+  jre_headless,
+  makeWrapper,
+}:
+
+let
+  jre = jre_headless;
+  this = stdenv.mkDerivation (finalAttrs: {
+    version = "7.15.0";
+    pname = "openapi-generator-cli";
+
+    jarfilename = "openapi-generator-cli-${finalAttrs.version}.jar";
+
+    nativeBuildInputs = [
+      makeWrapper
+    ];
+
+    src = fetchurl {
+      url = "mirror://maven/org/openapitools/openapi-generator-cli/${finalAttrs.version}/${finalAttrs.jarfilename}";
+      sha256 = "sha256-TaGnzbeMOkOx6rBkiJETXow1R9Lu26Ddadrzd/hl82Y=";
+    };
+
+    dontUnpack = true;
+
+    installPhase = ''
+      runHook preInstall
+
+      install -D "$src" "$out/share/java/${finalAttrs.jarfilename}"
+
+      makeWrapper ${jre}/bin/java $out/bin/${finalAttrs.pname} \
+        --add-flags "-jar $out/share/java/${finalAttrs.jarfilename}"
+
+      runHook postInstall
+    '';
+
+    meta = with lib; {
+      description = "Allows generation of API client libraries (SDK generation), server stubs and documentation automatically given an OpenAPI Spec";
+      homepage = "https://github.com/OpenAPITools/openapi-generator";
+      changelog = "https://github.com/OpenAPITools/openapi-generator/releases/tag/v${finalAttrs.version}";
+      sourceProvenance = with sourceTypes; [ binaryBytecode ];
+      license = licenses.asl20;
+      maintainers = with maintainers; [ shou ];
+      mainProgram = "openapi-generator-cli";
+    };
+
+    passthru.tests.example = callPackage ./example.nix {
+      openapi-generator-cli = this;
+    };
+  });
+in
+this