push sheeet

pkgs/by-name/ou/ouch/package.nix

@@ -0,0 +1,80 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  pkg-config,
+  bzip2,
+  bzip3,
+  xz,
+  git,
+  zlib,
+  zstd,
+
+  # RAR code is under non-free unRAR license
+  # see the meta.license section below for more details
+  enableUnfree ? false,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "ouch";
+  version = "0.6.1";
+
+  src = fetchFromGitHub {
+    owner = "ouch-org";
+    repo = "ouch";
+    rev = version;
+    hash = "sha256-vNeOJOyQsjDUzScA1a/W+SI1Z67HTLiHjwWZZpr1Paw=";
+  };
+
+  cargoHash = "sha256-mMoYJ3dLpb1Y3Ocdyxg1brE7xYeZBbtUg0J/2HTK0hE=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    pkg-config
+    rustPlatform.bindgenHook
+  ];
+
+  nativeCheckInputs = [
+    git
+  ];
+
+  buildInputs = [
+    bzip2
+    bzip3
+    xz
+    zlib
+    zstd
+  ];
+
+  buildNoDefaultFeatures = true;
+  buildFeatures = [
+    "use_zlib"
+    "use_zstd_thin"
+    # "bzip3" will be optional in the next version
+    "zstd/pkg-config"
+  ]
+  ++ lib.optionals enableUnfree [
+    "unrar"
+  ];
+
+  postInstall = ''
+    installManPage artifacts/*.1
+    installShellCompletion artifacts/ouch.{bash,fish} --zsh artifacts/_ouch
+  '';
+
+  env.OUCH_ARTIFACTS_FOLDER = "artifacts";
+
+  meta = {
+    description = "Command-line utility for easily compressing and decompressing files and directories";
+    homepage = "https://github.com/ouch-org/ouch";
+    changelog = "https://github.com/ouch-org/ouch/blob/${version}/CHANGELOG.md";
+    license = with lib.licenses; [ mit ] ++ lib.optionals enableUnfree [ unfreeRedistributable ];
+    maintainers = with lib.maintainers; [
+      figsoda
+      psibi
+      krovuxdev
+    ];
+    mainProgram = "ouch";
+  };
+}

pkgs/by-name/ou/oui/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule rec {
+  pname = "oui";
+  version = "0.1.8";
+
+  src = fetchFromGitHub {
+    owner = "thatmattlove";
+    repo = "oui";
+    rev = "v${version}";
+    hash = "sha256-RLm8V2fLFvOwjnnq16ZmhwVdtgXPaehan7JTX3Xz30w=";
+  };
+
+  vendorHash = "sha256-TLVw4tnfvgK2h/Xj5LNNjDG4WQ83Bw8yBhZc16Tjmws=";
+
+  meta = with lib; {
+    description = "MAC Address CLI Toolkit";
+    homepage = "https://github.com/thatmattlove/oui";
+    license = with licenses; [ bsd3 ];
+    teams = [ teams.wdz ];
+    mainProgram = "oui";
+  };
+}

pkgs/by-name/ou/out-of-tree/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  buildGoModule,
+  fetchgit,
+  qemu,
+  podman,
+  makeWrapper,
+}:
+
+buildGoModule rec {
+  pname = "out-of-tree";
+  version = "2.1.1";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  src = fetchgit {
+    tag = "v${version}";
+    url = "https://code.dumpstack.io/tools/${pname}.git";
+    hash = "sha256-XzO8NU7A5m631PjAm0F/K7qLrD+ZDSdHXaNowGaZAPo=";
+  };
+
+  vendorHash = "sha256-p1dqzng3ak9lrnzrEABhE1TP1lM2Ikc8bmvp5L3nUp0=";
+
+  doCheck = false;
+
+  postFixup = ''
+    wrapProgram $out/bin/out-of-tree \
+      --prefix PATH : "${
+        lib.makeBinPath [
+          qemu
+          podman
+        ]
+      }"
+  '';
+
+  meta = with lib; {
+    description = "Kernel {module, exploit} development tool";
+    mainProgram = "out-of-tree";
+    homepage = "https://out-of-tree.io";
+    maintainers = [ maintainers.dump_stack ];
+    license = licenses.agpl3Plus;
+  };
+}

pkgs/by-name/ou/outfieldr/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  fetchFromGitLab,
+  stdenv,
+  zig_0_14,
+}:
+
+let
+  zig = zig_0_14;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "outfieldr";
+  version = "1.1.1";
+
+  src = fetchFromGitLab {
+    owner = "ve-nt";
+    repo = "outfieldr";
+    rev = finalAttrs.version;
+    hash = "sha256-rokGB1be09ExK9VH5tCW8ccZiIMd3A9pbuMFrOouhOc=";
+  };
+
+  nativeBuildInputs = [
+    zig.hook
+  ];
+
+  meta = {
+    description = "TLDR client written in Zig";
+    homepage = "https://gitlab.com/ve-nt/outfieldr";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ hasnep ];
+    mainProgram = "tldr";
+    inherit (zig.meta) platforms;
+  };
+})

pkgs/by-name/ou/outfly/package.nix

@@ -0,0 +1,80 @@
+{
+  lib,
+  fetchFromGitea,
+  rustPlatform,
+  makeDesktopItem,
+  pkg-config,
+  libxkbcommon,
+  alsa-lib,
+  libGL,
+  vulkan-loader,
+  wayland,
+  libXrandr,
+  libXcursor,
+  libX11,
+  libXi,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "outfly";
+  version = "0.14.0";
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "outfly";
+    repo = "outfly";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-FRvu3FgbT3i5888ll573nhb7naYx04Oi8nrcfgEHxUo=";
+  };
+
+  runtimeInputs = [
+    libxkbcommon
+    libGL
+    libXrandr
+    libX11
+    vulkan-loader
+  ];
+
+  buildInputs = [
+    alsa-lib.dev
+    libXcursor
+    libXi
+    wayland
+  ];
+
+  nativeBuildInputs = [ pkg-config ];
+  doCheck = false; # no meaningful tests
+
+  postFixup = ''
+    patchelf $out/bin/outfly \
+    --add-rpath ${lib.makeLibraryPath runtimeInputs}
+  '';
+
+  cargoHash = "sha256-5t6PPlfV/INqb4knz1Bv6dqw47RxUmVO0DSlQNUIQL4=";
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "outfly";
+      exec = "outfly";
+      desktopName = "OutFly";
+      categories = [ "Game" ];
+    })
+  ];
+  meta = {
+    description = "Breathtaking 3D space game in the rings of Jupiter";
+    homepage = "https://yunicode.itch.io/outfly";
+    downloadPage = "https://codeberg.org/outfly/outfly/releases";
+    changelog = "https://codeberg.org/outfly/outfly/releases/tag/v${version}";
+    license = with lib.licenses; [
+      cc-by-30
+      cc-by-40
+      cc-by-sa-20
+      cc-by-sa-30
+      cc0
+      gpl3
+      ofl
+      publicDomain
+    ];
+    maintainers = with lib.maintainers; [ _71rd ];
+    mainProgram = "outfly";
+  };
+}

pkgs/by-name/ou/outfox/package.nix

@@ -0,0 +1,88 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoPatchelfHook,
+  alsa-lib,
+  freetype,
+  libjack2,
+  libglvnd,
+  libpulseaudio,
+  makeDesktopItem,
+  makeWrapper,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "outfox";
+  version = "0.5.0-pre042";
+
+  src =
+    {
+      i686-linux = fetchurl {
+        url = "https://github.com/TeamRizu/OutFox/releases/download/OF5.0.0-042/OutFox-alpha-0.5.0-pre042-Linux-14.04-32bit-i386-i386-legacy-date-20231227.tar.gz";
+        hash = "sha256-NFjNoqJ7Fq4A7Y0k6oQcWjykV+/b/MiRtJ1p6qlZdjs=";
+      };
+      x86_64-linux = fetchurl {
+        url = "https://github.com/TeamRizu/OutFox/releases/download/OF5.0.0-042/OutFox-alpha-0.5.0-pre042-Linux-22.04-amd64-current-date-20231224.tar.gz";
+        hash = "sha256-dW+g/JYav3rUuI+nHDi6rXu/O5KYiEdk/HH82jgOUnI=";
+      };
+      aarch64-linux = fetchurl {
+        url = "https://github.com/TeamRizu/OutFox/releases/download/OF5.0.0-042/OutFox-alpha-0.5.0-pre042-Raspberry-Pi-Linux-18.04-arm64-arm64v8-modern-date-20231225.tar.gz";
+        hash = "sha256-7Qrq6t8KmUSIK4Rskkxw5l4UZ2vsb9/orzPegHySaJ4=";
+      };
+      armv7l-linux = fetchurl {
+        url = "https://github.com/TeamRizu/OutFox/releases/download/OF5.0.0-042/OutFox-alpha-0.5.0-pre042-Raspberry-Pi-Linux-14.04-arm32-arm32v7-legacy-date-20231227.tar.gz";
+        hash = "sha256-PRp7kuqFBRy7nextTCB+/poc+A9AX2EiQphx6aUfT8E=";
+      };
+    }
+    .${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    makeWrapper
+  ];
+
+  buildInputs = [
+    alsa-lib
+    freetype
+    libjack2
+    libglvnd
+    libpulseaudio
+  ];
+
+  desktop = makeDesktopItem {
+    name = "project-outfox";
+    desktopName = "Project OutFox";
+    genericName = "Rhythm game engine";
+    exec = "OutFox";
+    tryExec = "OutFox";
+    categories = [ "Game" ];
+  };
+
+  patchPhase = ''
+    find ./Appearance -type f -executable -exec chmod -x {} \;
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/OutFox $out/share/applications
+    cp -r ./. $out/share/OutFox
+    ln -s ${desktop}/share/applications/project-outfox.desktop $out/share/applications/project-outfox.desktop
+    makeWrapper $out/share/OutFox/OutFox $out/bin/OutFox --argv0
+  '';
+
+  meta = {
+    description = "Rhythm game engine forked from StepMania";
+    homepage = "https://projectoutfox.com";
+    changelog = "https://projectoutfox.com/releases/${version}";
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = lib.licenses.unfree;
+    platforms = [
+      "x86_64-linux"
+      "i686-linux"
+      "aarch64-linux"
+      "armv7l-linux"
+    ];
+    maintainers = with lib.maintainers; [ maxwell-lt ];
+    mainProgram = "OutFox";
+  };
+}

pkgs/by-name/ou/outguess/package.nix

@@ -0,0 +1,33 @@
+{
+  fetchFromGitHub,
+  stdenv,
+  lib,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "outguess";
+  version = "0.4";
+
+  src = fetchFromGitHub {
+    owner = "resurrecting-open-source-projects";
+    repo = "outguess";
+    tag = finalAttrs.version;
+    hash = "sha256-yv01jquPTnVk9fd1tqAt1Lxis+ZHZqdG3NiTFxfoXAE=";
+  };
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  strictDeps = true;
+
+  configureFlags = [ "--with-generic-jconfig" ];
+
+  meta = {
+    description = "Universal steganographic tool that allows the insertion of hidden information into the redundant bits of data sources";
+    homepage = "https://github.com/resurrecting-open-source-projects/outguess";
+    license = lib.licenses.bsdOriginal;
+    maintainers = with lib.maintainers; [ HeitorAugustoLN ];
+    mainProgram = "outguess";
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ou/outils/package.nix

@@ -0,0 +1,44 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch2,
+  lib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "outils";
+  version = "0.13";
+
+  src = fetchFromGitHub {
+    owner = "leahneukirchen";
+    repo = "outils";
+    rev = "v${version}";
+    hash = "sha256-FokJytwQsbGsryBzyglpb1Hg3wti/CPQTOfIGIz9ThA=";
+  };
+
+  patches = [
+    (fetchpatch2 {
+      url = "https://github.com/leahneukirchen/outils/commit/50877e1bf7c905044e0b50b227ecff48cfec394b.patch?full_index=1";
+      name = "outils-add-recallocarray-prototype.patch";
+      hash = "sha256-jOnCMPcHKMRR3J0Yh+ZTHAn7P85FO80yXVX0K2vtlVk=";
+    })
+  ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/leahneukirchen/outils";
+    description = "Port of OpenBSD-exclusive tools such as `calendar`, `vis`, and `signify`";
+    license = with licenses; [
+      beerware
+      bsd2
+      bsd3
+      bsdOriginal
+      isc
+      mit
+      publicDomain
+    ];
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ somasis ];
+  };
+}

pkgs/by-name/ou/outputcheck/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  lit,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "outputcheck";
+  version = "0.4.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "stp";
+    repo = "OutputCheck";
+    rev = "eab62a5dd5129f6a4ebfbe4bbe41d35611f7c48d";
+    hash = "sha256-0D5Lljn66jB/EW/ntC2eTuXAt0w0cceeeqf3aKuyeF0=";
+  };
+
+  # - Fix deprecated 'U' mode in python 3.11
+  #   https://github.com/python/cpython/blob/3.11/Doc/library/functions.rst?plain=1#L1386
+  # - Fix expected error and actual parser error mismatch
+  # - Fix version number cannot find error
+  postPatch = ''
+    substituteInPlace OutputCheck/Driver.py \
+      --replace-fail "argparse.FileType('rU')" "argparse.FileType('r')"
+
+    substituteInPlace tests/invalid-regex-syntax.smt2 \
+      --replace-fail "unbalanced parenthesis" "missing ), unterminated subpattern"
+
+    echo ${version} > RELEASE-VERSION
+  '';
+
+  nativeCheckInputs = [ lit ];
+
+  build-system = with python3.pkgs; [ setuptools ];
+
+  checkPhase = ''
+    runHook preCheck
+
+    lit -v tests/
+
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [ "OutputCheck" ];
+
+  meta = {
+    description = "Tool for checking tool output inspired by LLVM's FileCheck";
+    homepage = "https://github.com/stp/OutputCheck";
+    changelog = "https://github.com/stp/OutputCheck/releases/tag/${version}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ fsagbuya ];
+    mainProgram = "OutputCheck";
+  };
+}