push sheeet

pkgs/by-name/ry/rye/package.nix

@@ -0,0 +1,111 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+
+  # nativeBuildInputs
+  installShellFiles,
+  pkg-config,
+
+  # buildInputs
+  openssl,
+  stdenv,
+
+  buildPackages,
+  versionCheckHook,
+
+  # passthru
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rye";
+  version = "0.44.0";
+
+  src = fetchFromGitHub {
+    owner = "mitsuhiko";
+    repo = "rye";
+    tag = version;
+    hash = "sha256-K9xad5Odza0Oxz49yMJjqpfh3cCgmWnbAlv069fHV6Q=";
+  };
+
+  cargoHash = "sha256-+gFa8hruXIweFm24XvfhqXZxNLAYKVNX+xBSCdAk54A=";
+
+  env = {
+    OPENSSL_NO_VENDOR = 1;
+  };
+
+  nativeBuildInputs = [
+    installShellFiles
+    pkg-config
+  ];
+
+  buildInputs = [
+    openssl
+  ];
+
+  postInstall =
+    let
+      emulator = stdenv.hostPlatform.emulator buildPackages;
+    in
+    ''
+      installShellCompletion --cmd rye \
+        --bash <(${emulator} $out/bin/rye self completion -s bash) \
+        --fish <(${emulator} $out/bin/rye self completion -s fish) \
+        --zsh <(${emulator} $out/bin/rye self completion -s zsh)
+    '';
+
+  checkFlags = [
+    "--skip=utils::test_is_inside_git_work_tree"
+
+    # The following require internet access to fetch a python binary
+    "--skip=test_add_and_sync_no_auto_sync"
+    "--skip=test_add_autosync"
+    "--skip=test_add_dev"
+    "--skip=test_add_explicit_version_or_url"
+    "--skip=test_add_flask"
+    "--skip=test_add_from_find_links"
+    "--skip=test_autosync_remember"
+    "--skip=test_basic_list"
+    "--skip=test_basic_script"
+    "--skip=test_basic_tool_behavior"
+    "--skip=test_config_empty"
+    "--skip=test_config_get_set_multiple"
+    "--skip=test_config_incompatible_format_and_show_path"
+    "--skip=test_config_save_missing_folder"
+    "--skip=test_config_show_path"
+    "--skip=test_dotenv"
+    "--skip=test_empty_sync"
+    "--skip=test_exclude_hashes"
+    "--skip=test_fetch"
+    "--skip=test_generate_hashes"
+    "--skip=test_init_default"
+    "--skip=test_init_lib"
+    "--skip=test_init_script"
+    "--skip=test_lint_and_format"
+    "--skip=test_list_never_overwrite"
+    "--skip=test_list_not_rye_managed"
+    "--skip=test_lockfile"
+    "--skip=test_publish_outside_project"
+    "--skip=test_version"
+  ];
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Tool to easily manage python dependencies and environments";
+    homepage = "https://github.com/mitsuhiko/rye";
+    changelog = "https://github.com/mitsuhiko/rye/releases/tag/${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ GaetanLepage ];
+    mainProgram = "rye";
+  };
+}

pkgs/by-name/ry/rygel/add-option-for-installation-sysconfdir.patch

