push sheeet

pkgs/by-name/sr/sr2t/package.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  python3,
+  fetchFromGitLab,
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "sr2t";
+  version = "0.0.26";
+  pyproject = true;
+
+  src = fetchFromGitLab {
+    owner = "0bs1d1an";
+    repo = "sr2t";
+    rev = "refs/tags/${version}";
+    hash = "sha256-BPsYnKBTxt5WUd2+WumMdVi8p6iryOWG2MjI97qbaCw=";
+  };
+
+  build-system = with python3.pkgs; [ hatchling ];
+
+  dependencies = with python3.pkgs; [
+    prettytable
+    pyyaml
+    setuptools
+    xlsxwriter
+  ];
+
+  # Project has no tests
+  doCheck = false;
+
+  pythonImportsCheck = [ "sr2t" ];
+
+  meta = with lib; {
+    description = "Tool to convert scanning reports to a tabular format";
+    homepage = "https://gitlab.com/0bs1d1an/sr2t";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ fab ];
+    mainProgram = "sr2t";
+  };
+}

pkgs/by-name/sr/srain/package.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  gtk3,
+  libconfig,
+  libsoup_3,
+  libsecret,
+  libayatana-appindicator,
+  openssl,
+  gettext,
+  glib,
+  glib-networking,
+  appstream-glib,
+  dbus-glib,
+  python3Packages,
+  meson,
+  ninja,
+  wrapGAppsHook3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srain";
+  version = "1.8.1";
+
+  src = fetchFromGitHub {
+    owner = "SrainApp";
+    repo = "srain";
+    rev = version;
+    hash = "sha256-F7TFCPTAU856403QNUUyf+10s/Yr4xDN/CarJNcUv4A=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gettext
+    appstream-glib
+    wrapGAppsHook3
+    python3Packages.sphinx
+  ];
+
+  buildInputs = [
+    gtk3
+    glib
+    glib-networking
+    dbus-glib
+    libconfig
+    libsoup_3
+    libsecret
+    libayatana-appindicator
+    openssl
+  ];
+
+  meta = with lib; {
+    description = "Modern IRC client written in GTK";
+    mainProgram = "srain";
+    homepage = "https://srain.silverrainz.me";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ wineee ];
+  };
+}

pkgs/by-name/sr/srandrd/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libX11,
+  libXrandr,
+  libXinerama,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srandrd";
+  version = "0.6.3";
+
+  src = fetchFromGitHub {
+    owner = "jceb";
+    repo = "srandrd";
+    rev = "v${version}";
+    sha256 = "sha256-Wf+tVqDaNAiH6UHN8fFv2wM+LEch6wKlZOkqWEqLLkw=";
+  };
+
+  buildInputs = [
+    libX11
+    libXrandr
+    libXinerama
+  ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/jceb/srandrd";
+    description = "Simple randr daemon";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.utdemir ];
+    mainProgram = "srandrd";
+  };
+
+}

