push sheeet

pkgs/by-name/rt/rt-tests/package.nix

@@ -0,0 +1,44 @@
+{
+  stdenv,
+  lib,
+  makeWrapper,
+  fetchurl,
+  numactl,
+  python3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rt-tests";
+  version = "2.8";
+
+  src = fetchurl {
+    url = "https://git.kernel.org/pub/scm/utils/rt-tests/rt-tests.git/snapshot/${pname}-${version}.tar.gz";
+    sha256 = "sha256-iBpd7K9VpvUH5wXBKypyQl8NAHN3Om5/PcoJ8RH37mI=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [
+    numactl
+    python3
+  ];
+
+  makeFlags = [
+    "prefix=$(out)"
+    "DESTDIR="
+    "PYLIB=$(out)/${python3.sitePackages}"
+    "CC=${stdenv.cc.targetPrefix}cc"
+    "AR=${stdenv.cc.bintools.targetPrefix}ar"
+  ];
+
+  postInstall = ''
+    wrapProgram "$out/bin/determine_maximum_mpps.sh" --prefix PATH : $out/bin
+  '';
+
+  meta = with lib; {
+    homepage = "https://git.kernel.org/pub/scm/utils/rt-tests/rt-tests.git";
+    description = "Suite of real-time tests - cyclictest, hwlatdetect, pip_stress, pi_stress, pmqtest, ptsematest, rt-migrate-test, sendme, signaltest, sigwaittest, svsematest";
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ poelzi ];
+    license = licenses.gpl2Only;
+  };
+}

pkgs/by-name/rt/rt/dont-check-users_groups.patch

