push sheeet

pkgs/by-name/rv/rvvm/package.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+
+  SDL2,
+
+  libX11,
+  libXext,
+
+  guiBackend ? "sdl",
+
+  enableSDL ? guiBackend == "sdl",
+  enableX11 ? guiBackend == "x11",
+}:
+
+assert lib.assertMsg (builtins.elem guiBackend [
+  "sdl"
+  "x11"
+  "none"
+]) "Unsupported GUI backend";
+assert lib.assertMsg (!(enableSDL && enableX11)) "RVVM can have only one GUI backend at a time";
+assert lib.assertMsg (
+  stdenv.hostPlatform.isDarwin -> !enableX11
+) "macOS supports only SDL GUI backend";
+
+stdenv.mkDerivation rec {
+  pname = "rvvm";
+  version = "0.6";
+
+  src = fetchFromGitHub {
+    owner = "LekKit";
+    repo = "RVVM";
+    rev = "v${version}";
+    sha256 = "sha256-5nSlKyWDAx0EeKFzzwP5+99XuJz9BHXEF1WNkRMLa9U=";
+  };
+
+  buildInputs =
+    [ ]
+    ++ lib.optionals enableSDL [ SDL2 ]
+    ++ lib.optionals enableX11 [
+      libX11
+      libXext
+    ];
+
+  enableParallelBuilding = true;
+
+  buildFlags = [
+    "all"
+    "lib"
+  ];
+
+  makeFlags = [
+    "PREFIX=$(out)"
+  ]
+  ++ lib.optional enableSDL "USE_SDL=2" # Use SDL2 instead of SDL1
+  ++ lib.optional (!enableSDL && !enableX11) "USE_FB=0";
+
+  meta = with lib; {
+    homepage = "https://github.com/LekKit/RVVM";
+    description = "RISC-V Virtual Machine";
+    license = with licenses; [
+      gpl3 # or
+      mpl20
+    ];
+    platforms = platforms.linux ++ platforms.darwin;
+    maintainers = with maintainers; [ kamillaova ];
+    mainProgram = "rvvm";
+  };
+}

pkgs/by-name/rv/rvz/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  zlib,
+}:
+
+buildGoModule rec {
+  pname = "rvz";
+  version = "1.0.3";
+
+  src = fetchFromGitHub {
+    owner = "bodgit";
+    repo = "rvz";
+    rev = "v${version}";
+    hash = "sha256-OxU+Pm9OfFuwmmc2+b7eLhN8JR3SB8cjvh9lPS0qJ5Y=";
+  };
+
+  vendorHash = "sha256-Spmp0ZuvC0IpbfZrXNzJQ18LIuRRfwvuwf3E7S+30GY=";
+
+  buildInputs = [ zlib ];
+
+  rev = "aa4ae9eeff06cd2942db0d5af5f4fa5872530256";
+  buildDate = "2022-11-18T23:11:47Z";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version}"
+    "-X main.commit=${rev}"
+    "-X main.date=${buildDate}"
+  ];
+
+  subPackages = [ "cmd/rvz" ];
+
+  checkPhase = ''
+    go test -v -short -coverprofile=cover.out ./...
+  '';
+
+  meta = {
+    description = "Golang library for reading RVZ disc images";
+    homepage = "https://github.com/bodgit/rvz";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ dansbandit ];
+    mainProgram = "rvz";
+  };
+}