push sheeet

pkgs/by-name/sg/sg3_utils/package.nix

@@ -0,0 +1,25 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sg3_utils";
+  version = "1.48";
+
+  src = fetchurl {
+    url = "https://sg.danny.cz/sg/p/sg3_utils-${version}.tgz";
+    sha256 = "sha256-1itsPPIDkPpzVwRDkAhBZtJfHZMqETXEULaf5cKD13M=";
+  };
+
+  meta = with lib; {
+    homepage = "https://sg.danny.cz/sg/";
+    description = "Utilities that send SCSI commands to devices";
+    platforms = platforms.linux;
+    license = with licenses; [
+      bsd2
+      gpl2Plus
+    ];
+  };
+}

pkgs/by-name/sg/sgdboop/hide_desktop_entry.patch

@@ -0,0 +1,22 @@
+From a4ca664abfac0b7efa7dbc48c6438bc1a5333962 Mon Sep 17 00:00:00 2001
+From: Fazzi <faaris.ansari@proton.me>
+Date: Sat, 24 May 2025 20:55:50 +0100
+Subject: [PATCH] desktopFile: hide entry from app launchers
+
+---
+ linux-release/com.steamgriddb.SGDBoop.desktop | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/linux-release/com.steamgriddb.SGDBoop.desktop b/linux-release/com.steamgriddb.SGDBoop.desktop
+index 9c84cdb..9899682 100644
+--- a/linux-release/com.steamgriddb.SGDBoop.desktop
++++ b/linux-release/com.steamgriddb.SGDBoop.desktop
+@@ -4,7 +4,7 @@ Comment=Apply Steam assets from SteamGridDB
+ Exec=SGDBoop %U
+ Terminal=false
+ Type=Application
+-NoDisplay=false
++NoDisplay=true
+ Icon=com.steamgriddb.SGDBoop
+ MimeType=x-scheme-handler/sgdb
+ Categories=Utility

pkgs/by-name/sg/sgdboop/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  curl,
+  pkg-config,
+  wrapGAppsHook3,
+}:
+stdenv.mkDerivation rec {
+  pname = "sgdboop";
+  version = "1.3.1";
+
+  src = fetchFromGitHub {
+    owner = "SteamGridDB";
+    repo = "SGDBoop";
+    tag = "v${version}";
+    hash = "sha256-FpVQQo2N/qV+cFhYZ1FVm+xlPHSVMH4L+irnQEMlUQs=";
+  };
+
+  patches = [
+    # Hide the app from app launchers, as it is not meant to be run directly
+    # Remove when https://github.com/SteamGridDB/SGDBoop/pull/112 is merged
+    ./hide_desktop_entry.patch
+  ];
+
+  makeFlags = [
+    # The flatpak install just copies things to /app - otherwise wants to do things with XDG
+    "FLATPAK_ID=fake"
+  ];
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail "/app/" "$out/"
+  '';
+
+  postInstall = ''
+    rm -r "$out/share/metainfo"
+  '';
+
+  nativeBuildInputs = [
+    pkg-config
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    curl
+  ];
+
+  meta = {
+    description = "Applying custom artwork to Steam, using SteamGridDB";
+    homepage = "https://github.com/SteamGridDB/SGDBoop/";
+    license = lib.licenses.zlib;
+    maintainers = with lib.maintainers; [
+      saturn745
+      fazzi
+    ];
+    mainProgram = "SGDBoop";
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/sg/sgfutils/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  openssl,
+  libiconv,
+  makeWrapper,
+  imagemagick,
+  makeFontsConf,
+}:
+stdenv.mkDerivation {
+  pname = "sgfutils";
+  version = "0.25-unstable-2017-11-27";
+  src = fetchFromGitHub {
+    owner = "yangboz";
+    repo = "sgfutils";
+    rev = "11ab171c46cc16cc71ac6fc901d38ea88d6532a4";
+    hash = "sha256-KWYgTxz32WK3MKouj1WAJtZmleKt5giCpzQPwfWruZQ=";
+  };
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ openssl ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ libiconv ];
+  buildPhase = ''
+    runHook preBuild
+    make all
+    runHook postBuild
+  '';
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp sgf sgfsplit sgfvarsplit sgfstrip sgfinfo sgfmerge sgftf \
+      sgfcheck sgfdb sgfdbinfo sgfcharset sgfcmp sgfx \
+      ngf2sgf nip2sgf nk2sgf gib2sgf sgftopng ugi2sgf \
+      $out/bin
+    runHook postInstall
+  '';
+  postFixup = ''
+    wrapProgram $out/bin/sgftopng \
+      --prefix PATH : ${lib.makeBinPath [ imagemagick ]} \
+      --set-default FONTCONFIG_FILE ${makeFontsConf { fontDirectories = [ ]; }}
+  '';
+  meta = with lib; {
+    homepage = "https://homepages.cwi.nl/~aeb/go/sgfutils/html/sgfutils.html";
+    description = "Command line utilities that help working with SGF files";
+    longDescription = ''
+      The package sgfutils is a collection of command line utilities that help working with SGF files,
+      especially when they describe go (igo, weiqi, baduk) games.
+    '';
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ ggpeti ];
+    platforms = platforms.all; # tested on x86_64-linux and aarch64-darwin
+  };
+}

