push sheeet

pkgs/by-name/ow/owamp/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoconf,
+  automake,
+  mandoc,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "owamp";
+  version = "4.4.6";
+
+  src = fetchFromGitHub {
+    owner = "perfsonar";
+    repo = "owamp";
+    tag = "v${version}";
+    sha256 = "5o85XSn84nOvNjIzlaZ2R6/TSHpKbWLXTO0FmqWsNMU=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+  ];
+  buildInputs = [ mandoc ];
+
+  preConfigure = ''
+    I2util/bootstrap.sh
+    ./bootstrap
+  '';
+
+  meta = with lib; {
+    homepage = "http://software.internet2.edu/owamp/";
+    description = "Tool for performing one-way active measurements";
+    platforms = platforms.linux;
+    maintainers = [ maintainers.teto ];
+    license = licenses.asl20;
+  };
+}

pkgs/by-name/ow/owi/package.nix

@@ -0,0 +1,94 @@
+{
+  lib,
+  ocaml-ng,
+  fetchFromGitHub,
+  llvmPackages,
+  rustc,
+  zig,
+  makeWrapper,
+  unstableGitUpdater,
+  nixosTests,
+}:
+
+let
+  ocamlPackages = ocaml-ng.ocamlPackages_5_2;
+in
+ocamlPackages.buildDunePackage {
+  pname = "owi";
+  version = "0.2-unstable-2025-09-25";
+
+  src = fetchFromGitHub {
+    owner = "ocamlpro";
+    repo = "owi";
+    rev = "3c5ea7f07bf0c530286870bfb37010e44b75677d";
+    fetchSubmodules = true;
+    hash = "sha256-3YGNm60ro9DzjxnjRpE2b1fde4tCxo+y8DM8nS73Hwc=";
+  };
+
+  nativeBuildInputs = with ocamlPackages; [
+    findlib
+    menhir
+    # unwrapped because wrapped tries to enforce a target and the build
+    # script wants to do its own thing
+    llvmPackages.clang-unwrapped
+    # lld + llc isn't included in unwrapped, so we pull it in here
+    llvmPackages.bintools-unwrapped
+    makeWrapper
+    rustc
+    zig
+  ];
+
+  buildInputs = with ocamlPackages; [
+    bos
+    cmdliner
+    digestif
+    dolmen_type
+    dune-build-info
+    dune-site
+    hc
+    integers
+    menhirLib
+    ocaml_intrinsics
+    patricia-tree
+    prelude
+    processor
+    scfg
+    sedlex
+    smtml
+    uutf
+    xmlm
+    yojson
+    z3
+    zarith
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/owi \
+      --prefix PATH : ${
+        lib.makeBinPath [
+          llvmPackages.bintools-unwrapped
+          llvmPackages.clang-unwrapped
+          rustc
+          zig
+        ]
+      }
+  '';
+
+  doCheck = false;
+
+  passthru = {
+    updateScript = unstableGitUpdater { };
+    tests = { inherit (nixosTests) owi; };
+  };
+
+  meta = {
+    description = "Symbolic execution for Wasm, C, C++, Rust and Zig";
+    homepage = "https://ocamlpro.github.io/owi/";
+    downloadPage = "https://github.com/OCamlPro/owi";
+    license = lib.licenses.agpl3Plus;
+    maintainers = [ lib.maintainers.ethancedwards8 ];
+    teams = with lib.teams; [ ngi ];
+    mainProgram = "owi";
+    badPlatforms = lib.platforms.darwin;
+  };
+}

pkgs/by-name/ow/owl-compositor/package.nix

@@ -0,0 +1,89 @@
+{
+  lib,
+  clangStdenv,
+  fetchFromGitHub,
+  gnustep-back,
+  wrapGNUstepAppsHook,
+  libxkbcommon,
+  makeWrapper,
+  wayland,
+  wayland-scanner,
+  darwin,
+}:
+
+let
+  stdenv = clangStdenv;
+in
+
+stdenv.mkDerivation {
+  pname = "owl-compositor";
+  version = "0-unstable-2021-11-10";
+
+  src = fetchFromGitHub {
+    owner = "owl-compositor";
+    repo = "owl";
+    rev = "91abf02613cd2ddb97be58b5b6703240320233a0";
+    hash = "sha256-a+TznasOVEzSNrs66/y91AeMRDEfyd+WO5mO811hLj0=";
+  };
+
+  # use pregenerated nib files because generating them requires Xcode
+  postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    sed -i "/ibtool/d" configure
+    mkdir -p build/Owl.app/Contents/Resources/English.lproj
+    cp ${./mac/MainMenu.nib} build/Owl.app/Contents/Resources/English.lproj/MainMenu.nib
+    cp ${./mac/OwlPreferences.nib} build/Owl.app/Contents/Resources/English.lproj/OwlPreferences.nib
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    makeWrapper
+    wayland-scanner
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    darwin.DarwinTools
+    darwin.bootstrap_cmds
+  ]
+  ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [
+    wrapGNUstepAppsHook
+  ];
+
+  buildInputs = [
+    libxkbcommon
+    wayland
+  ]
+  ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [
+    gnustep-back
+  ];
+
+  preConfigure = ''
+    mkdir -p build
+    cd build
+  '';
+
+  configureScript = "../configure";
+
+  # error: "Your gnustep-base was configured for the objc-nonfragile-abi but you are not using it now."
+  env.NIX_CFLAGS_COMPILE = lib.optionalString (
+    !stdenv.hostPlatform.isDarwin
+  ) "-fobjc-runtime=gnustep-2.0";
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{Applications,bin}
+    mv Owl.app $out/Applications
+    makeWrapper $out/{Applications/Owl.app${lib.optionalString stdenv.hostPlatform.isDarwin "/Contents/MacOS"},bin}/Owl
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Portable Wayland compositor in Objective-C";
+    homepage = "https://github.com/owl-compositor/owl";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ wegank ];
+    platforms = platforms.unix;
+    mainProgram = "Owl";
+  };
+}