@@ -0,0 +1,35 @@
+diff --git a/meson.build b/meson.build
+index 27bde61f..3d434de9 100644
+--- a/meson.build
++++ b/meson.build
+@@ -22,7 +22,11 @@ if not get_option('uninstalled')
+     rygel_datadir = join_paths(get_option('prefix'), get_option('datadir'), 'rygel')
+     rygel_libexecdir = join_paths(get_option('prefix'), get_option('libexecdir'),
+     'rygel')
+-    rygel_sysconfdir = join_paths(get_option('prefix'), get_option('sysconfdir'))
++    if get_option('sysconfdir_install') != ''
++        rygel_sysconfdir = join_paths(get_option('prefix'), get_option('sysconfdir_install'))
++    else
++        rygel_sysconfdir = join_paths(get_option('prefix'), get_option('sysconfdir'))
++    endif
+     rygel_plugindir = join_paths(rygel_libdir, 'rygel-2.8', 'plugins')
+     rygel_enginedir = join_paths(rygel_libdir, 'rygel-2.8', 'engines')
+     rygel_presetdir = join_paths(rygel_datadir, 'presets')
+@@ -57,7 +61,7 @@ conf.set_quoted('DATA_DIR', rygel_datadir)
+ conf.set_quoted('PLUGIN_DIR', rygel_plugindir)
+ conf.set_quoted('BIG_ICON_DIR', rygel_bigicondir)
+ conf.set_quoted('SMALL_ICON_DIR', rygel_smallicondir)
+-conf.set_quoted('SYS_CONFIG_DIR', rygel_sysconfdir)
++conf.set_quoted('SYS_CONFIG_DIR', get_option('sysconfdir'))
+ conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
+ conf.set_quoted('MX_EXTRACT_PATH', join_paths(rygel_libexecdir, 'mx-extract'))
+ conf.set_quoted('DESKTOP_DIR', join_paths(get_option('prefix'), get_option('datadir'), 'applications'))
+diff --git a/meson_options.txt b/meson_options.txt
+index fd04776a..3dee43ba 100644
+--- a/meson_options.txt
++++ b/meson_options.txt
+@@ -1,3 +1,4 @@
++option('sysconfdir_install', type: 'string', value: '', description: 'sysconfdir to use during installation')
+ option('uninstalled', type: 'boolean', value: 'false', description: 'Run Rygel from build directory only')
+ option('api-docs', type: 'boolean', value: 'false', description: 'Build the API documentation')
+ option('man_pages', type: 'boolean', value: 'true', description: 'Build the man pages')

pkgs/by-name/ry/rygel/package.nix

@@ -0,0 +1,132 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  docbook-xsl-nons,
+  meson,
+  ninja,
+  pkg-config,
+  vala,
+  gettext,
+  libxml2,
+  libxslt,
+  gobject-introspection,
+  wrapGAppsHook3,
+  wrapGAppsNoGuiHook,
+  python3,
+  gdk-pixbuf,
+  glib,
+  gssdp_1_6,
+  gupnp_1_6,
+  gupnp-av,
+  gupnp-dlna,
+  gst_all_1,
+  libgee,
+  libsoup_3,
+  libX11,
+  withGtk ? true,
+  gtk3,
+  libmediaart,
+  pipewire,
+  sqlite,
+  systemd,
+  tinysparql,
+  shared-mime-info,
+  gnome,
+  rygel,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rygel";
+  version = "0.44.2";
+
+  # TODO: split out lib
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/rygel/${lib.versions.majorMinor finalAttrs.version}/rygel-${finalAttrs.version}.tar.xz";
+    hash = "sha256-eW7uSUzfYNwr+CsAuPmaFLocfPQNKUSBf/DBqmBz1aA=";
+  };
+
+  patches = [
+    ./add-option-for-installation-sysconfdir.patch
+  ];
+
+  nativeBuildInputs = [
+    docbook-xsl-nons
+    meson
+    ninja
+    pkg-config
+    vala
+    gettext
+    libxml2
+    libxslt # for xsltproc
+    gobject-introspection
+    (if withGtk then wrapGAppsHook3 else wrapGAppsNoGuiHook)
+    python3
+  ];
+
+  buildInputs = [
+    gdk-pixbuf
+    glib
+    gssdp_1_6
+    gupnp_1_6
+    gupnp-av
+    gupnp-dlna
+    libgee
+    libsoup_3
+    libmediaart
+    pipewire
+    # Move this to withGtk when it's not unconditionally included
+    # https://gitlab.gnome.org/GNOME/rygel/-/issues/221
+    # https://gitlab.gnome.org/GNOME/rygel/-/merge_requests/27
+    libX11
+    sqlite
+    systemd
+    tinysparql
+    shared-mime-info
+  ]
+  ++ lib.optionals withGtk [ gtk3 ]
+  ++ (with gst_all_1; [
+    gstreamer
+    gst-editing-services
+    gst-plugins-base
+    gst-plugins-good
+    gst-plugins-bad
+    gst-plugins-ugly
+  ]);
+
+  mesonFlags = [
+    "-Dsystemd-user-units-dir=${placeholder "out"}/lib/systemd/user"
+    "-Dapi-docs=false"
+    "--sysconfdir=/etc"
+    "-Dsysconfdir_install=${placeholder "out"}/etc"
+    (lib.mesonEnable "gtk" withGtk)
+  ];
+
+  doCheck = true;
+
+  postPatch = ''
+    patchShebangs data/xml/process-xml.py
+  '';
+
+  passthru = {
+    updateScript = gnome.updateScript {
+      packageName = "rygel";
+      versionPolicy = "odd-unstable";
+    };
+    noGtk = rygel.override { withGtk = false; };
+  };
+
+  meta = with lib; {
+    description = "Home media solution (UPnP AV MediaServer) that allows you to easily share audio, video and pictures to other devices";
+    homepage = "https://gitlab.gnome.org/GNOME/rygel";
+    changelog = "https://gitlab.gnome.org/GNOME/rygel/-/blob/rygel-${finalAttrs.version}/NEWS?ref_type=tags";
+    license = licenses.lgpl21Plus;
+    teams = [ teams.gnome ];
+    platforms = platforms.linux;
+  };
+})

