push sheeet

pkgs/by-name/ot/otadump/no-static.patch

@@ -0,0 +1,13 @@
+diff --git a/Cargo.toml b/Cargo.toml
+index 65be773..3499dee 100644
+--- a/Cargo.toml
++++ b/Cargo.toml
+@@ -30,7 +30,7 @@ nom = "7.1.3"
+ nom-derive = "0.10.1"
+ prost = "0.11.8"
+ rayon = "1.7.0"
+-rust-lzma = { version = "0.6.0", features = ["static"] }
++rust-lzma = "0.6.0"
+ sha2 = "0.10.6"
+ sync-unsafe-cell = "0.1.0"
+ tempfile = "3.6.0"

pkgs/by-name/ot/otadump/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  protobuf,
+  xz,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "otadump";
+  version = "0.1.2";
+
+  src = fetchFromGitHub {
+    owner = "crazystylus";
+    repo = "otadump";
+    rev = version;
+    hash = "sha256-4zPVcTU+0otV4EPQi80uSRkpRo9XzI0V3Kr17ugXX2U=";
+  };
+
+  patches = [ ./no-static.patch ];
+
+  nativeBuildInputs = [
+    pkg-config
+    protobuf
+  ];
+
+  buildInputs = [ xz ];
+
+  doCheck = false; # There are no tests
+
+  cargoHash = "sha256-6L1FJWEaDBqpJvj9uGjYuAqqDoQlkVwOWfbG46Amkkw=";
+
+  meta = {
+    description = "Command-line tool to extract partitions from Android OTA files";
+    homepage = "https://github.com/crazystylus/otadump";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.axka ];
+    mainProgram = "otadump";
+  };
+}

pkgs/by-name/ot/otb/1-otb-swig-include-itk.diff

@@ -0,0 +1,17 @@
+diff --git a/Modules/Core/Wrappers/SWIG/src/python/CMakeLists.txt b/Modules/Core/Wrappers/SWIG/src/python/CMakeLists.txt
+index 1a33064..d791805 100644
+--- a/Modules/Core/Wrappers/SWIG/src/python/CMakeLists.txt
++++ b/Modules/Core/Wrappers/SWIG/src/python/CMakeLists.txt
+@@ -17,6 +17,12 @@
+ # See the License for the specific language governing permissions and
+ # limitations under the License.
+ #
++# Add ITK
++find_package(ITK REQUIRED)
++include(${ITK_USE_FILE})
++include_directories(${ITK_INCLUDE_DIRS})
++message(STATUS "ITK FOUND: ${ITK_INCLUDE_DIRS}")
++
+ include_directories( ${Python_INCLUDE_DIRS} )
+ include_directories ( ${CMAKE_CURRENT_SOURCE_DIR})
+ set_source_files_properties ( ../otbApplication.i PROPERTIES CPLUSPLUS ON )

pkgs/by-name/ot/otb/itk-1-fftw-all.diff

@@ -0,0 +1,32 @@
+diff -burN ITK-5.0.0.orig/CMake/FindFFTW.cmake ITK-5.0.0/CMake/FindFFTW.cmake
+--- ITK-5.0.0.orig/CMake/FindFFTW.cmake	2019-05-22 17:54:36.000000000 +0200
++++ ITK-5.0.0/CMake/FindFFTW.cmake	2019-06-24 16:45:46.316235664 +0200
+@@ -59,7 +59,7 @@
+   if(ITK_USE_CUFFTW)
+     find_path(CUFFTW_INCLUDE_PATH cufftw.h ${FFTW_INC_SEARCHPATH})
+   else()
+-    find_path(FFTW_INCLUDE_PATH fftw3.h ${FFTW_INC_SEARCHPATH})
++    find_path(FFTW_INCLUDE_PATH fftw3.h NO_DEFAULT_PATH)
+   endif()
+ 
+   if(FFTW_INCLUDE_PATH)
+@@ -183,7 +189,7 @@
+     if(ITK_USE_FFTWD)
+       mark_as_advanced(FFTWD_BASE_LIB FFTWD_THREADS_LIB FFTWD_LIBRARIES)
+-      find_library(FFTWD_BASE_LIB fftw3 ${FFTW_LIB_SEARCHPATH}) #Double Precision Lib
+-      find_library(FFTWD_THREADS_LIB fftw3_threads ${FFTW_LIB_SEARCHPATH}) #Double Precision Lib only if compiled with threads support
++      find_library(FFTWD_BASE_LIB fftw3 ${FFTW_LIB_SEARCHPATH}  NO_DEFAULT_PATH) #Double Precision Lib
++      find_library(FFTWD_THREADS_LIB fftw3_threads ${FFTW_LIB_SEARCHPATH}  NO_DEFAULT_PATH) #Double Precision Lib only if compiled with threads support
+ 
+       if(FFTWD_BASE_LIB)
+         set(FFTWD_FOUND 1)
+@@ -203,7 +209,7 @@
+     if(ITK_USE_FFTWF)
+       mark_as_advanced(FFTWF_BASE_LIB FFTWF_THREADS_LIB FFTWF_LIBRARIES)
+-      find_library(FFTWF_BASE_LIB fftw3f ${FFTW_LIB_SEARCHPATH}) #Single Precision Lib
+-      find_library(FFTWF_THREADS_LIB fftw3f_threads ${FFTW_LIB_SEARCHPATH}) #Single Precision Lib only if compiled with threads support
++      find_library(FFTWF_BASE_LIB fftw3f ${FFTW_LIB_SEARCHPATH}  NO_DEFAULT_PATH) #Single Precision Lib
++      find_library(FFTWF_THREADS_LIB fftw3f_threads ${FFTW_LIB_SEARCHPATH}  NO_DEFAULT_PATH) #Single Precision Lib only if compiled with threads support
+ 
+       if(FFTWF_BASE_LIB)
+         set(FFTWF_FOUND 1)