@@ -0,0 +1,12 @@
+diff --git a/sbin/rt-test-dependencies.in b/sbin/rt-test-dependencies.in
+index e51feb197..d75b1bc4e 100644
+--- a/sbin/rt-test-dependencies.in
++++ b/sbin/rt-test-dependencies.in
+@@ -423,6 +423,7 @@ sub check_perl_version {
+ }
+ 
+ sub check_users_groups {
++    return 0;
+     section("users / groups");
+ 
+     my $fails = 0;

pkgs/by-name/rt/rt/override-generated.patch

@@ -0,0 +1,21 @@
+commit 7aec1e9478ef679227e759ab9537df7584c6a852
+Author: Shea Levy <shea@shealevy.com>
+Date:   Fri Jan 15 09:09:18 2016 -0500
+
+    Make it possible to override hard-coded paths
+
+diff --git a/lib/RT/Generated.pm.in b/lib/RT/Generated.pm.in
+index 9dcb80b..99b034b 100644
+--- a/lib/RT/Generated.pm.in
++++ b/lib/RT/Generated.pm.in
+@@ -82,4 +82,10 @@ $MasonDataDir = '@MASON_DATA_PATH@';
+ $MasonSessionDir = '@MASON_SESSION_PATH@';
+ 
+ 
++if ( my $override_file = $ENV{RT_PATHS_OVERRIDE} )
++{
++    require "$override_file" || die "Couldn't load paths override file: $@";
++}
++
++
+ 1;

pkgs/by-name/rt/rt/package.nix

@@ -0,0 +1,181 @@
+{
+  lib,
+  stdenv,
+  autoreconfHook,
+  buildEnv,
+  fetchFromGitHub,
+  perl,
+  perlPackages,
+  makeWrapper,
+  gnupg,
+  openssl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rt";
+  version = "5.0.8";
+
+  src = fetchFromGitHub {
+    repo = "rt";
+    rev = "rt-${version}";
+    owner = "bestpractical";
+    hash = "sha256-4/iC1PjLgLAp7XWTafe8HW3bTkDWWQxtSEIOs8wluzE=";
+  };
+
+  patches = [
+    ./dont-check-users_groups.patch # needed for "make testdeps" to work in the build
+    ./override-generated.patch
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    makeWrapper
+  ];
+
+  buildInputs = [
+    perl
+    (buildEnv {
+      name = "rt-perl-deps";
+      paths =
+        with perlPackages;
+        (requiredPerlModules [
+          ApacheSession
+          BusinessHours
+          CGIEmulatePSGI
+          CGIPSGI
+          CSSMinifierXS
+          CSSSquish
+          ConvertColor
+          CryptEksblowfish
+          CryptSSLeay
+          CryptX509
+          DBDPg
+          DBIxSearchBuilder
+          DataGUID
+          DataICal
+          DataPage
+          DataPagePageset
+          DateExtract
+          DateManip
+          DateTimeFormatNatural
+          DevelGlobalDestruction
+          EmailAddress
+          EmailAddressList
+          EncodeDetect
+          EncodeHanExtra
+          FCGI
+          FCGIProcManager
+          FileShareDir
+          FileWhich
+          GD
+          GDGraph
+          GnuPGInterface
+          GraphViz2
+          HTMLFormatExternal
+          HTMLFormatTextWithLinks
+          HTMLFormatTextWithLinksAndTables
+          HTMLGumbo
+          HTMLMason
+          HTMLMasonPSGIHandler
+          HTMLQuoted
+          HTMLRewriteAttributes
+          HTMLScrubber
+          IPCRun
+          IPCRun3
+          JSON
+          JavaScriptMinifierXS
+          LWP
+          LWPProtocolHttps
+          LocaleMaketextFuzzy
+          LocaleMaketextLexicon
+          LogDispatch
+          MIMETools
+          MIMETypes
+          MailTools
+          ModulePath
+          ModuleRefresh
+          ModuleVersionsReport
+          Moose
+          MooseXNonMoose
+          MooseXRoleParameterized
+          MozillaCA
+          NetCIDR
+          NetIP
+          ParallelForkManager
+          PathDispatcher
+          PerlIOeol
+          Plack
+          PodParser
+          RegexpCommon
+          RegexpCommonnetCIDR
+          RegexpIPv6
+          RoleBasic
+          ScopeUpper
+          Starlet
+          Starman
+          StringShellQuote
+          SymbolGlobalName
+          TermReadKey
+          TextPasswordPronounceable
+          TextQuoted
+          TextTemplate
+          TextWikiFormat
+          TextWordDiff
+          TextWrapper
+          TimeParseDate
+          TreeSimple
+          UNIVERSALrequire
+          WebMachine
+          XMLRSS
+          perlldap
+        ]);
+    })
+  ];
+
+  preAutoreconf = ''
+    echo rt-${version} > .tag
+  '';
+  preConfigure = ''
+    appendToVar configureFlags "--with-web-user=$UID"
+    appendToVar configureFlags "--with-web-group=$(id -g)"
+    appendToVar configureFlags "--with-rt-group=$(id -g)"
+    appendToVar configureFlags "--with-bin-owner=$UID"
+    appendToVar configureFlags "--with-libs-owner=$UID"
+    appendToVar configureFlags "--with-libs-group=$(id -g)"
+  '';
+  configureFlags = [
+    "--enable-graphviz"
+    "--enable-gd"
+    "--enable-gpg"
+    "--enable-smime"
+    "--with-db-type=Pg"
+  ];
+
+  buildPhase = ''
+    make testdeps
+  '';
+
+  postFixup = ''
+    for i in $(find $out/bin -type f); do
+      wrapProgram $i --prefix PERL5LIB ':' $PERL5LIB \
+        --prefix PATH ":" "${
+          lib.makeBinPath [
+            openssl
+            gnupg
+          ]
+        }"
+    done
+
+    rm -r $out/var
+    mkdir -p $out/var/data
+    ln -s /var/log/rt $out/var/log
+    ln -s /run/rt/mason_data $out/var/mason_data
+    ln -s /var/lib/rt/shredder $out/var/data/RT-Shredder
+    ln -s /var/lib/rt/smime $out/var/data/smime
+    ln -s /var/lib/rt/gpg $out/var/data/gpg
+  '';
+
+  meta = {
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/rt/rt5677-firmware/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+}:
+
+stdenvNoCC.mkDerivation {
+  name = "rt5677-firmware";
+
+  src = fetchFromGitHub {
+    owner = "raphael";
+    repo = "linux-samus";
+    rev = "995de6c2093797905fbcd79f1a3625dd3f50be37";
+    sha256 = "sha256-PjPFpz4qJLC+vTomV31dA3AKGjfYjKB2ZYfUpnj61Cg=";
+  };
+
+  installPhase = ''
+    mkdir -p $out/lib/firmware
+    cp ./firmware/rt5677_elf_vad $out/lib/firmware
+  '';
+
+  meta = with lib; {
+    description = "Firmware for Realtek rt5677 device";
+    license = licenses.unfreeRedistributableFirmware;
+    maintainers = [ maintainers.zohl ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/rt/rtabmap/package.nix

@@ -0,0 +1,106 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+
+  # nativeBuildInputs
+  cmake,
+  qt6,
+  pkg-config,
+  wrapGAppsHook3,
+
+  # buildInputs
+  opencv,
+  pcl,
+  liblapack,
+  xorg,
+  libusb1,
+  yaml-cpp,
+  libnabo,
+  libpointmatcher,
+  eigen,
+  g2o,
+  ceres-solver,
+  octomap,
+  freenect,
+  libdc1394,
+  libGL,
+  libGLU,
+  librealsense,
+  vtkWithQt6,
+  zed-open-capture,
+  hidapi,
+
+  # passthru
+  gitUpdater,
+}:
+let
+  pcl' = pcl.override { vtk = vtkWithQt6; };
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rtabmap";
+  version = "0.22.1";
+
+  src = fetchFromGitHub {
+    owner = "introlab";
+    repo = "rtabmap";
+    tag = finalAttrs.version;
+    hash = "sha256-6kDjIfUgyaqrsVAWO6k0h1qIDN/idMOJJxLpqMQ6DFY=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    qt6.wrapQtAppsHook
+    pkg-config
+    wrapGAppsHook3
+  ];
+  buildInputs = [
+    ## Required
+    opencv
+    opencv.cxxdev
+    pcl'
+    liblapack
+    xorg.libSM
+    xorg.libICE
+    xorg.libXt
+
+    ## Optional
+    libusb1
+    eigen
+    g2o
+    ceres-solver
+    yaml-cpp
+    libnabo
+    libpointmatcher
+    octomap
+    freenect
+    libdc1394
+    librealsense
+    qt6.qtbase
+    libGL
+    libGLU
+    zed-open-capture
+    hidapi
+  ];
+
+  # Configure environment variables
+  NIX_CFLAGS_COMPILE = "-Wno-c++20-extensions";
+
+  cmakeFlags = [
+    (lib.cmakeFeature "CMAKE_INCLUDE_PATH" "${pcl'}/include/pcl-${lib.versions.majorMinor pcl'.version}")
+  ];
+
+  passthru = {
+    updateScript = gitUpdater { };
+  };
+
+  meta = {
+    description = "Real-Time Appearance-Based 3D Mapping";
+    homepage = "https://introlab.github.io/rtabmap/";
+    changelog = "https://github.com/introlab/rtabmap/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ marius851000 ];
+    platforms = with lib.platforms; linux;
+  };
+})

pkgs/by-name/rt/rtags/package.nix

@@ -0,0 +1,63 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  fetchpatch,
+  cmake,
+  llvmPackages,
+  openssl,
+  emacs,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rtags";
+  version = "2.38";
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    llvmPackages.llvm.dev
+  ];
+  buildInputs = [
+    llvmPackages.llvm
+    llvmPackages.libclang
+    openssl
+    emacs
+  ]
+  ++ lib.optionals stdenv.cc.isGNU [ llvmPackages.clang-unwrapped ];
+
+  src = fetchFromGitHub {
+    owner = "andersbakken";
+    repo = "rtags";
+    tag = "v${version}";
+    hash = "sha256-EJ5pC53S36Uu7lM6KuLvLN6MAyrQW/Yk5kPqZNS5m8c=";
+    fetchSubmodules = true;
+    # unicode file names lead to different checksums on HFS+ vs. other
+    # filesystems because of unicode normalisation
+    postFetch = ''
+      rm $out/src/rct/tests/testfile_*.txt
+    '';
+  };
+
+  # This should be fixed with the next version bump
+  # https://github.com/Andersbakken/rtags/issues/1411
+  patches = [
+    (fetchpatch {
+      name = "define-obsolete-function-alias.patch";
+      url = "https://github.com/Andersbakken/rtags/commit/63f18acb21e664fd92fbc19465f0b5df085b5e93.patch";
+      sha256 = "sha256-dmEPtnk8Pylmf5479ovHKItRZ+tJuOWuYOQbWB/si/Y=";
+    })
+  ];
+
+  preConfigure = ''
+    export LIBCLANG_CXXFLAGS="-isystem ${llvmPackages.clang.cc}/include $(llvm-config --cxxflags) -fexceptions" \
+           LIBCLANG_LIBDIR="${llvmPackages.clang.cc}/lib"
+  '';
+
+  meta = {
+    description = "C/C++ client-server indexer based on clang";
+    homepage = "https://github.com/andersbakken/rtags";
+    license = lib.licenses.gpl3;
+    platforms = with lib.platforms; x86_64 ++ aarch64;
+  };
+}