pkgs/by-name/sr/sratom/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  lv2,
+  meson,
+  ninja,
+  pkg-config,
+  serd,
+  sord,
+  writeScript,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sratom";
+  version = "0.6.18";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchurl {
+    url = "https://download.drobilla.net/${pname}-${version}.tar.xz";
+    hash = "sha256-TGptngtNbAHMBqiEmRD+zrkuZmyzh3nGFN0kBKmTHpI=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    lv2
+    serd
+    sord
+  ];
+
+  postPatch = ''
+    patchShebangs --build scripts/dox_to_sphinx.py
+  '';
+
+  mesonFlags = [
+    "-Ddocs=disabled"
+  ];
+
+  passthru = {
+    updateScript = writeScript "update-sratom" ''
+      #!/usr/bin/env nix-shell
+      #!nix-shell -i bash -p curl pcre common-updater-scripts
+
+      set -eu -o pipefail
+
+      # Expect the text in format of 'download.drobilla.net/sratom-0.30.16.tar.xz">'
+      new_version="$(curl -s https://drobilla.net/category/sratom/ |
+          pcregrep -o1 'download.drobilla.net/sratom-([0-9.]+).tar.xz' |
+          head -n1)"
+      update-source-version ${pname} "$new_version"
+    '';
+  };
+
+  meta = with lib; {
+    homepage = "https://drobilla.net/software/sratom";
+    description = "Library for serialising LV2 atoms to/from RDF";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/sr/sratoolkit/attribute_unused.patch

@@ -0,0 +1,14 @@
+diff --git a/libs/kxml/xml.c b/libs/kxml/xml.c
+index ce445424..41e21612 100644
+--- a/libs/kxml/xml.c
++++ b/libs/kxml/xml.c
+@@ -46,6 +46,9 @@ struct s_KNodeNamelist;
+ #include <assert.h>
+ #include <string.h>
+ 
++#ifndef ATTRIBUTE_UNUSED
++#define ATTRIBUTE_UNUSED
++#endif
+ 
+ #define XML_DEBUG(msg) DBGMSG (DBG_XML, DBG_FLAG(DBG_XML_XML), msg)
+ 

pkgs/by-name/sr/sratoolkit/package.nix

@@ -0,0 +1,58 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  python3,
+  bison,
+  flex,
+  libxml2,
+  openjdk,
+  ncbi-vdb,
+  mbedtls,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "sratoolkit";
+
+  # NOTE: When updating make sure to update ncbi-vdb as well for versions to match
+  version = "3.2.1";
+
+  src = fetchFromGitHub {
+    owner = "ncbi";
+    repo = "sra-tools";
+    tag = finalAttrs.version;
+    hash = "sha256-OeM4syv9c1rZn2ferrhXyKJu68ywVYwnHoqnviWBZy4=";
+  };
+
+  patches = [ ./attribute_unused.patch ];
+
+  cmakeFlags = [
+    "-DVDB_INCDIR=${ncbi-vdb}/include"
+    "-DVDB_LIBDIR=${ncbi-vdb}/lib"
+  ];
+
+  buildInputs = [
+    ncbi-vdb
+    libxml2
+    mbedtls
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    python3
+    bison
+    flex
+    openjdk
+  ];
+
+  meta = {
+    homepage = "https://github.com/ncbi/sra-tools";
+    description = "Collection of tools and libraries for using data in the INSDC Sequence Read Archives";
+    license = lib.licenses.ncbiPd;
+    maintainers = with lib.maintainers; [
+      t4ccer
+    ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/sr/srb2/cmake.patch

@@ -0,0 +1,13 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index a4c631102..13b5743ca 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -141,7 +141,7 @@ include(GitUtilities)
+ if("${SRB2_SDL2_EXE_NAME}" STREQUAL "")
+ 	# cause a reconfigure if the branch changes
+ 	get_git_dir(SRB2_GIT_DIR)
+-	configure_file("${SRB2_GIT_DIR}/HEAD" HEAD COPYONLY)
++	#configure_file("${SRB2_GIT_DIR}/HEAD" HEAD COPYONLY)
+ 
+ 	git_current_branch(SRB2_GIT_REVISION)
+ 

pkgs/by-name/sr/srb2/package.nix

@@ -0,0 +1,121 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  fetchFromGitHub,
+  cmake,
+  curl,
+  libopenmpt,
+  miniupnpc,
+  game-music-emu,
+  libpng,
+  SDL2,
+  SDL2_mixer,
+  zlib,
+  makeWrapper,
+  makeDesktopItem,
+  copyDesktopItems,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "srb2";
+  version = "2.2.15";
+
+  src = fetchFromGitHub {
+    owner = "STJr";
+    repo = "SRB2";
+    rev = "SRB2_release_${finalAttrs.version}";
+    hash = "sha256-eJ0GYe3Rw6qQXj+jtyt8MkP87DaCiO9ffChg+SpQqaI=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  buildInputs = [
+    curl
+    game-music-emu
+    libpng
+    libopenmpt
+    miniupnpc
+    SDL2
+    SDL2_mixer
+    zlib
+  ];
+
+  assets = stdenv.mkDerivation {
+    pname = "srb2-data";
+    version = finalAttrs.version;
+
+    src = fetchgit {
+      url = "https://git.do.srb2.org/STJr/srb2assets-public";
+      rev = "SRB2_release_${finalAttrs.version}";
+      hash = "sha256-1kwhWHzL2TbSx1rhFExbMhXqn0HMBRhR6LZiuoRx+iI=";
+      fetchLFS = true;
+    };
+
+    installPhase = ''
+      runHook preInstall
+
+      mkdir -p $out/share/srb2
+      cp -r * $out/share/srb2
+
+      runHook postInstall
+    '';
+  };
+
+  cmakeFlags = [
+    "-DSRB2_ASSET_DIRECTORY=${finalAttrs.assets}/share/srb2"
+    "-DGME_INCLUDE_DIR=${game-music-emu}/include"
+    "-DOPENMPT_INCLUDE_DIR=${libopenmpt.dev}/include"
+    "-DSDL2_MIXER_INCLUDE_DIR=${lib.getDev SDL2_mixer}/include/SDL2"
+    "-DSDL2_INCLUDE_DIR=${lib.getInclude SDL2}/include/SDL2"
+  ];
+
+  patches = [
+    ./cmake.patch
+  ];
+
+  desktopItems = [
+    (makeDesktopItem rec {
+      name = "Sonic Robo Blast 2";
+      exec = "srb2";
+      icon = "srb2";
+      comment = finalAttrs.meta.description;
+      desktopName = name;
+      genericName = name;
+      categories = [ "Game" ];
+      startupWMClass = ".srb2-wrapped";
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin $out/share/applications $out/share/pixmaps $out/share/icons
+
+    copyDesktopItems
+
+    cp ../srb2.png $out/share/pixmaps/.
+    cp ../srb2.png $out/share/icons/.
+
+    cp bin/lsdlsrb2 $out/bin/srb2
+    wrapProgram $out/bin/srb2 --set SRB2WADDIR "${finalAttrs.assets}/share/srb2"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Sonic Robo Blast 2 is a 3D Sonic the Hedgehog fangame based on a modified version of Doom Legacy";
+    homepage = "https://www.srb2.org/";
+    platforms = platforms.linux;
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [
+      zeratax
+      donovanglover
+    ];
+    mainProgram = "srb2";
+  };
+})

pkgs/by-name/sr/srb2kart/package.nix

@@ -0,0 +1,107 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  fetchFromGitHub,
+  cmake,
+  curl,
+  nasm,
+  game-music-emu,
+  libpng,
+  SDL2,
+  SDL2_mixer,
+  zlib,
+  makeWrapper,
+  makeDesktopItem,
+  copyDesktopItems,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "srb2kart";
+  version = "1.6";
+
+  src = fetchFromGitHub {
+    owner = "STJr";
+    repo = "Kart-Public";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-5sIHdeenWZjczyYM2q+F8Y1SyLqL+y77yxYDUM3dVA0=";
+  };
+
+  assets = stdenv.mkDerivation {
+    pname = "srb2kart-data";
+    version = finalAttrs.version;
+
+    src = fetchzip {
+      url = "https://github.com/STJr/Kart-Public/releases/download/v${finalAttrs.version}/AssetsLinuxOnly.zip";
+      hash = "sha256-yaVdsQUnyobjSbmemeBEyu35GeZCX1ylTRcjcbDuIu4=";
+      stripRoot = false;
+    };
+
+    installPhase = ''
+      runHook preInstall
+
+      mkdir -p $out/share/srb2kart
+      cp -r * $out/share/srb2kart
+
+      runHook postInstall
+    '';
+  };
+
+  nativeBuildInputs = [
+    cmake
+    nasm
+    makeWrapper
+    copyDesktopItems
+  ];
+
+  buildInputs = [
+    curl
+    game-music-emu
+    libpng
+    SDL2
+    SDL2_mixer
+    zlib
+  ];
+
+  cmakeFlags = [
+    "-DSRB2_ASSET_DIRECTORY=${finalAttrs.assets}/share/srb2kart"
+    "-DGME_INCLUDE_DIR=${game-music-emu}/include"
+    "-DSDL2_MIXER_INCLUDE_DIR=${lib.getDev SDL2_mixer}/include/SDL2"
+    "-DSDL2_INCLUDE_DIR=${lib.getDev SDL2}/include/SDL2"
+  ];
+
+  desktopItems = [
+    (makeDesktopItem rec {
+      name = "Sonic Robo Blast 2 Kart";
+      exec = "srb2kart";
+      icon = "srb2kart";
+      comment = "Kart racing mod based on SRB2";
+      desktopName = name;
+      genericName = name;
+      startupWMClass = ".srb2kart-wrapped";
+      categories = [ "Game" ];
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm644 ../srb2.png $out/share/pixmaps/srb2kart.png
+    install -Dm644 ../srb2.png $out/share/icons/srb2kart.png
+    install -Dm755 bin/srb2kart $out/bin/srb2kart
+
+    wrapProgram $out/bin/srb2kart \
+      --set SRB2WADDIR "${finalAttrs.assets}/share/srb2kart"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Classic styled kart racer";
+    homepage = "https://mb.srb2.org/threads/srb2kart.25868/";
+    platforms = platforms.linux;
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ donovanglover ];
+    mainProgram = "srb2kart";
+  };
+})

pkgs/by-name/sr/src-cli/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  stdenv,
+  xorg,
+  testers,
+  src-cli,
+}:
+
+buildGoModule rec {
+  pname = "src-cli";
+  version = "6.7.1104";
+
+  src = fetchFromGitHub {
+    owner = "sourcegraph";
+    repo = "src-cli";
+    rev = version;
+    hash = "sha256-ABghlNOeWqsXapz3dMtzGBre8BcttZG3PlYCqPk3+fM=";
+  };
+
+  vendorHash = "sha256-bpfDnVqJoJi9WhlA6TDWAhBRkbbQn1BHfnLJ8BTmhGM=";
+
+  subPackages = [
+    "cmd/src"
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X=github.com/sourcegraph/src-cli/internal/version.BuildTag=${version}"
+  ];
+
+  passthru.tests = {
+    version = testers.testVersion {
+      package = src-cli;
+      command = "src version -client-only";
+    };
+  };
+
+  meta = with lib; {
+    description = "Sourcegraph CLI";
+    homepage = "https://github.com/sourcegraph/src-cli";
+    changelog = "https://github.com/sourcegraph/src-cli/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.asl20;
+    maintainers = with maintainers; [
+      figsoda
+      keegancsmith
+    ];
+    mainProgram = "src";
+  };
+}

pkgs/by-name/sr/src/package.nix

@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  asciidoc,
+  fetchFromGitLab,
+  git,
+  makeWrapper,
+  python3,
+  rcs,
+  asciidoctor,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "src";
+  version = "1.41";
+
+  src = fetchFromGitLab {
+    owner = "esr";
+    repo = "src";
+    tag = finalAttrs.version;
+    hash = "sha256-i5i6+RmQ/70ul2r/NC6xv/8sUP3+8mkQIDgyC1NrSrI=";
+  };
+
+  nativeBuildInputs = [
+    asciidoc
+    asciidoctor
+    makeWrapper
+  ];
+
+  buildInputs = [
+    git
+    python3
+    rcs
+  ];
+
+  strictDeps = true;
+
+  preConfigure = ''
+    patchShebangs .
+  '';
+
+  makeFlags = [
+    "prefix=${placeholder "out"}"
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/src \
+      --suffix PATH ":" "${rcs}/bin"
+  '';
+
+  meta = {
+    homepage = "http://www.catb.org/esr/src/";
+    description = "Simple single-file revision control";
+    longDescription = ''
+      SRC, acronym of Simple Revision Control, is RCS/SCCS reloaded with a
+      modern UI, designed to manage single-file solo projects kept more than one
+      to a directory. Use it for FAQs, ~/bin directories, config files, and the
+      like. Features integer sequential revision numbers, a command set that
+      will seem familiar to Subversion/Git/hg users, and no binary blobs
+      anywhere.
+    '';
+    changelog = "https://gitlab.com/esr/src/-/raw/${finalAttrs.version}/NEWS.adoc";
+    license = lib.licenses.bsd2;
+    mainProgram = "src";
+    maintainers = [ ];
+    inherit (python3.meta) platforms;
+  };
+})

