push sheeet

pkgs/by-name/re/renpy/noSteam.patch

@@ -0,0 +1,16 @@
+diff --git a/renpy/common/00steam.rpy b/renpy/common/00steam.rpy
+index 9a5f9c405..68c8c26e0 100644
+--- a/renpy/common/00steam.rpy
++++ b/renpy/common/00steam.rpy
+@@ -1029,11 +1029,6 @@ init -1499 python in achievement:
+             steam = None
+             steamapi = None
+ 
+-    if renpy.windows or renpy.macintosh or renpy.linux:
+-        steam_preinit()
+-        steam_init()
+-
+-
+ init 1500 python in achievement:
+ 
+     # Steam position.

pkgs/by-name/re/renpy/package.nix

@@ -0,0 +1,144 @@
+{
+  assimp,
+  fetchFromGitHub,
+  ffmpeg,
+  freetype,
+  fribidi,
+  glew,
+  harfbuzz,
+  lib,
+  libGL,
+  libGLU,
+  libpng,
+  makeWrapper,
+  pkg-config,
+  python3,
+  SDL2,
+  stdenv,
+  versionCheckHook,
+  withoutSteam ? true,
+  zlib,
+}:
+
+let
+  python = python3;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "renpy";
+  version = "8.4.1.25072401";
+
+  src = fetchFromGitHub {
+    owner = "renpy";
+    repo = "renpy";
+    tag = finalAttrs.version;
+    hash = "sha256-wJnMqUrRGWcsuZWdqbiUI/BD2sSRjJKEzsCOzSngoZM=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    pkg-config
+    python.pkgs.cython
+    python.pkgs.setuptools
+  ];
+
+  buildInputs = [
+    assimp
+    ffmpeg
+    freetype
+    fribidi
+    glew
+    harfbuzz
+    libGL
+    libGLU
+    libpng
+    SDL2
+    zlib
+  ]
+  ++ (with python.pkgs; [
+    ecdsa
+    future
+    pefile
+    pygame-sdl2
+    python
+    requests
+    six
+    tkinter
+  ]);
+
+  RENPY_DEPS_INSTALL = lib.concatStringsSep "::" (
+    [
+      ffmpeg.lib
+      freetype
+      fribidi
+      glew.dev
+      harfbuzz.dev
+      libpng
+      SDL2
+      (lib.getDev SDL2)
+      zlib
+    ]
+    ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [
+      libGL
+      libGLU
+    ]
+  );
+
+  enableParallelBuilding = true;
+
+  patches = [
+    ./shutup-erofs-errors.patch
+  ]
+  ++ lib.optional withoutSteam ./noSteam.patch;
+
+  postPatch = ''
+    cp tutorial/game/tutorial_director.rpy{m,}
+
+    cat > renpy/vc_version.py << EOF
+    version = '${finalAttrs.version}'
+    official = False
+    nightly = False
+    # Look at https://renpy.org/latest.html for what to put.
+    version_name = "Tomorrowland"
+    EOF
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+    ${python.pythonOnBuildForHost.interpreter} setup.py build --parallel=$NIX_BUILD_CORES
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    ${python.pythonOnBuildForHost.interpreter} setup.py install_lib -d $out/${python.sitePackages}
+    mkdir -p $out/share/renpy
+    cp -vr sdk-fonts gui launcher renpy the_question tutorial renpy.py $out/share/renpy
+
+    makeWrapper ${python.interpreter} $out/bin/renpy \
+      --set PYTHONPATH "$PYTHONPATH:$out/${python.sitePackages}" \
+      --add-flags "$out/share/renpy/renpy.py"
+
+    runHook postInstall
+  '';
+
+  env = {
+    NIX_CFLAGS_COMPILE = "-I${python.pkgs.pygame-sdl2}/include";
+  };
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  doInstallCheck = true;
+  versionCheckProgramArg = "--version";
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    description = "Visual Novel Engine";
+    mainProgram = "renpy";
+    homepage = "https://renpy.org/";
+    changelog = "https://renpy.org/doc/html/changelog.html";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ shadowrz ];
+  };
+})

pkgs/by-name/re/renpy/shutup-erofs-errors.patch

@@ -0,0 +1,29 @@
+From 09e598ddf1f6af72ccb6c7c9301abff689e64f88 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?=E5=A4=9C=E5=9D=82=E9=9B=85?=
+ <23130178+ShadowRZ@users.noreply.github.com>
+Date: Wed, 17 May 2023 14:32:03 +0800
+Subject: [PATCH] Don't print a backtrace on EROFS
+
+This can shut up EROFS errors caused by writing to read-only /nix/store.
+---
+ renpy/script.py | 4 ++++
+ 1 file changed, 4 insertions(+)
+
+diff --git a/renpy/script.py b/renpy/script.py
+index de35457ba..b7d511560 100644
+--- a/renpy/script.py
++++ b/renpy/script.py
+@@ -705,6 +705,10 @@ class Script(object):
+                                 rpydigest = hashlib.md5(fullf.read()).digest()
+ 
+                             self.write_rpyc_md5(f, rpydigest)
++                    except OSError as e:
++                        if e.errno != 30:
++                            import traceback
++                            traceback.print_exc()
+                     except Exception:
+                         import traceback
+                         traceback.print_exc()
+-- 
+2.40.1
+

pkgs/by-name/re/renpy/update.sh

@@ -0,0 +1,11 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p bash nix-update html-xml-utils
+
+set -ex
+
+SCRIPT_DIR="$(cd "$(dirname "${BASH_SOURCE[0]}")" &>/dev/null && pwd)"
+
+codename=`curl -L https://renpy.org/latest.html | hxclean | hxselect -c h1 small`
+sed -E -i "s/(version_name = ).*/\1$codename/" $SCRIPT_DIR/package.nix
+
+nix-update renpy