pkgs/by-name/rt/rtaudio_6/package.nix

@@ -0,0 +1,69 @@
+{
+  stdenv,
+  lib,
+  config,
+  fetchFromGitHub,
+  testers,
+  cmake,
+  pkg-config,
+  alsaSupport ? stdenv.hostPlatform.isLinux,
+  alsa-lib,
+  pulseaudioSupport ? config.pulseaudio or stdenv.hostPlatform.isLinux,
+  libpulseaudio,
+  jackSupport ? true,
+  libjack2,
+  coreaudioSupport ? stdenv.hostPlatform.isDarwin,
+  validatePkgConfig,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rtaudio";
+  version = "6.0.1";
+
+  src = fetchFromGitHub {
+    owner = "thestk";
+    repo = "rtaudio";
+    tag = finalAttrs.version;
+    hash = "sha256-Acsxbnl+V+Y4mKC1gD11n0m03E96HMK+oEY/YV7rlIY=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    validatePkgConfig
+  ];
+
+  buildInputs =
+    lib.optionals alsaSupport [
+      alsa-lib
+    ]
+    ++ lib.optionals pulseaudioSupport [
+      libpulseaudio
+    ]
+    ++ lib.optionals jackSupport [
+      libjack2
+    ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "RTAUDIO_API_ALSA" alsaSupport)
+    (lib.cmakeBool "RTAUDIO_API_PULSE" pulseaudioSupport)
+    (lib.cmakeBool "RTAUDIO_API_JACK" jackSupport)
+    (lib.cmakeBool "RTAUDIO_API_CORE" coreaudioSupport)
+  ];
+
+  passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+
+  meta = {
+    description = "Set of C++ classes that provide a cross platform API for realtime audio input/output";
+    homepage = "https://www.music.mcgill.ca/~gary/rtaudio/";
+    changelog = "https://github.com/thestk/rtaudio/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ magnetophon ];
+    platforms = lib.platforms.unix;
+    pkgConfigModules = [
+      "rtaudio"
+    ];
+  };
+})

pkgs/by-name/rt/rtfm/package.nix