pkgs/by-name/sr/srec2bin/package.nix

@@ -0,0 +1,28 @@
+{
+  fetchFromGitHub,
+  lib,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "srec2bin";
+  version = "1.51";
+
+  src = fetchFromGitHub {
+    owner = "srec2bin";
+    repo = "srec";
+    tag = "V${finalAttrs.version}";
+    hash = "sha256-akExYUp59Y0XA/MWif+/agz7DcsY/8Y6UI7jt/qMdwk=";
+  };
+
+  patches = [ ./package.patch ]; # upstream builds for windows
+
+  meta = {
+    description = "Tool for converting Motorola S-Record file into a binary image";
+    homepage = "https://github.com/srec2bin/srec";
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ KSJ2000 ];
+    mainProgram = "srec2bin";
+  };
+})

pkgs/by-name/sr/srec2bin/package.patch

@@ -0,0 +1,31 @@
+diff --git a/Makefile b/Makefile
+index 56bbd49..23164ce 100644
+--- a/Makefile
++++ b/Makefile
+@@ -4,12 +4,12 @@ CFLAGS = -c -Wall -O2 -MMD
+ LDFLAGS = -fno-exceptions -s
+ 
+ MAKEFLAGS += -s
+-
+-ifeq ($(OS), Windows_NT)
+-	CC = mingw32-gcc
+-	EXE_SUFFIX = .exe
+-else
++UNAME := $(shell uname -s)
++EXE_SUFFIX = ""
++ifeq ($(UNAME), Linux)
+ 	CC = gcc
++else ifeq ($(UNAME), Darwin)
++	CC = clang
+ endif
+ 
+ LD = $(CC)
+@@ -59,4 +59,6 @@ clean:
+ 	-$(RM) $(RULES)
+ 	-$(RM) $(BIN2SREC_EXE) $(SREC2BIN_EXE) $(BINSPLIT_EXE)
+ 
+--include $(RULES)
+\ No newline at end of file
++-include $(RULES)
++install:
++	install -Dm755 $(BIN2SREC_EXE) $(SREC2BIN_EXE) $(BINSPLIT_EXE) -t $(out)/bin

