push sheeet

pkgs/by-name/sx/sx-go/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  fetchpatch,
+  libpcap,
+}:
+
+buildGoModule rec {
+  pname = "sx-go";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "v-byte-cpu";
+    repo = "sx";
+    rev = "v${version}";
+    sha256 = "sha256-HTIzA1QOVn3V/hGUu7wLIYUNYmcJ/FXi2yr6BGRizZA=";
+  };
+
+  vendorHash = "sha256-TWRMNt6x8zuvhP1nz4R6IVCX+9HityvVpzxRhDiMyO4=";
+
+  patches = [
+    # Fix darwin builds: https://github.com/v-byte-cpu/sx/pull/120
+    (fetchpatch {
+      name = "non-linux-method-signature.patch";
+      url = "https://github.com/v-byte-cpu/sx/commit/56457bfaa49eb6fbb7a33d7092d9c636b9c85895.patch";
+      hash = "sha256-0lCu3tZ0fEiC7qWfk1APLVwwrK9eovbVa/yG7OuXEWQ=";
+    })
+  ];
+
+  buildInputs = [
+    libpcap
+  ];
+
+  postFixup = ''
+    # Rename binary to avoid conflict with sx
+    mv $out/bin/sx $out/bin/${pname}
+  '';
+
+  meta = with lib; {
+    description = "Command-line network scanner";
+    homepage = "https://github.com/v-byte-cpu/sx";
+    license = licenses.mit;
+    maintainers = with maintainers; [ fab ];
+    mainProgram = "sx-go";
+  };
+}

pkgs/by-name/sx/sx/package.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  makeDesktopItem,
+  patsh,
+  coreutils,
+  xorg,
+  nixosTests,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "sx";
+  version = "3.0";
+
+  src = fetchFromGitHub {
+    owner = "earnestly";
+    repo = "sx";
+    rev = finalAttrs.version;
+    hash = "sha256-hKoz7Kuus8Yp7D0F05wCOQs6BvV0NkRM9uUXTntLJxQ=";
+  };
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  nativeBuildInputs = [ patsh ];
+
+  buildInputs = [
+    coreutils # needed for cross
+    xorg.xauth
+    xorg.xorgserver
+  ];
+
+  postInstall = ''
+    patsh -f $out/bin/sx -s ${builtins.storeDir} --path "$HOST_PATH"
+
+    install -Dm755 -t $out/share/xsessions ${
+      makeDesktopItem {
+        name = "sx";
+        desktopName = "sx";
+        comment = "Start a xorg server";
+        exec = "sx";
+      }
+    }/share/applications/sx.desktop
+  '';
+
+  passthru = {
+    providedSessions = [ "sx" ];
+    tests = {
+      inherit (nixosTests) sx;
+    };
+  };
+
+  meta = {
+    description = "Simple alternative to both xinit and startx for starting a Xorg server";
+    homepage = "https://github.com/earnestly/sx";
+    license = lib.licenses.mit;
+    mainProgram = "sx";
+    maintainers = with lib.maintainers; [
+      figsoda
+      thiagokokada
+    ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/sx/sxcs/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  xorg,
+  installShellFiles,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  name = "sxcs";
+  version = "1.1.0";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "NRK";
+    repo = "sxcs";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-rYmbbdZjeLCvGvNocI3+KVU2KBkYvRisayTyScTRay8=";
+  };
+
+  buildInputs = [
+    xorg.libX11
+    xorg.libXcursor
+  ];
+  nativeBuildInputs = [ installShellFiles ];
+
+  buildPhase = ''
+    runHook preBuild
+    ${stdenv.cc.targetPrefix}cc -o sxcs sxcs.c -O3 -s -l X11 -l Xcursor
+    runHook postBuild
+  '';
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 sxcs -t $out/bin
+    installManPage sxcs.1
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Minimal X11 Color Picker and Magnifier";
+    homepage = "https://codeberg.org/NRK/sxcs";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/sx/sxhkd/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  asciidoc,
+  libxcb,
+  xcbutil,
+  xcbutilkeysyms,
+  xcbutilwm,
+  nixosTests,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "sxhkd";
+  version = "0.6.3";
+
+  src = fetchFromGitHub {
+    owner = "baskerville";
+    repo = "sxhkd";
+    rev = finalAttrs.version;
+    hash = "sha256-kbjbTzYL2dz/RpG+SgBYy+XS3W9PBEWkg6ocqAFG3VQ=";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+    "man"
+  ];
+
+  nativeBuildInputs = [
+    asciidoc
+  ];
+
+  buildInputs = [
+    libxcb
+    xcbutil
+    xcbutilkeysyms
+    xcbutilwm
+  ];
+
+  strictDeps = true;
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  passthru.tests = {
+    inherit (nixosTests) startx;
+  };
+
+  meta = {
+    description = "Simple X hotkey daemon";
+    homepage = "https://github.com/baskerville/sxhkd";
+    license = lib.licenses.bsd2;
+    mainProgram = "sxhkd";
+    maintainers = with lib.maintainers; [
+      vyp
+      ncfavier
+    ];
+    inherit (libxcb.meta) platforms;
+  };
+})