push sheeet

pkgs/by-name/ru/runit/fix-ar-ranlib.patch

@@ -0,0 +1,18 @@
+--- runit-2.1.2/src/print-ar.sh
++++ runit-2.1.2/src/print-ar.sh
+@@ -1,7 +1,7 @@
+ cat warn-auto.sh
+ echo 'main="$1"; shift'
+ echo 'rm -f "$main"'
+-echo 'ar cr "$main" ${1+"$@"}'
++echo '$AR cr "$main" ${1+"$@"}'
+ case "`cat systype`" in
+   sunos-5.*) ;;
+   unix_sv*) ;;
+@@ -10,5 +10,5 @@ case "`cat systype`" in
+   dgux-*) ;;
+   hp-ux-*) ;;
+   sco*) ;;
+-  *) echo 'ranlib "$main"' ;;
++  *) echo '$RANLIB "$main"' ;;
+ esac

pkgs/by-name/ru/runit/package.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+
+  # Build runit-init as a static binary
+  static ? false,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "runit";
+  version = "2.2.0";
+
+  src = fetchurl {
+    url = "http://smarden.org/runit/${pname}-${version}.tar.gz";
+    sha256 = "sha256-le9NKGi5eMcXn+R5AeXFeOEc8nPSkr1iCL06fMsCkpA=";
+  };
+
+  patches = [
+    ./fix-ar-ranlib.patch
+  ];
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  sourceRoot = "admin/${pname}-${version}";
+
+  doCheck = true;
+
+  buildInputs = lib.optionals static [
+    stdenv.cc.libc
+    stdenv.cc.libc.static
+  ];
+
+  postPatch = ''
+    sed -i "s,\(#define RUNIT\) .*,\1 \"$out/bin/runit\"," src/runit.h
+    # usernamespace sandbox of nix seems to conflict with runit's assumptions
+    # about unix users. Therefor skip the check
+    sed -i '/.\/chkshsgr/d' src/Makefile
+  ''
+  + lib.optionalString (!static) ''
+    sed -i 's,-static,,g' src/Makefile
+  '';
+
+  preBuild = ''
+    cd src
+
+    # Both of these are originally hard-coded to gcc
+    echo ${stdenv.cc.targetPrefix}cc > conf-cc
+    echo ${stdenv.cc.targetPrefix}cc ${lib.optionalString stdenv.hostPlatform.isDarwin "-Xlinker -x "}> conf-ld
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -t $out/bin $(< ../package/commands)
+
+    mkdir -p $man/share/man
+    cp -r ../man $man/share/man/man8
+  '';
+
+  meta = with lib; {
+    description = "UNIX init scheme with service supervision";
+    license = licenses.bsd3;
+    homepage = "http://smarden.org/runit";
+    maintainers = with maintainers; [ joachifm ];
+    platforms = platforms.linux ++ platforms.darwin;
+  };
+}