pkgs/by-name/sr/srecord/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  boost,
+  libtool,
+  groff,
+  ghostscript,
+  libgcrypt ? null,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srecord";
+  version = "1.64";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/${pname}/${pname}-${version}.tar.gz";
+    sha256 = "1qk75q0k5vzmm3932q9hqz2gp8n9rrdfjacsswxc02656f3l3929";
+  };
+
+  buildInputs = [
+    boost
+    libtool
+    groff
+    ghostscript
+    libgcrypt
+  ];
+
+  configureFlags = lib.optional (libgcrypt == null) "--without-gcrypt";
+
+  meta = with lib; {
+    description = "Collection of powerful tools for manipulating EPROM load files";
+    homepage = "https://srecord.sourceforge.net/";
+    license = licenses.gpl3Plus;
+    maintainers = [ maintainers.bjornfor ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/by-name/sr/sregex/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sregex";
+  version = "0.0.1";
+
+  src = fetchFromGitHub {
+    owner = "openresty";
+    repo = "sregex";
+    rev = "v${version}";
+    hash = "sha256-HZ9O/3BQHHrTVLLlU0o1fLHxyRSesBhreT3IdGHnNsg=";
+  };
+
+  makeFlags = [
+    "PREFIX=$(out)"
+    "CC:=$(CC)"
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/openresty/sregex";
+    description = "Non-backtracking NFA/DFA-based Perl-compatible regex engine matching on large data streams";
+    mainProgram = "sregex-cli";
+    license = licenses.bsd3;
+    maintainers = [ ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/sr/srelay/arm.patch

@@ -0,0 +1,12 @@
+diff -ru srelay-0.4.8b4.orig/configure srelay-0.4.8b4/configure
+--- srelay-0.4.8b4.orig/configure	2010-12-21 01:11:14.000000000 +1100
++++ srelay-0.4.8b4/configure	2016-06-22 09:03:42.250000345 +1000
+@@ -1875,7 +1875,7 @@
+ 	;;
+   linux*)
+ 	case "$host_cpu" in
+-	  i*86|mips*|powerpc*|sparc*|x86_64*)
++	  i*86|mips*|powerpc*|sparc*|x86_64*|arm*)
+ 	    OS=LINUX
+ 	    cat >>confdefs.h <<\_ACEOF
+ #define LINUX 1

pkgs/by-name/sr/srelay/package.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libxcrypt,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srelay";
+  version = "0.4.8";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/socks-relay/socks-relay/srelay-${version}/srelay-${version}.tar.gz";
+    sha256 = "1sn6005aqyfvrlkm5445cyyaj6h6wfyskfncfmds55x34hfyxpvl";
+  };
+
+  patches = [ ./arm.patch ];
+
+  buildInputs = [ libxcrypt ];
+
+  installPhase = "install -D srelay $out/bin/srelay";
+
+  meta = {
+    description = "SOCKS proxy and relay";
+    homepage = "http://socks-relay.sourceforge.net/";
+    platforms = lib.platforms.unix;
+    license = lib.licenses.bsd3;
+    # never built on aarch64-linux since first introduction in nixpkgs
+    broken = stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64;
+    mainProgram = "srelay";
+  };
+}

pkgs/by-name/sr/srgn/package.nix

@@ -0,0 +1,38 @@
+{
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  lib,
+  stdenv,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "srgn";
+  version = "0.14.0";
+
+  src = fetchFromGitHub {
+    owner = "alexpovel";
+    repo = "srgn";
+    rev = "srgn-v${version}";
+    hash = "sha256-ZWjpkClhac4VD4b/Veffb5FHGvh+oeTu3ukaOux6MG0=";
+  };
+
+  cargoHash = "sha256-d/wFD0kxWNOsYaY4G5P9iM85dSo0UZGSte5AqOosM2g=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    for shell in bash zsh fish; do
+      installShellCompletion --cmd srgn "--$shell" <("$out/bin/srgn" --completions "$shell")
+    done
+  '';
+
+  meta = with lib; {
+    description = "Code surgeon for precise text and code transplantation";
+    license = licenses.mit;
+    maintainers = with maintainers; [ magistau ];
+    mainProgram = "srgn";
+    homepage = "https://github.com/${src.owner}/${src.repo}/";
+    downloadPage = "https://github.com/${src.owner}/${src.repo}/releases/tag/${src.rev}";
+    changelog = "https://github.com/${src.owner}/${src.repo}/blob/${src.rev}/CHANGELOG.md";
+  };
+}

pkgs/by-name/sr/srht-gen-oauth-tok/fix-html-parsing.patch

@@ -0,0 +1,16 @@
+diff --git a/srht-gen-oauth-tok b/srht-gen-oauth-tok
+index a05e209..f2949b5 100755
+--- a/srht-gen-oauth-tok
++++ b/srht-gen-oauth-tok
+@@ -78,7 +78,10 @@ $mech->submit_form( with_fields => { comment => $tok_comment } );
+ 
+ # Parse the response as XML and find the access token via an XPath expression
+ my $xpc = XML::LibXML::XPathContext->new(
+-    XML::LibXML->load_xml(string => $mech->content())
++    XML::LibXML->load_html(
++        string => $mech->content(),
++        recover => 1,
++    )
+ );
+ # The token is set as the description (<dd>) of a 'Personal Access Token' term (<dt>)
+ my $token = $xpc->find("//dt[text() = 'Personal Access Token']/following-sibling::dd/*/node()");

