push sheeet

pkgs/by-name/rq/rq/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "rq";
+  version = "1.0.4";
+
+  src = fetchFromGitHub {
+    owner = "dflemstr";
+    repo = "rq";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-QyYTbMXikLSe3eYJRUALQJxUJjA6VlvaLMwGrxIKfZI=";
+  };
+
+  cargoHash = "sha256-BwbGiLoygNUua+AAKw/JAAG1kuWLdnP+8o+FFuvbFlM=";
+
+  postPatch = ''
+    # Remove #[deny(warnings)] which is equivalent to -Werror in C.
+    # Prevents build failures when upgrading rustc, which may give more warnings.
+    substituteInPlace src/lib.rs \
+      --replace-fail "#![deny(warnings)]" ""
+
+    # build script tries to get version information from git
+    # this fixes the --version output
+    rm build.rs
+  '';
+
+  VERGEN_SEMVER = finalAttrs.version;
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Tool for doing record analysis and transformation";
+    mainProgram = "rq";
+    homepage = "https://github.com/dflemstr/rq";
+    license = with lib.licenses; [ asl20 ];
+    maintainers = with lib.maintainers; [
+      aristid
+      Br1ght0ne
+      figsoda
+    ];
+  };
+})

pkgs/by-name/rq/rqbit/package.nix