pkgs/by-name/ot/otb/itk-2-totalprogress-all.diff

@@ -0,0 +1,9 @@
+diff -burN ITK-5.3.0.orig/Modules/Filtering/MathematicalMorphology/include/itkVanHerkGilWermanErodeDilateImageFilter.hxx ITK-5.3.0/Modules/Filtering/MathematicalMorphology/include/itkVanHerkGilWermanErodeDilateImageFilter.hxx
+--- ITK-5.3.0.orig/Modules/Filtering/MathematicalMorphology/include/itkVanHerkGilWermanErodeDilateImageFilter.hxx	2024-08-23 17:54:36.000000000 +0200
++++ ITK-5.3.0/Modules/Filtering/MathematicalMorphology/include/itkVanHerkGilWermanErodeDilateImageFilter.hxx	2024-08-23 16:45:46.316235664 +0200
+@@ -21,4 +21,4 @@
+#include "itkImageRegionIterator.h"
+
+#include "itkVanHerkGilWermanUtilities.h"
+-
++#include "itkTotalProgressReporter.h"

pkgs/by-name/ot/otb/package.nix

@@ -0,0 +1,309 @@
+{
+  cmake,
+  fetchFromGitHub,
+  fetchpatch,
+  makeWrapper,
+  lib,
+  stdenv,
+  which,
+
+  # build dependencies
+  boost,
+  curl,
+  eigen,
+  fftwFloat,
+  gdal,
+  itk,
+  libsvm,
+  libgeotiff,
+  muparser,
+  muparserx,
+  opencv,
+  perl,
+  python3,
+  shark,
+  swig,
+  tinyxml,
+
+  # otb modules
+  enableFFTW ? false,
+  enableFeatureExtraction ? true,
+  enableHyperspectral ? true,
+  enableLearning ? true,
+  enableMiscellaneous ? true,
+  enableOpenMP ? false,
+  enablePython ? true,
+  extraPythonPackages ? ps: [ ],
+  enableRemote ? true,
+  enableShark ? true,
+  enableSAR ? true,
+  enableSegmentation ? true,
+  enableStereoProcessing ? true,
+  enableThirdParty ? true,
+}:
+let
+  inherit (lib) optionals;
+  pythonInputs =
+    optionals enablePython (with python3.pkgs; [ numpy ]) ++ (extraPythonPackages python3.pkgs);
+
+  # ITK configs for OTB requires 5.3.0 and
+  # filter out gdcm, libminc from list of ITK deps as it's not needed for OTB
+  itkVersion = "5.3.0";
+  itkMajorMinorVersion = lib.versions.majorMinor itkVersion;
+  itkDepsToRemove = [
+    "gdcm"
+    "libminc"
+  ]
+  ++ optionals (!enableFFTW) [
+    # remove fftw to avoid GPL contamination
+    # https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/issues/2454#note_112821
+    "fftw"
+  ];
+  itkIsInDepsToRemove = dep: builtins.any (d: d == dep.name) itkDepsToRemove;
+
+  # remove after https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/issues/2451
+  otbSwig = swig.overrideAttrs (oldArgs: {
+    version = "4.2.1";
+    src = fetchFromGitHub {
+      owner = "swig";
+      repo = "swig";
+      tag = "v4.2.1";
+      hash = "sha256-VlUsiRZLScmbC7hZDzKqUr9481YXVwo0eXT/jy6Fda8=";
+    };
+  });
+
+  # override the ITK version with OTB version
+  # https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/blob/develop/SuperBuild/CMake/External_itk.cmake?ref_type=heads#L145
+  otb-itk = (itk.override { enableRtk = false; }).overrideAttrs (oldArgs: {
+    version = itkVersion;
+    src = fetchFromGitHub {
+      owner = "InsightSoftwareConsortium";
+      repo = "ITK";
+      tag = "v${itkVersion}";
+      hash = "sha256-+qCd8Jzpl5fEPTUpLyjjFBkfgCn3+Lf4pi8QnjCwofs=";
+    };
+
+    # https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/tree/develop/SuperBuild/patches/ITK?ref_type=heads
+    patches = oldArgs.patches or [ ] ++ [
+      ./itk-1-fftw-all.diff
+      ./itk-2-totalprogress-all.diff
+      # add gcc13 patch for itk 5.3.0 as well
+      (fetchpatch {
+        name = "fix-gcc13-build";
+        url = "https://github.com/InsightSoftwareConsortium/ITK/commit/9a719a0d2f5f489eeb9351b0ef913c3693147a4f.patch";
+        hash = "sha256-dDyqYOzo91afR8W7k2N64X6l7t6Ws1C9iuRkWHUe0fg=";
+      })
+    ];
+
+    # fix the CMake config files for ITK which contains double slashes
+    postInstall = (oldArgs.postInstall or "") + ''
+      sed -i 's|''${ITK_INSTALL_PREFIX}//nix/store|/nix/store|g' $out/lib/cmake/ITK-${itkMajorMinorVersion}/ITKConfig.cmake
+    '';
+
+    cmakeFlags = oldArgs.cmakeFlags or [ ] ++ [
+      (lib.cmakeBool "ITK_USE_SYSTEM_EIGEN" true)
+
+      # turn off all the itk modules from nixpkgs
+      (lib.cmakeBool "ITK_USE_SYSTEM_GDCM" false)
+      (lib.cmakeBool "ITK_USE_SYSTEM_MINC" false)
+      (lib.cmakeBool "Module_ITKMINC" false)
+      (lib.cmakeBool "Module_ITKIOMINC" false)
+      (lib.cmakeBool "Module_ITKIOTransformMINC" false)
+      (lib.cmakeBool "Module_SimpleITKFilters" false)
+      (lib.cmakeBool "Module_ITKReview" false)
+      (lib.cmakeBool "Module_MGHIO" false)
+      (lib.cmakeBool "Module_AdaptiveDenoising" false)
+      (lib.cmakeBool "Module_GenericLabelInterpolator" false)
+
+      # enable itk modules for otb
+      # https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/blob/develop/SuperBuild/CMake/External_itk.cmake?ref_type=heads
+      # https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/blob/develop/SuperBuild/CMake/External_itk.cmake?ref_type=heads#L143
+      (lib.cmakeBool "BUILD_TESTING" false)
+      (lib.cmakeBool "ITK_BUILD_DEFAULT_MODULES" false)
+      (lib.cmakeBool "ITKGroup_Core" false)
+      (lib.cmakeBool "Module_ITKCommon" true)
+      (lib.cmakeBool "Module_ITKFiniteDifference" true)
+      (lib.cmakeBool "Module_ITKGPUCommon" true)
+      (lib.cmakeBool "Module_ITKGPUFiniteDifference" true)
+      (lib.cmakeBool "Module_ITKImageAdaptors" true)
+      (lib.cmakeBool "Module_ITKImageFunction" true)
+      (lib.cmakeBool "Module_ITKMesh" true)
+      (lib.cmakeBool "Module_ITKQuadEdgeMesh" true)
+      (lib.cmakeBool "Module_ITKSpatialObjects" true)
+      (lib.cmakeBool "Module_ITKTransform" true)
+      (lib.cmakeBool "Module_ITKAnisotropicSmoothing" true)
+      (lib.cmakeBool "Module_ITKAntiAlias" true)
+      (lib.cmakeBool "Module_ITKBiasCorrection" true)
+      (lib.cmakeBool "Module_ITKBinaryMathematicalMorphology" true)
+      (lib.cmakeBool "Module_ITKColormap" true)
+      (lib.cmakeBool "Module_ITKConvolution" true)
+      (lib.cmakeBool "Module_ITKCurvatureFlow" true)
+      (lib.cmakeBool "Module_ITKDeconvolution" true)
+      (lib.cmakeBool "Module_ITKDenoising" true)
+      (lib.cmakeBool "Module_ITKDisplacementField" true)
+      (lib.cmakeBool "Module_ITKDistanceMap" true)
+      (lib.cmakeBool "Module_ITKFastMarching" true)
+      (lib.cmakeBool "Module_ITKFFT" true)
+      (lib.cmakeBool "Module_ITKGPUAnisotropicSmoothing" true)
+      (lib.cmakeBool "Module_ITKGPUImageFilterBase" true)
+      (lib.cmakeBool "Module_ITKGPUSmoothing" true)
+      (lib.cmakeBool "Module_ITKGPUThresholding" true)
+      (lib.cmakeBool "Module_ITKImageCompare" true)
+      (lib.cmakeBool "Module_ITKImageCompose" true)
+      (lib.cmakeBool "Module_ITKImageFeature" true)
+      (lib.cmakeBool "Module_ITKImageFilterBase" true)
+      (lib.cmakeBool "Module_ITKImageFusion" true)
+      (lib.cmakeBool "Module_ITKImageGradient" true)
+      (lib.cmakeBool "Module_ITKImageGrid" true)
+      (lib.cmakeBool "Module_ITKImageIntensity" true)
+      (lib.cmakeBool "Module_ITKImageLabel" true)
+      (lib.cmakeBool "Module_ITKImageSources" true)
+      (lib.cmakeBool "Module_ITKImageStatistics" true)
+      (lib.cmakeBool "Module_ITKLabelMap" true)
+      (lib.cmakeBool "Module_ITKMathematicalMorphology" true)
+      (lib.cmakeBool "Module_ITKPath" true)
+      (lib.cmakeBool "Module_ITKQuadEdgeMeshFiltering" true)
+      (lib.cmakeBool "Module_ITKSmoothing" true)
+      (lib.cmakeBool "Module_ITKSpatialFunction" true)
+      (lib.cmakeBool "Module_ITKThresholding" true)
+      (lib.cmakeBool "Module_ITKEigen" true)
+      (lib.cmakeBool "Module_ITKNarrowBand" true)
+      (lib.cmakeBool "Module_ITKOptimizers" true)
+      (lib.cmakeBool "Module_ITKOptimizersv4" true)
+      (lib.cmakeBool "Module_ITKPolynomials" true)
+      (lib.cmakeBool "Module_ITKStatistics" true)
+      (lib.cmakeBool "Module_ITKRegistrationCommon" true)
+      (lib.cmakeBool "Module_ITKGPURegistrationCommon" true)
+      (lib.cmakeBool "Module_ITKGPUPDEDeformableRegistration" true)
+      (lib.cmakeBool "Module_ITKMetricsv4" true)
+      (lib.cmakeBool "Module_ITKPDEDeformableRegistration" true)
+      (lib.cmakeBool "Module_ITKRegistrationMethodsv4" true)
+      (lib.cmakeBool "Module_ITKClassifiers" true)
+      (lib.cmakeBool "Module_ITKConnectedComponents" true)
+      (lib.cmakeBool "Module_ITKDeformableMesh" true)
+      (lib.cmakeBool "Module_ITKKLMRegionGrowing" true)
+      (lib.cmakeBool "Module_ITKLabelVoting" true)
+      (lib.cmakeBool "Module_ITKLevelSets" true)
+      (lib.cmakeBool "Module_ITKLevelSetsv4" true)
+      (lib.cmakeBool "Module_ITKMarkovRandomFieldsClassifiers" true)
+      (lib.cmakeBool "Module_ITKRegionGrowing" true)
+      (lib.cmakeBool "Module_ITKSignedDistanceFunction" true)
+      (lib.cmakeBool "Module_ITKVoronoi" true)
+      (lib.cmakeBool "Module_ITKWatersheds" true)
+    ];
+
+    buildInputs = oldArgs.buildInputs or [ ] ++ [
+      # add eigen as well as itk nixpkgs doesn't add it for version lower than 5.4.0
+      eigen
+    ];
+
+    propagatedBuildInputs =
+      lib.lists.filter (pkg: !(itkIsInDepsToRemove pkg)) oldArgs.propagatedBuildInputs or [ ]
+      ++ lib.optionals enableFFTW [
+        # the only missing dependency for OTB from itk propagated list if FFTW option is enabled
+        fftwFloat
+      ];
+
+  });
+
+  otb-shark = shark.override { enableOpenMP = enableOpenMP; };
+
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "otb";
+  version = "10.0-unstable-2025-04-03";
+
+  src = fetchFromGitHub {
+    owner = "orfeotoolbox";
+    repo = "otb";
+    rev = "93649b68f54975a1a48a0acd49f2602a55fc8032";
+    hash = "sha256-S6yhV//qlKdWWcT9J1p64WuVS0QNepIYTr/t4JvyEwE=";
+  };
+
+  patches = [
+    # fixes for gdal 10
+    # https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/merge_requests/1056
+    (fetchpatch {
+      url = "https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/merge_requests/1056/diffs.patch";
+      hash = "sha256-Zj/wkx0vxn5vqj0hszn7NxoYW1yf63G3HPVKbSdZIOY=";
+    })
+    ./1-otb-swig-include-itk.diff
+  ];
+
+  postPatch = ''
+    substituteInPlace Modules/Core/Wrappers/SWIG/src/python/CMakeLists.txt \
+      --replace-fail ''\'''${ITK_INCLUDE_DIRS}' "${otb-itk}/include/ITK-${itkMajorMinorVersion}"
+  ''
+  # Add the header file "vcl_legacy_aliases.h", which defines the legacy vcl_* functions.
+  # This patch fixes the unreproducible build of OTB.
+  # See https://gitlab.orfeo-toolbox.org/orfeotoolbox/otb/-/issues/2484.
+  + ''
+    sed -i '/#include "vcl_compiler.h"/a #include "vcl_legacy_aliases.h"' Modules/Core/Mosaic/include/otbMosaicFunctors.h
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    makeWrapper
+    which
+  ];
+
+  # https://www.orfeo-toolbox.org/CookBook/CompilingOTBFromSource.html#native-build-with-system-dependencies
+  # activates all modules and python by default
+  cmakeFlags = [
+    (lib.cmakeBool "OTBGroup_Core" true)
+    (lib.cmakeBool "OTB_BUILD_FeaturesExtraction" enableFeatureExtraction)
+    (lib.cmakeBool "OTB_BUILD_Hyperspectral" enableHyperspectral)
+    (lib.cmakeBool "OTB_BUILD_Learning" enableLearning)
+    (lib.cmakeBool "OTB_BUILD_Miscellaneous" enableMiscellaneous)
+    (lib.cmakeBool "OTB_USE_OPENMP" enableOpenMP)
+    (lib.cmakeBool "OTB_BUILD_RemoteModules" enableRemote)
+    (lib.cmakeBool "OTB_BUILD_SAR" enableSAR)
+    (lib.cmakeBool "OTB_USE_SHARK" enableShark)
+    (lib.cmakeBool "OTB_BUILD_Segmentation" enableSegmentation)
+    (lib.cmakeBool "OTB_BUILD_StereoProcessing" enableStereoProcessing)
+    (lib.cmakeBool "OTBGroup_ThirdParty" enableThirdParty)
+    (lib.cmakeBool "OTB_WRAP_PYTHON" enablePython)
+    (lib.cmakeBool "BUILD_TESTING" finalAttrs.doInstallCheck)
+    (lib.cmakeBool "OTB_USE_FFTW" enableFFTW)
+  ];
+
+  propagatedBuildInputs = [
+    boost
+    curl
+    gdal
+    libgeotiff
+    libsvm
+    muparser
+    muparserx
+    opencv
+    otb-itk
+    perl
+    tinyxml
+  ]
+  ++ otb-itk.propagatedBuildInputs
+  ++ optionals enablePython (
+    [
+      python3
+      otbSwig
+    ]
+    ++ pythonInputs
+  )
+  ++ optionals enableShark [ otb-shark ];
+
+  doInstallCheck = true;
+
+  postInstall = ''
+    wrapProgram $out/bin/otbcli \
+      --set OTB_INSTALL_DIR "$out" \
+      --set OTB_APPLICATION_PATH "$out/lib/otb/applications"
+  '';
+
+  meta = {
+    description = "Open Source processing of remote sensing images";
+    homepage = "https://www.orfeo-toolbox.org/";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ daspk04 ];
+    teams = [ lib.teams.geospatial ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ot/otel-cli/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  getent,
+  coreutils,
+  nix-update-script,
+  stdenv,
+}:
+
+buildGoModule rec {
+  pname = "otel-cli";
+  version = "0.4.5";
+
+  src = fetchFromGitHub {
+    owner = "equinix-labs";
+    repo = "otel-cli";
+    rev = "v${version}";
+    hash = "sha256-JYi9CbP4mUhX0zNjhi6QlBzLKcj2zdPwlyBSIYKp6vk=";
+  };
+
+  vendorHash = "sha256-fWQz7ZrU8gulhpOHSN8Prn4EMC0KXy942FZD/PMsLxc=";
+
+  preCheck = ''
+    ln -s $GOPATH/bin/otel-cli .
+  ''
+  + lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
+    substituteInPlace main_test.go \
+      --replace-fail 'const minimumPath = `/bin:/usr/bin`' 'const minimumPath = `${
+        lib.makeBinPath [
+          getent
+          coreutils
+        ]
+      }`'
+  '';
+
+  patches = [ ./patches/bin-echo-patch.patch ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/equinix-labs/otel-cli";
+    description = "Command-line tool for sending OpenTelemetry traces";
+    changelog = "https://github.com/equinix-labs/otel-cli/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      emattiza
+      urandom
+    ];
+    mainProgram = "otel-cli";
+  };
+}

pkgs/by-name/ot/otel-cli/patches/bin-echo-patch.patch

@@ -0,0 +1,21 @@
+diff --git a/data_for_test.go b/data_for_test.go
+index c0b8980..691e270 100644
+--- a/data_for_test.go
++++ b/data_for_test.go
+@@ -555,14 +555,14 @@ var suites = []FixtureSuite{
+ 					"--endpoint", "{{endpoint}}",
+ 					"--verbose", "--fail",
+ 					"--attrs", "zy=ab", // ensure CLI args still propagate
+-					"--", "/bin/echo", "a", "z",
++					"--", "echo", "a", "z",
+ 				},
+ 			},
+ 			Expect: Results{
+ 				SpanCount: 1,
+ 				CliOutput: "a z\n",
+ 				SpanData: map[string]string{
+-					"attributes": "/^process.command=/bin/echo,process.command_args=/bin/echo,a,z,process.owner=\\w+,process.parent_pid=\\d+,process.pid=\\d+,zy=ab/",
++					"attributes": "/^process.command=echo,process.command_args=echo,a,z,process.owner=\\w+,process.parent_pid=\\d+,process.pid=\\d+,zy=ab/",
+ 				},
+ 			},
+ 		},

pkgs/by-name/ot/otel-desktop-viewer/package.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  stdenv,
+  apple-sdk,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "otel-desktop-viewer";
+  version = "0.2.5";
+
+  src = fetchFromGitHub {
+    owner = "CtrlSpice";
+    repo = "otel-desktop-viewer";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-4CFemHoMt5Fxaq66zxzWrGxq4AJuZkm45Gb4t8wseWg=";
+  };
+
+  # NOTE: This project uses Go workspaces, but 'buildGoModule' does not support
+  # them at the time of writing; trying to build with 'env.GOWORK = "off"'
+  # fails with the following error message:
+  #
+  #     main module (github.com/CtrlSpice/otel-desktop-viewer) does not contain package github.com/CtrlSpice/otel-desktop-viewer/desktopexporter
+  #
+  # cf. https://github.com/NixOS/nixpkgs/issues/203039
+  proxyVendor = true;
+  vendorHash = "sha256-2fPkSWPfEDMYH8E7dTq2AAFrsf3jimH315a8OJOIAII=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${finalAttrs.version}"
+  ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [ apple-sdk ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+  versionCheckProgram = "${placeholder "out"}/bin/${finalAttrs.meta.mainProgram}";
+  versionCheckProgramArg = "--version";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/CtrlSpice/otel-desktop-viewer/releases/tag/v${finalAttrs.version}";
+    description = "Receive & visualize OpenTelemtry traces locally within one CLI tool";
+    homepage = "https://github.com/CtrlSpice/otel-desktop-viewer";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      gaelreyrol
+      jkachmar
+      lf-
+    ];
+    mainProgram = "otel-desktop-viewer";
+  };
+})

pkgs/by-name/ot/otel-desktop-viewer/version-0.1.4.patch

@@ -0,0 +1,13 @@
+diff --git a/main.go b/main.go
+index 7e43908..062385c 100644
+--- a/main.go
++++ b/main.go
+@@ -15,7 +15,7 @@ func main() {
+ 	info := component.BuildInfo{
+ 		Command:     "otel-desktop-viewer",
+ 		Description: "Basic OTel with Custom Desktop Exporter",
+-		Version:     "0.1.1",
++		Version:     "0.1.4",
+ 	}
+ 
+ 	if err := run(info); err != nil {

pkgs/by-name/ot/oterm/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  python3Packages,
+  fetchFromGitHub,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "oterm";
+  version = "0.14.4";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "ggozad";
+    repo = "oterm";
+    tag = version;
+    hash = "sha256-zTRCAg5BjwdP2s1LZrOjLctqYe/jX4Mc3gK+IwVoLR4=";
+  };
+
+  pythonRelaxDeps = [
+    "aiosql"
+    "aiosqlite"
+    "httpx"
+    "ollama"
+    "packaging"
+    "pillow"
+    "pydantic"
+    "textual"
+    "typer"
+    "fastmcp"
+  ];
+
+  build-system = with python3Packages; [ hatchling ];
+
+  dependencies = with python3Packages; [
+    aiohttp
+    aiosql
+    aiosqlite
+    fastmcp
+    httpx
+    mcp
+    ollama
+    packaging
+    pillow
+    pyperclip
+    python-dotenv
+    rich-pixels
+    textual
+    textual-image
+    textualeffects
+    typer
+  ];
+
+  pythonImportsCheck = [ "oterm" ];
+
+  # Python tests require a HTTP connection to ollama
+
+  # Fails on darwin with: PermissionError: [Errno 1] Operation not permitted: '/var/empty/Library'
+  nativeCheckInputs = lib.optionals (!stdenv.hostPlatform.isDarwin) [
+    versionCheckHook
+  ];
+  versionCheckProgramArg = "--version";
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Text-based terminal client for Ollama";
+    homepage = "https://github.com/ggozad/oterm";
+    changelog = "https://github.com/ggozad/oterm/releases/tag/${src.tag}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ gaelj ];
+    mainProgram = "oterm";
+  };
+}

pkgs/by-name/ot/otf2/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  buildPackages,
+  which,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "otf2";
+  version = "3.1.1";
+
+  outputs = [
+    "out"
+    "lib"
+    "doc"
+  ];
+
+  src = fetchurl {
+    url = "http://perftools.pages.jsc.fz-juelich.de/cicd/otf2/tags/otf2-${finalAttrs.version}/otf2-${finalAttrs.version}.tar.gz";
+    hash = "sha256-Wk4BOlGsTteU/jXFW3AM1yA0b9p/M+yEx2uGpfuICm4=";
+  };
+
+  postPatch = ''
+    substituteInPlace build-config/common/platforms/platform-backend-user-provided \
+      --replace-fail 'CC=' 'CC=${stdenv.cc.targetPrefix}cc' \
+      --replace-fail 'CXX=' 'CXX=${stdenv.cc.targetPrefix}c++'
+    substituteInPlace build-config/common/platforms/platform-frontend-user-provided \
+      --replace-fail 'CC_FOR_BUILD=' 'CC_FOR_BUILD=${buildPackages.stdenv.cc.targetPrefix}cc' \
+      --replace-fail 'CXX_FOR_BUILD=' 'CXX_FOR_BUILD=${buildPackages.stdenv.cc.targetPrefix}c++'
+  '';
+
+  strictDeps = true;
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+
+  configureFlags = [
+    (lib.enableFeature finalAttrs.finalPackage.doCheck "backend-test-runs")
+    (lib.withFeature true "custom-compilers")
+  ]
+  ++ lib.optionals (!lib.systems.equals stdenv.buildPlatform stdenv.hostPlatform) [
+    "ac_scorep_cross_compiling=yes"
+  ];
+
+  nativeBuildInputs = [
+    which # used in configure script
+  ];
+
+  enableParallelBuilding = true;
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  doCheck = true;
+  enableParallelChecking = true;
+  doInstallCheck = true;
+
+  versionCheckProgram = [ "${placeholder "out"}/bin/otf2-config" ];
+
+  meta = {
+    homepage = "https://www.vi-hps.org/projects/score-p";
+    changelog = "https://perftools.pages.jsc.fz-juelich.de/cicd/otf2/tags/otf2-${finalAttrs.version}/ChangeLog.txt";
+    description = "Open Trace Format 2 library";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ lesuisse ];
+  };
+})

pkgs/by-name/ot/otf2bdf/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  freetype,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "otf2bdf";
+  version = "3.1";
+
+  # Original site http://sofia.nmsu.edu/~mleisher/Software/otf2bdf/ unreachable,
+  # This is a mirror.
+  src = fetchFromGitHub {
+    owner = "jirutka";
+    repo = "otf2bdf";
+    rev = "v${version}";
+    hash = "sha256-HK9ZrnwKhhYcBvSl+3RwFD7m/WSaPkGKX6utXnk5k+A=";
+  };
+
+  buildInputs = [ freetype ];
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/man/man1
+    install otf2bdf $out/bin
+    cp otf2bdf.man $out/share/man/man1/otf2bdf.1
+  '';
+
+  meta = with lib; {
+    #homepage = "http://sofia.nmsu.edu/~mleisher/Software/otf2bdf/";  # timeout
+    homepage = "https://github.com/jirutka/otf2bdf";
+    description = "OpenType to BDF font converter";
+    license = licenses.mit0;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ hzeller ];
+    mainProgram = "otf2bdf";
+  };
+}

pkgs/by-name/ot/otfcc/fix-aarch64.patch

@@ -0,0 +1,22 @@
+diff --git a/premake5.lua b/premake5.lua
+index 997fd79..54a20a0 100644
+--- a/premake5.lua
++++ b/premake5.lua
+@@ -49,7 +49,7 @@ end
+ workspace "otfcc"
+ 	configurations { "release", "debug" }
+ 	
+-	platforms { "x64", "x86" }
++	platforms { "x64", "x86", "arm" }
+ 	filter "action:xcode4"
+ 		platforms { "x64" }
+ 	filter {}
+@@ -67,6 +67,8 @@ workspace "otfcc"
+ 		architecture "x86"
+ 	filter "platforms:x64"
+ 		architecture "x64"
++	filter "platforms:arm"
++		architecture "arm"
+ 	filter {}
+ 	
+ 	filter "action:vs2017"

pkgs/by-name/ot/otfcc/move-makefiles.patch

@@ -0,0 +1,13 @@
+diff --git a/premake5.lua b/premake5.lua
+index 997fd79..54a20a0 100644
+--- a/premake5.lua
++++ b/premake5.lua
+@@ -88,7 +90,7 @@ workspace "otfcc"
+ 		flags { "StaticRuntime" }
+ 		includedirs { "dep/polyfill-msvc" }
+ 	filter "action:gmake"
+-		location "build/gmake"
++		location "."
+ 	filter "action:xcode4"
+ 		location "build/xcode"
+ 	filter {}

pkgs/by-name/ot/otfcc/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  premake5,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "otfcc";
+  version = "0.10.4";
+
+  # archived by the owner on Jun 3, 2022. No viable forks.
+  src = fetchFromGitHub {
+    owner = "caryll";
+    repo = "otfcc";
+    rev = "v${version}";
+    sha256 = "1nrkzpqklfpqsccji4ans40rj88l80cv7dpxwx4g577xrvk13a0f";
+  };
+
+  nativeBuildInputs = [ premake5 ];
+
+  patches = [
+    ./fix-aarch64.patch
+    ./move-makefiles.patch
+  ];
+
+  buildFlags = lib.optionals stdenv.hostPlatform.isAarch64 [ "config=release_arm" ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp bin/release-*/otfcc* $out/bin/
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Optimized OpenType builder and inspector";
+    homepage = "https://github.com/caryll/otfcc";
+    license = licenses.asl20;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ ttuegel ];
+    # Build fails on all platforms with
+    #        > configure flags: gmake
+    #   > ** Warning: action 'xcode4' sets 'os' field, which is deprecated, use 'targetos' instead.
+    #   > Error: invalid value 'StaticRuntime' for flags
+    broken = true;
+  };
+
+}

pkgs/by-name/ot/otio/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  cmake,
+  fetchFromGitHub,
+  imath,
+  python3,
+  rapidjson,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "otio";
+  version = "0.17.0";
+
+  src = fetchFromGitHub {
+    owner = "AcademySoftwareFoundation";
+    repo = "OpenTimelineIO";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-53KXjbhHxuEtu6iRGWrirvFamuZ/WbOTcKCfs1iqKmM=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    python3
+  ];
+
+  buildInputs = [
+    imath
+    rapidjson
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "OTIO_PYTHON_INSTALL" false)
+    (lib.cmakeBool "OTIO_DEPENDENCIES_INSTALL" false)
+    (lib.cmakeBool "OTIO_FIND_IMATH" true)
+    (lib.cmakeBool "OTIO_SHARED_LIBS" true)
+    (lib.cmakeBool "OTIO_AUTOMATIC_SUBMODULES" false)
+  ];
+
+  meta = {
+    description = "Interchange format and API for editorial cut information";
+    homepage = "http://opentimeline.io/";
+    changelog = "https://github.com/AcademySoftwareFoundation/OpenTimelineIO/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ liberodark ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ot/otpauth/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGo124Module,
+}:
+
+buildGo124Module rec {
+  pname = "otpauth";
+  version = "0.6.0";
+
+  src = fetchFromGitHub {
+    owner = "dim13";
+    repo = "otpauth";
+    rev = "v${version}";
+    sha256 = "sha256-QpQuMeldkZRXFi7I2yc7HS45gvsneZdPsSzkGWmnMX8=";
+  };
+
+  vendorHash = "sha256-Vx+nSSXidSJdEDoI2Bzx+5CQstNmW9dIOg8jEpAaguQ=";
+
+  meta = with lib; {
+    description = "Google Authenticator migration decoder";
+    mainProgram = "otpauth";
+    homepage = "https://github.com/dim13/otpauth";
+    license = licenses.isc;
+    maintainers = with maintainers; [ ereslibre ];
+  };
+}

pkgs/by-name/ot/otpclient/package.nix

@@ -0,0 +1,62 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  gtk3,
+  wrapGAppsHook3,
+  jansson,
+  libgcrypt,
+  libzip,
+  libpng,
+  libcotp,
+  protobuf,
+  protobufc,
+  qrencode,
+  libsecret,
+  libuuid,
+  zbar,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "otpclient";
+  version = "4.1.1";
+
+  src = fetchFromGitHub {
+    owner = "paolostivanin";
+    repo = "otpclient";
+    tag = "v${version}";
+    hash = "sha256-yve6DMtMqPTkyI01lRvJy0rObEt9KMrekjPegjT5blk=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    gtk3
+    jansson
+    libcotp
+    libgcrypt
+    libpng
+    libsecret
+    libuuid
+    libzip
+    protobuf
+    protobufc
+    qrencode
+    zbar
+  ];
+
+  meta = {
+    description = "Highly secure and easy to use OTP client written in C/GTK that supports both TOTP and HOTP";
+    homepage = "https://github.com/paolostivanin/OTPClient";
+    changelog = "https://github.com/paolostivanin/OTPClient/releases/tag/v${version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ alexbakker ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/ot/otpw/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  coreutils,
+  fetchurl,
+  libxcrypt,
+  pam,
+  procps,
+  unixtools,
+  util-linux,
+  versionCheckHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "otpw";
+  version = "1.5";
+
+  src = fetchurl {
+    url = "https://www.cl.cam.ac.uk/~mgk25/download/otpw-${finalAttrs.version}.tar.gz";
+    hash = "sha256-mKyjimHHcTZ3uW8kQmynBTSAwP0HfZGx6ZvJ+SzLgyo=";
+  };
+
+  patchPhase = ''
+    sed -i 's/^CFLAGS.*/CFLAGS=-O2 -fPIC/' Makefile
+    substituteInPlace otpw-gen.c \
+      --replace "head -c 20 /dev/urandom 2>&1" "${coreutils}/bin/head -c 20 /dev/urandom 2>&1" \
+      --replace "ls -lu /etc/. /tmp/. / /usr/. /bin/. /usr/bin/." "${coreutils}/bin/ls -lu /etc/. /tmp/. / /usr/. /bin/. /usr/bin/." \
+      --replace "PATH=/usr/ucb:/bin:/usr/bin;ps lax" "PATH=/usr/ucb:/bin:/usr/bin;${unixtools.procps}/bin/ps lax" \
+      --replace "last | head -50" "${util-linux}/bin/last | ${coreutils}/bin/head -50" \
+      --replace "uptime;netstat -n;hostname;date;w" "${coreutils}/bin/uptime; ${unixtools.net-tools}/bin/netstat -n; ${unixtools.net-tools}/bin/hostname; ${coreutils}/bin/date; ${procps}/bin/w"
+  '';
+
+  buildInputs = [
+    libxcrypt
+    pam
+  ];
+
+  env.NIX_CFLAGS_COMPILE = toString [
+    # demologin.c:132:25: error: implicit declaration of function 'crypt' []
+    #   132 |     if (!user || strcmp(crypt(password, user->pwd.pw_passwd),
+    "-Wno-error=implicit-function-declaration"
+    # demologin.c:132:25: error: passing argument 1 of 'strcmp' makes pointer from integer without a cast []
+    #   132 |     if (!user || strcmp(crypt(password, user->pwd.pw_passwd),
+    "-Wno-error=int-conversion"
+  ];
+
+  enableParallelBuilding = true;
+
+  installPhase = ''
+    mkdir -p $out/bin $out/lib/security $out/share/man/man{1,8}
+    cp pam_*.so $out/lib/security
+    cp otpw-gen $out/bin
+    cp *.1 $out/share/man/man1
+    cp *.8 $out/share/man/man8
+  '';
+
+  hardeningDisable = [
+    "stackprotector"
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = "${placeholder "out"}/bin/${finalAttrs.meta.mainProgram}";
+  doInstallCheck = true;
+
+  meta = {
+    description = "One-time password login package";
+    mainProgram = "otpw-gen";
+    homepage = "http://www.cl.cam.ac.uk/~mgk25/otpw.html";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ot/otree/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "otree";
+  version = "0.6.1";
+
+  src = fetchFromGitHub {
+    owner = "fioncat";
+    repo = "otree";
+    tag = "v${version}";
+    hash = "sha256-a160Mi0VZesU3PQOKrgiN/5yxx82xHtjcMazH5o0LJs=";
+  };
+
+  cargoHash = "sha256-ZubL48hXyrBg9K64GsLmRZgdFhDWYbYNH2PhwE9qAQ4=";
+
+  meta = {
+    description = "Command line tool to view objects (JSON/YAML/TOML/XML) in TUI tree widget";
+    homepage = "https://github.com/fioncat/otree";
+    changelog = "https://github.com/fioncat/otree/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    mainProgram = "otree";
+    maintainers = with lib.maintainers; [
+      anas
+      kiara
+    ];
+  };
+}

pkgs/by-name/ot/ots/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "ots";
+  version = "0.3.1";
+
+  src = fetchFromGitHub {
+    owner = "sniptt-official";
+    repo = "ots";
+    rev = "v${version}";
+    hash = "sha256-GOCuH9yiVs3N3sHCCoSGaQkaaJs4NY/klNBRWjZGLE4=";
+  };
+
+  vendorHash = "sha256-fLElExANWdPCCqpCAofqp0kba/FsQEHEhlxOFaC/kZw=";
+
+  ldflags = [
+    "-X main.version=${version}"
+    "-X main.buildSource=nix"
+  ];
+
+  meta = {
+    description = "Share end-to-end encrypted secrets with others via a one-time URL";
+    mainProgram = "ots";
+    homepage = "https://ots.sniptt.com";
+    changelog = "https://github.com/sniptt-official/ots/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ elliot ];
+  };
+}

pkgs/by-name/ot/ott/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  ocamlPackages,
+  opaline,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ott";
+  version = "0.34";
+
+  src = fetchFromGitHub {
+    owner = "ott-lang";
+    repo = "ott";
+    rev = version;
+    hash = "sha256-S6EMQgEBrtXB9hTM7x6irZPsI9c9JHeuCk/9pcpQMNg=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    pkg-config
+    opaline
+  ]
+  ++ (with ocamlPackages; [
+    findlib
+    ocaml
+  ]);
+  buildInputs = with ocamlPackages; [ ocamlgraph ];
+
+  installTargets = "ott.install";
+
+  postInstall = ''
+    opaline -prefix $out
+  ''
+  # There is `emacsPackages.ott-mode` for this now.
+  + ''
+    rm -r $out/share/emacs
+  '';
+
+  meta = {
+    description = "Tool for the working semanticist";
+    mainProgram = "ott";
+    longDescription = ''
+      Ott is a tool for writing definitions of programming languages and
+      calculi. It takes as input a definition of a language syntax and
+      semantics, in a concise and readable ASCII notation that is close to
+      what one would write in informal mathematics. It generates LaTeX to
+      build a typeset version of the definition, and Coq, HOL, and Isabelle
+      versions of the definition. Additionally, it can be run as a filter,
+      taking a LaTeX/Coq/Isabelle/HOL source file with embedded (symbolic)
+      terms of the defined language, parsing them and replacing them by
+      target-system terms.
+    '';
+    homepage = "http://www.cl.cam.ac.uk/~pes20/ott";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ jwiegley ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/ot/otto-matic/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  sdl3,
+  libGL,
+  cmake,
+  makeWrapper,
+  unstableGitUpdater,
+}:
+
+stdenv.mkDerivation {
+  pname = "OttoMatic";
+  version = "4.0.1-unstable-2025-04-27";
+
+  src = fetchFromGitHub {
+    owner = "jorio";
+    repo = "OttoMatic";
+    rev = "69f0111d1768abe56498bf8121f0f9cbc85aedd3";
+    hash = "sha256-7RpEVL3tNhEhkZYVjgsI6S+CQfyiz/ukroldrtohA4k=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    cmake
+    makeWrapper
+  ];
+
+  buildInputs = [
+    sdl3
+    libGL
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/bin"
+    mkdir -p "$out/share/OttoMatic"
+    mv Data ReadMe.txt "$out/share/OttoMatic/"
+    install -Dm755 {.,$out/bin}/OttoMatic
+    wrapProgram $out/bin/OttoMatic --chdir "$out/share/OttoMatic"
+    install -Dm644 $src/packaging/io.jor.ottomatic.desktop $out/share/applications/io.jor.ottomatic.desktop
+    install -Dm644 $src/packaging/io.jor.ottomatic.png $out/share/pixmaps/io.jor.ottomatic.png
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = {
+    description = "Port of Otto Matic, a 2001 Macintosh game by Pangea Software, for modern operating systems";
+    homepage = "https://github.com/jorio/OttoMatic";
+    license = lib.licenses.cc-by-sa-40;
+    maintainers = with lib.maintainers; [ lux ];
+    platforms = lib.platforms.linux;
+    mainProgram = "OttoMatic";
+  };
+}

pkgs/by-name/ot/otus-lisp/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  xxd,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "otus-lisp";
+  version = "2.6";
+
+  src = fetchFromGitHub {
+    owner = "yuriy-chumak";
+    repo = "ol";
+    rev = finalAttrs.version;
+    hash = "sha256-5ixpTTXwJbLM2mJ/nwzjz0aKG/QGVLPScY8EaG7swGU=";
+  };
+
+  nativeBuildInputs = [ xxd ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = {
+    description = "Purely functional dialect of Lisp";
+    homepage = "https://yuriy-chumak.github.io/ol/";
+    license = with lib.licenses; [
+      mit
+      lgpl3Only
+    ]; # dual licensed
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ nagy ];
+    mainProgram = "ol";
+  };
+})