push sheeet

pkgs/by-name/s-/s-search/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  stdenv,
+  testers,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "s-search";
+  version = "0.7.4";
+
+  src = fetchFromGitHub {
+    owner = "zquestz";
+    repo = "s";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-bcJeNUGTcXAwB+/xly3AMJE3BTjqiC6QvuqgfDgZZrk=";
+  };
+
+  vendorHash = "sha256-0E/9fONanSxb2Tv5wKIpf1J/A6Hdge23xy3r6pFyV9E=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd s \
+      --bash <($out/bin/s --completion bash) \
+      --fish <($out/bin/s --completion fish) \
+      --zsh <($out/bin/s --completion zsh)
+  '';
+
+  passthru = {
+    # `versionCheckHook` fails due to the program requires `sh` to be available in `PATH`
+    tests.version = testers.testVersion {
+      package = finalAttrs.finalPackage;
+      command = "s --version";
+    };
+
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Web search from the terminal";
+    longDescription = ''
+      Command-line tool that generates a search query link and opens it in the
+      browser of your choice.
+    '';
+    homepage = "https://github.com/zquestz/s";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      yzx9
+    ];
+    mainProgram = "s";
+  };
+})

pkgs/by-name/s-/s-tar/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "s-tar";
+  version = "1.6";
+  src = fetchurl {
+    url = "mirror://sourceforge/s-tar/star-${version}.tar.bz2";
+    sha256 = "0xpp8gf0ghwdgncdwx17fpadxislwrj48gcm42851hz6p8p6c60v";
+  };
+
+  preConfigure = "rm configure";
+  preBuild = "sed 's_/bin/__g' -i RULES/*";
+  makeFlags = [ "GMAKE_NOWARN=true" ];
+  env.NIX_CFLAGS_COMPILE = "-std=c89";
+  installFlags = [
+    "DESTDIR=$(out)"
+    "INS_BASE=/"
+  ];
+  postInstall = ''
+    find $out/bin -type l -delete
+    rm -r $out/etc $out/include $out/sbin
+  '';
+
+  meta = {
+    description = "Very fast tar like tape archiver with improved functionality";
+    longDescription = ''
+      Star archives and extracts multiple files to and from a single file called a tarfile.
+      A tarfile is usually a magnetic tape, but it can be any file.
+      In all cases, appearance of a directory name refers to the files and (recursively) sub-directories of that directory.
+      Star's actions are controlled by the mandatory command flags from the list below.
+      The way star acts may be modified by additional options.
+      Note that unpacking tar archives may be a security risk because star may overwrite existing files.
+    '';
+    homepage = "https://cdrtools.sourceforge.net/private/star.html";
+    license = lib.licenses.cddl;
+    maintainers = [ lib.maintainers.wucke13 ];
+    platforms = [ "x86_64-linux" ];
+  };
+}

pkgs/by-name/s-/s-tui/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  python3Packages,
+  fetchFromGitHub,
+  nix-update-script,
+  s-tui,
+  testers,
+  stress,
+}:
+
+python3Packages.buildPythonPackage rec {
+  pname = "s-tui";
+  version = "1.2.0";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "amanusk";
+    repo = "s-tui";
+    tag = "v${version}";
+    hash = "sha256-VdQSDRDdRO6jHSuscOQZXnVM6nWHaXRfR4sZ3x5lriI=";
+  };
+
+  propagatedBuildInputs = [
+    python3Packages.urwid
+    python3Packages.psutil
+    stress
+  ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests = testers.testVersion { package = s-tui; };
+  };
+
+  meta = with lib; {
+    homepage = "https://amanusk.github.io/s-tui/";
+    description = "Stress-Terminal UI monitoring tool";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ lilacious ];
+    broken = stdenv.hostPlatform.isDarwin; # https://github.com/amanusk/s-tui/issues/49
+    mainProgram = "s-tui";
+  };
+}