pkgs/by-name/ry/rymcast/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  autoPatchelfHook,
+  makeWrapper,
+  alsa-lib,
+  curl,
+  gtk3,
+  webkitgtk_4_0,
+  zenity,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rymcast";
+  version = "1.0.6";
+
+  src = fetchzip {
+    url = "https://www.inphonik.com/files/rymcast/rymcast-${version}-linux-x64.tar.gz";
+    hash = "sha256:0vjjhfrwdibjjgz3awbg30qxkjrzc4cya1f4pigwjh3r0vvrq0ga";
+    stripRoot = false;
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    makeWrapper
+  ];
+
+  buildInputs = [
+    alsa-lib
+    curl
+    gtk3
+    (lib.getLib stdenv.cc.cc)
+    webkitgtk_4_0
+    zenity
+  ];
+
+  installPhase = ''
+    mkdir -p "$out/bin"
+    cp RYMCast "$out/bin/"
+    wrapProgram "$out/bin/RYMCast" \
+      --set PATH "${lib.makeBinPath [ zenity ]}"
+  '';
+
+  meta = with lib; {
+    description = "Player for Mega Drive/Genesis VGM files";
+    homepage = "https://www.inphonik.com/products/rymcast-genesis-vgm-player/";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+    license = licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+  };
+}

pkgs/by-name/ry/rymdport/package.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  pkg-config,
+  libGL,
+  xorg,
+}:
+
+buildGoModule rec {
+  pname = "rymdport";
+  version = "3.9.1";
+
+  src = fetchFromGitHub {
+    owner = "Jacalz";
+    repo = "rymdport";
+    rev = "v${version}";
+    hash = "sha256-5INmb8zMFUB8ibA+ACNWoL54tOhWYHF85MZzRNRmJow=";
+  };
+
+  vendorHash = "sha256-WPJj3zlEJeghRw0lHHUXm7n0a6d8Yf78s7jnBwmAZ4U=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = with xorg; [
+    libGL
+    libX11
+    libXcursor
+    libXext
+    libXi
+    libXinerama
+    libXrandr
+    libXxf86vm
+  ];
+
+  postInstall = ''
+    for res in $(ls internal/assets/icons | sed -e 's/icon-//g' -e 's/.png//g'); do
+      install -Dm444 internal/assets/icons/icon-$res.png \
+        $out/share/icons/hicolor/''${res}x''${res}/apps/io.github.jacalz.rymdport.png
+    done
+    install -Dm444 internal/assets/svg/icon.svg $out/share/icons/hicolor/scalable/apps/io.github.jacalz.rymdport.svg
+    install -Dm444 internal/assets/unix/io.github.jacalz.rymdport.desktop -t $out/share/applications
+  '';
+
+  meta = {
+    description = "Easy encrypted file, folder, and text sharing between devices";
+    homepage = "https://github.com/Jacalz/rymdport";
+    changelog = "https://github.com/Jacalz/rymdport/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ dotlambda ];
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+    mainProgram = "rymdport";
+  };
+}