pkgs/by-name/sr/srht-gen-oauth-tok/package.nix

@@ -0,0 +1,48 @@
+{
+  stdenv,
+  pkgs,
+  lib,
+  fetchFromSourcehut,
+  nixosTests,
+}:
+
+let
+  perl = pkgs.perl.withPackages (pps: [
+    pps.CryptSSLeay
+    pps.WWWMechanize
+    pps.XMLLibXML
+  ]);
+in
+stdenv.mkDerivation rec {
+  pname = "srht-gen-oauth-tok";
+  version = "0.1";
+
+  src = fetchFromSourcehut {
+    domain = "entropic.network";
+    owner = "~nessdoor";
+    repo = "srht-gen-oauth-tok";
+    rev = version;
+    hash = "sha256-GcqP3XbVw2sR5n4+aLUmA4fthNkuVAGnhV1h7suJYdI=";
+  };
+
+  patches = [ ./fix-html-parsing.patch ];
+
+  buildInputs = [ perl ];
+  nativeBuildInputs = [ perl ];
+
+  installPhase = "install -Dm755 srht-gen-oauth-tok $out/bin/srht-gen-oauth-tok";
+
+  meta = {
+    description = "Script to register a new Sourcehut OAuth token for a given user";
+    longDescription = ''
+      srht-gen-oauth-tok is a Perl script for automating the generation of user
+      OAuth tokens for Sourcehut-based code forges. This is done by emulating a
+      browser and interacting with the Web interface.
+    '';
+    maintainers = with lib.maintainers; [ nessdoor ];
+    mainProgram = "srht-gen-oauth-tok";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.all;
+    sourceProvenance = [ lib.sourceTypes.fromSource ];
+  };
+}

pkgs/by-name/sr/srisum/package.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "srisum";
+  version = "5.0.0";
+
+  src = fetchFromGitHub {
+    owner = "zkat";
+    repo = "srisum-rs";
+    rev = "v${version}";
+    hash = "sha256-Nw3uTGOcz1ivAm9X+PnOdNA937wuK3vtJQ0iJHlHVdw=";
+  };
+
+  cargoHash = "sha256-J++aj925krYvOTzcuVZSEk+eYupL0M7o407fd1dCjeA=";
+
+  doInstallCheck = true;
+
+  meta = {
+    description = "Command-line utility to compute and check subresource integrity hashes";
+    homepage = "https://github.com/zkat/srisum-rs";
+    changelog = "https://github.com/zkat/srisum-rs/raw/v${version}/CHANGELOG.md";
+    license = with lib.licenses; [ asl20 ];
+    maintainers = with lib.maintainers; [ pjjw ];
+    platforms = lib.platforms.all;
+    mainProgram = "srisum";
+  };
+}

