push sheeet

pkgs/by-name/pr/proxychains-ng/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  # "dlsym" for OSX version < 12
+  darwinHookMethod ? "dyld",
+}:
+
+stdenv.mkDerivation rec {
+  pname = "proxychains-ng";
+  version = "4.17";
+
+  src = fetchFromGitHub {
+    owner = "rofl0r";
+    repo = "proxychains-ng";
+    rev = "v${version}";
+    sha256 = "sha256-cHRWPQm6aXsror0z+S2Ddm7w14c1OvEruDublWsvnXs=";
+  };
+
+  patches = [
+    # https://github.com/NixOS/nixpkgs/issues/136093
+    ./swap-priority-4-and-5-in-get_config_path.patch
+    # The fix is not present in v4.17; remove the patch next version update.
+    # https://github.com/rofl0r/proxychains-ng/issues/557
+    (fetchpatch {
+      url = "https://github.com/rofl0r/proxychains-ng/commit/fffd2532ad34bdf7bf430b128e4c68d1164833c6.patch";
+      hash = "sha256-l3qSFUDMUfVDW1Iw+R2aW/wRz4CxvpR4eOwx9KzuAAo=";
+    })
+  ];
+
+  configureFlags = lib.optionals stdenv.hostPlatform.isDarwin [
+    "--hookmethod=${darwinHookMethod}"
+  ];
+
+  installFlags = [
+    "install-config"
+    "install-zsh-completion"
+  ];
+
+  meta = with lib; {
+    description = "Preloader which hooks calls to sockets in dynamically linked programs and redirects it through one or more socks/http proxies";
+    homepage = "https://github.com/rofl0r/proxychains-ng";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [
+      zenithal
+      usertam
+    ];
+    platforms = platforms.unix;
+    mainProgram = "proxychains4";
+  };
+}

pkgs/by-name/pr/proxychains-ng/swap-priority-4-and-5-in-get_config_path.patch

@@ -0,0 +1,25 @@
+diff --git a/src/common.c b/src/common.c
+index 1da1c45..fb68ada 100644
+--- a/src/common.c
++++ b/src/common.c
+@@ -113,13 +113,13 @@ char *get_config_path(char* default_path, char* pbuf, size_t bufsize) {
+ 	if(check_path(path))
+ 		goto have;
+ 
+-	// priority 4: $SYSCONFDIR/proxychains.conf
+-	path = SYSCONFDIR "/" PROXYCHAINS_CONF_FILE;
++	// priority 4: /etc/proxychains.conf
++	path = "/etc/" PROXYCHAINS_CONF_FILE;
+ 	if(check_path(path))
+ 		goto have;
+ 
+-	// priority 5: /etc/proxychains.conf
+-	path = "/etc/" PROXYCHAINS_CONF_FILE;
++	// priority 5: $SYSCONFDIR/proxychains.conf
++	path = SYSCONFDIR "/" PROXYCHAINS_CONF_FILE;
+ 	if(check_path(path))
+ 		goto have;
+ 
+-- 
+2.37.2
+