pkgs/by-name/ow/owl-lisp/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  which,
+  dash,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "owl-lisp";
+  version = "0.2.2";
+
+  src = fetchFromGitLab {
+    owner = "owl-lisp";
+    repo = "owl";
+    rev = "v${version}";
+    hash = "sha256-GfvOkYLo8fgAvGuUa59hDy+sWJSwyntwqMO8TAK/lUo=";
+  };
+
+  nativeBuildInputs = [
+    which
+    dash
+  ];
+
+  # Tests fail with bash, replacing with dash seems to work around it
+  # FIXME: Why?
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail 'sh tests/run' 'dash tests/run'
+  '';
+
+  makeFlags = [
+    "PREFIX=${placeholder "out"}"
+    "CC=${stdenv.cc.targetPrefix}cc"
+  ];
+
+  # tests are run as part of the compilation process
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Functional Scheme for world domination";
+    homepage = "https://gitlab.com/owl-lisp/owl";
+    license = licenses.mit;
+    maintainers = with maintainers; [ peterhoeg ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/ow/owl/package.nix

@@ -0,0 +1,38 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  libev,
+  libnl,
+  libpcap,
+}:
+
+stdenv.mkDerivation {
+  pname = "owl";
+  version = "0-unstable-2022-01-30";
+
+  src = fetchFromGitHub {
+    owner = "seemoo-lab";
+    repo = "owl";
+    rev = "8e4e840b212ae5a09a8a99484be3ab18bad22fa7";
+    hash = "sha256-kFk+JFLGWGBu5FPH3qp/Bxa6t04f1kpeHz3H8GNF3fg=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [
+    libev
+    libnl
+    libpcap
+  ];
+
+  meta = with lib; {
+    description = "Open Apple Wireless Direct Link (AWDL) implementation written in C";
+    homepage = "https://owlink.org/";
+    license = licenses.gpl3Only;
+    maintainers = [ ];
+    platforms = [ "x86_64-linux" ];
+    mainProgram = "owl";
+  };
+}

pkgs/by-name/ow/owmods-cli/package.nix