@@ -0,0 +1,126 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  crystal,
+  wrapGAppsHook4,
+  gobject-introspection,
+  desktopToDarwinBundle,
+  webkitgtk_6_0,
+  sqlite,
+  libadwaita,
+  gtk4,
+  glib,
+  pango,
+  symlinkJoin,
+  gitUpdater,
+  _experimental-update-script-combinators,
+  runCommand,
+  crystal2nix,
+  writeShellScript,
+}:
+let
+  version = "0.6.2";
+
+  src = fetchFromGitHub {
+    owner = "hugopl";
+    repo = "rtfm";
+    tag = "v${version}";
+    hash = "sha256-0yKldVTZdFV1Tj1MUI7TCqF3Ho/D7NOGR9UuLaLUFdo=";
+  };
+
+  gtk-doc =
+    let
+      gtk4' = gtk4.override { x11Support = true; };
+      pango' = pango.override { withIntrospection = true; };
+    in
+    symlinkJoin {
+      name = "gtk-doc";
+      paths = [
+        gtk4'.devdoc
+        pango'.devdoc
+        glib.devdoc
+        libadwaita.devdoc
+        webkitgtk_6_0.devdoc
+      ];
+    };
+in
+crystal.buildCrystalPackage {
+  pname = "rtfm";
+  inherit version src;
+
+  shardsFile = ./shards.nix;
+  copyShardDeps = true;
+
+  postPatch = ''
+    substituteInPlace src/doc2dash/create_gtk_docset.cr \
+      --replace-fail 'basedir = Path.new("/usr/share/doc")' 'basedir = Path.new(ARGV[0]? || "${gtk-doc}/share/doc")' \
+      --replace-fail 'webkit2gtk-4.0' 'webkitgtk-6.0'
+    substituteInPlace src/doc2dash/create_crystal_docset.cr \
+      --replace-fail 'doc_source = Path.new(ARGV[0]? || "/usr/share/doc/crystal/api")' 'doc_source = Path.new(ARGV[0]? || "${crystal}/share/doc/crystal/api")'
+    substituteInPlace src/doc2dash/docset_builder.cr \
+      --replace-fail 'File.copy(original, real_dest)' 'File.copy(original, real_dest); File.chmod(real_dest, 0o600)'
+  '';
+
+  preBuild = ''
+    cd lib/gi-crystal
+    shards build -Dpreview_mt --release --no-debug
+    cd ../..
+    install -Dm755 lib/gi-crystal/bin/gi-crystal bin/gi-crystal
+  '';
+
+  buildTargets = [ "all" ];
+
+  nativeBuildInputs = [
+    wrapGAppsHook4
+    gobject-introspection
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [ desktopToDarwinBundle ];
+
+  buildInputs = [
+    webkitgtk_6_0
+    sqlite
+    libadwaita
+    gtk4
+    pango
+  ];
+
+  postInstall = ''
+    glib-compile-schemas $out/share/glib-2.0/schemas
+  '';
+
+  doInstallCheck = false;
+
+  passthru = {
+    updateScript = _experimental-update-script-combinators.sequence [
+      (gitUpdater { rev-prefix = "v"; })
+      (_experimental-update-script-combinators.copyAttrOutputToFile "rtfm.shardLock" "./shard.lock")
+      {
+        command = [
+          (writeShellScript "update-lock" "cd $1; ${lib.getExe crystal2nix}")
+          ./.
+        ];
+        supportedFeatures = [ "silent" ];
+      }
+      {
+        command = [
+          "rm"
+          "./shard.lock"
+        ];
+        supportedFeatures = [ "silent" ];
+      }
+    ];
+    shardLock = runCommand "shard.lock" { inherit src; } ''
+      cp $src/shard.lock $out
+    '';
+  };
+
+  meta = with lib; {
+    description = "Dash/docset reader with built in documentation for Crystal and GTK APIs";
+    homepage = "https://github.com/hugopl/rtfm/";
+    license = licenses.mit;
+    mainProgram = "rtfm";
+    maintainers = with maintainers; [ sund3RRR ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/rt/rtfm/shards.nix

@@ -0,0 +1,42 @@
+{
+  db = {
+    url = "https://github.com/crystal-lang/crystal-db.git";
+    rev = "v0.12.0";
+    sha256 = "1in8w2dz7nlhqgc9l6b3pi6f944m29nhbg3p5j40qzvsrr8lqaj7";
+  };
+  fzy = {
+    url = "https://github.com/hugopl/fzy.git";
+    rev = "v0.6.0";
+    sha256 = "1mpw3ridzvqkf807wik6wzwpzcsk0075kifagsfnz38vx1mw2y55";
+  };
+  gi-crystal = {
+    url = "https://github.com/hugopl/gi-crystal.git";
+    rev = "69388976418f5cc5ebc0cb7fb6aae5efd345ce8d";
+    sha256 = "15ayic628ma1h7b56bx11y8yl361qrpxlqngy0jkv793v7vpwd9b";
+  };
+  gtk4 = {
+    url = "https://github.com/hugopl/gtk4.cr.git";
+    rev = "v0.17.0";
+    sha256 = "0lv3nvsanxi4g2322zvkf1jxx5zgzaapk228vcw2cl0ja1drm06d";
+  };
+  harfbuzz = {
+    url = "https://github.com/hugopl/harfbuzz.cr.git";
+    rev = "v0.2.0";
+    sha256 = "06wgqxwyib5416yp53j2iwcbr3bl4jjxb1flm7z103l365par694";
+  };
+  libadwaita = {
+    url = "https://github.com/hugopl/libadwaita.cr.git";
+    rev = "cffabb56e911d2a90c53c2fd14d6bd08bf5ac446";
+    sha256 = "0gcq04vgxg0vff9fcalgzq9phq0y76diihkzhlfn91bdxwkx7rl3";
+  };
+  pango = {
+    url = "https://github.com/hugopl/pango.cr.git";
+    rev = "v0.3.1";
+    sha256 = "0xlf127flimnll875mcq92q7xsi975rrgdpcpmnrwllhdhfx9qmv";
+  };
+  sqlite3 = {
+    url = "https://github.com/crystal-lang/crystal-sqlite3.git";
+    rev = "v0.20.0";
+    sha256 = "0mqy6rc26i0sf2fdllbbzdhbd1d35npmpqqjz0b1n1vrzrm6fg05";
+  };
+}

pkgs/by-name/rt/rtg-tools/package.nix

@@ -0,0 +1,69 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  jdk,
+  ant,
+  git,
+  coreutils,
+  hostname,
+  gawk,
+  unzip,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rtg-tools";
+  version = "3.13";
+
+  src = fetchFromGitHub {
+    owner = "RealTimeGenomics";
+    repo = "rtg-tools";
+    rev = version;
+    hash = "sha256-vPzKrgnX6BCQmn9aOVWWpFLC6SbPBHZhZ+oL1LCbvmo=";
+  };
+
+  nativeBuildInputs = [
+    ant
+    jdk
+    git # Required by build.xml to manage the build revision
+    unzip
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+    ant rtg-tools.jar
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp build/rtg-tools.jar $out/bin/RTG.jar
+    cp installer/rtg $out/bin/
+    runHook postInstall
+  '';
+
+  postPatch = ''
+    # Use a location outside nix (must be writable)
+    substituteInPlace installer/rtg \
+      --replace-fail  '$THIS_DIR/rtg.cfg' '$HOME/.config/rtg-tools/rtg.cfg'  \
+       --replace-fail 'RTG_JAVA="java"' 'RTG_JAVA="${lib.getExe jdk}"' \
+      --replace-fail uname ${lib.getExe' coreutils "uname"} \
+      --replace-fail awk ${lib.getExe gawk} \
+      --replace-fail "hostname -s" "${lib.getExe hostname} -s"
+
+    sed -i '/USER_JAVA_OPTS=$RTG_JAVA_OPTS/a mkdir -p $HOME/.config/rtg-tools'  installer/rtg
+  '';
+
+  checkPhase = ''
+    ant runalltests
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/RealTimeGenomics/rtg-tools";
+    description = "Useful utilities for dealing with VCF files and sequence data, especially vcfeval";
+    license = licenses.bsd2;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ apraga ];
+  };
+}

pkgs/by-name/rt/rtkit/meson-actual-use-systemd_systemunitdir.patch

@@ -0,0 +1,22 @@
+From 7d62095b94f8df3891c984a1535026d2658bb177 Mon Sep 17 00:00:00 2001
+From: Edmund Wu <fangkazuto@gmail.com>
+Date: Sat, 11 Apr 2020 16:59:35 -0400
+Subject: [PATCH] meson: actually use systemd_systemunitdir
+
+---
+ meson.build | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/meson.build b/meson.build
+index 02e6c73..ba5ba1e 100644
+--- a/meson.build
++++ b/meson.build
+@@ -58,7 +58,7 @@ if policydir == ''
+         policydir = get_option('datadir') / 'polkit-1' / 'actions'
+ endif
+ 
+-systemunitdir = ''
++systemunitdir = get_option('systemd_systemunitdir')
+ if systemunitdir == '' and systemd_dep.found()
+         systemunitdir = systemd_dep.get_pkgconfig_variable(
+                 'systemdsystemunitdir',

pkgs/by-name/rt/rtkit/meson-fix-librt-find_library-check.patch

@@ -0,0 +1,22 @@
+From 98f70edd8f534c371cb4308b9720739c5178918d Mon Sep 17 00:00:00 2001
+From: Felipe Sateler <fsateler@users.noreply.github.com>
+Date: Sat, 11 Apr 2020 10:59:21 -0400
+Subject: [PATCH] meson: fix librt find_library check
+
+---
+ meson.build | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/meson.build b/meson.build
+index 02e6c73..49da472 100644
+--- a/meson.build
++++ b/meson.build
+@@ -22,7 +22,7 @@ polkit_dep = dependency('polkit-gobject-1', required: false)
+ systemd_dep = dependency('systemd', required: false)
+ thread_dep = dependency('threads')
+ 
+-librt_dep = cc.find_library('z')
++librt_dep = cc.find_library('rt')
+ cc.check_header('sched.h', dependencies: librt_dep)
+ cc.has_function('sched_setscheduler', dependencies: librt_dep)
+ 

pkgs/by-name/rt/rtkit/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  unixtools,
+  dbus,
+  libcap,
+  polkit,
+  systemd,
+}:
+
+stdenv.mkDerivation {
+  pname = "rtkit";
+  version = "0.13";
+
+  src = fetchFromGitHub {
+    owner = "heftig";
+    repo = "rtkit";
+    rev = "c295fa849f52b487be6433e69e08b46251950399";
+    sha256 = "0yfsgi3pvg6dkizrww1jxpkvcbhzyw9110n1dypmzq0c5hlzjxcd";
+  };
+
+  patches = [
+    ./meson-actual-use-systemd_systemunitdir.patch
+    ./meson-fix-librt-find_library-check.patch
+    ./rtkit-daemon-dont-log-debug-messages-by-default.patch
+  ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    unixtools.xxd
+  ];
+  buildInputs = [
+    dbus
+    libcap
+    polkit
+    systemd
+  ];
+
+  mesonFlags = [
+    "-Dinstalled_tests=false"
+
+    "-Ddbus_systemservicedir=${placeholder "out"}/share/dbus-1/system-services"
+    "-Ddbus_interfacedir=${placeholder "out"}/share/dbus-1/interfaces"
+    "-Ddbus_rulesdir=${placeholder "out"}/etc/dbus-1/system.d"
+    "-Dpolkit_actiondir=${placeholder "out"}/share/polkit-1/actions"
+    "-Dsystemd_systemunitdir=${placeholder "out"}/etc/systemd/system"
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/heftig/rtkit";
+    description = "Daemon that hands out real-time priority to processes";
+    mainProgram = "rtkitctl";
+    license = with licenses; [
+      gpl3
+      bsd0
+    ]; # lib is bsd license
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/rt/rtkit/rtkit-daemon-dont-log-debug-messages-by-default.patch

@@ -0,0 +1,73 @@
+From 4880b9c67628a781bdb183dcdc69f12cb829817d Mon Sep 17 00:00:00 2001
+From: Jean Delvare <jdelvare@suse.de>
+Date: Sat, 15 Apr 2023 11:53:27 +0200
+Subject: [PATCH] rtkit-daemon: Don't log debug messages by default
+
+The rtkit-daemon service is a lot more verbose than other services
+when it doesn't have anything to do. Stop logging the debug messages
+by default to avoid flooding the system log.
+
+This addresses issue #22.
+---
+ rtkit-daemon.c | 13 +++++++++++++
+ 1 file changed, 13 insertions(+)
+
+diff --git a/rtkit-daemon.c b/rtkit-daemon.c
+index 17122fa..0c5d814 100644
+--- a/rtkit-daemon.c
++++ b/rtkit-daemon.c
+@@ -154,6 +154,9 @@ static bool canary_demote_unknown = FALSE;
+ /* Log to stderr? */
+ static bool log_stderr = FALSE;
+ 
++/* Also log debugging messages? */
++static bool log_debug = FALSE;
++
+ /* Scheduling policy to use */
+ static int sched_policy = SCHED_RR;
+ 
+@@ -1876,6 +1879,7 @@ enum {
+         ARG_CANARY_DEMOTE_UNKNOWN,
+         ARG_CANARY_REFUSE_SEC,
+         ARG_STDERR,
++        ARG_DEBUG,
+         ARG_INTROSPECT
+ };
+ 
+@@ -1905,6 +1909,7 @@ static const struct option long_options[] = {
+     { "canary-demote-unknown",       no_argument,       0, ARG_CANARY_DEMOTE_UNKNOWN },
+     { "canary-refuse-sec",           required_argument, 0, ARG_CANARY_REFUSE_SEC },
+     { "stderr",                      no_argument,       0, ARG_STDERR },
++    { "debug",                       no_argument,       0, ARG_DEBUG },
+     { "introspect",                  no_argument,       0, ARG_INTROSPECT },
+     { NULL, 0, 0, 0}
+ };
+@@ -1933,6 +1938,7 @@ static void show_help(const char *exe) {
+                "      --version                       Show version\n\n"
+                "OPTIONS:\n"
+                "      --stderr                        Log to STDERR in addition to syslog\n"
++               "      --debug                         Also log debugging mssages\n"
+                "      --user-name=USER                Run daemon as user (%s)\n\n"
+                "      --scheduling-policy=(RR|FIFO)   Choose scheduling policy (%s)\n"
+                "      --our-realtime-priority=[%i..%i] Realtime priority for the daemon (%u)\n"
+@@ -2222,6 +2228,10 @@ static int parse_command_line(int argc, char *argv[], int *ret) {
+                                 log_stderr = TRUE;
+                                 break;
+ 
++                        case ARG_DEBUG:
++                                log_debug = TRUE;
++                                break;
++
+                         case ARG_INTROSPECT:
+                                 fputs(introspect_xml, stdout);
+                                 *ret = 0;
+@@ -2251,6 +2261,9 @@ static int parse_command_line(int argc, char *argv[], int *ret) {
+                 return -1;
+         }
+ 
++	if (!log_debug)
++                setlogmask(LOG_UPTO(LOG_INFO));
++
+         assert(our_realtime_priority >= (unsigned) sched_get_priority_min(sched_policy));
+         assert(our_realtime_priority <= (unsigned) sched_get_priority_max(sched_policy));
+ 

pkgs/by-name/rt/rtklib-ex/package.nix

@@ -0,0 +1,54 @@
+{
+  stdenv,
+  cmake,
+  nix-update-script,
+  blas,
+  lapack,
+  lib,
+  fetchFromGitHub,
+  qt6,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rtklib-ex";
+  version = "2.5.0";
+
+  src = fetchFromGitHub {
+    owner = "rtklibexplorer";
+    repo = "RTKLIB";
+    tag = "v${version}";
+    hash = "sha256-j00VEQvxOiAc3EQX3x2b3RxYkbtvCZ17ugnW6b6ChWU=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    blas
+    lapack
+    qt6.wrapQtAppsHook
+    qt6.qttools
+  ];
+
+  buildInputs = [
+    qt6.qtbase
+    qt6.qtserialport
+  ];
+
+  doCheck = true;
+
+  cmakeFlags = [
+    (lib.cmakeFeature "CMAKE_INSTALL_DATAROOTDIR" "${placeholder "out"}/share")
+  ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Open Source Program Package for GNSS Positioning";
+    homepage = "https://rtkexplorer.com";
+    changelog = "https://github.com/rtklibexplorer/RTKLIB/releases/tag/${src.tag}";
+    license = lib.licenses.bsd2;
+    maintainers = [ lib.maintainers.skaphi ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/rt/rtl-ais/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  libusb1,
+  rtl-sdr,
+}:
+
+stdenv.mkDerivation {
+  pname = "rtl-ais";
+  version = "0.8.1";
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    rtl-sdr
+    libusb1
+  ];
+
+  src = fetchFromGitHub {
+    owner = "dgiardini";
+    repo = "rtl-ais";
+    rev = "0e85f4e5f9ce7378834c3129bc894580efc24291";
+    sha256 = "0wm4zai1vs89mf0zgz52q5w5rj8f3i3v6zg42hfb7aqabi25r3jf";
+  };
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Simple AIS tuner and generic dual-frequency FM demodulator";
+    homepage = "https://github.com/dgiardini/rtl-ais";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ mgdm ];
+    mainProgram = "rtl_ais";
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/rt/rtl8192su-firmware/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+}:
+stdenvNoCC.mkDerivation {
+  pname = "rtl8192su";
+  version = "0-unstable-2016-10-05";
+
+  src = fetchFromGitHub {
+    owner = "chunkeey";
+    repo = "rtl8192su";
+    rev = "c00112c9a14133290fe30bd3b44e45196994cb1c";
+    sha256 = "0j3c35paapq1icmxq0mg7pm2xa2m69q7bkfmwgq99d682yr2cb5l";
+  };
+
+  dontBuild = true;
+
+  installPhase = ''
+    for i in rtl8192sfw.bin \
+             rtl8192sufw-ap.bin \
+             rtl8192sufw-apple.bin \
+             rtl8192sufw-windows.bin \
+             rtl8712u-linux-firmware-bad.bin \
+             rtl8712u-most-recent-v2.6.6-bad.bin \
+             rtl8712u-most-recent-v2.6.6-bad.bin \
+             rtl8712u-oldest-but-good.bin;
+    do
+      install -D -pm644 firmwares/$i $out/lib/firmware/rtlwifi/$i
+    done
+  '';
+
+  meta = with lib; {
+    description = "Firmware for Realtek RTL8188SU/RTL8191SU/RTL8192SU";
+    homepage = "https://github.com/chunkeey/rtl8192su";
+    license = licenses.unfreeRedistributableFirmware;
+    maintainers = with maintainers; [ mic92 ];
+    platforms = with platforms; linux;
+  };
+}

pkgs/by-name/rt/rtl8761b-firmware/package.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+}:
+
+stdenvNoCC.mkDerivation {
+  name = "rtl8761b-firmware";
+
+  src = fetchFromGitHub {
+    owner = "Realtek-OpenSource";
+    repo = "android_hardware_realtek";
+    rev = "rtk1395";
+    sha256 = "sha256-vd9sZP7PGY+cmnqVty3sZibg01w8+UNinv8X85B+dzc=";
+  };
+
+  installPhase = ''
+    install -D -pm644 \
+      bt/rtkbt/Firmware/BT/rtl8761b_fw \
+      $out/lib/firmware/rtl_bt/rtl8761b_fw.bin
+
+    install -D -pm644 \
+      bt/rtkbt/Firmware/BT/rtl8761b_config \
+      $out/lib/firmware/rtl_bt/rtl8761b_config.bin
+  '';
+
+  meta = with lib; {
+    description = "Firmware for Realtek RTL8761b";
+    license = licenses.unfreeRedistributableFirmware;
+    maintainers = with maintainers; [ milibopp ];
+    platforms = with platforms; linux;
+  };
+}

pkgs/by-name/rt/rtl_433/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  libusb1,
+  rtl-sdr,
+  soapysdr-with-plugins,
+}:
+
+stdenv.mkDerivation rec {
+  version = "25.02";
+  pname = "rtl_433";
+
+  src = fetchFromGitHub {
+    owner = "merbanan";
+    repo = "rtl_433";
+    rev = version;
+    hash = "sha256-S0jtcgbpS2NOezZJ0uq1pVj0nsa82F0NRmQD9glILz4=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    cmake
+  ];
+
+  buildInputs = [
+    libusb1
+    rtl-sdr
+    soapysdr-with-plugins
+  ];
+
+  doCheck = true;
+
+  meta = with lib; {
+    description = "Decode traffic from devices that broadcast on 433.9 MHz, 868 MHz, 315 MHz, 345 MHz and 915 MHz";
+    homepage = "https://github.com/merbanan/rtl_433";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [
+      earldouglas
+      markuskowa
+    ];
+    platforms = platforms.all;
+    mainProgram = "rtl_433";
+  };
+}

pkgs/by-name/rt/rtl_fm_streamer/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  libusb1,
+  libev,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rtl_fm_streamer";
+  version = "unstable-2021-06-08";
+
+  src = fetchFromGitHub {
+    owner = "AlbrechtL";
+    repo = "rtl_fm_streamer";
+    rev = "ceb2bf06883f986ed01aa57c84989ba35b6b9a27";
+    hash = "sha256-9M7GS6AC7HEJge04vl7V6ZdtwWvbMu/Rhaf9fwQa9WA=";
+  };
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace '/etc/udev/rules.d' "$out/etc/udev/rules.d"
+
+    substituteInPlace rtl-sdr.rules \
+      --replace 'MODE:="0666"' 'ENV{ID_SOFTWARE_RADIO}="1", MODE="0660", GROUP="plugdev"'
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    libusb1
+    libev
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "INSTALL_UDEV_RULES" stdenv.hostPlatform.isLinux)
+  ];
+
+  doInstallCheck = true;
+
+  meta = {
+    description = "Turns your Realtek RTL2832 based DVB dongle into a FM radio stereo receiver";
+    homepage = "https://github.com/AlbrechtL/rtl_fm_streamer";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ doronbehar ];
+    broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64;
+  };
+})