pkgs/by-name/sg/sgp4/package.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+}:
+
+stdenv.mkDerivation {
+  pname = "sgp4";
+  version = "unstable-2022-11-13";
+
+  src = fetchFromGitHub {
+    owner = "dnwrnr";
+    repo = "sgp4";
+    rev = "6a448b4850e5fbf8c1ca03bb5f6013a9fdc1fd91";
+    hash = "sha256-gfJQOLhys5wKzZCxFVqbo+5l7jPeGPzrvYsdZKPSCJc=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = with lib; {
+    description = "Simplified perturbations models library";
+    homepage = "https://github.com/dnwrnr/sgp4";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ alexwinter ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/sg/sgx-azure-dcap-client/package.nix

@@ -0,0 +1,99 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  lib,
+  curl,
+  nlohmann_json,
+  openssl,
+  pkg-config,
+  linkFarmFromDrvs,
+  callPackage,
+}:
+let
+  # Although those headers are also included in the source of `sgx-psw`, the `azure-dcap-client` build needs specific versions
+  filterSparse = list: ''
+    cp -r "$out"/. .
+    find "$out" -mindepth 1 -delete
+    cp ${lib.concatStringsSep " " list} "$out/"
+  '';
+  headers = linkFarmFromDrvs "azure-dcap-client-intel-headers" [
+    (fetchFromGitHub rec {
+      name = "${repo}-headers";
+      owner = "intel";
+      repo = "linux-sgx";
+      # See: <src/Linux/configure> for the revision `azure-dcap-client` uses.
+      rev = "1ccf25b64abd1c2eff05ead9d14b410b3c9ae7be";
+      hash = "sha256-WJRoS6+NBVJrFmHABEEDpDhW+zbWFUl65AycCkRavfs=";
+      sparseCheckout = [
+        "common/inc/sgx_report.h"
+        "common/inc/sgx_key.h"
+        "common/inc/sgx_attributes.h"
+      ];
+      postFetch = filterSparse sparseCheckout;
+    })
+  ];
+in
+stdenv.mkDerivation rec {
+  pname = "azure-dcap-client";
+  version = "1.12.3";
+
+  src = fetchFromGitHub {
+    owner = "microsoft";
+    repo = "azure-dcap-client";
+    rev = version;
+    hash = "sha256-zTDaICsSPXctgFRCZBiZwXV9dLk2pFL9kp5a8FkiTZA=";
+  };
+
+  patches = [
+    # Fix gcc-13 build:
+    #   https://github.com/microsoft/Azure-DCAP-Client/pull/197
+    (fetchpatch {
+      name = "gcc-13.patch";
+      url = "https://github.com/microsoft/Azure-DCAP-Client/commit/fbcae7b3c8f1155998248cf5b5f4c1df979483f5.patch";
+      hash = "sha256-ezEuQql3stn58N1ZPKMlhPpUOBkDpCcENpGwFAmWtHc=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    curl
+    nlohmann_json
+    openssl
+  ];
+
+  postPatch = ''
+    mkdir -p src/Linux/ext/intel
+    find -L '${headers}' -type f -exec ln -s {} src/Linux/ext/intel \;
+
+    substitute src/Linux/Makefile{.in,} \
+      --replace-fail '##CURLINC##' '${curl.dev}/include/curl/' \
+      --replace-fail '$(TEST_SUITE): $(PROVIDER_LIB) $(TEST_SUITE_OBJ)' '$(TEST_SUITE): $(TEST_SUITE_OBJ)'
+  '';
+
+  env.NIX_CFLAGS_COMPILE = "-Wno-deprecated-declarations";
+
+  makeFlags = [
+    "-C src/Linux"
+    "prefix=$(out)"
+  ];
+
+  # Online test suite; run with
+  # $(nix-build -A sgx-azure-dcap-client.tests.suite)/bin/tests
+  passthru.tests.suite = callPackage ./test-suite.nix { };
+
+  meta = {
+    description = "Interfaces between SGX SDKs and the Azure Attestation SGX Certification Cache";
+    homepage = "https://github.com/microsoft/azure-dcap-client";
+    maintainers = with lib.maintainers; [
+      phlip9
+      trundle
+      veehaitch
+    ];
+    platforms = [ "x86_64-linux" ];
+    license = [ lib.licenses.mit ];
+  };
+}

pkgs/by-name/sg/sgx-azure-dcap-client/test-suite.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  sgx-azure-dcap-client,
+  gtest,
+  makeWrapper,
+}:
+sgx-azure-dcap-client.overrideAttrs (old: {
+  nativeBuildInputs = old.nativeBuildInputs ++ [
+    makeWrapper
+    gtest
+  ];
+
+  patches = (old.patches or [ ]) ++ [
+    ./tests-missing-includes.patch
+  ];
+
+  buildFlags = [
+    "tests"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -D ./src/Linux/tests "$out/bin/tests"
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    wrapProgram "$out/bin/tests" \
+      --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ sgx-azure-dcap-client ]}"
+  '';
+})

pkgs/by-name/sg/sgx-azure-dcap-client/tests-missing-includes.patch

@@ -0,0 +1,12 @@
+diff --git a/src/UnitTest/test_local_cache.cpp b/src/UnitTest/test_local_cache.cpp
+index 5fbc31b..6b8d52e 100644
+--- a/src/UnitTest/test_local_cache.cpp
++++ b/src/UnitTest/test_local_cache.cpp
+@@ -5,6 +5,7 @@
+ #include <gtest/gtest.h>
+ 
+ #undef NDEBUG // ensure that asserts are never compiled out
++#include <array>
+ #include <cassert>
+ #include <cstdio>
+ #include <cstring>

pkgs/by-name/sg/sgx-ssl/package.nix

@@ -0,0 +1,96 @@
+{
+  stdenv,
+  callPackage,
+  fetchFromGitHub,
+  fetchurl,
+  lib,
+  perl,
+  sgx-sdk,
+  which,
+  debug ? false,
+}:
+let
+  sgxVersion = sgx-sdk.versionTag;
+  opensslVersion = "3.0.13";
+in
+stdenv.mkDerivation {
+  pname = "sgx-ssl" + lib.optionalString debug "-debug";
+  version = "${sgxVersion}_${opensslVersion}";
+
+  src = fetchFromGitHub {
+    owner = "intel";
+    repo = "intel-sgx-ssl";
+    rev = "3.0_Rev2";
+    hash = "sha256-dmLyaG6v+skjSa0KxLAfIfSBOxp9grrI7ds6WdGPe0I=";
+  };
+
+  postUnpack =
+    let
+      opensslSourceArchive = fetchurl {
+        url = "https://www.openssl.org/source/openssl-${opensslVersion}.tar.gz";
+        hash = "sha256-iFJXU/edO+wn0vp8ZqoLkrOqlJja/ZPXz6SzeAza4xM=";
+      };
+    in
+    ''
+      ln -s ${opensslSourceArchive} $sourceRoot/openssl_source/openssl-${opensslVersion}.tar.gz
+    '';
+
+  postPatch = ''
+    patchShebangs Linux/build_openssl.sh
+
+    # Skip the tests. Build and run separately (see below).
+    substituteInPlace Linux/sgx/Makefile \
+      --replace-fail '$(MAKE) -C $(TEST_DIR) all' \
+                     'bash -c "true"'
+  '';
+
+  nativeBuildInputs = [
+    perl
+    sgx-sdk
+    which
+  ];
+
+  makeFlags = [
+    "-C Linux"
+  ]
+  ++ lib.optionals debug [
+    "DEBUG=1"
+  ];
+
+  installFlags = [
+    "DESTDIR=$(out)"
+  ];
+
+  # These tests build on any x86_64-linux but BOTH SIM and HW will only _run_ on
+  # real Intel hardware. Split these out so OfBorg doesn't choke on this pkg.
+  #
+  # ```
+  # nix run .#sgx-ssl.tests.HW
+  # nix run .#sgx-ssl.tests.SIM
+  # ```
+  passthru.tests = {
+    HW = callPackage ./tests.nix {
+      sgxMode = "HW";
+      inherit opensslVersion;
+    };
+    SIM = callPackage ./tests.nix {
+      sgxMode = "SIM";
+      inherit opensslVersion;
+    };
+  };
+
+  meta = {
+    description = "Cryptographic library for Intel SGX enclave applications based on OpenSSL";
+    homepage = "https://github.com/intel/intel-sgx-ssl";
+    maintainers = with lib.maintainers; [
+      phlip9
+      trundle
+      veehaitch
+    ];
+    platforms = [ "x86_64-linux" ];
+    license = with lib.licenses; [
+      bsd3
+      openssl
+    ];
+  };
+}

pkgs/by-name/sg/sgx-ssl/tests.nix

@@ -0,0 +1,96 @@
+# This package _builds_ (but doesn't run!) the sgx-ssl test enclave + harness.
+# The whole package effectively does:
+#
+# ```
+# SGX_MODE=${sgxMode} make -C Linux/sgx/test_app
+# cp Linux/sgx/{TestApp,TestEnclave.signed.so} $out/bin
+# ```
+#
+# OfBorg fails to run these tests since they require real Intel HW. That
+# includes the simulation mode! The tests appears to do something fancy with
+# cpuid and exception trap handlers that make them very non-portable.
+#
+# These tests are split out from the parent pkg since recompiling the parent
+# takes like 30 min : )
+
+{
+  lib,
+  openssl,
+  sgx-psw,
+  sgx-sdk,
+  sgx-ssl,
+  stdenv,
+  which,
+  opensslVersion ? throw "required parameter",
+  sgxMode ? throw "required parameter", # "SIM" or "HW"
+}:
+stdenv.mkDerivation {
+  inherit (sgx-ssl) postPatch src version;
+  pname = sgx-ssl.pname + "-tests-${sgxMode}";
+
+  postUnpack = sgx-ssl.postUnpack + ''
+    sourceRootAbs=$(readlink -e $sourceRoot)
+    packageDir=$sourceRootAbs/Linux/package
+
+    # Do the inverse of 'make install' and symlink built artifacts back into
+    # '$src/Linux/package/' to avoid work.
+    mkdir $packageDir/lib $packageDir/lib64
+    ln -s ${lib.getLib sgx-ssl}/lib/* $packageDir/lib/
+    ln -s ${lib.getLib sgx-ssl}/lib64/* $packageDir/lib64/
+    ln -sf ${lib.getDev sgx-ssl}/include/* $packageDir/include/
+
+    # test_app needs some internal openssl headers.
+    # See: tail end of 'Linux/build_openssl.sh'
+    tar -C $sourceRootAbs/openssl_source -xf $sourceRootAbs/openssl_source/openssl-${opensslVersion}.tar.gz
+    echo '#define OPENSSL_VERSION_STR "${opensslVersion}"' > $sourceRootAbs/Linux/sgx/osslverstr.h
+    ln -s $sourceRootAbs/openssl_source/openssl-${opensslVersion}/include/crypto $sourceRootAbs/Linux/sgx/test_app/enclave/
+    ln -s $sourceRootAbs/openssl_source/openssl-${opensslVersion}/include/internal $sourceRootAbs/Linux/sgx/test_app/enclave/
+  '';
+
+  nativeBuildInputs = [
+    openssl.bin
+    sgx-sdk
+    which
+  ];
+
+  preBuild = ''
+    # Need to regerate the edl header
+    make -C Linux/sgx/libsgx_tsgxssl sgx_tsgxssl_t.c
+  '';
+
+  makeFlags = [
+    "-C Linux/sgx/test_app"
+    "SGX_MODE=${sgxMode}"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    # Enclaves can't be stripped after signing.
+    install -Dm 755 Linux/sgx/test_app/TestEnclave.signed.so -t $TMPDIR/enclaves
+
+    install -Dm 755 Linux/sgx/test_app/TestApp -t $out/bin
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    # Move the enclaves where they actually belong.
+    mv $TMPDIR/enclaves/*.signed.so* $out/bin/
+
+    # HW SGX must runs against sgx-psw, not sgx-sdk.
+    if [[ "${sgxMode}" == "HW" ]]; then
+      patchelf \
+        --set-rpath "$( \
+          patchelf --print-rpath $out/bin/TestApp \
+            | sed 's|${lib.getLib sgx-sdk}|${lib.getLib sgx-psw}|' \
+        )" \
+        $out/bin/TestApp
+    fi
+  '';
+
+  meta = {
+    platforms = [ "x86_64-linux" ];
+    mainProgram = "TestApp";
+  };
+}

pkgs/by-name/sg/sgxs-tools/package.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  fetchCrate,
+  rustPlatform,
+  pkg-config,
+  openssl_3,
+  protobuf,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "sgxs-tools";
+  version = "0.9.2";
+  nativeBuildInputs = [
+    pkg-config
+    protobuf
+  ];
+  buildInputs = [ openssl_3 ];
+  src = fetchCrate {
+    inherit pname version;
+    hash = "sha256-vLbSjDULrYL8emQTha4fhEbr00OlhXNa00QhCKCnWDc=";
+  };
+
+  cargoHash = "sha256-5JMChgqFny9bB8ur/5koW3/YFCOVjb7cDsn4Ki2FSzA=";
+  meta = {
+    description = "Utilities for working with the SGX stream format";
+    homepage = "https://github.com/fortanix/rust-sgx";
+    maintainers = [ lib.maintainers.ozwaldorf ];
+    platforms = [ "x86_64-linux" ];
+    license = lib.licenses.mpl20;
+  };
+}