@@ -0,0 +1,87 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  openssl,
+  buildNpmPackage,
+  nodejs_20,
+  nix-update-script,
+}:
+let
+  pname = "rqbit";
+
+  version = "8.1.1";
+
+  src = fetchFromGitHub {
+    owner = "ikatson";
+    repo = "rqbit";
+    rev = "v${version}";
+    hash = "sha256-5ErcI3hwC2EgxsjgEVlbHP1MzBf/LndpgTfynQGc29s=";
+  };
+
+  rqbit-webui = buildNpmPackage {
+    pname = "rqbit-webui";
+
+    nodejs = nodejs_20;
+
+    inherit version src;
+
+    sourceRoot = "${src.name}/crates/librqbit/webui";
+
+    npmDepsHash = "sha256-vib8jpf7Jn1qv0m/dWJ4TbisByczNbtEd8hIM5ll2Q8=";
+
+    installPhase = ''
+      runHook preInstall
+
+      mkdir -p $out/dist
+      cp -r dist/** $out/dist
+
+      runHook postInstall
+    '';
+  };
+in
+rustPlatform.buildRustPackage {
+  inherit pname version src;
+
+  cargoHash = "sha256-gYasOjrG0oeT/6Ben57MKAvBtgpoSmZ93RZQqSXAxIc=";
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [ pkg-config ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ openssl ];
+
+  preConfigure = ''
+    mkdir -p crates/librqbit/webui/dist
+    cp -R ${rqbit-webui}/dist/** crates/librqbit/webui/dist
+  '';
+
+  postPatch = ''
+    # This script fascilitates the build of the webui,
+    #  we've already built that
+    rm crates/librqbit/build.rs
+  '';
+
+  doCheck = false;
+
+  passthru.webui = rqbit-webui;
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--subpackage"
+      "webui"
+    ];
+  };
+
+  meta = {
+    description = "Bittorrent client in Rust";
+    homepage = "https://github.com/ikatson/rqbit";
+    changelog = "https://github.com/ikatson/rqbit/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      cafkafk
+      toasteruwu
+    ];
+    mainProgram = "rqbit";
+  };
+}

pkgs/by-name/rq/rqlite/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "rqlite";
+  version = "9.1.2";
+
+  src = fetchFromGitHub {
+    owner = "rqlite";
+    repo = "rqlite";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-7QAJofhssL2N5szD4j9rcv830sEnMyrS2Mg4s4G33HI=";
+  };
+
+  vendorHash = "sha256-zGAC7yDccfhZ+2WeiN9DAsOFTa3j4ymPxeFNwam7+Ts=";
+
+  subPackages = [
+    "cmd/rqlite"
+    "cmd/rqlited"
+    "cmd/rqbench"
+  ];
+
+  # Leaving other flags from https://github.com/rqlite/rqlite/blob/master/package.sh
+  # since automatically retrieving those is nontrivial and inessential
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/rqlite/rqlite/cmd.Version=${finalAttrs.version}"
+  ];
+
+  # Tests are in a different subPackage which fails trying to access the network
+  doCheck = false;
+
+  meta = {
+    description = "Lightweight, distributed relational database built on SQLite";
+    homepage = "https://github.com/rqlite/rqlite";
+    changelog = "https://github.com/rqlite/rqlite/blob/${finalAttrs.src.tag}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ dit7ya ];
+  };
+})

pkgs/by-name/rq/rquickshare/fix-pnpm-outdated-lockfile.patch

@@ -0,0 +1,35 @@
+diff --git a/app/legacy/pnpm-lock.yaml b/app/legacy/pnpm-lock.yaml
+index ce6a292..76ba03e 100644
+--- a/app/legacy/pnpm-lock.yaml
++++ b/app/legacy/pnpm-lock.yaml
+@@ -12,8 +12,8 @@ importers:
+         specifier: link:../../core_lib
+         version: link:../../core_lib
+       '@tauri-apps/api':
+-        specifier: 1.5.6
+-        version: 1.5.6
++        specifier: 1.6.0
++        version: 1.6.0
+       pinia:
+         specifier: ^2.2.1
+         version: 2.2.1(typescript@5.6.0-dev.20240811)(vue@3.4.27(typescript@5.6.0-dev.20240811))
+@@ -500,10 +500,6 @@ packages:
+     peerDependencies:
+       tailwindcss: '>=3.0.0 || insiders'
+ 
+-  '@tauri-apps/api@1.5.6':
+-    resolution: {integrity: sha512-LH5ToovAHnDVe5Qa9f/+jW28I6DeMhos8bNDtBOmmnaDpPmJmYLyHdeDblAWWWYc7KKRDg9/66vMuKyq0WIeFA==}
+-    engines: {node: '>= 14.6.0', npm: '>= 6.6.0', yarn: '>= 1.19.1'}
+-
+   '@tauri-apps/api@1.6.0':
+     resolution: {integrity: sha512-rqI++FWClU5I2UBp4HXFvl+sBWkdigBkxnpJDQUWttNyG7IZP4FwQGhTNL5EOw0vI8i6eSAJ5frLqO7n7jbJdg==}
+     engines: {node: '>= 14.6.0', npm: '>= 6.6.0', yarn: '>= 1.19.1'}
+@@ -2707,8 +2703,6 @@ snapshots:
+       postcss-selector-parser: 6.0.10
+       tailwindcss: 3.4.9
+ 
+-  '@tauri-apps/api@1.5.6': {}
+-
+   '@tauri-apps/api@1.6.0': {}
+ 
+   '@tauri-apps/cli-darwin-arm64@1.5.14':

pkgs/by-name/rq/rquickshare/package.nix

@@ -0,0 +1,133 @@
+{
+  lib,
+  cargo-tauri,
+  cargo-tauri_1,
+  fetchFromGitHub,
+  glib-networking,
+  libayatana-appindicator,
+  libsoup_2_4,
+  libsoup_3,
+  nix-update,
+  nodejs,
+  openssl,
+  pkg-config,
+  pnpm_9,
+  protobuf,
+  rustPlatform,
+  stdenv,
+  webkitgtk_4_0,
+  webkitgtk_4_1,
+  wrapGAppsHook4,
+  writeShellScript,
+
+  # This package provides can be built using tauri v1 or v2.
+  # Try legacy (v1) version if main (v2) doesn't work.
+  app-type ? "main", # main or legacy
+}:
+let
+  app-type-either =
+    arg1: arg2:
+    if app-type == "main" then
+      arg1
+    else if app-type == "legacy" then
+      arg2
+    else
+      throw "Wrong argument for app-type in rquickshare package";
+
+  proper-cargo-tauri = app-type-either cargo-tauri cargo-tauri_1;
+in
+rustPlatform.buildRustPackage rec {
+  pname = "rquickshare" + (app-type-either "" "-legacy");
+  version = "0.11.5";
+
+  src = fetchFromGitHub {
+    owner = "Martichou";
+    repo = "rquickshare";
+    tag = "v${version}";
+    hash = "sha256-DZdzk0wqKhVa51PgQf8UsAY6EbGKvRIGru71Z8rvrwA=";
+  };
+
+  patches = [ ./fix-pnpm-outdated-lockfile.patch ];
+
+  # from https://github.com/NixOS/nixpkgs/blob/04e40bca2a68d7ca85f1c47f00598abb062a8b12/pkgs/by-name/ca/cargo-tauri/test-app.nix#L23-L26
+  postPatch = lib.optionalString stdenv.hostPlatform.isLinux ''
+    substituteInPlace $cargoDepsCopy/libappindicator-sys-*/src/lib.rs \
+      --replace-fail "libayatana-appindicator3.so.1" "${libayatana-appindicator}/lib/libayatana-appindicator3.so.1"
+  '';
+
+  pnpmRoot = "app/${app-type}";
+  pnpmDeps = pnpm_9.fetchDeps {
+    inherit
+      pname
+      version
+      src
+      patches
+      ;
+    postPatch = "cd ${pnpmRoot}";
+    fetcherVersion = 1;
+    hash = app-type-either "sha256-V46V/VPwCKEe3sAp8zK0UUU5YigqgYh1GIOorqIAiNE=" "sha256-8QRigYNtxirXidFFnTzA6rP0+L64M/iakPqe2lZKegs=";
+  };
+
+  cargoRoot = "app/${app-type}/src-tauri";
+  buildAndTestSubdir = cargoRoot;
+  cargoPatches = [
+    ./remove-duplicate-versions-of-sys-metrics.patch
+    ./remove-code-signing-darwin.patch
+  ];
+  cargoHash = app-type-either "sha256-XfN+/oC3lttDquLfoyJWBaFfdjW/wyODCIiZZksypLM=" "sha256-4vBHxuKg4P9H0FZYYNUT+AVj4Qvz99q7Bhd7x47UC2w=";
+
+  nativeBuildInputs = [
+    proper-cargo-tauri.hook
+
+    # Setup pnpm
+    nodejs
+    pnpm_9.configHook
+
+    protobuf
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    pkg-config
+    wrapGAppsHook4
+  ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux (
+    [
+      glib-networking
+      libayatana-appindicator
+      openssl
+    ]
+    ++ lib.optionals (app-type == "main") [
+      libsoup_3
+      webkitgtk_4_1
+    ]
+    ++ lib.optionals (app-type == "legacy") [
+      libsoup_2_4
+      webkitgtk_4_0
+    ]
+  );
+
+  env.OPENSSL_NO_VENDOR = 1;
+
+  passthru =
+    # Don't set an update script for the legacy version
+    # so r-ryantm won't create two duplicate PRs
+    lib.optionalAttrs (app-type == "main") {
+      updateScript = writeShellScript "update-rquickshare.sh" ''
+        ${lib.getExe nix-update} rquickshare
+        sed -i 's/version = "0.0.0";/' pkgs/by-name/rq/rquickshare/package.nix
+        ${lib.getExe nix-update} rquickshare-legacy
+      '';
+    };
+
+  meta = {
+    description = "Rust implementation of NearbyShare/QuickShare from Android for Linux and macOS";
+    homepage = "https://github.com/Martichou/rquickshare";
+    changelog = "https://github.com/Martichou/rquickshare/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.gpl3Plus;
+    mainProgram = app-type-either "rquickshare" "r-quick-share";
+    maintainers = with lib.maintainers; [
+      perchun
+      luftmensch-luftmensch
+    ];
+  };
+}

pkgs/by-name/rq/rquickshare/remove-code-signing-darwin.patch

@@ -0,0 +1,12 @@
+diff --git a/app/main/src-tauri/tauri.conf.json b/app/main/src-tauri/tauri.conf.json
+index 1114b19..c4cc8f4 100644
+--- a/app/main/src-tauri/tauri.conf.json
++++ b/app/main/src-tauri/tauri.conf.json
+@@ -23,7 +23,6 @@
+     "macOS": {
+       "frameworks": [],
+       "exceptionDomain": "",
+-      "signingIdentity": "-",
+       "providerShortName": null,
+       "entitlements": null
+     },

pkgs/by-name/rq/rquickshare/remove-duplicate-versions-of-sys-metrics.patch

@@ -0,0 +1,114 @@
+diff --git a/app/legacy/src-tauri/Cargo.lock b/app/legacy/src-tauri/Cargo.lock
+index 14872dc..341fcc8 100644
+--- a/app/legacy/src-tauri/Cargo.lock
++++ b/app/legacy/src-tauri/Cargo.lock
+@@ -4296,7 +4296,7 @@ dependencies = [
+  "rand 0.9.0",
+  "serde",
+  "sha2",
+- "sys_metrics 0.2.7 (git+https://github.com/Martichou/sys_metrics)",
++ "sys_metrics",
+  "tokio",
+  "tokio-util",
+  "tracing-subscriber",
+@@ -4316,7 +4316,7 @@ dependencies = [
+  "rqs_lib",
+  "serde",
+  "serde_json",
+- "sys_metrics 0.2.7 (registry+https://github.com/rust-lang/crates.io-index)",
++ "sys_metrics",
+  "tauri",
+  "tauri-build",
+  "tauri-plugin-autostart",
+@@ -4920,21 +4920,6 @@ dependencies = [
+  "libc",
+ ]
+ 
+-[[package]]
+-name = "sys_metrics"
+-version = "0.2.7"
+-source = "registry+https://github.com/rust-lang/crates.io-index"
+-checksum = "c9b266b80f59f86e2e1e0a4938e316e32c3730d94a749f236305152279f77484"
+-dependencies = [
+- "core-foundation-sys",
+- "glob",
+- "io-kit-sys",
+- "lazy_static",
+- "libc",
+- "mach",
+- "serde",
+-]
+-
+ [[package]]
+ name = "sys_metrics"
+ version = "0.2.7"
+diff --git a/app/legacy/src-tauri/Cargo.toml b/app/legacy/src-tauri/Cargo.toml
+index fb735b2..cfd1349 100644
+--- a/app/legacy/src-tauri/Cargo.toml
++++ b/app/legacy/src-tauri/Cargo.toml
+@@ -20,7 +20,7 @@ notify-rust = "4.10"
+ rqs_lib = { path = "../../../core_lib", features = ["experimental"] }
+ serde = { version = "1.0", features = ["derive"] }
+ serde_json = "1.0"
+-sys_metrics = "0.2"
++sys_metrics = { git = "https://github.com/Martichou/sys_metrics" }
+ tauri = { version = "1.8", features = ["api-all", "reqwest-native-tls-vendored", "devtools", "system-tray"] }
+ tauri-plugin-autostart = { git = "https://github.com/tauri-apps/plugins-workspace", branch = "v1" }
+ tauri-plugin-single-instance = { git = "https://github.com/tauri-apps/plugins-workspace", branch = "v1" }
+diff --git a/app/main/src-tauri/Cargo.lock b/app/main/src-tauri/Cargo.lock
+index 5580ef5..4327d4c 100644
+--- a/app/main/src-tauri/Cargo.lock
++++ b/app/main/src-tauri/Cargo.lock
+@@ -4247,7 +4247,7 @@ dependencies = [
+  "rand 0.9.0",
+  "serde",
+  "sha2",
+- "sys_metrics 0.2.7 (git+https://github.com/Martichou/sys_metrics)",
++ "sys_metrics",
+  "tokio",
+  "tokio-util",
+  "tracing-subscriber",
+@@ -4267,7 +4267,7 @@ dependencies = [
+  "rqs_lib",
+  "serde",
+  "serde_json",
+- "sys_metrics 0.2.7 (registry+https://github.com/rust-lang/crates.io-index)",
++ "sys_metrics",
+  "tauri",
+  "tauri-build",
+  "tauri-plugin-autostart",
+@@ -4932,21 +4932,6 @@ dependencies = [
+  "syn 2.0.95",
+ ]
+ 
+-[[package]]
+-name = "sys_metrics"
+-version = "0.2.7"
+-source = "registry+https://github.com/rust-lang/crates.io-index"
+-checksum = "c9b266b80f59f86e2e1e0a4938e316e32c3730d94a749f236305152279f77484"
+-dependencies = [
+- "core-foundation-sys",
+- "glob",
+- "io-kit-sys",
+- "lazy_static",
+- "libc",
+- "mach",
+- "serde",
+-]
+-
+ [[package]]
+ name = "sys_metrics"
+ version = "0.2.7"
+diff --git a/app/main/src-tauri/Cargo.toml b/app/main/src-tauri/Cargo.toml
+index 8864112..7707922 100644
+--- a/app/main/src-tauri/Cargo.toml
++++ b/app/main/src-tauri/Cargo.toml
+@@ -20,7 +20,7 @@ notify-rust = "4.10"
+ rqs_lib = { path = "../../../core_lib", features = ["experimental"] }
+ serde = { version = "1.0", features = ["derive"] }
+ serde_json = "1.0"
+-sys_metrics = "0.2"
++sys_metrics = { git = "https://github.com/Martichou/sys_metrics" }
+ tauri = { version = "2.2", features = [ "devtools", "tray-icon", "native-tls-vendored", "image-png"] }
+ tauri-plugin-autostart = "2.2"
+ tauri-plugin-process = "2.2"