push sheeet

pkgs/by-name/so/solanum/dont-create-logdir.patch

@@ -0,0 +1,14 @@
+diff --git a/Makefile.am b/Makefile.am
+index 19e7b396..21093521 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -35,9 +35,6 @@ include/serno.h:
+ 		echo '#define DATECODE 0UL' >>include/serno.h; \
+ 	fi
+ 
+-install-data-hook:
+-	test -d ${DESTDIR}${logdir} || mkdir -p ${DESTDIR}${logdir}
+-
+ install-exec-hook:
+ 	rm -f ${DESTDIR}${libdir}/*.la
+ 	rm -f ${DESTDIR}${moduledir}/*.la

pkgs/by-name/so/solanum/package.nix

@@ -0,0 +1,91 @@
+{
+  lib,
+  stdenv,
+  autoconf,
+  automake,
+  libtool,
+  bison,
+  fetchFromGitHub,
+  flex,
+  lksctp-tools,
+  openssl,
+  pkg-config,
+  sqlite,
+  util-linux,
+  unstableGitUpdater,
+  nixosTests,
+}:
+
+stdenv.mkDerivation {
+  pname = "solanum";
+  version = "0-unstable-2025-09-20";
+
+  src = fetchFromGitHub {
+    owner = "solanum-ircd";
+    repo = "solanum";
+    rev = "380dca67c2f270f1b60634b6ed9a90c80884684d";
+    hash = "sha256-R+TXRFzTVWxWVRSmPgmFjYplEonDKszsBckPWUS+gOU=";
+  };
+
+  patches = [
+    ./dont-create-logdir.patch
+  ];
+
+  postPatch = ''
+    substituteInPlace include/defaults.h --replace 'ETCPATH "' '"/etc/solanum'
+  '';
+
+  preConfigure = ''
+    ./autogen.sh
+  '';
+
+  configureFlags = [
+    "--enable-epoll"
+    "--enable-ipv6"
+    "--enable-openssl=${openssl.dev}"
+    "--with-program-prefix=solanum-"
+    "--localstatedir=/var/lib"
+    "--with-rundir=/run"
+    "--with-logdir=/var/log"
+  ]
+  ++ lib.optionals (stdenv.hostPlatform.isLinux) [
+    "--enable-sctp=${lksctp-tools.out}/lib"
+  ];
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    libtool
+    bison
+    flex
+    pkg-config
+    util-linux
+  ];
+
+  buildInputs = [
+    openssl
+    sqlite
+  ];
+
+  doCheck = !stdenv.hostPlatform.isDarwin;
+
+  enableParallelBuilding = true;
+  # Missing install depends:
+  #   ...-binutils-2.40/bin/ld: cannot find ./.libs/libircd.so: No such file or directory
+  #   collect2: error: ld returned 1 exit status
+  #   make[4]: *** [Makefile:634: solanum] Error 1
+  enableParallelInstalling = false;
+
+  passthru = {
+    tests = { inherit (nixosTests) solanum; };
+    updateScript = unstableGitUpdater { };
+  };
+
+  meta = with lib; {
+    description = "IRCd for unified networks";
+    homepage = "https://github.com/solanum-ircd/solanum";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ hexa ];
+    platforms = platforms.unix;
+  };
+}