push sheeet

pkgs/by-name/rx/rx/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  makeWrapper,
+  cmake,
+  pkg-config,
+  xorg ? null,
+  libGL ? null,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rx";
+  version = "0.5.2";
+
+  src = fetchFromGitHub {
+    owner = "cloudhead";
+    repo = "rx";
+    rev = "v${version}";
+    sha256 = "sha256-LTpaV/fgYUgA2M6Wz5qLHnTNywh13900g+umhgLvciM=";
+  };
+
+  cargoHash = "sha256-gRhjqQNL1Cu6/RpF2AeIGwbuDkFvyOf3gnpYt5Hlhfc=";
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    makeWrapper
+  ];
+
+  buildInputs = lib.optionals stdenv.hostPlatform.isLinux (
+    with xorg;
+    [
+      # glfw-sys dependencies:
+      libX11
+      libXrandr
+      libXinerama
+      libXcursor
+      libXi
+      libXext
+    ]
+  );
+
+  # FIXME: GLFW (X11) requires DISPLAY env variable for all tests
+  doCheck = false;
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
+    mkdir -p $out/share/applications
+    cp $src/rx.desktop $out/share/applications
+    wrapProgram $out/bin/rx --prefix LD_LIBRARY_PATH : ${libGL}/lib
+  '';
+
+  meta = with lib; {
+    description = "Modern and extensible pixel editor implemented in Rust";
+    mainProgram = "rx";
+    homepage = "https://rx.cloudhead.io/";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [
+      minijackson
+      Br1ght0ne
+    ];
+    platforms = [ "x86_64-linux" ];
+  };
+}

pkgs/by-name/rx/rxp/package.nix

@@ -0,0 +1,23 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rxp";
+  version = "1.5.2";
+
+  src = fetchurl {
+    url = "https://www.inf.ed.ac.uk/research/isddarch/admin/rxp-${finalAttrs.version}.tar.gz";
+    hash = "sha256-+mQbSlGF0KHZYQyCRbnVr/WXLBoooNqU8+ONafbBRRM=";
+  };
+
+  meta = {
+    license = lib.licenses.gpl2Plus;
+    description = "Validating XML parser written in C";
+    homepage = "https://www.cogsci.ed.ac.uk/~richard/rxp.html";
+    platforms = lib.platforms.unix;
+    mainProgram = "rxp";
+  };
+})

pkgs/by-name/rx/rxvt/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  libtool,
+  libX11,
+  libXt,
+  libXpm,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rxvt";
+  version = "2.7.10";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/rxvt/${pname}-${version}.tar.gz";
+    sha256 = "0jfl71gz3k7zh3kxdb8lxi06kajjnx7bq1rxjgk680l209jxask1";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    libtool
+    libX11
+    libXt
+    libXpm
+  ];
+
+  configurePhase = ''
+    LIBTOOL=${libtool}/bin/libtool ./configure --prefix=$out --enable-everything --enable-smart-resize --enable-256-color
+  '';
+
+  meta = with lib; {
+    homepage = "https://rxvt.sourceforge.net/";
+    description = "Colour vt102 terminal emulator with less features and lower memory consumption";
+    longDescription = ''
+      rxvt (acronym for our extended virtual terminal) is a terminal
+      emulator for the X Window System, originally written by Rob Nation
+      as an extended version of the older xvt terminal by John Bovey of
+      University of Kent. Mark Olesen extensively modified it later and
+      took over maintenance for several years.
+
+      rxvt is intended to be a slimmed-down alternate for xterm,
+      omitting some of its little-used features, like Tektronix 4014
+      emulation and toolkit-style configurability.
+    '';
+    maintainers = [ ];
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    knownVulnerabilities = [
+      "Usage of ANSI escape sequences causes unexpected newline-termination, leading to unexpected command execution (https://www.openwall.com/lists/oss-security/2021/05/17/1)"
+    ];
+  };
+}