@@ -0,0 +1,75 @@
+{
+  lib,
+  stdenv,
+  nix-update-script,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  installShellFiles,
+  zstd,
+  libsoup_3,
+  makeWrapper,
+  mono,
+  wrapWithMono ? true,
+  openssl,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "owmods-cli";
+  version = "0.15.2";
+
+  src = fetchFromGitHub {
+    owner = "ow-mods";
+    repo = "ow-mod-man";
+    rev = "cli_v${version}";
+    hash = "sha256-5ymU9X4J5UPLHxV+7WB29e5Wuq++wYA9bqI2YPjDtWs=";
+  };
+
+  cargoHash = "sha256-Z/muI8JLjOFJBSIMWlvCyFW4JI3lP6/O0AI8Uj8AtBo=";
+
+  nativeBuildInputs = [
+    pkg-config
+    installShellFiles
+  ]
+  ++ lib.optional wrapWithMono makeWrapper;
+
+  buildInputs = [
+    zstd
+    libsoup_3
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    openssl
+  ];
+
+  env = {
+    ZSTD_SYS_USE_PKG_CONFIG = true;
+  };
+
+  buildAndTestSubdir = "owmods_cli";
+
+  postInstall = ''
+    cargo xtask dist_cli
+    installManPage dist/cli/man/*
+    installShellCompletion --cmd owmods \
+    dist/cli/completions/owmods.{bash,fish,zsh}
+  ''
+  + lib.optionalString wrapWithMono ''
+    wrapProgram $out/bin/${meta.mainProgram} --prefix PATH : '${mono}/bin'
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "CLI version of the mod manager for Outer Wilds Mod Loader";
+    homepage = "https://github.com/ow-mods/ow-mod-man/tree/main/owmods_cli";
+    downloadPage = "https://github.com/ow-mods/ow-mod-man/releases/tag/cli_v${version}";
+    changelog = "https://github.com/ow-mods/ow-mod-man/releases/tag/cli_v${version}";
+    mainProgram = "owmods";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [
+      bwc9876
+      spoonbaker
+      locochoco
+    ];
+  };
+}

pkgs/by-name/ow/owmods-gui/package.nix

@@ -0,0 +1,122 @@
+{
+  lib,
+  libsoup_3,
+  dbus,
+  glib,
+  glib-networking,
+  librsvg,
+  webkitgtk_4_1,
+  pkg-config,
+  wrapGAppsHook3,
+  makeDesktopItem,
+  copyDesktopItems,
+  rustPlatform,
+  buildNpmPackage,
+  fetchFromGitHub,
+  mono,
+  wrapWithMono ? true,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "owmods-gui";
+  version = "0.15.3";
+
+  src = fetchFromGitHub {
+    owner = "ow-mods";
+    repo = "ow-mod-man";
+    tag = "gui_v${version}";
+    hash = "sha256-mR4CKcdwlkJPyYK0KPSGbWMaSmHlGo5kOGHoZybduco=";
+  };
+
+  cargoHash = "sha256-KcJAbhIeScFHLjEboQmt0NiqoIen2TihtDJaJwsVuEQ=";
+
+  buildFeatures = [
+    "tauri/custom-protocol"
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    copyDesktopItems
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    dbus
+    libsoup_3
+    glib
+    librsvg
+    glib-networking
+    webkitgtk_4_1
+  ];
+
+  buildAndTestSubdir = "owmods_gui/backend";
+
+  preFixup = lib.optionalString wrapWithMono "gappsWrapperArgs+=(--prefix PATH : '${mono}/bin')";
+
+  postPatch =
+    let
+      frontend = buildNpmPackage {
+        inherit version;
+
+        env.VITE_VERSION_SUFFIX = "-nix";
+
+        pname = "owmods-gui-ui";
+        src = "${src}/owmods_gui/frontend";
+
+        packageJSON = "${src}/owmods_gui/frontend/package.json";
+        npmDepsHash = "sha256-puDgzzzYy9HsuMo5V/E8Z8k6blCkl01JdfbpdhtnvS0=";
+
+        postBuild = ''
+          cp -r ../dist/ $out
+        '';
+        distPhase = "true";
+        dontInstall = true;
+        installInPlace = true;
+        distDir = "../dist";
+
+        meta = {
+          description = "Web frontend for the Outer Wilds Mod Manager";
+          homepage = "https://github.com/ow-mods/ow-mod-man/tree/main/owmods_gui/frontend";
+          license = lib.licenses.gpl3Plus;
+        };
+      };
+    in
+    ''
+      substituteInPlace owmods_gui/backend/tauri.conf.json \
+        --replace-fail '"frontendDist": "../dist"' '"frontendDist": "${frontend}"'
+    '';
+
+  postInstall = ''
+    install -DT owmods_gui/backend/icons/128x128@2x.png $out/share/icons/hicolor/256x256@2/apps/outer-wilds-mod-manager.png
+    install -DT owmods_gui/backend/icons/128x128.png $out/share/icons/hicolor/128x128/apps/outer-wilds-mod-manager.png
+    install -DT owmods_gui/backend/icons/32x32.png $out/share/icons/hicolor/32x32/apps/outer-wilds-mod-manager.png
+
+    mv $out/bin/owmods_gui $out/bin/outer-wilds-mod-manager
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "outer-wilds-mod-manager";
+      exec = "outer-wilds-mod-manager %u";
+      icon = "outer-wilds-mod-manager";
+      desktopName = "Outer Wilds Mod Manager";
+      categories = [ "Game" ];
+      comment = "Manage Outer Wilds Mods";
+      mimeTypes = [ "x-scheme-handler/owmods" ];
+    })
+  ];
+
+  meta = {
+    description = "GUI version of the mod manager for Outer Wilds Mod Loader";
+    homepage = "https://github.com/ow-mods/ow-mod-man/tree/main/owmods_gui";
+    downloadPage = "https://github.com/ow-mods/ow-mod-man/releases/tag/gui_v${version}";
+    changelog = "https://github.com/ow-mods/ow-mod-man/releases/tag/gui_v${version}";
+    mainProgram = "outer-wilds-mod-manager";
+    platforms = lib.platforms.linux;
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [
+      bwc9876
+      locochoco
+      spoonbaker
+    ];
+  };
+}

pkgs/by-name/ow/owncast/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nixosTests,
+  bash,
+  which,
+  ffmpeg-full,
+  makeBinaryWrapper,
+}:
+let
+  version = "0.2.3";
+in
+buildGoModule {
+  pname = "owncast";
+  inherit version;
+  src = fetchFromGitHub {
+    owner = "owncast";
+    repo = "owncast";
+    rev = "v${version}";
+    hash = "sha256-JCIB4G3cOSkEEO/jcsj4mUP+HeQfgn0jX4OL8NX9/C0=";
+  };
+  vendorHash = "sha256-FuynEBoPS0p1bRgmaeCxn1RPqbYHcltZpQ9SE71xHEE=";
+
+  propagatedBuildInputs = [ ffmpeg-full ];
+
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  # lefthook is included as a tool in go.mod for a pre-commit hook, but causes the build to fail
+  preBuild = ''
+    # Remove lefthook from tools section in go.mod
+    sed -i '/tool (/,/)/{ /[[:space:]]*github.com\/evilmartians\/lefthook[[:space:]]*$/d; }' go.mod
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/owncast \
+      --prefix PATH : ${
+        lib.makeBinPath [
+          bash
+          which
+          ffmpeg-full
+        ]
+      }
+  '';
+
+  installCheckPhase = ''
+    runHook preCheck
+    $out/bin/owncast --help
+    runHook postCheck
+  '';
+
+  passthru.tests.owncast = nixosTests.owncast;
+
+  meta = with lib; {
+    description = "Self-hosted video live streaming solution";
+    homepage = "https://owncast.online";
+    license = licenses.mit;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [
+      flexiondotorg
+      MayNiklas
+    ];
+    mainProgram = "owncast";
+  };
+}

pkgs/by-name/ow/owncloud-client/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nix-update-script,
+  qt6Packages,
+  # nativeBuildInputs
+  pkg-config,
+  cmake,
+  extra-cmake-modules,
+  # buildInputs
+  sqlite,
+  libsecret,
+  libre-graph-api-cpp-qt-client,
+  kdsingleapplication,
+  ## darwin only
+  libinotify-kqueue,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "owncloud-client";
+  version = "5.3.2";
+
+  src = fetchFromGitHub {
+    owner = "owncloud";
+    repo = "client";
+    tag = "v${version}";
+    hash = "sha256-HEnjtedmdNJTpc/PmEyoEsLGUydFkVF3UAsSdzQ4L1Q=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+    extra-cmake-modules
+    qt6Packages.qttools
+    qt6Packages.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    sqlite
+    libsecret
+    qt6Packages.qtbase
+    qt6Packages.qtsvg # Needed for the systray icon
+    qt6Packages.qtkeychain
+    libre-graph-api-cpp-qt-client
+    kdsingleapplication
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    libinotify-kqueue
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Synchronise your ownCloud with your computer using this desktop client";
+    homepage = "https://owncloud.org";
+    maintainers = with lib.maintainers; [
+      qknight
+      hellwolf
+    ];
+    platforms = lib.platforms.unix;
+    license = lib.licenses.gpl2Plus;
+    changelog = "https://github.com/owncloud/client/releases/tag/v${version}";
+  };
+}

pkgs/by-name/ow/owntone/package.nix

@@ -0,0 +1,100 @@
+{
+  config,
+  lib,
+  stdenv,
+  autoPatchelfHook,
+  autoreconfHook,
+  fetchFromGitHub,
+  nix-update-script,
+
+  chromecastSupport ? config.chromecast or stdenv.hostPlatform.isLinux,
+  pulseSupport ? config.pulseaudio or stdenv.hostPlatform.isLinux,
+
+  avahi,
+  curl,
+  bison,
+  ffmpeg,
+  flex,
+  gettext,
+  gnutls,
+  gperf,
+  json_c,
+  libconfuse,
+  libevent,
+  libgcrypt,
+  libgpg-error,
+  libplist,
+  libpulseaudio,
+  libsodium,
+  libtool,
+  libunistring,
+  libwebsockets,
+  libxml2,
+  pkg-config,
+  protobufc,
+  sqlite,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  version = "28.12";
+  pname = "owntone";
+
+  src = fetchFromGitHub {
+    owner = "owntone";
+    repo = "owntone-server";
+    tag = finalAttrs.version;
+    hash = "sha256-Mj3G1+Hwa/zl0AM4SO6TcB4W3WJkpIDzrSPEFx0vaEk=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    autoreconfHook
+    bison
+    flex
+    libtool
+    gperf
+    pkg-config
+  ];
+
+  buildInputs = [
+    avahi
+    curl
+    ffmpeg
+    gettext
+    json_c
+    libconfuse
+    libevent
+    libgcrypt
+    libgpg-error
+    libplist
+    libsodium
+    libunistring
+    libwebsockets
+    libxml2
+    protobufc
+    sqlite
+    zlib
+  ]
+  ++ lib.optionals chromecastSupport [ gnutls ]
+  ++ lib.optionals pulseSupport [ libpulseaudio ];
+
+  configureFlags =
+    lib.optionals chromecastSupport [ "--enable-chromecast" ]
+    ++ lib.optionals pulseSupport [ "--with-pulseaudio" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Media server to stream audio to AirPlay and Chromecast receivers";
+    homepage = "https://github.com/owntone/owntone-server";
+    downloadPage = "https://github.com/owntone/owntone-server/releases/tag/${finalAttrs.version}";
+    changelog = "https://github.com/owntone/owntone-server/releases/tag/${finalAttrs.version}";
+    mainProgram = "owntone";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      hensoko
+    ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/ow/owntracks-recorder/package.nix

@@ -0,0 +1,86 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  mosquitto,
+  curl,
+  openssl,
+  lmdb,
+  lua,
+  libsodium,
+  libuuid,
+  libconfig,
+  testers,
+  owntracks-recorder,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "owntracks-recorder";
+  version = "1.0.1";
+
+  src = fetchFromGitHub {
+    owner = "owntracks";
+    repo = "recorder";
+    rev = finalAttrs.version;
+    hash = "sha256-/nLt8R8s3k6MQhtMXOLUDluuU7eNwZGYh5/km8tXtiE=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    (lib.getDev curl)
+    (lib.getLib libconfig)
+    (lib.getDev openssl)
+    (lib.getDev lmdb)
+    (lib.getDev mosquitto)
+    (lib.getDev libuuid)
+    (lib.getDev lua)
+    (lib.getDev libsodium)
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    cp config.mk.in config.mk
+
+    substituteInPlace config.mk \
+      --replace "INSTALLDIR = /usr/local" "INSTALLDIR = $out" \
+      --replace "DOCROOT = /var/spool/owntracks/recorder/htdocs" "DOCROOT = $out/htdocs" \
+      --replace "WITH_LUA ?= no" "WITH_LUA ?= yes" \
+      --replace "WITH_ENCRYPT ?= no" "WITH_ENCRYPT ?= yes"
+
+    runHook postConfigure
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+
+    install -m 0755 ot-recorder $out/bin
+    install -m 0755 ocat $out/bin
+
+    cp -r docroot $out/htdocs
+
+    runHook postInstall
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = owntracks-recorder;
+    command = "ocat --version";
+    version = finalAttrs.version;
+  };
+
+  meta = with lib; {
+    description = "Store and access data published by OwnTracks apps";
+    homepage = "https://github.com/owntracks/recorder";
+    changelog = "https://github.com/owntracks/recorder/blob/master/Changelog";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ gaelreyrol ];
+    mainProgram = "ot-recorder";
+  };
+})

pkgs/by-name/ow/owocr/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+}:
+
+python3Packages.buildPythonApplication {
+  pname = "owocr";
+  version = "1.7.5-unstable-2024-06-26";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "AuroraWright";
+    repo = "owocr";
+    rev = "743c64aa16a760f87bf5ea1f54364d828eb3eddb"; # no tags
+    hash = "sha256-TXQwJRgRp7fZBN0r4XGVtlb+iOMRqEUf+LbfBG/vsr8=";
+  };
+
+  build-system = [ python3Packages.setuptools ];
+
+  dependencies = with python3Packages; [
+    fire
+    jaconv
+    loguru
+    numpy
+    pillow
+    pyperclipfix
+    pynput
+    websockets
+    desktop-notifier
+    mss
+    pysbd
+    langid
+    psutil
+    pywinctl
+    # extra optional libs for OCR engines
+    azure-ai-vision-imageanalysis
+    easyocr
+    pyjson5 # Google Lens
+    google-cloud-vision
+    manga-ocr
+    rapidocr
+    requests # winRT OCR
+  ];
+
+  doCheck = false; # no tests
+
+  meta = {
+    description = "Optical character recognition for Japanese text";
+    homepage = "https://github.com/AuroraWright/owocr";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ sigmanificient ];
+  };
+}

pkgs/by-name/ow/owofetch/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  stdenvNoCC,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "owofetch";
+
+  version = "0.3.1";
+
+  src = fetchFromGitHub {
+    owner = "netthier";
+    repo = "owofetch-rs";
+    rev = "v${version}";
+    sha256 = "sha256-I8mzOUvm72KLLBumpgn9gNyx9FKvUrB4ze1iM1+OA18=";
+  };
+
+  cargoHash = "sha256-0ON1h8+ruLOvBR7Q/hOIW6j+BjfPAAuYA2wrUYj59Ow=";
+
+  meta = with lib; {
+    description = "Alternative to *fetch, uwuifies all stats";
+    homepage = "https://github.com/netthier/owofetch-rs";
+    license = licenses.gpl3Only;
+    platforms = platforms.x86_64;
+    maintainers = with maintainers; [ nullishamy ];
+    mainProgram = "owofetch";
+  };
+}