pkgs/by-name/ry/ryokucha/package.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  vala,
+  gtk4,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ryokucha";
+  version = "0.3.1";
+
+  src = fetchFromGitHub {
+    owner = "ryonakano";
+    repo = "ryokucha";
+    rev = finalAttrs.version;
+    hash = "sha256-bmN8ZiFjUXtWMrZz7BJtO/9TMjcc4d3x8EpFvhvsewY=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    vala
+  ];
+
+  buildInputs = [ gtk4 ];
+
+  strictDeps = true;
+
+  meta = {
+    description = "GTK4 library that includes customized widgets";
+    homepage = "https://github.com/ryonakano/ryokucha";
+    license = lib.licenses.lgpl3Plus;
+    maintainers = with lib.maintainers; [ aleksana ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ry/ryubing/package.nix

@@ -0,0 +1,161 @@
+{
+  lib,
+  buildDotnetModule,
+  cctools,
+  darwin,
+  dotnetCorePackages,
+  fetchFromGitLab,
+  libX11,
+  libgdiplus,
+  moltenvk,
+  ffmpeg,
+  openal,
+  libsoundio,
+  sndio,
+  stdenv,
+  pulseaudio,
+  vulkan-loader,
+  glew,
+  libGL,
+  libICE,
+  libSM,
+  libXcursor,
+  libXext,
+  libXi,
+  libXrandr,
+  udev,
+  SDL2,
+  SDL2_mixer,
+  gtk3,
+  wrapGAppsHook3,
+}:
+
+buildDotnetModule rec {
+  pname = "ryubing";
+  version = "1.3.2";
+
+  src = fetchFromGitLab {
+    domain = "git.ryujinx.app";
+    owner = "Ryubing";
+    repo = "Ryujinx";
+    tag = version;
+    hash = "sha256-6BCDFd0nU96OgI5lqf4fbyNkG4PS5P4raHVbvBAhB5A=";
+  };
+
+  nativeBuildInputs =
+    lib.optional stdenv.hostPlatform.isLinux [
+      wrapGAppsHook3
+    ]
+    ++ lib.optional stdenv.hostPlatform.isDarwin [
+      cctools
+      darwin.sigtool
+    ];
+
+  enableParallelBuilding = false;
+
+  dotnet-sdk = dotnetCorePackages.sdk_9_0;
+  dotnet-runtime = dotnetCorePackages.runtime_9_0;
+
+  nugetDeps = ./deps.json;
+
+  runtimeDeps = [
+    libX11
+    libgdiplus
+    SDL2_mixer
+    openal
+    libsoundio
+    sndio
+    vulkan-loader
+    ffmpeg
+
+    # Avalonia UI
+    glew
+    libICE
+    libSM
+    libXcursor
+    libXext
+    libXi
+    libXrandr
+    gtk3
+
+    # Headless executable
+    libGL
+    SDL2
+  ]
+  ++ lib.optional (!stdenv.hostPlatform.isDarwin) [
+    udev
+    pulseaudio
+  ]
+  ++ lib.optional stdenv.hostPlatform.isDarwin [ moltenvk ];
+
+  projectFile = "Ryujinx.sln";
+  testProjectFile = "src/Ryujinx.Tests/Ryujinx.Tests.csproj";
+
+  # Tests on Darwin currently fail because of Ryujinx.Tests.Unicorn
+  doCheck = !stdenv.hostPlatform.isDarwin;
+
+  dotnetFlags = [
+    "/p:ExtraDefineConstants=DISABLE_UPDATER%2CFORCE_EXTERNAL_BASE_DIR"
+  ];
+
+  executables = [
+    "Ryujinx"
+  ];
+
+  makeWrapperArgs = lib.optional stdenv.hostPlatform.isLinux [
+    # Without this Ryujinx fails to start on wayland. See https://github.com/Ryujinx/Ryujinx/issues/2714
+    "--set SDL_VIDEODRIVER x11"
+  ];
+
+  preInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
+    # workaround for https://github.com/Ryujinx/Ryujinx/issues/2349
+    mkdir -p $out/lib/sndio-6
+    ln -s ${sndio}/lib/libsndio.so $out/lib/sndio-6/libsndio.so.6
+  '';
+
+  preFixup = ''
+    ${lib.optionalString stdenv.hostPlatform.isLinux ''
+      mkdir -p $out/share/{applications,icons/hicolor/scalable/apps,mime/packages}
+
+      pushd ${src}/distribution/linux
+
+      install -D ./Ryujinx.desktop  $out/share/applications/Ryujinx.desktop
+      install -D ./Ryujinx.sh       $out/bin/Ryujinx.sh
+      install -D ./mime/Ryujinx.xml $out/share/mime/packages/Ryujinx.xml
+      install -D ../misc/Logo.svg   $out/share/icons/hicolor/scalable/apps/Ryujinx.svg
+
+      popd
+    ''}
+
+    # Don't make a softlink on OSX because of its case insensitivity
+    ${lib.optionalString (!stdenv.hostPlatform.isDarwin) "ln -s $out/bin/Ryujinx $out/bin/ryujinx"}
+  '';
+
+  passthru.updateScript = ./updater.sh;
+
+  meta = with lib; {
+    homepage = "https://ryujinx.app";
+    changelog = "https://git.ryujinx.app/ryubing/ryujinx/-/wikis/changelog";
+    description = "Experimental Nintendo Switch Emulator written in C# (community fork of Ryujinx)";
+    longDescription = ''
+      Ryujinx is an open-source Nintendo Switch emulator, created by gdkchan,
+      written in C#. This emulator aims at providing excellent accuracy and
+      performance, a user-friendly interface and consistent builds. It was
+      written from scratch and development on the project began in September
+      2017. The project has since been abandoned on October 1st 2024 and QoL
+      updates are now managed under a fork.
+    '';
+    license = licenses.mit;
+    maintainers = with maintainers; [
+      jk
+      artemist
+      willow
+    ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "aarch64-darwin"
+    ];
+    mainProgram = "Ryujinx";
+  };
+}

pkgs/by-name/ry/ryubing/updater.sh

@@ -0,0 +1,37 @@
+#! /usr/bin/env nix-shell
+#! nix-shell -I nixpkgs=./. -i bash -p coreutils gnused curl common-updater-scripts nix-prefetch-git jq
+# shellcheck shell=bash
+set -euo pipefail
+cd "$(dirname "${BASH_SOURCE[0]}")"
+
+# If NEW_VERSION or COMMIT are not set, fetch the latest version
+if [ -z ${NEW_VERSION+x} ] && [ -z ${COMMIT+x} ]; then
+    RELEASE_DATA=$(curl -s "https://git.ryujinx.app/api/v4/projects/1/repository/tags?order_by=updated&sort=desc")
+    if [ -z "$RELEASE_DATA" ] || [[ $RELEASE_DATA =~ "imposed ratelimits" ]]; then
+        echo "failed to get release job data" >&2
+        exit 1
+    fi
+    NEW_VERSION=$(echo "$RELEASE_DATA" | jq -r '[.[] | select(.name | startswith("Canary") | not)][0].name')
+fi
+
+OLD_VERSION="$(sed -nE 's/\s*version = "(.*)".*/\1/p' ./package.nix)"
+
+echo "comparing versions $OLD_VERSION -> $NEW_VERSION"
+if [[ "$OLD_VERSION" == "$NEW_VERSION" ]]; then
+    echo "Already up to date!"
+    if [[ "${1-default}" != "--deps-only" ]]; then
+      exit 0
+    fi
+fi
+
+cd ../../../..
+
+if [[ "${1-default}" != "--deps-only" ]]; then
+    SHA="$(nix-prefetch-git https://git.ryujinx.app/ryubing/ryujinx --rev "$NEW_VERSION" --quiet | jq -r '.sha256')"
+    SRI=$(nix --experimental-features nix-command hash to-sri "sha256:$SHA")
+    update-source-version ryubing "$NEW_VERSION" "$SRI"
+fi
+
+echo "building Nuget lockfile"
+
+eval "$(nix-build -A ryubing.fetch-deps --no-out-link)"

pkgs/by-name/ry/ryzen-monitor-ng/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  unstableGitUpdater,
+}:
+
+stdenv.mkDerivation {
+  pname = "ryzen-monitor-ng";
+  version = "2.0.5-unstable-2023-11-05";
+
+  # Upstream has not updated ryzen_smu header version
+  # This fork corrects ryzen_smu header version and
+  # adds support for Matisse AMD CPUs.
+  src = fetchFromGitHub {
+    owner = "plasmin";
+    repo = "ryzen_monitor_ng";
+    rev = "8b7854791d78de731a45ce7d30dd17983228b7b1";
+    hash = "sha256-xdYNtXCbNy3/y5OAHZEi9KgPtwr1LTtLWAZC5DDCfmE=";
+    # Upstream repo contains pre-compiled binaries and object files
+    # that are out of date.
+    # These need to be removed before build stage.
+    postFetch = ''
+      rm "$out/src/ryzen_monitor"
+      make -C "$out" clean
+    '';
+  };
+
+  makeFlags = [ "PREFIX=${placeholder "out"}" ];
+
+  passthru.updateScript = unstableGitUpdater { };
+
+  meta = with lib; {
+    description = "Access Ryzen SMU information exposed by the ryzen_smu driver";
+    homepage = "https://github.com/plasmin/ryzen_monitor_ng";
+    changelog = "https://github.com/plasmin/ryzen_monitor_ng/blob/master/CHANGELOG.md";
+    license = licenses.agpl3Only;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ phdyellow ];
+    mainProgram = "ryzen_monitor";
+  };
+}

pkgs/by-name/ry/ryzenadj/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pciutils,
+  cmake,
+}:
+stdenv.mkDerivation rec {
+  pname = "ryzenadj";
+  version = "0.17.0";
+
+  src = fetchFromGitHub {
+    owner = "FlyGoat";
+    repo = "RyzenAdj";
+    rev = "v${version}";
+    sha256 = "sha256-28ld8htm3DewTSV3WTG4dFOcX4JAEUMK9rq4AAm1/zY=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    pciutils
+  ];
+
+  strictDeps = true;
+
+  installPhase = ''
+    install -D libryzenadj.so $out/lib/libryzenadj.so
+    install -D ryzenadj $out/bin/ryzenadj
+  '';
+
+  meta = with lib; {
+    description = "Adjust power management settings for Ryzen Mobile Processors";
+    mainProgram = "ryzenadj";
+    homepage = "https://github.com/FlyGoat/RyzenAdj";
+    license = licenses.lgpl3Only;
+    maintainers = with maintainers; [ rhendric ];
+    platforms = [ "x86_64-linux" ];
+  };
+}