pkgs/by-name/rt/rtlamr/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildGoModule,
+}:
+
+buildGoModule {
+  pname = "rtlamr";
+  version = "0.9.3-unstable-2023-08-13";
+
+  src = fetchFromGitHub {
+    owner = "bemasher";
+    repo = "rtlamr";
+    rev = "dcdddc5a6e7717a038e9346d0adcf9669e4f60b7";
+    sha256 = "sha256-r3dMCpNBCQsqSlFYYfOtVMMgPOagWks6PPWOn5PsLZs";
+  };
+
+  vendorHash = "sha256-uT6zfsWgIot0EMNqwtwJNFXN/WaAyOGfcYJjuyOXT4g=";
+
+  meta = {
+    description = "Rtl-sdr receiver for Itron ERT compatible smart meters";
+    longDescription = ''
+      An rtl-sdr receiver for Itron ERT compatible smart meters operating
+      in the 900MHz ISM band
+    '';
+    homepage = "https://github.com/bemasher/rtlamr";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [ jmendyk ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/rt/rtlcss/package.nix

@@ -0,0 +1,29 @@
+{
+  buildNpmPackage,
+  fetchFromGitHub,
+  lib,
+}:
+
+buildNpmPackage rec {
+  pname = "rtlcss";
+  version = "4.1.0";
+
+  src = fetchFromGitHub {
+    owner = "MohammadYounes";
+    repo = "rtlcss";
+    rev = "v${version}";
+    hash = "sha256-KdAf7jzt8o/YEzT/bLCXj546HX0oC90kr44u3p3qv/k=";
+  };
+
+  npmDepsHash = "sha256-ghVgvw55w7T9WxokYtlFSgCfGvcOxFzm2wQIFi+6uBY=";
+
+  dontNpmBuild = true;
+
+  meta = with lib; {
+    description = "Framework for converting Left-To-Right (LTR) Cascading Style Sheets(CSS) to Right-To-Left (RTL)";
+    mainProgram = "rtlcss";
+    homepage = "https://rtlcss.com";
+    license = licenses.mit;
+    maintainers = [ ];
+  };
+}

pkgs/by-name/rt/rtmpdump/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  zlib,
+  gnutlsSupport ? false,
+  gnutls,
+  nettle,
+  opensslSupport ? true,
+  openssl,
+}:
+
+assert (gnutlsSupport || opensslSupport);
+
+stdenv.mkDerivation {
+  pname = "rtmpdump";
+  version = "2.6";
+
+  src = fetchgit {
+    url = "git://git.ffmpeg.org/rtmpdump";
+    # Releases are not tagged.
+    rev = "6f6bb1353fc84f4cc37138baa99f586750028a01";
+    hash = "sha256-rwMA9eougKnkpG+fe6vZIwOBt2CC1d9qI9a079EbE5o=";
+  };
+
+  preBuild = ''
+    makeFlagsArray+=(CC="$CC")
+  '';
+
+  makeFlags = [
+    "prefix=$(out)"
+    "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
+  ]
+  ++ lib.optional gnutlsSupport "CRYPTO=GNUTLS"
+  ++ lib.optional opensslSupport "CRYPTO=OPENSSL"
+  ++ lib.optional stdenv.hostPlatform.isDarwin "SYS=darwin";
+
+  propagatedBuildInputs = [
+    zlib
+  ]
+  ++ lib.optionals gnutlsSupport [
+    gnutls
+    nettle
+  ]
+  ++ lib.optional opensslSupport openssl;
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  separateDebugInfo = true;
+
+  meta = with lib; {
+    description = "Toolkit for RTMP streams";
+    homepage = "https://rtmpdump.mplayerhq.hu/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ codyopel ];
+  };
+}

pkgs/by-name/rt/rtorrent/package.nix

@@ -0,0 +1,90 @@
+{
+  autoreconfHook,
+  cppunit,
+  curl,
+  fetchFromGitHub,
+  installShellFiles,
+  lib,
+  libtool,
+  libtorrent-rakshasa,
+  lua5_4_compat,
+  ncurses,
+  nixosTests,
+  nix-update-script,
+  openssl,
+  pkg-config,
+  stdenv,
+  versionCheckHook,
+  withLua ? false,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rtorrent";
+  version = "0.16.0";
+
+  src = fetchFromGitHub {
+    owner = "rakshasa";
+    repo = "rtorrent";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-+lpivm3MXbuJ4XYhK5OaASpqpDKcCdW7JCFjQYBYCSA=";
+  };
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  nativeBuildInputs = [
+    autoreconfHook
+    installShellFiles
+    pkg-config
+  ];
+
+  buildInputs = [
+    cppunit
+    curl
+    libtool
+    libtorrent-rakshasa
+    ncurses
+    openssl
+    zlib
+  ]
+  ++ lib.optionals withLua [ lua5_4_compat ];
+
+  configureFlags = [
+    "--with-xmlrpc-tinyxml2"
+    "--with-posix-fallocate"
+  ]
+  ++ lib.optionals withLua [ "--with-lua" ];
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    installManPage doc/old/rtorrent.1
+    install -Dm644 doc/rtorrent.rc-example -t $out/share/doc/rtorrent/rtorrent.rc
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "-h";
+
+  passthru = {
+    inherit libtorrent-rakshasa;
+    tests = { inherit (nixosTests) rtorrent; };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Ncurses client for libtorrent, ideal for use with screen, tmux, or dtach";
+    homepage = "https://rakshasa.github.io/rtorrent/";
+    license = lib.licenses.gpl2Plus;
+    mainProgram = "rtorrent";
+    maintainers = with lib.maintainers; [
+      ebzzry
+      codyopel
+      thiagokokada
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/rt/rtptools/package.nix

@@ -0,0 +1,20 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+}:
+stdenv.mkDerivation rec {
+  pname = "rtptools";
+  version = "1.22";
+  src = fetchurl {
+    url = "http://www.cs.columbia.edu/irt/software/rtptools/download/rtptools-${version}.tar.gz";
+    sha256 = "0a4c0vmhxibfc58rrxpbav2bsk546chkg50ir4h3i57v4fjb4xic";
+  };
+  meta = {
+    description = "Number of small applications that can be used for processing RTP data";
+    homepage = "https://www.cs.columbia.edu/irt/software/rtptools/";
+    maintainers = [ ];
+    platforms = lib.platforms.unix;
+    license = lib.licenses.bsd3;
+  };
+}

pkgs/by-name/rt/rtrlib/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  cmake,
+  libssh,
+  openssl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rtrlib";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    repo = "rtrlib";
+    owner = "rtrlib";
+    rev = "v${version}";
+    sha256 = "sha256-ISb4ojcDvXY/88GbFMrA5V5+SGE6CmE5D+pokDTwotQ=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [
+    libssh
+    openssl
+  ];
+
+  postFixup = ''
+    substituteInPlace "$out"/lib/pkgconfig/rtrlib.pc \
+      --replace '=''${prefix}//' '=/'
+  '';
+
+  meta = with lib; {
+    description = "Open-source C implementation of the RPKI/Router Protocol client";
+    homepage = "https://github.com/rtrlib/rtrlib";
+    license = licenses.mit;
+    maintainers = with maintainers; [ Anillc ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/rt/rtrtr/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rtrtr";
+  version = "0.3.2";
+
+  src = fetchFromGitHub {
+    owner = "NLnetLabs";
+    repo = "rtrtr";
+    rev = "v${version}";
+    hash = "sha256-1TmzC/d/odfYdo1CiCsFW3U7OCpTF4Gkw2w4c2yaxxw=";
+  };
+
+  cargoHash = "sha256-SeQ2zRBbETabAhOItu3C6PUjL7vUsVDzWGbYcUIslF4=";
+  nativeBuildInputs = [ pkg-config ];
+
+  buildNoDefaultFeatures = true;
+
+  meta = {
+    description = "RPKI data proxy";
+    longDescription = ''
+      TRTR is an RPKI data proxy, designed to collect Validated ROA Payloads
+      from one or more sources in multiple formats and dispatch it onwards. It
+      provides the means to implement multiple distribution architectures for RPKI
+      such as centralised RPKI validators that dispatch data to local caching RTR
+      servers. RTRTR can read RPKI data from multiple RPKI Relying Party packages via
+      RTR and JSON and, in turn, provide an RTR service for routers to connect to.
+    '';
+    homepage = "https://github.com/NLnetLabs/rtrtr";
+    changelog = "https://github.com/NLnetLabs/rtrtr/blob/v${version}/Changelog.md";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ steamwalker ];
+    mainProgram = "rtrtr";
+  };
+}

pkgs/by-name/rt/rtss/package.nix

@@ -0,0 +1,27 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rtss";
+  version = "0.6.2";
+
+  src = fetchFromGitHub {
+    owner = "Freaky";
+    repo = "rtss";
+    rev = "v${version}";
+    sha256 = "sha256-WeeZsB42/4SlIaWwKvOqWiPNV5p0QOToynI8ozVVxJM=";
+  };
+
+  cargoHash = "sha256-7+58CMm9nPg9tVXphUcIufFGONOxjAlSWBseq5fbM44=";
+
+  meta = with lib; {
+    description = "Annotate output with relative durations between lines";
+    mainProgram = "rtss";
+    homepage = "https://github.com/Freaky/rtss";
+    license = licenses.mit;
+    maintainers = with maintainers; [ djanatyn ];
+  };
+}

pkgs/by-name/rt/rttr/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rttr";
+  version = "0.9.6";
+
+  src = fetchFromGitHub {
+    owner = "rttrorg";
+    repo = "rttr";
+    rev = "v${version}";
+    sha256 = "1yxad8sj40wi75hny8w6imrsx8wjasjmsipnlq559n4b6kl84ijp";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+  ];
+
+  cmakeFlags = [
+    "-DBUILD_EXAMPLES=OFF"
+    "-DBUILD_UNIT_TESTS=OFF"
+    "-DBUILD_PACKAGE=OFF"
+  ];
+
+  meta = with lib; {
+    broken = stdenv.hostPlatform.isDarwin;
+    description = "C++ Reflection Library";
+    homepage = "https://www.rttr.org";
+    license = licenses.mit;
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/rt/rtz/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  bzip2,
+  openssl,
+  zstd,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rtz";
+  version = "0.7.1";
+
+  src = fetchFromGitHub {
+    owner = "twitchax";
+    repo = "rtz";
+    rev = "v${version}";
+    hash = "sha256-V7N9NFIc/WWxLaahkjdS47Qj8sc3HRdKSkrBqi1ngA8=";
+  };
+
+  cargoHash = "sha256-Lm81Qnu3ZQw43fCcQOR63EV1aYXuPyR9Gy+F6BCiwUw=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    bzip2
+    openssl
+    zstd
+  ];
+
+  buildFeatures = [ "web" ];
+
+  meta = with lib; {
+    description = "Tool to easily work with timezone lookups via a binary, a library, or a server";
+    homepage = "https://github.com/twitchax/rtz";
+    changelog = "https://github.com/twitchax/rtz/releases/tag/${src.rev}";
+    license = licenses.mit;
+    maintainers = with maintainers; [ figsoda ];
+    mainProgram = "rtz";
+  };
+}