pkgs/by-name/sr/srm-cuarzo/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  libdisplay-info,
+  libdrm,
+  libGL,
+  libinput,
+  libgbm,
+  seatd,
+  udev,
+}:
+stdenv.mkDerivation (self: {
+  pname = "srm-cuarzo";
+  version = "0.13.0-1";
+  rev = "v${self.version}";
+  hash = "sha256-5BwLqAZdfO5vyEMPZImaxymvLoNuu6bOiOkvR8JERxg=";
+
+  src = fetchFromGitHub {
+    inherit (self) rev hash;
+    owner = "CuarzoSoftware";
+    repo = "SRM";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    libdisplay-info
+    libdrm
+    libGL
+    libinput
+    libgbm
+    seatd
+    udev
+  ];
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  preConfigure = ''
+    # The root meson.build file is in src/
+    cd src
+  '';
+
+  meta = {
+    description = "Simple Rendering Manager";
+    homepage = "https://github.com/CuarzoSoftware/SRM";
+    maintainers = [ ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/sr/srm/fix-output-in-verbose-mode.patch

@@ -0,0 +1,57 @@
+diff --git a/src/sunlink.c b/src/sunlink.c
+index 7050713..ffcb8d3 100644
+--- a/src/sunlink.c
++++ b/src/sunlink.c
+@@ -468,6 +468,8 @@ static int overwrite_selector(struct srm_target *srm)
+       if(overwrite_byte(srm, 5, 0x00) < 0) return -1;
+       if(overwrite_byte(srm, 6, 0xFF) < 0) return -1;
+       if(overwrite_random(srm, 7, 1) < 0) return -1;
++      if((srm->options&SRM_OPT_V) > 1)
++	printf("\n");
+     }
+   else if(srm->options & SRM_MODE_DOE)
+     {
+@@ -475,6 +477,8 @@ static int overwrite_selector(struct srm_target *srm)
+ 	error("US DoE mode");
+       if(overwrite_random(srm, 1, 2) < 0) return -1;
+       if(overwrite_bytes(srm, 3, 'D', 'o', 'E') < 0) return -1;
++      if((srm->options&SRM_OPT_V) > 1)
++	printf("\n");
+     }
+   else if(srm->options & SRM_MODE_OPENBSD)
+     {
+@@ -483,12 +487,16 @@ static int overwrite_selector(struct srm_target *srm)
+       if(overwrite_byte(srm, 1, 0xFF) < 0) return -1;
+       if(overwrite_byte(srm, 2, 0x00) < 0) return -1;
+       if(overwrite_byte(srm, 3, 0xFF) < 0) return -1;
++      if((srm->options&SRM_OPT_V) > 1)
++	printf("\n");
+     }
+   else if(srm->options & SRM_MODE_SIMPLE)
+     {
+       if((srm->options&SRM_OPT_V) > 1)
+ 	error("Simple mode");
+       if(overwrite_byte(srm, 1, 0x00) < 0) return -1;
++      if((srm->options&SRM_OPT_V) > 1)
++	printf("\n");
+     }
+   else if(srm->options & SRM_MODE_RCMP)
+     {
+@@ -497,6 +505,8 @@ static int overwrite_selector(struct srm_target *srm)
+       if(overwrite_byte(srm, 1, 0x00) < 0) return -1;
+       if(overwrite_byte(srm, 2, 0xFF) < 0) return -1;
+       if(overwrite_string(srm, 3, "RCMP") < 0) return -1;
++      if((srm->options&SRM_OPT_V) > 1)
++	printf("\n");
+     }
+   else
+     {
+@@ -535,6 +545,8 @@ static int overwrite_selector(struct srm_target *srm)
+       if(overwrite_random(srm, 32, 4) < 0) return -1;
+       /* if you want to backup your partition or shrink your vmware image having the file zero-ed gives best compression results. */
+       if(overwrite_byte(srm, 36, 0x00) < 0) return -1;
++      if((srm->options&SRM_OPT_V) > 1)
++	printf("\n");
+     }
+ #if 0
+   if((srm->options & SRM_OPT_V) > 1)

pkgs/by-name/sr/srm/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchsvn,
+  autoreconfHook,
+}:
+
+stdenv.mkDerivation {
+  pname = "srm";
+  version = "1.2.15-unstable-2017-12-18";
+
+  src = fetchsvn {
+    url = "svn://svn.code.sf.net/p/srm/srm/trunk/";
+    rev = "268";
+    sha256 = "sha256-bY8p6IS5zeByoe/uTmvBAaBN4Wu7J19dVSpbtqx4OeQ=";
+  };
+
+  patches = [ ./fix-output-in-verbose-mode.patch ];
+  nativeBuildInputs = [ autoreconfHook ];
+
+  meta = with lib; {
+    description = "Delete files securely";
+    longDescription = ''
+      srm (secure rm) is a command-line compatible rm(1) which
+      overwrites file contents before unlinking. The goal is to
+      provide drop in security for users who wish to prevent recovery
+      of deleted information, even if the machine is compromised.
+    '';
+    homepage = "https://srm.sourceforge.net";
+    license = licenses.mit;
+    maintainers = with maintainers; [ edwtjo ];
+    platforms = platforms.unix;
+  };
+}

pkgs/by-name/sr/srsran/package.nix

@@ -0,0 +1,78 @@
+{
+  stdenv,
+  lib,
+  cmake,
+  fetchFromGitHub,
+  pkg-config,
+  fftwFloat,
+  mbedtls,
+  boost,
+  lksctp-tools,
+  libconfig,
+  pcsclite,
+  uhd,
+  soapysdr-with-plugins,
+  libbladeRF,
+  zeromq,
+  enableLteRates ? false,
+  enableAvx ? stdenv.hostPlatform.avxSupport,
+  enableAvx2 ? stdenv.hostPlatform.avx2Support,
+  enableFma ? stdenv.hostPlatform.fmaSupport,
+  enableAvx512 ? stdenv.hostPlatform.avx512Support,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srsran";
+  version = "23.11";
+
+  src = fetchFromGitHub {
+    owner = "srsran";
+    repo = "srsran";
+    rev = "release_${builtins.replaceStrings [ "." ] [ "_" ] version}";
+    sha256 = "sha256-3cQMZ75I4cyHpik2d/eBuzw7M4OgbKqroCddycw4uW8=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    fftwFloat
+    mbedtls
+    boost
+    libconfig
+    lksctp-tools
+    pcsclite
+    uhd
+    soapysdr-with-plugins
+    libbladeRF
+    zeromq
+  ];
+
+  cmakeFlags = [
+    "-DENABLE_WERROR=OFF"
+    (lib.cmakeBool "ENABLE_LTE_RATES" enableLteRates)
+    (lib.cmakeBool "ENABLE_AVX" enableAvx)
+    (lib.cmakeBool "ENABLE_AVX2" enableAvx2)
+    (lib.cmakeBool "ENABLE_FMA" enableFma)
+    (lib.cmakeBool "ENABLE_AVX512" enableAvx512)
+  ];
+
+  postInstall = lib.optionalString (!stdenv.hostPlatform.isStatic) ''
+    rm $out/lib/*.a
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.srslte.com/";
+    description = "Open-source 4G and 5G software radio suite";
+    license = licenses.agpl3Plus;
+    platforms = with platforms; linux;
+    maintainers = with maintainers; [ hexagonal-sun ];
+  };
+}

pkgs/by-name/sr/srt-live-server/add-ctime-include.patch

@@ -0,0 +1,11 @@
+diff --git a/slscore/common.hpp b/slscore/common.hpp
+index 30aeeea..bed0e62 100644
+--- a/slscore/common.hpp
++++ b/slscore/common.hpp
+@@ -29,6 +29,7 @@
+ #include <stddef.h>
+ #include <stdint.h>
+ #include <string>
++#include <ctime>
+ #include <vector>
+ #include <unistd.h>

pkgs/by-name/sr/srt-live-server/fix-insecure-printfs.patch

@@ -0,0 +1,61 @@
+diff --color -ur a/Makefile b/Makefile
+--- a/Makefile	2021-04-16 13:02:41.416453040 +0200
++++ b/Makefile	2021-04-16 13:21:23.020089623 +0200
+@@ -1,3 +1,4 @@
++PREFIX = /usr/local
+ SHELL = /bin/sh
+ MAIN_NAME=sls
+ CLIENT_NAME=slc
+@@ -64,3 +65,16 @@
+ 	rm -f $(OUTPUT_PATH)/*.o
+ 	rm -rf $(BIN_PATH)/*
+ 
++install: all
++	@echo installing executable files to ${DESTDIR}${PREFIX}/bin
++	@mkdir -p "${DESTDIR}${PREFIX}/bin"
++	@cp -f ${BIN_PATH}/${MAIN_NAME} "${DESTDIR}${PREFIX}/bin"
++	@chmod 755 "${DESTDIR}${PREFIX}/bin/${MAIN_NAME}"
++	@cp -f ${BIN_PATH}/${CLIENT_NAME} "${DESTDIR}${PREFIX}/bin"
++	@chmod 755 "${DESTDIR}${PREFIX}/bin/${CLIENT_NAME}"
++
++uninstall:
++	@echo removing executable files from ${DESTDIR}${PREFIX}/bin
++	@rm -f "${DESTDIR}${PREFIX}/bin/${MAIN_NAME}"
++	@rm -f "${DESTDIR}${PREFIX}/bin/${CLIENT_NAME}"
++
+diff --color -ur a/slscore/HttpClient.cpp b/slscore/HttpClient.cpp
+--- a/slscore/HttpClient.cpp	2021-04-16 13:02:41.416453040 +0200
++++ b/slscore/HttpClient.cpp	2021-04-16 13:11:40.343866698 +0200
+@@ -90,7 +90,7 @@
+ 		goto FUNC_END;
+ 	}
+ 	if (NULL != method && strlen(method) > 0) {
+-		sprintf(m_http_method, method);
++		strcpy(m_http_method, method);
+ 	}
+ 
+ 	m_interval = interval;
+diff --color -ur a/slscore/SLSLog.cpp b/slscore/SLSLog.cpp
+--- a/slscore/SLSLog.cpp	2021-04-16 13:02:41.416453040 +0200
++++ b/slscore/SLSLog.cpp	2021-04-16 13:08:16.836119519 +0200
+@@ -85,7 +85,7 @@
+     vsnprintf (buf , 4095 , fmt , vl);
+     //sprintf(buf_info, "%s %s: %s\n" , cur_time, LOG_LEVEL_NAME[level], buf);
+     sprintf(buf_info, "%s:%03d %s %s: %s\n" , cur_time, cur_time_msec, APP_NAME, LOG_LEVEL_NAME[level], buf);
+-    printf(buf_info);
++    puts(buf_info);
+ 
+     if (m_log_file) {
+         fwrite(buf_info, strlen(buf_info), 1, m_log_file);
+diff --color -ur a/slscore/SLSSrt.cpp b/slscore/SLSSrt.cpp
+--- a/slscore/SLSSrt.cpp	2021-04-16 13:02:41.417452995 +0200
++++ b/slscore/SLSSrt.cpp	2021-04-16 13:10:11.004957820 +0200
+@@ -124,7 +124,7 @@
+     std::map<int, std::string>::iterator it;
+     for(it=map_error.begin(); it!=map_error.end(); ++it) {
+         sprintf(szBuf, "%d: %s\n", it->first, it->second.c_str());
+-        printf(szBuf);
++        puts(szBuf);
+     }
+     printf("----------end------------\n");
+     map_error.clear();

pkgs/by-name/sr/srt-live-server/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  srt,
+  zlib,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srt-live-server";
+  version = "1.4.8";
+
+  src = fetchFromGitHub {
+    owner = "Edward-Wu";
+    repo = "srt-live-server";
+    rev = "V${version}";
+    sha256 = "0x48sxpgxznb1ymx8shw437pcgk76ka5rx0zhn9b3cyi9jlq1yld";
+  };
+
+  patches = [
+    # https://github.com/Edward-Wu/srt-live-server/pull/94
+    ./fix-insecure-printfs.patch
+
+    # https://github.com/Edward-Wu/srt-live-server/pull/127  # adds `#include <ctime>`
+    ./add-ctime-include.patch
+  ];
+
+  buildInputs = [
+    srt
+    zlib
+  ];
+
+  makeFlags = [
+    "PREFIX=$(out)"
+  ];
+
+  meta = with lib; {
+    description = "Open-source low latency livestreaming server, based on Secure Reliable Tranport (SRT)";
+    license = licenses.mit;
+    homepage = "https://github.com/Edward-Wu/srt-live-server";
+    maintainers = with maintainers; [ shamilton ];
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/sr/srt-to-vtt-cl/fix-validation.patch

@@ -0,0 +1,13 @@
+--- a/Makefile
++++ b/Makefile
+@@ -1,9 +1,4 @@
+-ERR = $(shell which clang++ >/dev/null; echo $$?)
+-ifeq "$(ERR)" "0"
+-	CXX ?= clang++
+-else
+-	CXX ?= g++
+-endif
++CXX ?= g++
+ CXXFLAGS = -std=c++11 -O2 -MMD -I ./deps
+ OBJECTS := src/text_encoding_detect.o src/Utils.o src/Converter.o src/main.o
+ DEPENDS := $(OBJECTS:.o=.d)

pkgs/by-name/sr/srt-to-vtt-cl/package.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+
+stdenv.mkDerivation {
+  pname = "srt-to-vtt-cl";
+  version = "unstable-2019-01-03";
+
+  src = fetchFromGitHub {
+    owner = "nwoltman";
+    repo = "srt-to-vtt-cl";
+    rev = "ce3d0776906eb847c129d99a85077b5082f74724";
+    sha256 = "0qxysj08gjr6npyvg148llmwmjl2n9cyqjllfnf3gxb841dy370n";
+  };
+
+  patches = [
+    ./fix-validation.patch
+    ./simplify-macOS-builds.patch
+  ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp bin/srt-vtt $out/bin
+  '';
+
+  meta = with lib; {
+    description = "Convert SRT files to VTT";
+    license = licenses.mit;
+    maintainers = with maintainers; [ ericdallo ];
+    homepage = "https://github.com/nwoltman/srt-to-vtt-cl";
+    platforms = platforms.unix;
+    mainProgram = "srt-vtt";
+  };
+}

pkgs/by-name/sr/srt-to-vtt-cl/simplify-macOS-builds.patch

@@ -0,0 +1,31 @@
+From be08356f421825d3d2dd7ab687f86d9981a31f9a Mon Sep 17 00:00:00 2001
+From: "Travis A. Everett" <travis.a.everett@gmail.com>
+Date: Thu, 3 Aug 2023 20:15:40 -0500
+Subject: [PATCH] simplify macOS builds
+
+---
+ Makefile | 8 +-------
+ 1 file changed, 1 insertion(+), 7 deletions(-)
+
+diff --git a/Makefile b/Makefile
+index 6dfd829..19c3ae3 100644
+--- a/Makefile
++++ b/Makefile
+@@ -8,13 +8,7 @@ CXXFLAGS = -std=c++11 -O2 -MMD -I ./deps
+ OBJECTS := src/text_encoding_detect.o src/Utils.o src/Converter.o src/main.o
+ DEPENDS := $(OBJECTS:.o=.d)
+ EXEC = srt-vtt
+-UNAME_S := $(shell uname -s)
+-ifeq ($(UNAME_S), Darwin)
+-	BIN_DIR = bin/Mac-OSX
+-else
+-	UNAME_M := $(shell uname -m)
+-	BIN_DIR = bin/$(UNAME_S)/$(UNAME_M)
+-endif
++BIN_DIR = bin
+ EXEC_PATH = $(BIN_DIR)/$(EXEC)
+ 
+ .PHONY: test
+-- 
+2.39.0
+

pkgs/by-name/sr/srt/no-msvc-compat-headers.patch

@@ -0,0 +1,10 @@
+--- srt-1.3.2/common/filelist_win32.maf.orig	2018-06-15 21:44:11.000000000 +0200
++++ srt-1.3.2/common/filelist_win32.maf	2018-09-25 20:26:36.903688700 +0200
+@@ -4,7 +4,6 @@
+ #
+ # These are included by platform_sys.h header contained in ../srtcore/filelist.maf
+ #
+-win/unistd.h
+ 
+ SOURCES
+ win_time.cpp

pkgs/by-name/sr/srt/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  cmake,
+  openssl,
+  windows,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "srt";
+  version = "1.5.4";
+
+  src = fetchFromGitHub {
+    owner = "Haivision";
+    repo = "srt";
+    rev = "v${version}";
+    sha256 = "sha256-NLy9GuP4OT/kKAIIDXSHtsmaBzXRuFohFM/aM+46cao=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    openssl
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isMinGW [
+    windows.pthreads
+  ];
+
+  patches = [
+    # Fix the build with CMake 4.
+    (fetchpatch {
+      name = "srt-fix-cmake-4.patch";
+      url = "https://github.com/Haivision/srt/commit/0def1b1a1094fc57752f241250e9a1aed71bbffd.patch";
+      hash = "sha256-dnBGNut+I9trkQzr81Wo36O2Pt7d2gsjA1buJBegPMM=";
+    })
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isMinGW [
+    ./no-msvc-compat-headers.patch
+  ];
+
+  cmakeFlags = [
+    # the cmake package does not handle absolute CMAKE_INSTALL_INCLUDEDIR correctly
+    # (setting it to an absolute path causes include files to go to $out/$out/include,
+    #  because the absolute path is interpreted with root at $out).
+    "-DCMAKE_INSTALL_INCLUDEDIR=include"
+    "-DENABLE_SHARED=${if stdenv.hostPlatform.isStatic then "OFF" else "ON"}"
+    # TODO Remove this when https://github.com/Haivision/srt/issues/538 is fixed and available to nixpkgs
+    # Workaround for the fact that srt incorrectly disables GNUInstallDirs when LIBDIR is specified,
+    # see https://github.com/NixOS/nixpkgs/pull/54463#discussion_r249878330
+    "-UCMAKE_INSTALL_LIBDIR"
+  ];
+
+  meta = with lib; {
+    description = "Secure, Reliable, Transport";
+    homepage = "https://github.com/Haivision/srt";
+    license = licenses.mpl20;
+    maintainers = with maintainers; [ nh2 ];
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/sr/srtp/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  libpcap,
+  meson,
+  ninja,
+  openssl,
+  pkg-config,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libsrtp";
+  version = "2.7.0";
+
+  src = fetchFromGitHub {
+    owner = "cisco";
+    repo = "libsrtp";
+    rev = "v${version}";
+    sha256 = "sha256-5AFsigie3YUrfvZYEIopjBJSNdoKoFlMBP9lv68+f6Q=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    libpcap
+    openssl
+  ];
+
+  # rtpw tests hang
+  preConfigure = ''
+    rm test/rtpw_test.sh \
+       test/rtpw_test_gcm.sh
+  '';
+
+  mesonFlags = [
+    "-Dcrypto-library=openssl"
+    "-Dcrypto-library-kdf=disabled"
+    "-Ddoc=disabled"
+    "-Dtests=${if doCheck then "enabled" else "disabled"}"
+  ];
+
+  doCheck = true;
+
+  meta = with lib; {
+    homepage = "https://github.com/cisco/libsrtp";
+    description = "Secure RTP (SRTP) Reference Implementation";
+    license = licenses.bsd3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ r-burns ];
+  };
+}

pkgs/by-name/sr/srtrelay/package.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  srt,
+  ffmpeg,
+}:
+
+buildGoModule rec {
+  pname = "srtrelay";
+  version = "1.4.0";
+
+  src = fetchFromGitHub {
+    owner = "voc";
+    repo = "srtrelay";
+    rev = "v${version}";
+    sha256 = "sha256-idWAJD6dvvM5OHox5+MI8q3knyl2ANqBiXfQ0VlF67Q=";
+  };
+
+  vendorHash = "sha256-a4Efva0nWeyHjftuky76znbHOrZYXaIVENKbHK9xnb8=";
+
+  buildInputs = [ srt ];
+  nativeCheckInputs = [ ffmpeg ];
+
+  meta = with lib; {
+    description = "Streaming-Relay for the SRT-protocol";
+    homepage = "https://github.com/voc/srtrelay";
+    license = licenses.mit;
+    maintainers = with maintainers; [ fpletz ];
+    mainProgram = "srtrelay";
+  };
+}